CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.0.99-dev-20100315"
   8     CACHE STRING "Gromacs version string")
   9
  10 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  11 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  12
  13 if(NOT CMAKE_BUILD_TYPE)
  14     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  15 endif(NOT CMAKE_BUILD_TYPE)
  16
  17
  18 ########################################################################
  19 # User input options                                                   #
  20 ########################################################################
  21 option(GMX_DOUBLE "Use double precision" OFF)
  22 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  23 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" ON)
  24 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  25 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  26 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  27 set(GMX_ACCELERATION "none"
  28     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  29
  30 set(GMX_FFT_LIBRARY "fftw3"
  31     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  32 option(GMX_DISABLE_FFTW_MEASURE
  33        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  34 set(GMX_QMMM_PROGRAM "none"
  35     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  36 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  37 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  38 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  39 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  40 mark_as_advanced(GMX_MPI_IN_PLACE)
  41
  42 enable_language(C)
  43
  44 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  45 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  46 option(USE_VERSION_H "Generate development version string/information" ON)
  47 option(GMX_DISABLE_GCC41_CHECK "Disable check for (buggy) gcc 4.1.x" OFF)
  48
  49 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries.")
  50
  51
  52 #######################################################################
  53 # Check for options incompatible with OpenMM build                    #
  54 #######################################################################
  55 if(GMX_OPENMM)
  56     cmake_minimum_required(VERSION 2.6.4)
  57     # we'll use the built-in fft to avoid unnecessary dependencies
  58     set (GMX_FFT_LIBRARY "fftpack")
  59     if(GMX_MPI)
  60         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
  61     endif(GMX_MPI)
  62     if(GMX_THREADS)
  63         message(STATUS "Threads not compatible with OpenMM build, disabled")
  64         set(GMX_THREADS OFF)
  65     endif(GMX_THREADS)
  66     if(GMX_SOFTWARE_INVSQRT)
  67         set(GMX_SOFTWARE_INVSQRT OFF)
  68     endif(GMX_SOFTWARE_INVSQRT)
  69     if(NOT GMX_ACCELERATION MATCHES "none|None|NONE" OR NOT ${GMX_ACCELERATION} STREQUAL "")
  70         message(WARNING "The OpenMM build does not support other acceleration modes!")
  71         set(GMX_ACCELERATION "none")
  72     endif()
  73     if(GMX_FAHCORE)
  74         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
  75     endif(GMX_FAHCORE)
  76 endif(GMX_OPENMM)
  77
  78
  79 ########################################################################
  80 # Fix stupid flags on MSVC
  81 ########################################################################
  82 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  84     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  85     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  86     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  87 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  88
  89 set(GMX_EXTRA_LIBRARIES)
  90
  91 ########################################################################
  92 #Process MPI settings
  93 ########################################################################
  94 if(GMX_MPI)
  95     if(GMX_THREADS)
  96         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  97         set(GMX_THREADS OFF CACHE BOOL
  98             "Thread-based parallelization conflicts with MPI." FORCE)
  99     endif(GMX_THREADS)
 100     find_package(MPI)
 101     if(MPI_FOUND)
 102         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 103         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 104
 105         include_directories(${MPI_INCLUDE_PATH})
 106         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 107         add_definitions( -DMPI ) #for FAHCORE
 108         include(gmxTestMPI_IN_PLACE)
 109         if (GMX_MPI_IN_PLACE)
 110             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 111         endif (GMX_MPI_IN_PLACE)
 112     else(MPI_FOUND)
 113         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 114     endif(MPI_FOUND)
 115     include(gmxTestCatamount)
 116     gmx_test_catamount(GMX_CRAY_XT3)
 117     if(GMX_CRAY_XT3)
 118         set(GMX_NO_SYSTEM 1)
 119         set(GMX_NO_NICE 1)
 120     endif(GMX_CRAY_XT3)
 121     set(GMX_LIB_MPI 1)
 122 endif(GMX_MPI)
 123
 124 ########################################################################
 125 # Basic system tests (standard libraries, headers, functions, types)   #
 126 ########################################################################
 127 include(CheckIncludeFiles)
 128 check_include_files(string.h     HAVE_STRING_H)
 129 check_include_files(math.h       HAVE_MATH_H)
 130 check_include_files(limits.h     HAVE_LIMITS_H)
 131 check_include_files(memory.h     HAVE_MEMORY_H)
 132 check_include_files(unistd.h     HAVE_UNISTD_H)
 133 check_include_files(pwd.h        HAVE_PWD_H)
 134 check_include_files(stdint.h     HAVE_STDINT_H)
 135 check_include_files(stdlib.h     HAVE_STDLIB_H)
 136 check_include_files(pthread.h    HAVE_PTHREAD_H)
 137 check_include_files(dirent.h     HAVE_DIRENT_H)
 138 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 139 check_include_files(regex.h      HAVE_REGEX_H)
 140 check_include_files(copyfile.h   HAVE_COPYFILE_H)
 141 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 142 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 143 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 144 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 145 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 146 # SSE support
 147 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 148 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 149 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 150 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 151 check_include_files(io.h                 HAVE_IO_H)
 152
 153
 154 include(CheckFunctionExists)
 155 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 156 check_function_exists(strdup            HAVE_STRDUP)
 157 check_function_exists(vprintf           HAVE_VPRINTF)
 158 check_function_exists(memcmp            HAVE_MEMCMP)
 159 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 160 check_function_exists(memalign          HAVE_MEMALIGN)
 161 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 162 check_function_exists(isnan             HAVE_ISNAN)
 163 check_function_exists(_isnan            HAVE__ISNAN)
 164 check_function_exists(isfinite          HAVE_ISFINITE)
 165 check_function_exists(_isfinite         HAVE__ISFINITE)
 166 check_function_exists(fsync             HAVE_FSYNC)
 167 check_function_exists(_fileno           HAVE__FILENO)
 168 check_function_exists(fileno            HAVE_FILENO)
 169 check_function_exists(_commit           HAVE__COMMIT)
 170 check_function_exists(copyfile          HAVE_COPYFILE)
 171 # check_function_exists(CopyFile          HAVE_WIN_COPYFILE)
 172 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 173
 174 include(CheckLibraryExists)
 175 check_library_exists(m sqrt "" HAVE_LIBM)
 176 check_library_exists(m cbrt "" HAVE_CBRT)
 177
 178 include(CheckTypeSize)
 179 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 180 check_type_size("int"           SIZEOF_INT)
 181 check_type_size("long int"      SIZEOF_LONG_INT)
 182 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 183 check_type_size("off_t"         SIZEOF_OFF_T)
 184 check_type_size("void *"        SIZEOF_VOIDP)
 185
 186 if (SIZEOF_VOIDP LESS 8)
 187     set(GMX_64_BIT FALSE)
 188 else (SIZEOF_VOIDP LESS 8)
 189     set(GMX_64_BIT TRUE)
 190 endif (SIZEOF_VOIDP LESS 8)
 191
 192 # Check for some basic types that we *need*, so set these to int if they are not present
 193 check_type_size(uid_t uid_t)
 194 if(NOT uid_t)
 195   set(uid_t int)
 196 else(NOT uid_t)
 197   set(uid_t 0)
 198 endif(NOT uid_t)
 199
 200 check_type_size(gid_t gid_t)
 201 if(NOT gid_t)
 202   set(gid_t 1)
 203 else(NOT gid_t)
 204   set(gid_t 0)
 205 endif(NOT gid_t)
 206
 207 check_type_size(size_t size_t)
 208 if(NOT size_t)
 209   set(size_t int)
 210 else(NOT size_t)
 211   set(size_t 0)
 212 endif(NOT size_t)
 213
 214 check_type_size(off_t off_t)
 215 if(NOT off_t)
 216   set(off_t int)
 217 else(NOT off_t)
 218   set(off_t 0)
 219 endif(NOT off_t)
 220
 221 include(TestBigEndian)
 222 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 223
 224
 225
 226
 227 ########################################################################
 228 # Find external packages                                               #
 229 ########################################################################
 230
 231 find_package(LibXml2)
 232 if(LIBXML2_FOUND)
 233     include_directories(${LIBXML2_INCLUDE_DIR})
 234     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 235     set(HAVE_LIBXML2 1)
 236 endif(LIBXML2_FOUND)
 237
 238 find_package(X11)
 239 # X11 includes/libraries are only set in the ngmx subdirectory!
 240 if(X11_FOUND)
 241     set(HAVE_X11 1)
 242 endif(X11_FOUND)
 243
 244 if(GMX_THREADS)
 245     include(ThreadMPI)
 246     set(THREAD_MPI_LIB thread_mpi)
 247     set(GMX_MPI 1)
 248     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 249     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 250         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 251     endif()
 252 endif(GMX_THREADS)
 253
 254 if(GMX_OPENMM)
 255     set(CUDA_BUILD_EMULATION OFF)
 256     find_package(CUDA 2.3 REQUIRED)
 257     add_definitions(-DGMX_OPENMM)
 258     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 259         set(CUDA_VERBOSE_BUILD ON)
 260     endif()
 261     find_package(OpenMM)
 262 endif(GMX_OPENMM)
 263
 264 if(APPLE)
 265    find_library(ACCELERATE_FRAMEWORK Accelerate)
 266    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 267 endif(APPLE)
 268
 269 # only bother with finding git and using version.h if the source is a git repo
 270 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 271     if(USE_VERSION_H)
 272         # We need at least git v1.5.1 be able to parse git's date output. If not
 273         # fund or the version is too small, we can't generate version information.
 274         find_package(Git 1.5.1)
 275         # this should at some point become VERSION_LESS
 276         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 277             message("No compatible git version found, won't be able to generate proper development version information.")
 278         endif()
 279     endif()
 280 else()
 281     set(USE_VERSION_H OFF)
 282 endif()
 283
 284 if (GMX_DLOPEN)
 285     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 286 endif (GMX_DLOPEN)
 287
 288 ########################################################################
 289 # Generate development version info for cache
 290 ########################################################################
 291 # set(GEN_VERSION_INFO_INTERNAL "ON")
 292 # include(gmxGenerateVersionString)
 293
 294 ########################################################################
 295 # Our own GROMACS tests
 296 ########################################################################
 297
 298 include(CheckCCompilerFlag)
 299 include(CheckCXXCompilerFlag)
 300
 301 # check for buggy GCC 4.1.x
 302 include(gmxCheckGCCVersion)
 303
 304 include(gmxCFlags)
 305 gmx_c_flags()
 306
 307 add_definitions( -DHAVE_CONFIG_H )
 308 include_directories(${CMAKE_BINARY_DIR}/src)
 309 include_directories(${CMAKE_SOURCE_DIR}/include)
 310
 311 include(gmxCheckBuildUserTime)
 312 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 313
 314 include(gmxTestFloatFormat)
 315 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 316                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 317                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 318
 319 include(gmxTestLargeFiles)
 320 gmx_test_large_files(GMX_LARGEFILES)
 321
 322 include(gmxTestSignal)
 323 gmx_test_retsigtype(RETSIGTYPE)
 324
 325 include(gmxTestInline)
 326 gmx_test_inline(INLINE_KEYWORD)
 327
 328 include(gmxTestPipes)
 329 gmx_test_pipes(HAVE_PIPES)
 330
 331 include(gmxTestInlineASM)
 332 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 333 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 334
 335 # reasonable defaults for fast binaries.
 336 if (NOT DEFINED GMX_SSE_SET)
 337     if (GMX_X86_GCC_INLINE_ASM)
 338         set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec" FORCE)
 339         if (GMX_64_BIT)
 340             set(GMX_X86_64_ASM ON CACHE BOOL
 341                 "Add SSE assembly files for x86_64" FORCE)
 342         else (GMX_64_BIT)
 343             set(GMX_IA32_ASM ON CACHE BOOL
 344                 "Add SSE assembly files for IA32" FORCE)
 345         endif (GMX_64_BIT)
 346     endif (GMX_X86_GCC_INLINE_ASM)
 347     set (GMX_SSE_SET true CACHE INTERNAL "SSE is set" FORCE)
 348 endif (NOT DEFINED GMX_SSE_SET)
 349
 350
 351
 352
 353 include(gmxTestXDR)
 354 gmx_test_xdr(GMX_SYSTEM_XDR)
 355 if(NOT GMX_SYSTEM_XDR)
 356     set(GMX_INTERNAL_XDR 1)
 357 endif(NOT GMX_SYSTEM_XDR)
 358
 359 if(GMX_FORTRAN OR GMX_POWER6)
 360     enable_language(Fortran)
 361     include(FortranCInterface)
 362     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 363     if(extra_under_score)
 364         set(extrasuffix "_")
 365     endif(extra_under_score)
 366
 367     if(isupper)
 368         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 369         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 370     else(isupper)
 371         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 372         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 373     endif(isupper)
 374 else(GMX_FORTRAN OR GMX_POWER6)
 375         set(F77_FUNCDEF   "name ## _")
 376         set(F77_FUNCDEF_  "name ## _")
 377 endif(GMX_FORTRAN OR GMX_POWER6)
 378
 379
 380 # Process nonbonded accelerated kernels settings
 381 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 382 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 383 if(${GMX_ACCELERATION} STREQUAL "NONE")
 384   # nothing to do
 385 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 386     if (NOT GMX_64_BIT)
 387         # for 32-bit compiles, we might need to turn on sse
 388         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 389         if (XFLAGS_SSE)
 390             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 391         endif (XFLAGS_SSE)
 392         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 393         if (XXFLAGS_SSE)
 394             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 395         endif (XXFLAGS_SSE)
 396     endif (NOT GMX_64_BIT)
 397     if(HAVE_XMMINTRIN_H)
 398         if(GMX_IA32_ASM)
 399           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 400           set(GMX_IA32_SSE 1)
 401         else(GMX_IA32_ASM) #only use intrinsic if not using the ASM loops
 402           set(GMX_SSE 1)
 403         endif(GMX_IA32_ASM)
 404     endif(HAVE_XMMINTRIN_H)
 405     if(HAVE_EMMINTRIN_H)
 406         if(GMX_X86_64_ASM)
 407           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 408           set(GMX_X86_64_SSE 1)
 409         else(GMX_X86_64_ASM)  #only use intrinsic if not using the ASM loops
 410           if(NOT GMX_IA32_ASM)
 411             set(GMX_SSE2 1)
 412           endif(NOT GMX_IA32_ASM)
 413         endif(GMX_X86_64_ASM)
 414     endif(HAVE_EMMINTRIN_H)
 415 #    if(HAVE_PMMINTRIN_H)
 416 #        set(GMX_SSE3 1)
 417 #    endif(HAVE_PMMINTRIN_H)
 418 #    if(HAVE_SMMINTRIN_H)
 419 #        set(GMX_SSE4_1 1)
 420 #    endif(HAVE_SMMINTRIN_H)
 421
 422 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 423     set(GMX_FORTRAN 1)
 424 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 425     set(GMX_BLUEGENE 1)
 426 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 427     set(GMX_POWER6 1)
 428 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 429     set(GMX_IA64_ASM 1)
 430     set(DISABLE_WATERWATER_NLIST 1)
 431     set(DISABLE_WATER_NLIST 1)
 432 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 433     check_include_files(altivec.h HAVE_ALTIVEC_H)
 434     if(HAVE_ALTIVEC_H)
 435         set(GMX_PPC_ALTIVEC 1)
 436     endif(HAVE_ALTIVEC_H)
 437 else(${GMX_ACCELERATION} STREQUAL "NONE")
 438     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 439 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 440
 441
 442
 443
 444
 445
 446
 447 # Process QM/MM Settings
 448 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 449 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 450     set(GMX_QMMM_GAUSSIAN 1)
 451 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 452     set(GMX_QMMM_MOPAC 1)
 453 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 454     set(GMX_QMMM_GAMESS 1)
 455 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 456     set(GMX_QMMM_ORCA 1)
 457 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 458     # nothing to do
 459 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 460     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 461 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 462
 463 # Process FFT library settings - if not OpenMM build
 464 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 465 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 466 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 467     if(GMX_DOUBLE)
 468         find_package(FFTW3 REQUIRED)
 469     else(GMX_DOUBLE)
 470         find_package(FFTW3F REQUIRED)
 471     endif(GMX_DOUBLE)
 472
 473     if(NOT FFTW3_FOUND)
 474         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 475     endif(NOT FFTW3_FOUND)
 476
 477     set(GMX_FFT_FFTW3 1)
 478     include_directories(${FFTW3_INCLUDE_DIR})
 479     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 480
 481 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 482 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 483     if(GMX_DOUBLE)
 484         find_package(FFTW2 REQUIRED)
 485     else(GMX_DOUBLE)
 486         find_package(FFTW2F REQUIRED)
 487     endif(GMX_DOUBLE)
 488
 489     if(NOT FFTW2_FOUND)
 490            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 491     endif(NOT FFTW2_FOUND)
 492     include_directories(${FFTW2_INCLUDE_DIR})
 493     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 494
 495     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 496         set(FFTW2_NAME_DFFTW 1)
 497     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 498         set(FFTW2_NAME_SFFTW 1)
 499     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 500         set(FFTW2_NAME_FFTW 1)
 501     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 502
 503     set(GMX_FFT_FFTW2 1)
 504 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 505 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 506     find_package(MKL REQUIRED)
 507     include_directories(${MKL_INCLUDE_DIR})
 508     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 509
 510     set(GMX_FFT_MKL 1)
 511     set(HAVE_MKL 1)
 512
 513 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 514 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 515 #    set(GMX_FFT_ACML 1)
 516 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 517     MESSAGE(STATUS "Using internal FFT library - fftpack")
 518     set(GMX_FFT_FFTPACK 1)
 519 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 520     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 521 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 522
 523 # MKL has BLAS/LAPACK routines
 524 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 525   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 526   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 527 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 528   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 529   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 530 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 531
 532 # Math and thread libraries must often come after all others when linking...
 533 if(HAVE_LIBM)
 534     list(APPEND GMX_EXTRA_LIBRARIES m)
 535 endif(HAVE_LIBM)
 536
 537
 538
 539 if(GMX_FAHCORE)
 540   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 541       "Path to swindirect.h")
 542   include_directories(${COREWRAP_INCLUDE_DIR})
 543 endif(GMX_FAHCORE)
 544
 545 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 546 # these are set after everything else
 547 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 548     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 549         FORCE)
 550     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 551         "Flags used by the compiler during all build types" FORCE)
 552     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 553         "Flags used by the compiler during all build types" FORCE)
 554     set(CMAKE_EXE_LINKER_FLAGS
 555         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 556         CACHE STRING "Linker flags" FORCE)
 557 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 558
 559 ########################################################################
 560 # Specify install locations and which subdirectories to process        #
 561 ########################################################################
 562 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 563 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 564 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 565 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 566
 567 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 568
 569
 570 add_subdirectory(share)
 571 add_subdirectory(include)
 572 add_subdirectory(man)
 573
 574 add_subdirectory(src)
 575
 576 ########################################################################
 577 # Tests                                                                #
 578 ########################################################################
 579
 580 enable_testing()
 581 add_test(TestBuildAll make)
 582
 583 add_subdirectory(tests)