scripts/GMXRC.csh.in

   1 # csh/tcsh configuration file for Gromacs.
   2 # First we remove previous Gromacs stuff from paths
   3 # by selecting everything else.
   4 # Removal is not 100% necessary, but very useful when we
   5 # repeatedly switch between gmx versions in a shell.
   6
   7 # zero possibly unset vars to avoid warnings
   8 if (! $?LD_LIBRARY_PATH) setenv LD_LIBRARY_PATH ""
   9 if (! $?PKG_CONFIG_PATH) setenv PKG_CONFIG_PATH ""
  10 if (! $?PATH) setenv PATH ""
  11 if (! $?MANPATH) setenv MANPATH ""
  12 if (! $?GMXLDLIB) setenv GMXLDLIB ""
  13 if (! $?GMXBIN) setenv GMXBIN ""
  14 if (! $?GMXMAN) setenv GMXMAN ""
  15
  16 # remove previous gromacs part from ld_library_path
  17 set tmppath = ""
  18 foreach i ( `echo $LD_LIBRARY_PATH | sed "s/:/ /g"` )
  19   if ( "$i" != "$GMXLDLIB" ) then
  20     if ("${tmppath}" == "") then
  21       set tmppath = "$i"
  22     else
  23       set tmppath = "${tmppath}:$i"
  24     endif
  25   endif
  26 end
  27 setenv LD_LIBRARY_PATH $tmppath
  28
  29 # remove previous gromacs part from PKG_CONFIG_PATH
  30 set tmppath = ""
  31 foreach i ( `echo $PKG_CONFIG_PATH | sed "s/:/ /g"` )
  32   if ( "$i" != "$GMXLDLIB/pkgconfig" ) set tmppath = "${tmppath}:$i"
  33 end
  34 setenv PKG_CONFIG_PATH $tmppath
  35
  36 # remove gromacs stuff from binary path
  37 set tmppath = ""
  38 foreach i ( `echo $PATH | sed "s/:/ /g"` )
  39   if ( "$i" != "$GMXBIN" ) set tmppath = "${tmppath}:$i"
  40 end
  41 setenv PATH $tmppath
  42
  43 # and remove stuff from manual path
  44 set tmppath = ""
  45 foreach i ( `echo $MANPATH | sed "s/:/ /g"` )
  46   if ( "$i" != "$GMXMAN" ) set tmppath = "${tmppath}:$i"
  47 end
  48 if ("$tmppath" == "") then
  49     set tmppath = ":"
  50 endif
  51 setenv MANPATH $tmppath
  52
  53 ##########################################################
  54 # This is the real configuration part. We save the Gromacs
  55 # things in separate vars, so we can remove them later.
  56 # If you move gromacs, change the next four line.
  57 ##########################################################
  58 setenv GMXBIN @bindir@
  59 setenv GMXLDLIB @libdir@
  60 setenv GMXMAN @mandir@
  61 setenv GMXDATA @datadir@
  62
  63 # old variables begin with ':' now, or are empty.
  64 setenv PATH ${GMXBIN}${PATH}
  65 setenv LD_LIBRARY_PATH ${GMXLDLIB}${LD_LIBRARY_PATH}
  66 setenv PKG_CONFIG_PATH ${GMXLDLIB}/pkgconfig${PKG_CONFIG_PATH}
  67 setenv MANPATH ${GMXMAN}${MANPATH}
  68
  69 setenv GMXFONT  10x20
  70
  71 # Read completions if we understand it (i.e. have tcsh)
  72 if { complete >& /dev/null } then
  73   if ( -f $GMXBIN/completion.csh ) source $GMXBIN/completion.csh
  74 endif
  75
  76
  77
  78
  79
  80
  81
  82