scripts/GMXRC.csh.cmakein

   1 # csh/tcsh configuration file for Gromacs.
   2 # First we remove previous Gromacs stuff from paths
   3 # by selecting everything else.
   4 # Removal is not 100% necessary, but very useful when we
   5 # repeatedly switch between gmx versions in a shell.
   6
   7 # zero possibly unset vars to avoid warnings
   8 if (! $?LD_LIBRARY_PATH) setenv LD_LIBRARY_PATH ""
   9 if (! $?PKG_CONFIG_PATH) setenv PKG_CONFIG_PATH ""
  10 if (! $?PATH) setenv PATH ""
  11 if (! $?MANPATH) setenv MANPATH ""
  12 if (! $?GMXLDLIB) setenv GMXLDLIB ""
  13 if (! $?GMXBIN) setenv GMXBIN ""
  14 if (! $?GMXMAN) setenv GMXMAN ""
  15
  16 # remove previous gromacs part from ld_library_path
  17 set tmppath = ""
  18 foreach i ( `echo $LD_LIBRARY_PATH | sed "s/:/ /g"` )
  19   if ( "$i" != "$GMXLDLIB" ) set tmppath = "${tmppath}:$i"
  20 end
  21 setenv LD_LIBRARY_PATH $tmppath
  22
  23 # remove previous gromacs part from PKG_CONFIG_PATH
  24 set tmppath = ""
  25 foreach i ( `echo $PKG_CONFIG_PATH | sed "s/:/ /g"` )
  26   if ( "$i" != "$GMXLDLIB/pkgconfig" ) set tmppath = "${tmppath}:$i"
  27 end
  28 setenv PKG_CONFIG_PATH $tmppath
  29
  30 # remove gromacs stuff from binary path
  31 set tmppath = ""
  32 foreach i ( `echo $PATH | sed "s/:/ /g"` )
  33   if ( "$i" != "$GMXBIN" ) set tmppath = "${tmppath}:$i"
  34 end
  35 setenv PATH $tmppath
  36
  37 # and remove stuff from manual path
  38 set tmppath = ""
  39 foreach i ( `echo $MANPATH | sed "s/:/ /g"` )
  40   if ( "$i" != "$GMXMAN" ) set tmppath = "${tmppath}:$i"
  41 end
  42 setenv MANPATH $tmppath
  43
  44 ##########################################################
  45 # This is the real configuration part. We save the Gromacs
  46 # things in separate vars, so we can remove them later.
  47 # If you move gromacs, change the next four line.
  48 ##########################################################
  49 setenv GMXBIN @BIN_INSTALL_DIR@
  50 setenv GMXLDLIB @LIB_INSTALL_DIR@
  51 setenv GMXMAN @MAN_INSTALL_DIR@
  52 setenv GMXDATA @DATA_INSTALL_DIR@
  53
  54 # old variables begin with ':' now, or are empty.
  55 setenv PATH ${GMXBIN}${PATH}
  56 setenv LD_LIBRARY_PATH ${GMXLDLIB}${LD_LIBRARY_PATH}
  57 setenv PKG_CONFIG_PATH ${GMXLDLIB}/pkgconfig${PKG_CONFIG_PATH}
  58 setenv MANPATH ${GMXMAN}${MANPATH}
  59
  60 setenv GMXFONT  10x20
  61
  62 # Read completions if we understand it (i.e. have tcsh)
  63 if { complete >& /dev/null } then
  64   if ( -f $GMXBIN/completion.csh ) source $GMXBIN/completion.csh
  65 endif
  66
  67
  68
  69
  70
  71
  72
  73