CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 project(Gromacs)
   3 set(PROJECT_VERSION "4.0.99-dev-20100305"
   4     CACHE STRING "Gromacs version string")
   5
   6 # Cmake modules/macros are in a subdirectory to keep this file cleaner
   7 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
   8
   9 ########################################################################
  10 # User input options                                                   #
  11 ########################################################################
  12 option(GMX_DOUBLE "Use double precision" OFF)
  13 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  14 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" ON)
  15 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  16 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  17 set(GMX_ACCELERATION "none"
  18     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  19
  20 set(GMX_FFT_LIBRARY "fftw3"
  21     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  22 option(GMX_DISABLE_FFTW_MEASURE
  23        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  24 set(GMX_QMMM_PROGRAM "none"
  25     CACHE STRING "QM package choices: none,gaussian,mopac,gamess")
  26 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  27 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  28 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  29 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  30 mark_as_advanced(GMX_MPI_IN_PLACE)
  31
  32 enable_language(C)
  33
  34 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  35 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  36
  37 ########################################################################
  38 # Fix stupid flags on MSVC
  39 ########################################################################
  40 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  41     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  42     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  43     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  44     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  45 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  46
  47 set(GMX_EXTRA_LIBRARIES)
  48
  49 ########################################################################
  50 #Process MPI settings
  51 ########################################################################
  52 if(GMX_MPI)
  53     if(GMX_THREADS)
  54         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  55         set(GMX_THREADS OFF CACHE BOOL
  56             "Thread-based parallelization conflicts with MPI." FORCE)
  57     endif(GMX_THREADS)
  58     find_package(MPI)
  59     if(MPI_FOUND)
  60         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  61         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  62
  63         include_directories(${MPI_INCLUDE_PATH})
  64         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  65         add_definitions( -DMPI ) #for FAHCORE
  66         include(gmxTestMPI_IN_PLACE)
  67         if (GMX_MPI_IN_PLACE)
  68             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  69         endif (GMX_MPI_IN_PLACE)
  70     else(MPI_FOUND)
  71         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
  72     endif(MPI_FOUND)
  73     include(gmxTestCatamount)
  74     gmx_test_catamount(GMX_CRAY_XT3)
  75     if(GMX_CRAY_XT3)
  76         set(GMX_NO_SYSTEM 1)
  77         set(GMX_NO_NICE 1)
  78     endif(GMX_CRAY_XT3)
  79     set(GMX_LIB_MPI 1)
  80 endif(GMX_MPI)
  81
  82 ########################################################################
  83 # Basic system tests (standard libraries, headers, functions, types)   #
  84 ########################################################################
  85 include(CheckIncludeFiles)
  86 check_include_files(string.h     HAVE_STRING_H)
  87 check_include_files(limits.h     HAVE_LIMITS_H)
  88 check_include_files(memory.h     HAVE_MEMORY_H)
  89 check_include_files(unistd.h     HAVE_UNISTD_H)
  90 check_include_files(pwd.h        HAVE_PWD_H)
  91 check_include_files(stdint.h     HAVE_STDINT_H)
  92 check_include_files(stdlib.h     HAVE_STDLIB_H)
  93 check_include_files(pthread.h    HAVE_PTHREAD_H)
  94 check_include_files(dirent.h     HAVE_DIRENT_H)
  95 check_include_files(inttypes.h   HAVE_INTTYPES_H)
  96 check_include_files(regex.h      HAVE_REGEX_H)
  97 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
  98 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
  99 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 100 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 101 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 102 # SSE support
 103 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 104 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 105 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 106 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 107
 108 include(CheckFunctionExists)
 109 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 110 check_function_exists(strdup            HAVE_STRDUP)
 111 check_function_exists(vprintf           HAVE_VPRINTF)
 112 check_function_exists(memcmp            HAVE_MEMCMP)
 113 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 114 check_function_exists(isnan             HAVE_ISNAN)
 115 check_function_exists(_isnan            HAVE__ISNAN)
 116 check_function_exists(isfinite          HAVE_ISFINITE)
 117 check_function_exists(_isfinite         HAVE__ISFINITE)
 118 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 119
 120 include(CheckLibraryExists)
 121 check_library_exists(m sqrt "" HAVE_LIBM)
 122
 123 include(CheckTypeSize)
 124 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 125 check_type_size("int"           SIZEOF_INT)
 126 check_type_size("long int"      SIZEOF_LONG_INT)
 127 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 128 check_type_size("off_t"         SIZEOF_OFF_T)
 129 check_type_size("void *"        SIZEOF_VOIDP)
 130
 131 # Check for some basic types that we *need*, so set these to int if they are not present
 132 check_type_size(uid_t uid_t)
 133 if(NOT uid_t)
 134   set(uid_t int)
 135 else(NOT uid_t)
 136   set(uid_t 0)
 137 endif(NOT uid_t)
 138
 139 check_type_size(gid_t gid_t)
 140 if(NOT gid_t)
 141   set(gid_t 1)
 142 else(NOT gid_t)
 143   set(gid_t 0)
 144 endif(NOT gid_t)
 145
 146 check_type_size(size_t size_t)
 147 if(NOT size_t)
 148   set(size_t int)
 149 else(NOT size_t)
 150   set(size_t 0)
 151 endif(NOT size_t)
 152
 153 check_type_size(off_t off_t)
 154 if(NOT off_t)
 155   set(off_t int)
 156 else(NOT off_t)
 157   set(off_t 0)
 158 endif(NOT off_t)
 159
 160 include(TestBigEndian)
 161 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 162
 163
 164
 165 ########################################################################
 166 # Find external packages                                               #
 167 ########################################################################
 168
 169 find_package(LibXml2)
 170 if(LIBXML2_FOUND)
 171     include_directories(${LIBXML2_INCLUDE_DIR})
 172     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 173     set(HAVE_LIBXML2 1)
 174 endif(LIBXML2_FOUND)
 175
 176 find_package(X11)
 177 # X11 includes/libraries are only set in the ngmx subdirectory!
 178 if(X11_FOUND)
 179     set(HAVE_X11 1)
 180 endif(X11_FOUND)
 181
 182 if(GMX_THREADS)
 183     include(ThreadMPI)
 184     set(THREAD_MPI_LIB thread_mpi)
 185     set(GMX_MPI 1)
 186     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 187     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 188         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 189     endif()
 190 endif(GMX_THREADS)
 191
 192
 193 if(APPLE)
 194    find_library(ACCELERATE_FRAMEWORK Accelerate)
 195    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 196 endif(APPLE)
 197
 198 ########################################################################
 199 # Our own GROMACS tests
 200 ########################################################################
 201
 202 include(gmxCFlags)
 203 gmx_c_flags()
 204
 205 add_definitions( -DHAVE_CONFIG_H )
 206 include_directories(${CMAKE_BINARY_DIR}/src)
 207 include_directories(${CMAKE_SOURCE_DIR}/include)
 208
 209 include(gmxCheckBuildUserTime)
 210 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 211
 212 include(gmxTestFloatFormat)
 213 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 214                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 215                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 216
 217 include(gmxTestLargeFiles)
 218 gmx_test_large_files(GMX_LARGEFILES)
 219
 220 include(gmxTestSignal)
 221 gmx_test_retsigtype(RETSIGTYPE)
 222
 223 include(gmxTestInline)
 224 gmx_test_inline(INLINE_KEYWORD)
 225
 226 include(gmxTestPipes)
 227 gmx_test_pipes(HAVE_PIPES)
 228
 229 include(gmxTestInlineASM)
 230 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 231 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 232
 233 include(gmxTestXDR)
 234 gmx_test_xdr(GMX_SYSTEM_XDR)
 235 if(NOT GMX_SYSTEM_XDR)
 236     set(GMX_INTERNAL_XDR 1)
 237 endif(NOT GMX_SYSTEM_XDR)
 238
 239 if(GMX_FORTRAN OR GMX_POWER6)
 240     enable_language(Fortran)
 241     include(FortranCInterface)
 242     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 243     if(extra_under_score)
 244         set(extrasuffix "_")
 245     endif(extra_under_score)
 246
 247     if(isupper)
 248         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 249         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 250     else(isupper)
 251         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 252         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 253     endif(isupper)
 254 else(GMX_FORTRAN OR GMX_POWER6)
 255         set(F77_FUNCDEF   "name ## _")
 256         set(F77_FUNCDEF_  "name ## _")
 257 endif(GMX_FORTRAN OR GMX_POWER6)
 258
 259
 260 # Process nonbonded accelerated kernels settings
 261 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 262 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 263 if(${GMX_ACCELERATION} STREQUAL "NONE")
 264   # nothing to do
 265 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 266     if(HAVE_XMMINTRIN_H)
 267         set(GMX_SSE 1)
 268         if(GMX_IA32_ASM)
 269           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 270           set(GMX_IA32_SSE 1)
 271         endif(GMX_IA32_ASM)
 272     endif(HAVE_XMMINTRIN_H)
 273     if(HAVE_EMMINTRIN_H)
 274         if(GMX_X86_64_ASM)
 275           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 276           set(GMX_X86_64_SSE 1)
 277         else(GMX_X86_64_ASM)  #only use intrinsic if not using the ASM loops
 278           set(GMX_SSE2 1)
 279         endif(GMX_X86_64_ASM)
 280     endif(HAVE_EMMINTRIN_H)
 281 #    if(HAVE_PMMINTRIN_H)
 282 #        set(GMX_SSE3 1)
 283 #    endif(HAVE_PMMINTRIN_H)
 284 #    if(HAVE_SMMINTRIN_H)
 285 #        set(GMX_SSE4_1 1)
 286 #    endif(HAVE_SMMINTRIN_H)
 287
 288 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 289     set(GMX_FORTRAN 1)
 290 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 291     set(GMX_BLUEGENE 1)
 292 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 293     set(GMX_POWER6 1)
 294 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 295     set(GMX_IA64_ASM 1)
 296     set(DISABLE_WATERWATER_NLIST 1)
 297     set(DISABLE_WATER_NLIST 1)
 298 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 299     check_include_files(altivec.h HAVE_ALTIVEC_H)
 300     if(HAVE_ALTIVEC_H)
 301         set(GMX_PPC_ALTIVEC 1)
 302     endif(HAVE_ALTIVEC_H)
 303 else(${GMX_ACCELERATION} STREQUAL "NONE")
 304     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 305 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 306
 307
 308
 309
 310
 311
 312
 313 # Process QM/MM Settings
 314 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 315 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 316     set(GMX_QMMM_GAUSSIAN 1)
 317 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 318     set(GMX_QMMM_MOPAC 1)
 319 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 320     set(GMX_QMMM_GAMESS 1)
 321 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 322     # nothing to do
 323 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 324     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, None")
 325 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 326
 327 # Process FFT library settings
 328 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 329 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 330 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 331     if(GMX_DOUBLE)
 332         find_package(FFTW3 REQUIRED)
 333     else(GMX_DOUBLE)
 334         find_package(FFTW3F REQUIRED)
 335     endif(GMX_DOUBLE)
 336
 337     if(NOT FFTW3_FOUND)
 338         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 339     endif(NOT FFTW3_FOUND)
 340
 341     set(GMX_FFT_FFTW3 1)
 342     include_directories(${FFTW3_INCLUDE_DIR})
 343     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 344
 345 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 346 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 347     if(GMX_DOUBLE)
 348         find_package(FFTW2 REQUIRED)
 349     else(GMX_DOUBLE)
 350         find_package(FFTW2F REQUIRED)
 351     endif(GMX_DOUBLE)
 352
 353     if(NOT FFTW2_FOUND)
 354            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 355     endif(NOT FFTW2_FOUND)
 356     include_directories(${FFTW2_INCLUDE_DIR})
 357     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 358
 359     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 360         set(FFTW2_NAME_DFFTW 1)
 361     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 362         set(FFTW2_NAME_SFFTW 1)
 363     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 364         set(FFTW2_NAME_FFTW 1)
 365     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 366
 367     set(GMX_FFT_FFTW2 1)
 368 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 369 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 370     find_package(MKL REQUIRED)
 371     include_directories(${MKL_INCLUDE_DIR})
 372     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 373
 374     set(GMX_FFT_MKL 1)
 375     set(HAVE_MKL 1)
 376
 377 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 378 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 379 #    set(GMX_FFT_ACML 1)
 380 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 381     MESSAGE(STATUS "Using internal FFT library - fftpack")
 382     set(GMX_FFT_FFTPACK 1)
 383 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 384     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 385 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 386
 387 # MKL has BLAS/LAPACK routines
 388 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 389   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 390   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 391 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 392   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 393   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 394 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 395
 396 # Math and thread libraries must often come after all others when linking...
 397 if(HAVE_LIBM)
 398     list(APPEND GMX_EXTRA_LIBRARIES m)
 399 endif(HAVE_LIBM)
 400
 401
 402
 403 if(GMX_FAHCORE)
 404   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 405       "Path to swindirect.h")
 406   include_directories(${COREWRAP_INCLUDE_DIR})
 407 endif(GMX_FAHCORE)
 408
 409 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 410 set(CMAKE_C_FLAGS ${GROMACS_C_FLAGS} CACHE STRING "Compiler flags")
 411 set(CMAKE_EXE_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} CACHE STRING "Linker flags")
 412
 413 ########################################################################
 414 # Specify install locations and which subdirectories to process        #
 415 ########################################################################
 416 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 417 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 418 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 419 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 420
 421 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 422
 423
 424 add_subdirectory(share)
 425 add_subdirectory(include)
 426 add_subdirectory(man)
 427
 428 add_subdirectory(src)
 429
 430