configure.ac

   1 #######################################################################
   2 # Process this file wth autoconf to produce a configure script.
   3 #######################################################################
   4
   5 AC_PREREQ(2.50)
   6 AC_INIT(gromacs, 4.0.99_development_20090605, [gmx-users@gromacs.org])
   7 AC_CONFIG_SRCDIR(src/gmxlib/3dview.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE(tar-ustar)
  12 AC_PREFIX_DEFAULT(/usr/local/gromacs)
  13
  14 AM_CONFIG_HEADER(src/config.h)
  15 dnl This is the version info according to the libtool versioning system.
  16 dnl It does *not* correspond to the release number.
  17 SHARED_VERSION_INFO="5:0:0"
  18 AC_SUBST(SHARED_VERSION_INFO)
  19
  20 AC_DISABLE_SHARED
  21
  22
  23 #######################################################################
  24 # Simple options and makefile variables
  25 #######################################################################
  26
  27
  28 ### Single/Double
  29 AC_ARG_ENABLE(float,
  30              [AC_HELP_STRING([--disable-float],
  31                              [Use double instead of single precision])],, enable_float=yes)
  32
  33 AC_ARG_ENABLE(double,
  34              [AC_HELP_STRING([--enable-double],
  35                              [Same effect as --disable-float])],, enable_double=no)
  36 if test "$enable_double" = "yes"; then
  37    enable_float=no;
  38 fi
  39 if test "$enable_float" = "no"; then
  40   AC_DEFINE(GMX_DOUBLE,,[Compile in double precision])
  41 fi
  42 AM_CONDITIONAL([GMX_DOUBLE],[test "$enable_float" = "no"])
  43
  44
  45
  46 ### Fortran or not
  47 AC_ARG_ENABLE(fortran,
  48              [AC_HELP_STRING([--enable-fortran],
  49                              [Use Fortran kernels])],,
  50 [case "${host_cpu}-${host_os}" in
  51   sparc*-solaris* | alpha*-* | rs6000*-aix* | powerpc*-aix* | mips*-irix*) enable_fortran=yes ;;
  52   *) enable_fortran=no ;;
  53  esac])
  54 if test "$enable_fortran" = "yes"; then
  55   AC_DEFINE(GMX_FORTRAN,,[Enable Fortran support])
  56 fi
  57 # Generic fortran kernels will be turned off below if you enable power6-specific optimization!
  58 # always use CC for linking:
  59 AC_SUBST(F77LINK,"\$(LINK)")
  60
  61
  62
  63
  64
  65 ### MPI or not
  66 AC_ARG_ENABLE(mpi,
  67               [AC_HELP_STRING([--enable-mpi],
  68                               [Compile for parallel runs using MPI])],,enable_mpi=no)
  69
  70
  71 ### MPI environment
  72 AC_ARG_ENABLE(mpi-environment,
  73               [AC_HELP_STRING([--enable-mpi-environment=VAR],
  74                               [Only start parallel runs when VAR is set])],,
  75 [case "${host_cpu}" in
  76   mips*-irix*) enable_mpi_environment="MPI_ENVIRONMENT" ;;
  77   *) enable_mpi_environment=no ;;
  78 esac])
  79 if test "$enable_mpi_environment" != "no"; then
  80   AC_DEFINE_UNQUOTED(GMX_CHECK_MPI_ENV,"$enable_mpi_environment",[If defined, only start MPI runs when this variable is set])
  81 fi
  82
  83
  84 AC_ARG_ENABLE(apple_64bit,
  85               [AC_HELP_STRING([--enable-apple-64bit],
  86                               [Build 64bit binaries for newer Macs])],,enable_apple_64bit=no)
  87
  88 AC_ARG_ENABLE(debug,
  89               [AC_HELP_STRING([--enable-debug],
  90                               [Add -g to other command line arguments])],,enable_debug=no)
  91
  92 ### IA32 assembly code
  93 AC_ARG_ENABLE(ia32_sse,
  94               [AC_HELP_STRING([--disable-ia32-sse],
  95                               [Don't build SSE/SSE2 assembly loops on ia32])],,enable_ia32_sse=yes)
  96 case "${host_cpu}-${host_vendor}" in
  97    i?86-apple)
  98       if test "$enable_apple_64bit" = "yes"; then
  99         enable_ia32_sse=no;
 100       fi
 101    ;;
 102    i?86-*) ;;
 103    *) enable_ia32_sse=no ;;
 104 esac
 105
 106 ### AMD64 assembly code
 107 AC_ARG_ENABLE(x86_64_sse,
 108               [AC_HELP_STRING([--disable-x86-64-sse],
 109                               [Don't build SSE assembly loops on X86_64])],,enable_x86_64_sse=yes)
 110 case "${host_cpu}-${host_vendor}" in
 111    x86_64-* | amd64-*) ;;
 112    i?86-apple)
 113       if test "$enable_apple_64bit" != "yes"; then
 114         enable_x86_64_sse=no;
 115       fi
 116    ;;
 117    *) enable_x86_64_sse=no ;;
 118 esac
 119
 120
 121 ### Altivec on powerpc (motorola)
 122 AC_ARG_ENABLE(ppc_altivec,
 123               [AC_HELP_STRING([--disable-ppc-altivec],
 124                               [Don't build Altivec loops on PowerPC])],,enable_ppc_altivec=undef)
 125 # Power3/4/5 running AIX does not support altivec. We identify this with vendor=IBM.
 126 # IBM powerpc 970 boxes run linux, and have vendor=unknown.
 127 if test "$enable_ppc_altivec" = "undef"; then
 128   case "${host_cpu}-${host_vendor}" in
 129     ppc*-ibm* | powerpc*-ibm*) enable_ppc_altivec=no ;;
 130     ppc*-* | powerpc*-*) enable_ppc_altivec=yes ;;
 131     *) enable_ppc_altivec=no ;;
 132   esac
 133 fi
 134
 135
 136
 137 ### ia64 assembly code
 138 AC_ARG_ENABLE(ia64_asm,
 139               [AC_HELP_STRING([--disable-ia64-asm],
 140                               [Don't build assembly loops on ia64])],,enable_ia64_asm=yes)
 141 case "${host_cpu}" in
 142    ia64) ;;
 143    *) enable_ia64_asm=no ;;
 144 esac
 145
 146
 147 # IBM Power6-specific optimization
 148 AC_ARG_ENABLE(power6,
 149              [AC_HELP_STRING([--enable-power6],
 150                              [Use IBM Pwr6/PPC440/PPC450-specific F77 kernels])],,enable_power6=no)
 151 # Turn off generic fortran loops if we are using power6-specific optimization
 152 if test "$enable_power6" = "yes"; then
 153   enable_fortran=no;
 154 fi
 155
 156 AC_ARG_ENABLE(bluegene,
 157               [AC_HELP_STRING([--enable-bluegene],
 158                               [Build assembly intrinsics kernels on bluegene])],,enable_bluegene=no)
 159
 160 ### Enable adress code, this implies GMX_CG_INNERLOOP
 161 AC_ARG_ENABLE(adress,
 162               [AC_HELP_STRING([--enable-adress],
 163                               [Build EXPERIMENTAL AdResS code, based on charged group innerloop])],
 164               [AC_DEFINE(ADRESS,,[Enable experimental AdResS innerloop])],)
 165
 166
 167 ### Optimize for host cpu version
 168 AC_ARG_ENABLE(cpu-optimization,
 169               [AC_HELP_STRING([--disable-cpu-optimization],
 170                               [No detection or tuning flags for cpu version])],, enable_cpu_optimization=yes)
 171
 172
 173 ### Do software 1/sqrt(x)
 174 AC_ARG_ENABLE(software-invsqrt,
 175               [AC_HELP_STRING([--disable-software-invsqrt],
 176                               [No software 1/sqrt (disabled on sgi,ibm,ia64)])],,
 177 [case "${host_cpu}-${host_os}" in
 178   mips*-irix* | rs6000*-aix* | powerpc*-aix | ia64*-*) enable_software_invsqrt=no ;;
 179   *) enable_software_invsqrt=yes ;;
 180 esac])
 181 if test "$enable_software_invsqrt" = "yes"; then
 182   AC_DEFINE(GMX_SOFTWARE_INVSQRT,,[Use the GROMACS software 1/sqrt(x)])
 183 fi
 184 AM_CONDITIONAL([GMX_SOFTWARE_INVSQRT],[test "$enable_software_invsqrt" = "yes"])
 185
 186 AC_ARG_ENABLE(fahcore,
 187               [AC_HELP_STRING([--enable-fahcore],
 188                               [Create a library with mdrun functionality])],, enable_fahcore=no)
 189
 190
 191
 192 # The four options below used to improve code scheduling, but the newest CPUs can usually rearrange
 193 # instructions dynamically at runtime, so they might not make much difference now:
 194
 195
 196 AC_ARG_ENABLE(all-static,
 197               [AC_HELP_STRING([--enable-all-static],
 198                               [Make completely static binaries])],, enable_all_static=no)
 199 # Dont add the -all-static flag until after the compiler test.
 200
 201
 202 # FFT libraries - only use one...
 203 AC_ARG_WITH(fft,
 204             [AC_HELP_STRING([--with-fft=@<:@fftw3/fftw2/mkl(>=6.0)/fftpack@:>@],
 205                             [FFT library to use. fftw3 is default, fftpack built in.])],,
 206                              with_fft=fftw3)
 207
 208 AC_ARG_ENABLE(fftw-measure,
 209             [AC_HELP_STRING([--disable-fftw-measure],
 210                             [Dont optimize FFTs. This produces binary exactly]
 211                             [reproducible runs (as the -reprod flag to mdrun),]
 212                             [and if you are using FFTW on x86 and specified its]
 213                             [--enable-sse/sse2 flag (NOT default in FFTW!) the]
 214                             [kernels used are close-to-optimal anyway.])],,
 215                              enable_fftw_measure=yes)
 216
 217
 218 AC_ARG_ENABLE(threads,
 219               [AC_HELP_STRING([--enable-threads],
 220                               [Compile for parallel runs using threads])],,enable_threads=no)
 221
 222 # if test "$enable_threads" = "yes"; then
 223 #   with_threads=pthreads;
 224 #fi
 225
 226
 227 ### Use external BLAS/LAPACK libraries if the user wants to.
 228 ###
 229 AC_ARG_WITH(external_blas,
 230             [AC_HELP_STRING([--with-external-blas],
 231                             [Use system BLAS library (add to LIBS). Automatic on OS X.])],,
 232 [
 233 # default action - check if we are on OS X
 234 case "${host_vendor}-${host_os}" in
 235   apple-darwin*) with_external_blas="yes" ; extra_LDFLAGS="-framework Accelerate" ;;
 236   *)             with_external_blas="no"  ;;
 237 esac
 238 ])
 239 AM_CONDITIONAL([GMX_EXTERNAL_BLAS], [test "$with_external_blas" = "yes"])
 240
 241
 242 AC_ARG_WITH(external_lapack,
 243             [AC_HELP_STRING([--with-external-lapack],
 244                             [Use system LAPACK library (add to LIBS). Automatic on OS X.])],,
 245 [
 246 # default action - check if we are on OS X
 247 case "${host_vendor}-${host_os}" in
 248   apple-darwin*) with_external_lapack="yes" ; extra_LDFLAGS="-framework Accelerate" ;;
 249   *)             with_external_lapack="no"  ;;
 250 esac
 251 ])
 252 AM_CONDITIONAL([GMX_EXTERNAL_LAPACK], [test "$with_external_lapack" = "yes"])
 253
 254
 255
 256
 257 AC_ARG_WITH(qmmm_gaussian,
 258               [AC_HELP_STRING([--without-qmmm-gaussian],
 259                               [Use modified Gaussian0x for QM-MM (see website)])],,with_qmmm_gaussian=yes)
 260 if test "$with_qmmm_gaussian" = "yes"; then
 261   AC_DEFINE(GMX_QMMM_GAUSSIAN,,[Use (modified) Gaussian0x for QM-MM calculations])
 262 fi
 263
 264
 265 AC_ARG_WITH(qmmm_gamess,
 266               [AC_HELP_STRING([--without-qmmm-gamess],
 267                               [Use modified Gamess-UK for QM-MM (see website)])],,with_qmmm_gamess=no)
 268 if test "$with_qmmm_gamess" = "yes"; then
 269   AC_DEFINE(GMX_QMMM_GAMESS,,[Use (modified) Gamess-UK for QM-MM calculations])
 270 fi
 271
 272
 273 AC_ARG_WITH(qmmm_mopac,
 274               [AC_HELP_STRING([--without-qmmm-mopac],
 275                               [Use modified Mopac 7 for QM-MM (see website)])],,with_qmmm_mopac=no)
 276 if test "$with_qmmm_mopac" = "yes"; then
 277   AC_DEFINE(GMX_QMMM_MOPAC,,[Use (modified) Mopac 7 for QM-MM calculations])
 278 fi
 279
 280
 281 ############################################################
 282 # Add some debug info: Who is building, and on what machine?
 283 ############################################################
 284 AC_DEFINE_UNQUOTED([BUILD_TIME],["`date`"],[Date and time for build])
 285 AC_DEFINE_UNQUOTED([BUILD_USER],["`whoami`@`hostname`"],[User doing build])
 286 AC_DEFINE_UNQUOTED([BUILD_MACHINE],["`uname -srm`"],[Hardware and OS version for build host])
 287
 288
 289
 290 ############################################################
 291 # Checks for programs
 292 ############################################################
 293
 294 # normally we use the default compiler, but on alpha/linux we try the compaq ones first
 295 case "${host_cpu}-${host_os}" in
 296   alpha*-linux*)
 297     cc_names="ccc cc gcc"
 298     f77_names="fort f77 g77"
 299     ;;
 300   *)
 301     cc_names="cc icc xlc gcc"
 302     f77_names="f77 ifort xlf xlf77 cf77 fl32 g77 fort77 f90 xlf90 pgf77 cf77 fort fort77 pgf90"
 303     ;;
 304 esac
 305 # the (non-mpi) c compiler, which is also used for programs executed during build stage
 306 AC_PROG_CC( $cc_names )
 307 # Check for environment variable CC_FOR_BUILD before overwriting it
 308 if test -z "$CC_FOR_BUILD"; then
 309   CC_FOR_BUILD=$CC
 310 fi
 311 AC_SUBST(CC_FOR_BUILD)
 312
 313 if test "$enable_fortran" = "yes"; then
 314   AC_PROG_F77( $f77_names )
 315   if test -z "$F77"; then
 316     AC_MSG_ERROR([No fortran compiler found])
 317   fi
 318 fi
 319
 320 AM_PROG_AS( $CC )
 321
 322 # if we are using mpi, also get an MPICC. We cannot set that in the PROG_CC macro
 323 # above, since autoconf checks that the created file can be executed. This would
 324 # fail on platforms where MPI executables can only be run through a batchqueue.
 325
 326 if test "$enable_mpi" = "yes"; then
 327   AC_CHECK_PROGS(MPICC, mpxlc mpicc mpcc hcc, $CC)
 328 # now change the normal cc to the MPI one - see the comment above.
 329   CC=$MPICC
 330   AC_MSG_CHECKING([whether the MPI cc command works]) # be paranoid
 331   AC_TRY_LINK([#include <mpi.h>],[int argc; char **argv; MPI_Init(&argc,&argv);],
 332 AC_MSG_RESULT([yes]),AC_MSG_ERROR([Cannot compile and link MPI code with $CC]))
 333   AC_DEFINE(GMX_MPI,,[Make a parallel version of GROMACS using MPI])
 334   AC_DEFINE(GMX_LIB_MPI,,[Use a real MPI library])
 335
 336 # not all MPIs support MPI_IN_PLACE:
 337   AC_MSG_CHECKING([for MPI_IN_PLACE in collective operations])
 338   AC_TRY_COMPILE([
 339 #include <mpi.h>
 340 void test(void)
 341 {
 342     void *buf;
 343     MPI_Allreduce(MPI_IN_PLACE, buf, 10, MPI_FLOAT, MPI_SUM, MPI_COMM_WORLD);
 344 }
 345 ],,[
 346   AC_MSG_RESULT([yes])
 347   AC_DEFINE(MPI_IN_PLACE_EXISTS,[],[MPI_IN_PLACE available for collective operations])
 348 ],[
 349   AC_MSG_RESULT([no])
 350 ])
 351
 352 # on the cray xt3 we have to tell autoconf that we
 353 # are actually cross-compiling even if the architecture
 354 # of host and target are the same. so we enforce
 355 # cross-compilation if __QK_USER__ is defined
 356   AC_MSG_CHECKING([for catamount])
 357   AC_TRY_COMPILE([
 358 #if defined __QK_USER__
 359 #else
 360 #error not catamount
 361 #endif
 362 ],,[
 363   AC_MSG_RESULT([yes])
 364   cross_compiling=yes
 365   AC_DEFINE(GMX_CRAY_XT3,[],[Enable special hacks for Cray XT3])
 366   AC_DEFINE(GMX_NO_SYSTEM,[],[Ignore calls to system(3)])
 367   AC_DEFINE(GMX_NO_NICE,[],[Ignore calls to nice(3)])
 368   AC_DEFINE(GMX_BROKEN_CALLOC,[],[Don't use calloc(3)])
 369   extra_LDFLAGS="$extra_LDFLAGS -lgmalloc -lacml"
 370 ],[
 371   AC_MSG_RESULT([no])
 372 ])
 373 # end of "$enable_mpi" = "yes"
 374 fi
 375
 376
 377 AH_TEMPLATE([F77_OR_C_FUNC],
 378             [Set to F77_FUNC(name,NAME) if Fortran used, otherwise 'name' for C.])
 379 AH_TEMPLATE([F77_OR_C_FUNC_],
 380             [Set to F77_FUNC_(name,NAME) if Fortran used, otherwise 'name' for C.])
 381
 382
 383
 384 if test "$enable_fortran" = "yes"; then
 385   AC_F77_LIBRARY_LDFLAGS
 386   AC_F77_WRAPPERS
 387   AC_DEFINE([F77_OR_C_FUNC(name,NAME)],[F77_FUNC(name,NAME)])
 388   AC_DEFINE([F77_OR_C_FUNC_(name,NAME)],[F77_FUNC_(name,NAME)])
 389 else
 390   AC_DEFINE([F77_OR_C_FUNC(name,NAME)],[name])
 391   AC_DEFINE([F77_OR_C_FUNC_(name,NAME)],[name])
 392 fi
 393
 394
 395
 396 AC_PROG_CPP
 397 # Needed by libtool scripts?
 398 AC_PROG_EGREP
 399
 400 if test "$enable_cpu_optimization" = "yes"; then
 401   ACX_DETECT_GMXCPU
 402 else
 403   gmxcpu=""
 404 fi
 405 ACX_COMPILER_MAXOPT
 406
 407
 408 # We've postponed the threads check because we need to check with the right
 409 # compilers/flags
 410 if test "$enable_threads" = "yes"; then
 411   if test "$enable_mpi" = "yes"; then
 412     AC_MSG_ERROR([Cannot use both threads and MPI - yet.])
 413   fi
 414   # for now we just assume pthreads
 415   ACX_PTHREAD(,AC_MSG_ERROR([Cannot find POSIX threads - required for thread    support using configure!]))
 416   LIBS="$PTHREAD_LIBS $LIBS"
 417   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 418   CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 419   CC="$PTHREAD_CC "
 420   AC_DEFINE(THREAD_PTHREADS,,[Use pthreads for thread_mpi multithreading])
 421   AC_DEFINE(GMX_THREADS,,[Use threads for parallelization])
 422   AC_DEFINE(GMX_MPI,,[Make a parallel version of GROMACS using MPI])
 423   AM_CONDITIONAL(THREAD_PARALLEL,true)
 424 else
 425   AM_CONDITIONAL(THREAD_PARALLEL,false)
 426 fi
 427
 428
 429
 430 #############
 431 # Check integer endian
 432 #############
 433 AC_C_BIGENDIAN([AC_DEFINE([GMX_INTEGER_BIG_ENDIAN],,[Integer byte order is big endian.])],[],[
 434 AC_MSG_ERROR([Cannot determine endian in compiled output])])
 435 # Little endian implied if GMX_INTEGER_BIG_ENDIAN not defined in source.
 436
 437 #############
 438 # Make sure size_t can hold pointers.
 439 # On some Nec machines, you reportedly need to specify a flag for size_t to be 64 bits wide.
 440 #############
 441 AC_MSG_CHECKING([that size_t can hold pointers])
 442 AC_TRY_COMPILE([
 443 #include <stdlib.h>
 444 #include <stddef.h>
 445 ],[int chk[sizeof(size_t)-sizeof(int *)+1];],AC_MSG_RESULT([yes]),[
 446    AC_MSG_ERROR([size_t is smaller than int*. Check if your compiler needs a flag to make it 64 bit.])])
 447
 448
 449 #############
 450 # Check that SIGUSR1 is defined
 451 #############
 452 AC_MSG_CHECKING([for SIGUSR1])
 453 AC_TRY_COMPILE([#include <signal.h>],[int i=SIGUSR1;],[
 454 AC_MSG_RESULT([yes])
 455 AC_DEFINE(HAVE_SIGUSR1,,[SIGUSR1 supported and defined])
 456 ],AC_MSG_RESULT([no]))
 457
 458 #############
 459 # Check if pipes are supported
 460 #############
 461 AC_MSG_CHECKING([for pipes])
 462 AC_TRY_COMPILE([#include <stdio.h>],[
 463 FILE *pipe=popen("/tmp/pipe","r");
 464 ],[
 465 AC_MSG_RESULT([yes])
 466 AC_DEFINE(HAVE_PIPES,,[Pipes (popen/pclose) supported])
 467 ],AC_MSG_RESULT([no]))
 468
 469
 470
 471 #############
 472 # Check floating-point format and endian
 473 #############
 474 ACX_FLOAT_FORMAT
 475
 476
 477 AC_PROG_INSTALL
 478 AC_PROG_LN_S
 479 AC_PROG_MAKE_SET
 480 AC_LIBTOOL_WIN32_DLL
 481 AC_PROG_LIBTOOL
 482 AC_SYS_LARGEFILE
 483 #
 484 # Use our own version of AC_FUNC_FSEEKO from autoconf 2.63 instead
 485 # of the broken one we might get from autoconf 2.61.
 486 ACX_FUNC_FSEEKO_FIXED
 487
 488
 489
 490
 491 ############################################################################
 492 # Checks for libraries.
 493 ############################################################################
 494 #
 495 # Don't add math library for intel compilers
 496 if $CC -V 2>&1 | grep 'Intel Corporation' > /dev/null 2>&1; then
 497   AC_MSG_NOTICE([Using built-in math library with intel compiler])
 498 else
 499   AC_CHECK_LIB(m,sqrt,,AC_MSG_ERROR([No math library found]))
 500 fi
 501
 502 #####
 503 # Disable MASS support for now.
 504 #####
 505
 506
 507 case "$with_fft" in
 508 fftw2)
 509   if test "$enable_float" = "yes"; then
 510     sizeof_real=4
 511   else
 512     sizeof_real=8
 513   fi
 514   ACX_CHECK_FFTW2(fftw,$sizeof_real)
 515   ACX_CHECK_FFTW2(rfftw,$sizeof_real)
 516
 517   case ${ac_fftw_savedprefix} in
 518    d) AC_DEFINE(FFTW2_NAME_DFFTW,,[Use the d prefix on fftw2 includes]) ;;
 519    s) AC_DEFINE(FFTW2_NAME_SFFTW,,[Use the s prefix on fftw2 includes]) ;;
 520    *) AC_DEFINE(FFTW2_NAME_FFTW,,[Dont use any prefix on fftw2 includes]) ;;
 521   esac
 522
 523   AC_DEFINE(GMX_FFT_FFTW2,,[Use FFTW2 FFT library])
 524
 525   ;; #  end of fftw2 check
 526
 527 fftw3) # Much simpler check than fftw2
 528 # Check for header <fftw3.h> AC_CHECK_HEADERS doesnt work, since we must
 529 # use mpicc to get includes - cpp isnt always the same compiler.
 530 AC_MSG_CHECKING([for fftw3.h])
 531 AC_TRY_COMPILE([#include<fftw3.h>],,[
 532 # ok, look for library file too
 533 AC_MSG_RESULT(yes)
 534 if test "$enable_float" = "yes"; then
 535   AC_CHECK_LIB([fftw3f],main,,AC_MSG_ERROR([Cannot find fftw3f library]))
 536 else
 537   AC_CHECK_LIB([fftw3],main,,AC_MSG_ERROR([Cannot find fftw3 library]))
 538 fi
 539   AC_DEFINE(GMX_FFT_FFTW3,,[Use FFTW3 FFT library])
 540 ],[
 541 # not ok, echo a warning
 542 AC_MSG_ERROR(
 543 [Cannot find the default external FFT library (fftw3).
 544 Other alternatives are 'fftw2', or 'mkl' for Intel MKL.
 545 You are STRONGLY recommended to use one of these - fftw is free.
 546
 547 Use CPPFLAGS and LDFLAGS if the library is installed in a
 548 non-standard location. (see FAQ at http://www.gromacs.org)
 549
 550 If you dont care about performance you can also specify 'fftpack'
 551 to use a slower set of FFTs built into Gromacs.
 552 (Just install FFTW3 unless you really know what you are doing).
 553 ])
 554 ])
 555   ;;
 556
 557 mkl*)
 558 ###########
 559 # Intel Math Kernel Library version 6 and later.
 560 ##########
 561 AC_MSG_CHECKING([for mkl_dfti.h])
 562 AC_TRY_COMPILE([#include<mkl_dfti.h>],,AC_MSG_RESULT(yes),AC_MSG_ERROR([Cannot find mkl_dfti.h header from Intel Math Kernel Library>=6.0.]\
 563 ))
 564 ## Check for library
 565 #  AC_CHECK_LIB([guide],main,,AC_MSG_ERROR([Cannot find libguide (Intel MKL)]))
 566   AC_CHECK_LIB([mkl],DftiComputeForward,,
 567     AC_MSG_ERROR([Cannot find Intel Math Kernel Library >= 6.0]))
 568
 569   AC_DEFINE(GMX_FFT_MKL,,[Use Intel MKL FFT library])
 570   ;;
 571
 572 fftpack | no)
 573   AC_MSG_WARN([The built-in FFTPACK routines are slow.
 574 Are you sure you don't want to use FFTW? It is free and much faster...])
 575   AC_DEFINE(GMX_FFT_FFTPACK,,[Use Built-in FFTPACK FFT library])
 576   ;;
 577 *)
 578   AC_MSG_ERROR([Unknown FFT library])
 579   ;;
 580 esac
 581
 582
 583 if test "$enable_fftw_measure" != "yes"; then
 584    AC_DEFINE(GMX_DISABLE_FFTW_MEASURE,,[Do not optimize FFTW setups (not needed with SSE FFT kernels)])
 585 fi
 586
 587 ######
 588 # check for xtc headers
 589 case "${host_os}" in
 590 cygwin* | mingw*)   # use our own xdr stuff for cygwin/mingw
 591   ;;
 592 *)
 593   AC_CHECK_HEADERS([rpc/rpc.h])
 594   AC_CHECK_HEADERS([rpc/xdr.h],,,
 595 [#if HAVE_RPC_RPC_H
 596 # include <rpc/rpc.h>
 597 #endif
 598 ])
 599   AC_CHECK_LIB(nsl,xdr_float)
 600   AC_TRY_LINK([
 601 #if HAVE_RPC_RPC_H
 602 #include<rpc/rpc.h>
 603 #else
 604 #error NO rpc.h header
 605 #endif
 606 #if HAVE_RPC_XDR_H
 607 #include<rpc/xdr.h>
 608 #else
 609 #error No xdr.h header
 610 #endif
 611 ],[ XDR *xd; float f; xdr_float(xd,&f);],[have_xdr="yes"])
 612
 613   if test "$have_xdr" != "yes"; then
 614     AC_DEFINE(GMX_INTERNAL_XDR,,[Use our own instead of system XDR libraries])
 615     AC_MSG_WARN([Couldn't find XDR headers and/or libraries - using our own])
 616   fi
 617   ;;
 618 esac
 619
 620
 621 ########################################################################
 622 # Checks for header files and types
 623 ########################################################################
 624
 625 AC_CHECK_HEADERS([limits.h unistd.h],,AC_MSG_ERROR([Include headers not found]))
 626 AC_CHECK_HEADERS(unistd.h)
 627 AC_CHECK_HEADERS(sys/types.h)
 628 AC_CHECK_HEADERS(sys/time.h)
 629
 630 #####
 631 # Checks for additional and/or optional functions or libraries.
 632 #AC_FUNC_MALLOC
 633 AC_FUNC_MEMCMP
 634 AC_TYPE_SIGNAL
 635 AC_TYPE_OFF_T
 636 AC_FUNC_VPRINTF
 637 AM_WITH_DMALLOC
 638 AC_CHECK_FUNCS(strcasecmp)
 639 AC_CHECK_FUNCS(strdup)
 640 AC_CHECK_FUNCS(gettimeofday)
 641 AC_CHECK_FUNCS(isnan)
 642 AC_CHECK_FUNCS(_isnan)
 643
 644 # check for bool (must come late, since CFLAGS/includes might affect it)
 645 AC_CHECK_TYPES([bool])
 646
 647
 648
 649
 650
 651 #############
 652 # Check integer sizes, set to zero if e.g. long long is not supported.
 653 # (Note: this must come *after* type checks for the corresponding types!)
 654 #############
 655 AC_CHECK_SIZEOF(int)
 656 AC_CHECK_SIZEOF(long int)
 657 AC_CHECK_SIZEOF(long long int)
 658 AC_CHECK_SIZEOF(off_t)
 659 AC_CHECK_SIZEOF(void*)
 660
 661
 662
 663 #####
 664 # Look for X
 665 AC_PATH_XTRA
 666 if test "$no_x" != "yes"; then
 667   LIBS="$X_LIBS $LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 668   INCLUDES="$INCLUDES $X_CFLAGS"
 669   AM_CONDITIONAL(USE_X11,true)
 670 else
 671   AM_CONDITIONAL(USE_X11,false)
 672 fi
 673
 674 # GNU Scientific Library or not
 675 AC_ARG_WITH(gsl,
 676  [  --with-gsl                    Link to the GNU scientific library, enables extra functions in analysis],,with_gsl=no)
 677
 678 ######
 679 if test "$with_gsl" = "yes"; then
 680   ac_save_LDFLAGS="$LDFLAGS"
 681   AC_CHECK_HEADERS([gsl/gsl_version.h],[
 682 # header found, check for libraries
 683   AC_CHECK_LIB(gslcblas,main,[
 684   LDFLAGS="$ac_save_LDFLAGS -lgslcblas"
 685 # gslcblas library found, check main lib
 686   AC_CHECK_LIB(gsl,main)])])
 687 #
 688 fi
 689
 690
 691 AC_ARG_WITH(xml,
 692  [  --without-xml                 do not link to the xml2 library, disallows the use of certain file formats],,with_xml=yes)
 693
 694 #########
 695 # Check for libxml2, but it is optional, so dont stop
 696 # if it isnt there.
 697 if test "$with_xml" = "yes"; then
 698    ac_save_CPPFLAGS="$CPPFLAGS"
 699    CPPFLAGS="$ac_save_CPPFLAGS -I/usr/include/libxml2"
 700    AC_CHECK_HEADERS([libxml/parser.h],AC_CHECK_LIB(xml2,main))
 701    if test "$ac_cv_lib_xml2_main" = "yes"; then
 702      INCLUDES="$INCLUDES -I/usr/include/libxml2"
 703    fi
 704 # restore CPPFLAGS
 705    CPPFLAGS="$ac_save_CPPFLAGS"
 706 fi
 707
 708 ####
 709 # And collect the f77 libs to the linker - on Solaris, f77 stuff must go first,
 710 # and we need -L/usr/ucblib to find libucb... (stupid OS)
 711 # On e.g. ibm the mass libraries must come before -lm...
 712 case "${host_cpu}-${host_os}" in
 713   *-solaris*)
 714     LIBS="$FLIBS $LIBS"
 715     LDFLAGS="$LDFLAGS -L/usr/ucblib"
 716     ;;
 717   *) LIBS="$LIBS $FLIBS" ;;
 718 esac
 719
 720
 721 # add the Accelerate framework if enabled above.
 722 # LDFLAGS might have been set in the CPU optimization, so we cant assign it directly before that.
 723 LDFLAGS="$LDFLAGS $extra_LDFLAGS"
 724
 725
 726
 727
 728
 729
 730 #####
 731 # Checks for typedefs, structures, and compiler characteristics.
 732 AC_C_CONST
 733 AC_TYPE_SIZE_T
 734 AC_STRUCT_TM
 735 AC_C_INLINE
 736
 737 # AC_TYPE_UID_T is broken on Mac OS X, so use generic tests instead
 738 AC_CHECK_TYPES([uid_t],[],[AC_DEFINE(uid_t, int, [Define to `int' if <sys/types.h> doesn't define.])],[[#include <sys/types.h>]])
 739 AC_CHECK_TYPES([gid_t],[],[AC_DEFINE(gid_t, int, [Define to `int' if <sys/types.h> doesn't define.])],[[#include <sys/types.h>]])
 740
 741
 742 # Test stuff for ia32 and x86_64 assembly, and add objects/libraries.
 743 if test "$enable_ia32_sse" = "yes" -o "$enable_x86_64_sse" = "yes"; then
 744   AC_MSG_CHECKING([whether your compiler can handle assembly files (*.s)])
 745 #
 746 # Use 64-bit registers (rsp/rbp) on x86_64
 747 #
 748 if test "$enable_x86_64_sse" = "yes"; then
 749 cat > conftestasm.s << EOF
 750 checkasm:
 751         mov     %rsp, %rbp
 752         ret
 753 EOF
 754 else
 755 cat > conftestasm.s << EOF
 756 checkasm:
 757         movl    %esp, %ebp
 758         ret
 759 EOF
 760 fi
 761   if AC_TRY_COMMAND($CC $CFLAGS -c conftestasm.s); then
 762     if test -f conftestasm.o; then
 763       AC_MSG_RESULT([yes])
 764     else
 765       AC_MSG_RESULT([no])
 766       AC_MSG_ERROR([Upgrade your compiler (or disable assembly loops).])
 767     fi
 768   else
 769     AC_MSG_RESULT([no])
 770     AC_MSG_ERROR([Upgrade your compiler (or disable assembly loops).])
 771   fi
 772
 773 # ok, cc understands assembly.
 774 #
 775 # If we are using double precision we need SSE2
 776   if test "$enable_float" = "no"; then
 777 #   test SSE2 on ia32:
 778     if test "$enable_ia32_sse" = "yes"; then
 779       AC_MSG_CHECKING([whether as fully supports ia32 SSE2])
 780 cat > conftest.s << EOF
 781 checkasm:
 782         emms
 783         movapd 32(%esi,%edx,8),%xmm4
 784         emms
 785         ret
 786 EOF
 787       if AC_TRY_COMMAND($CC $CFLAGS -c conftest.s); then
 788         AC_MSG_RESULT([yes])
 789       else
 790         AC_MSG_RESULT([no])
 791         AC_MSG_ERROR([Upgrade to a more recent binutils (or disable assembly loops).])
 792       fi
 793       AC_DEFINE([GMX_IA32_SSE2],,[Double-precision SSE2 instructions on ia32])
 794     fi
 795 #   test SSE2 on X86_64:
 796     if test "$enable_x86_64_sse" = "yes"; then
 797       AC_MSG_CHECKING([whether as fully supports X86_64 SSE2])
 798 cat > conftest.s << EOF
 799 checkasm:
 800         emms
 801         movapd 32(%rsi,%rdx,8),%xmm4
 802         emms
 803         ret
 804 EOF
 805       if AC_TRY_COMMAND($CC $CFLAGS -c conftest.s); then
 806         AC_MSG_RESULT([yes])
 807       else
 808         AC_MSG_RESULT([no])
 809         AC_MSG_ERROR([Upgrade to a more recent binutils (or disable assembly loops).])
 810       fi
 811       AC_DEFINE([GMX_X86_64_SSE2],,[Double-precision SSE2 instructions on X86_64])
 812     fi
 813   else
 814 # end of double precision testing, now do single.
 815     if test "$enable_ia32_sse" = "yes"; then
 816       AC_MSG_CHECKING([whether as fully supports ia32 SSE])
 817 cat > conftest.s << EOF
 818 checkasm:
 819         emms
 820         movaps 32(%esi,%edx,8),%xmm4
 821         emms
 822         ret
 823 EOF
 824       if AC_TRY_COMMAND($CC $CFLAGS -c conftest.s); then
 825         AC_MSG_RESULT([yes])
 826       else
 827         AC_MSG_RESULT([no])
 828         AC_MSG_ERROR([Upgrade to a more recent binutils (or disable assembly loops).])
 829       fi
 830       AC_DEFINE([GMX_IA32_SSE],,[Single-precision SSE instructions on ia32])
 831     fi
 832 #   test SSE2 on X86_64:
 833     if test "$enable_x86_64_sse" = "yes"; then
 834       AC_MSG_CHECKING([whether as fully supports X86_64 SSE instructions])
 835 cat > conftest.s << EOF
 836 checkasm:
 837         emms
 838         movaps 32(%rsi,%rdx,8),%xmm4
 839         emms
 840         ret
 841 EOF
 842       if AC_TRY_COMMAND($CC $CFLAGS -c conftest.s); then
 843         AC_MSG_RESULT([yes])
 844       else
 845         AC_MSG_RESULT([no])
 846         AC_MSG_ERROR([Upgrade to a more recent binutils (or disable assembly loops).])
 847       fi
 848       AC_DEFINE([GMX_X86_64_SSE],,[Single-precision SSE instructions on X86_64])
 849     fi
 850   fi
 851 fi
 852
 853
 854 # Test stuff for ia64 assembly
 855 #
 856 # Nothing to test right now.
 857
 858
 859 #
 860 # Test altivec support.
 861 #
 862 if test "$enable_ppc_altivec" = "yes"; then
 863   if test "$enable_float" = "no"; then
 864     AC_MSG_WARN([PowerPC Altivec loops can only be used in single precision - disabling])
 865     enable_ppc_altivec=no
 866   else
 867     # On FSF (vanilla) GCC we must include altivec.h, and on apple we
 868     # should NOT do it after using -faltivec. Go figure...
 869     case "${host_os}" in
 870     darwin*)
 871         # do nothing on Apple systems
 872        ;;
 873     *)
 874         AC_CHECK_HEADERS([altivec.h])
 875        ;;
 876     esac
 877
 878     AC_MSG_CHECKING([whether the compiler supports altivec extensions])
 879     AC_TRY_COMPILE([],[
 880 #ifndef __VEC__
 881 choke_me
 882 #endif
 883 ],[
 884     AC_MSG_RESULT([yes])
 885     AC_DEFINE([GMX_PPC_ALTIVEC],,[Use PowerPC Altivec inner loops])],[
 886       AC_MSG_RESULT([no])
 887       AC_MSG_WARN([no altivec support found - On recent PowerPC CPUs]
 888 [you can get a huge performance gain by using an altivec-enabled compiler.]
 889 [On OS X, you need GCC>=3.3, or the IBM compilers. If you are using standard]
 890 [GCC, you need at least version 4.0])
 891       enable_ppc_altivec=no])
 892   fi
 893 fi
 894
 895 if test "$enable_ia64_asm" = "yes"; then
 896   AC_DEFINE(GMX_IA64_ASM,,[Use ia64 assembly tuned for Itanium2])
 897   AC_DEFINE(DISABLE_WATER_NLIST,,[Turn off all water neighborlist optimization])
 898   AC_DEFINE(DISABLE_WATERWATER_NLIST,,[Turn off water-water neighborlist optimization only])
 899 fi
 900
 901 if test "$enable_bluegene" = "yes"; then
 902   AC_DEFINE(GMX_BLUEGENE,,[Use assembly intrinsics kernels for BlueGene])
 903 fi
 904
 905 ##
 906 # Add the appropriate assembly loops
 907 #
 908 AM_CONDITIONAL([GMX_IA32_SSE],[test "$enable_ia32_sse" = "yes" -a "$enable_float" = "yes"])
 909 AM_CONDITIONAL([GMX_IA32_SSE2],[test "$enable_ia32_sse" = "yes" -a "$enable_float" = "no"])
 910 AM_CONDITIONAL([GMX_X86_64_SSE],[test "$enable_x86_64_sse" = "yes" -a "$enable_float" = "yes"])
 911 AM_CONDITIONAL([GMX_X86_64_SSE2],[test "$enable_x86_64_sse" = "yes" -a "$enable_float" = "no"])
 912 AM_CONDITIONAL([GMX_FORTRAN],[test "$enable_fortran" = "yes"])
 913 AM_CONDITIONAL([GMX_PPC_ALTIVEC],[test "$enable_ppc_altivec" = "yes" -a "$enable_float" = "yes"])
 914 AM_CONDITIONAL([GMX_IA64_ASM],[test "$enable_ia64_asm" = "yes"])
 915 AM_CONDITIONAL([GMX_BLUEGENE],[test "$enable_bluegene" = "yes"])
 916 AM_CONDITIONAL([GMX_POWER6],[test "$enable_power6" = "yes"])
 917
 918
 919 #############
 920 # Check integer endian
 921 #############
 922 AC_C_BIGENDIAN([AC_DEFINE([GMX_INTEGER_BIG_ENDIAN],,[Integer byte order is big endian.])],[],[
 923 AC_MSG_ERROR([Cannot determine endian in compiled output])])
 924 # Little endian implied if GMX_INTEGER_BIG_ENDIAN not defined in source.
 925
 926
 927
 928 case "${host_cpu}" in
 929    i?86)
 930          # Check if inline assembly works
 931          AC_MSG_CHECKING(if the compiler supports gcc inline assembly)
 932       AC_TRY_LINK([],[float f;int i; asm("fld %1\nfistpl %0\n" : "=m" (*&i) : "f" (f));],[AC_MSG_RESULT(yes)
 933 AC_DEFINE(GMX_X86_GCC_INLINE_ASM,,[Enable x86 gcc inline assembly])],[AC_MSG_RESULT(no)])
 934          # Check for MSVC inline assembly
 935      AC_MSG_CHECKING(if the compiler supports MSVC inline assembly)
 936       AC_TRY_LINK([],[float f;int i; _asm { fld f } ; _asm { fistpl i };],[AC_MSG_RESULT(yes)
 937 AC_DEFINE(GMX_X86_MSVC_INLINE_ASM,,[Enable x86 MSVC inline assembly])],[AC_MSG_RESULT(no)])
 938         ;;
 939    *) ;;
 940 esac
 941
 942
 943
 944
 945
 946
 947 ########################################################################
 948 # Final output stage
 949 ########################################################################
 950 AS="$CC"
 951 AC_SUBST(ASFLAGS)
 952 AC_SUBST(AS)
 953 AC_SUBST(INCLUDES)          # should be automatic, but doesnt seem to be?
 954
 955 # To tell libraries apart, we use four versions of the name. For instance, libgmx:
 956 # libgmx                single prec, no mpi.
 957 # libgmx_d              double prec, no mpi.
 958 # libgmx_mpi            single prec, mpi.
 959 # libgmx_mpi_d          double prec, mpi.
 960 # However, the non-suffixed names are linked to the _mpi and/or _d suffixed
 961 # ones upon installation if that is the only version available.
 962
 963 if test "$enable_mpi" = "yes"; then
 964   LIBSUFFIX="_mpi"
 965 fi
 966 if test "$enable_float" = "no"; then
 967   LIBSUFFIX="${LIBSUFFIX}_d"
 968 fi
 969 AC_SUBST(LIBSUFFIX)
 970
 971 # Unless the user has explicitly requested a prefix/suffix/transform, we
 972 # use _d on double precision files. Don't add anything for mpi, but at the
 973 # end we tell the user it is possible and smart to do in some cases!
 974 if test "$program_transform_name" = "s,x,x,"; then
 975   name_transform_provided=no;
 976   if test "$enable_float" = "no"; then
 977     program_transform_name="s,\$\$,_d,"
 978   fi
 979 else
 980   name_transform_provided=yes;
 981 fi
 982
 983
 984 # Use a variable for RPM - this way it can be
 985 # overridden with make RPM=rpm3 rpm
 986 RPM=rpm
 987 AC_SUBST(RPM)
 988
 989 if test "$enable_fahcore" = "yes"; then
 990   CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/../corewrap -include swindirect.h -DFULLINDIRECT -DUSE_FAH_XDR"
 991   if test "$enable_mpi" = "yes"; then
 992     CFLAGS="$CFLAGS -DMPI"
 993   fi
 994 fi
 995 AM_CONDITIONAL([GMX_FAHCORE],[test "$enable_fahcore" = "yes"])
 996
 997
 998 if test "$enable_all_static" = "yes"; then
 999   LDFLAGS="$LDFLAGS -all-static"
1000 fi
1001
1002 # we have asm source, so this is necessary for automake 1.6
1003 CCAS=$CC
1004 CCASFLAGS=$CFLAGS
1005
1006 AC_SUBST(CCAS)
1007 AC_SUBST(CCASFLAGS)
1008
1009 AC_CONFIG_FILES([ Makefile ])
1010 AC_CONFIG_FILES([ src/Makefile ])
1011 AC_CONFIG_FILES([ src/gmxlib/Makefile ])
1012 AC_CONFIG_FILES([ src/gmxlib/gmx_blas/Makefile ])
1013 AC_CONFIG_FILES([ src/gmxlib/gmx_lapack/Makefile ])
1014 AC_CONFIG_FILES([ src/gmxlib/selection/Makefile ])
1015 AC_CONFIG_FILES([ src/gmxlib/statistics/Makefile ])
1016 AC_CONFIG_FILES([ src/gmxlib/trajana/Makefile ])
1017 AC_CONFIG_FILES([ src/gmxlib/thread_mpi/Makefile ])
1018 AC_CONFIG_FILES([ src/gmxlib/nonbonded/Makefile ])
1019 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_c/Makefile ])
1020 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_ia32_sse/Makefile ])
1021 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_ia32_sse2/Makefile ])
1022 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_x86_64_sse/Makefile ])
1023 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_x86_64_sse2/Makefile ])
1024 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_ppc_altivec/Makefile ])
1025 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_ia64_single/Makefile ])
1026 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_ia64_double/Makefile ])
1027 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_bluegene/Makefile ])
1028 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_power6/Makefile ])
1029 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_f77_single/Makefile ])
1030 AC_CONFIG_FILES([ src/gmxlib/nonbonded/nb_kernel_f77_double/Makefile ])
1031 AC_CONFIG_FILES([ include/Makefile ])
1032 AC_CONFIG_FILES([ include/types/Makefile ])
1033 AC_CONFIG_FILES([ src/mdlib/Makefile ])
1034 AC_CONFIG_FILES([ src/kernel/Makefile ])
1035 AC_CONFIG_FILES([ src/tools/Makefile ])
1036 AC_CONFIG_FILES([ src/ngmx/Makefile ])
1037 AC_CONFIG_FILES([ src/contrib/Makefile ])
1038 AC_CONFIG_FILES([ scripts/Makefile ])
1039 AC_CONFIG_FILES([ admin/Makefile ])
1040 AC_CONFIG_FILES([ share/Makefile ])
1041 AC_CONFIG_FILES([ share/tutor/Makefile ])
1042 AC_CONFIG_FILES([ share/tutor/gmxdemo/Makefile ])
1043 AC_CONFIG_FILES([ share/tutor/nmr1/Makefile ])
1044 AC_CONFIG_FILES([ share/tutor/nmr2/Makefile ])
1045 AC_CONFIG_FILES([ share/tutor/water/Makefile ])
1046 AC_CONFIG_FILES([ share/tutor/mixed/Makefile ])
1047 AC_CONFIG_FILES([ share/tutor/methanol/Makefile ])
1048 AC_CONFIG_FILES([ share/tutor/speptide/Makefile ])
1049 AC_CONFIG_FILES([ share/template/Makefile ])
1050 AC_CONFIG_FILES([ share/top/Makefile ])
1051 AC_CONFIG_FILES([ share/html/Makefile ])
1052 AC_CONFIG_FILES([ share/html/images/Makefile ])
1053 AC_CONFIG_FILES([ share/html/online/Makefile ])
1054 AC_CONFIG_FILES([ man/Makefile man/man1/Makefile man/man7/Makefile ])
1055 AC_OUTPUT
1056
1057
1058
1059
1060
1061
1062
1063 #########################################################
1064 # Echo some important info, to avoid stupid mistakes
1065 #
1066
1067 if test "$enable_float" = "no" -a "$name_transform_provided" = "no"; then
1068   echo ""
1069   echo "* You are compiling a double precision version of Gromacs -"
1070   echo "  program names will be suffixed with _d to avoid overwriting single"
1071   echo "  precision files. You can override it with --program-suffix"
1072 fi
1073
1074 if test "$name_transform_provided" = "no" -a "$enable_mpi" = "yes"; then
1075   echo ""
1076   echo "* Seems you are compiling with MPI support. You can install the MPI-"
1077   echo "  enabled programs with suffixed names to have both MPI and non-MPI"
1078   echo "  versions. This is useful e.g. on supercomputers where you usually"
1079   echo "  cannot run MPI-linked programs on the login node."
1080   echo "  Set a suffix with e.g. --program-suffix=_mpi (or _mpi_d for double)."
1081   echo "  You only need MPI for mdrun, so if you already have non-MPI stuff"
1082   echo "  installed you can issue make mdrun; make install-mdrun."
1083 fi
1084
1085 if test "$host_vendor" = "apple" -a "$enable_apple_64bit" = "no"; then
1086   echo ""
1087   echo "* Did you know that you can compile a 64-bit version of Gromacs to improve"
1088   echo "  performance on recent Intel Macs? You need to install a 64-bit version"
1089   echo "  of FFTW first (add -m64 to CFLAGS, or download it from the Gromacs site)"
1090   echo "  after which you can simply specify --enable-apple-64bit to this script."
1091 fi
1092
1093 if test "$enable_shared" = "no"; then
1094   echo ""
1095   echo "* On most platforms you can save 10X space with dynamic libraries, although"
1096   echo "  the binaries might be less portable. Why not try --enable-shared ?"
1097 fi
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126