CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 set(PROJECT_VERSION "4.0.99_development_20090605"
   5     CACHE STRING "Gromacs version string")
   6
   7 # Cmake modules/macros are in a subdirectory to keep this file cleaner
   8 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
   9
  10 ########################################################################
  11 # User input options                                                   #
  12 ########################################################################
  13 option(GMX_DOUBLE "Use double precision" OFF)
  14 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  15 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" OFF)
  16 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  17 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  18 set(GMX_ACCELERATION "none"
  19     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  20
  21 set(GMX_FFT_LIBRARY "fftw3"
  22     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  23 option(GMX_DISABLE_FFTW_MEASURE
  24        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  25 set(GMX_QMMM_PROGRAM "none"
  26     CACHE STRING "QM package choices: none,gaussian,mopac,gamess")
  27 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  28 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  29
  30 enable_language(C)
  31
  32 ########################################################################
  33 # Fix stupid flags on MSVC
  34 ########################################################################
  35 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  36     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  37     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  38     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  39     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  40 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  41
  42 set(GMX_EXTRA_LIBRARIES)
  43
  44 ########################################################################
  45 #Process MPI settings
  46 ########################################################################
  47 if(GMX_MPI)
  48     if(GMX_THREADS)
  49         message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  50     endif(GMX_THREADS)
  51     find_package(MPI)
  52     if(MPI_FOUND)
  53         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  54         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  55
  56         include_directories(${MPI_INCLUDE_PATH})
  57         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  58         add_definitions( -DMPI ) #for FAHCORE
  59         include(gmxTestMPI_IN_PLACE)
  60         gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  61     else(MPI_FOUND)
  62         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
  63     endif(MPI_FOUND)
  64     include(gmxTestCatamount)
  65     gmx_test_catamount(GMX_CRAY_XT3)
  66     if(GMX_CRAY_XT3)
  67         set(GMX_NO_SYSTEM 1)
  68         set(GMX_NO_NICE 1)
  69     endif(GMX_CRAY_XT3)
  70     set(GMX_LIB_MPI 1)
  71 endif(GMX_MPI)
  72
  73 ########################################################################
  74 # Basic system tests (standard libraries, headers, functions, types)   #
  75 ########################################################################
  76 include(CheckIncludeFiles)
  77 check_include_files(string.h     HAVE_STRING_H)
  78 check_include_files(limits.h     HAVE_LIMITS_H)
  79 check_include_files(memory.h     HAVE_MEMORY_H)
  80 check_include_files(unistd.h     HAVE_UNISTD_H)
  81 check_include_files(pwd.h        HAVE_PWD_H)
  82 check_include_files(stdint.h     HAVE_STDINT_H)
  83 check_include_files(stdlib.h     HAVE_STDLIB_H)
  84 check_include_files(pthread.h    HAVE_PTHREAD_H)
  85 check_include_files(inttypes.h   HAVE_INTTYPES_H)
  86 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
  87 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
  88 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
  89 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
  90 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
  91 # SSE support
  92 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
  93 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
  94 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
  95 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
  96
  97 include(CheckFunctionExists)
  98 check_function_exists(strcasecmp        HAVE_STRCASECMP)
  99 check_function_exists(strdup            HAVE_STRDUP)
 100 check_function_exists(vprintf           HAVE_VPRINTF)
 101 check_function_exists(memcmp            HAVE_MEMCMP)
 102 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 103 check_function_exists(isnan             HAVE_ISNAN)
 104 check_function_exists(_isnan            HAVE__ISNAN)
 105 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 106
 107 include(CheckLibraryExists)
 108 check_library_exists(m sqrt "" HAVE_LIBM)
 109
 110 include(CheckTypeSize)
 111 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 112 check_type_size("int"           SIZEOF_INT)
 113 check_type_size("long int"      SIZEOF_LONG_INT)
 114 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 115 check_type_size("off_t"         SIZEOF_OFF_T)
 116 check_type_size("void *"        SIZEOF_VOIDP)
 117
 118 # Check for some basic types that we *need*, so set these to int if they are not present
 119 check_type_size(uid_t uid_t)
 120 if(NOT uid_t)
 121   set(uid_t int)
 122 else(NOT uid_t)
 123   set(uid_t 0)
 124 endif(NOT uid_t)
 125
 126 check_type_size(gid_t gid_t)
 127 if(NOT gid_t)
 128   set(gid_t 1)
 129 else(NOT gid_t)
 130   set(gid_t 0)
 131 endif(NOT gid_t)
 132
 133 check_type_size(size_t size_t)
 134 if(NOT size_t)
 135   set(size_t int)
 136 else(NOT size_t)
 137   set(size_t 0)
 138 endif(NOT size_t)
 139
 140 check_type_size(off_t off_t)
 141 if(NOT off_t)
 142   set(off_t int)
 143 else(NOT off_t)
 144   set(off_t 0)
 145 endif(NOT off_t)
 146
 147 include(TestBigEndian)
 148 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 149
 150
 151
 152 ########################################################################
 153 # Find external packages                                               #
 154 ########################################################################
 155
 156 find_package(LibXml2)
 157 if(LIBXML2_FOUND)
 158     include_directories(${LIBXML2_INCLUDE_DIR})
 159     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 160     set(HAVE_LIBXML2 1)
 161 endif(LIBXML2_FOUND)
 162
 163 find_package(X11)
 164 # X11 includes/libraries are only set in the ngmx subdirectory!
 165 if(X11_FOUND)
 166     set(HAVE_X11 1)
 167 endif(X11_FOUND)
 168
 169 if(GMX_THREADS)
 170     include(ThreadMPI)
 171     set(THREAD_MPI_LIB thread_mpi)
 172     set(GMX_MPI 1)
 173 endif(GMX_THREADS)
 174
 175
 176 if(APPLE)
 177    find_library(ACCELERATE_FRAMEWORK Accelerate)
 178    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 179 endif(APPLE)
 180
 181 ########################################################################
 182 # Our own GROMACS tests
 183 ########################################################################
 184
 185 include(gmxCFlags)
 186 gmx_c_flags()
 187
 188 add_definitions( -DHAVE_CONFIG_H )
 189 include_directories(${CMAKE_BINARY_DIR}/src)
 190 include_directories(${CMAKE_SOURCE_DIR}/include)
 191
 192 include(gmxCheckBuildUserTime)
 193 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 194
 195 include(gmxTestFloatFormat)
 196 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 197                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 198                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 199
 200 include(gmxTestLargeFiles)
 201 gmx_test_large_files(GMX_LARGEFILES)
 202
 203 include(gmxTestSignal)
 204 gmx_test_retsigtype(RETSIGTYPE)
 205 gmx_test_sigusr1(HAVE_SIGUSR1)
 206
 207 include(gmxTestInline)
 208 gmx_test_inline(INLINE_KEYWORD)
 209
 210 include(gmxTestPipes)
 211 gmx_test_pipes(HAVE_PIPES)
 212
 213 include(gmxTestInlineASM)
 214 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 215 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 216
 217 include(gmxTestXDR)
 218 gmx_test_xdr(GMX_SYSTEM_XDR)
 219 if(NOT GMX_SYSTEM_XDR)
 220     set(GMX_INTERNAL_XDR 1)
 221 endif(NOT GMX_SYSTEM_XDR)
 222
 223 if(GMX_FORTRAN OR GMX_POWER6)
 224     enable_language(Fortran)
 225     include(FortranCInterface)
 226     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 227     if(extra_under_score)
 228         set(extrasuffix "_")
 229     endif(extra_under_score)
 230
 231     if(isupper)
 232         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 233         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 234     else(isupper)
 235         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 236         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 237     endif(isupper)
 238 else(GMX_FORTRAN OR GMX_POWER6)
 239         set(F77_FUNCDEF   "name ## _")
 240         set(F77_FUNCDEF_  "name ## _")
 241 endif(GMX_FORTRAN OR GMX_POWER6)
 242
 243
 244 # Process nonbonded accelerated kernels settings
 245 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 246 if(${GMX_ACCELERATION} STREQUAL "NONE")
 247   # nothing to do
 248 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 249     if(HAVE_XMMINTRIN_H)
 250         set(GMX_SSE 1)
 251     endif(HAVE_XMMINTRIN_H)
 252     if(HAVE_EMMINTRIN_H)
 253         set(GMX_SSE2 1)
 254     endif(HAVE_EMMINTRIN_H)
 255 #    if(HAVE_PMMINTRIN_H)
 256 #        set(GMX_SSE3 1)
 257 #    endif(HAVE_PMMINTRIN_H)
 258 #    if(HAVE_SMMINTRIN_H)
 259 #        set(GMX_SSE4_1 1)
 260 #    endif(HAVE_SMMINTRIN_H)
 261
 262 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 263     set(GMX_FORTRAN 1)
 264 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 265     set(GMX_BLUEGENE 1)
 266 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 267     set(GMX_POWER6 1)
 268 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 269     set(GMX_IA64_ASM 1)
 270     set(DISABLE_WATERWATER_NLIST 1)
 271     set(DISABLE_WATER_NLIST 1)
 272 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 273     check_include_files(altivec.h HAVE_ALTIVEC_H)
 274     if(HAVE_ALTIVEC_H)
 275         set(GMX_PPC_ALTIVEC 1)
 276     endif(HAVE_ALTIVEC_H)
 277 else(${GMX_ACCELERATION} STREQUAL "NONE")
 278     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 279 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 280
 281
 282
 283
 284
 285
 286
 287 # Process QM/MM Settings
 288 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 289 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 290     set(GMX_QMMM_GAUSSIAN 1)
 291 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 292     set(GMX_QMMM_MOPAC 1)
 293 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 294     set(GMX_QMMM_GAMESS 1)
 295 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 296     # nothing to do
 297 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 298     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, None")
 299 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 300
 301 # Process FFT library settings
 302 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 303 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 304 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 305     if(GMX_DOUBLE)
 306         find_package(FFTW3 REQUIRED)
 307     else(GMX_DOUBLE)
 308         find_package(FFTW3F REQUIRED)
 309     endif(GMX_DOUBLE)
 310
 311     if(NOT FFTW3_FOUND)
 312         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 313     endif(NOT FFTW3_FOUND)
 314
 315     set(GMX_FFT_FFTW3 1)
 316     include_directories(${FFTW3_INCLUDE_DIR})
 317     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 318
 319 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 320 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 321     if(GMX_DOUBLE)
 322         find_package(FFTW2 REQUIRED)
 323     else(GMX_DOUBLE)
 324         find_package(FFTW2F REQUIRED)
 325     endif(GMX_DOUBLE)
 326
 327     if(NOT FFTW2_FOUND)
 328            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 329     endif(NOT FFTW2_FOUND)
 330     include_directories(${FFTW2_INCLUDE_DIR})
 331     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 332
 333     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 334         set(FFTW2_NAME_DFFTW 1)
 335     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 336         set(FFTW2_NAME_SFFTW 1)
 337     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 338         set(FFTW2_NAME_FFTW 1)
 339     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 340
 341     set(GMX_FFT_FFTW2 1)
 342 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 343 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 344     find_package(MKL REQUIRED)
 345     include_directories(${MKL_INCLUDE_DIR})
 346     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 347
 348     set(GMX_FFT_MKL 1)
 349     set(HAVE_MKL 1)
 350
 351 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 352 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 353 #    set(GMX_FFT_ACML 1)
 354 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 355     MESSAGE(STATUS "Using internal FFT library - fftpack")
 356     set(GMX_FFT_FFTPACK 1)
 357 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 358     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 359 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 360
 361 # MKL has BLAS/LAPACK routines
 362 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 363   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 364   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 365 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 366   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 367   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 368 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 369
 370 # Math and thread libraries must often come after all others when linking...
 371 if(HAVE_LIBM)
 372     list(APPEND GMX_EXTRA_LIBRARIES m)
 373 endif(HAVE_LIBM)
 374
 375
 376
 377 if(GMX_FAHCORE)
 378   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 379       "Path to swindirect.h")
 380   include_directories(${COREWRAP_INCLUDE_DIR})
 381 endif(GMX_FAHCORE)
 382
 383 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 384 set(CMAKE_C_FLAGS ${GROMACS_C_FLAGS} CACHE STRING "Compiler flags")
 385 set(CMAKE_EXE_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} CACHE STRING "Linker flags")
 386
 387 ########################################################################
 388 # Specify install locations and which subdirectories to process        #
 389 ########################################################################
 390 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 391 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 392 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 393 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 394
 395 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 396
 397
 398 add_subdirectory(share)
 399 add_subdirectory(include)
 400 add_subdirectory(man)
 401
 402 add_subdirectory(src)
 403
 404