tests/CppCheck.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 find_program(CPPCHECK_EXECUTABLE
  36     NAMES cppcheck
  37     DOC "cppcheck executable")
  38 mark_as_advanced(CPPCHECK_EXECUTABLE)
  39 option(CPPCHECK_XML_OUTPUT "Whether to produce XML output from cppcheck (mainly for Jenkins)"
  40        OFF)
  41 mark_as_advanced(CPPCHECK_XML_OUTPUT)
  42
  43 # Depends on stderr redirection and cat
  44 if (CPPCHECK_EXECUTABLE AND UNIX)
  45     # Produce the list of files to check
  46     file(GLOB_RECURSE _inputfiles RELATIVE ${CMAKE_SOURCE_DIR}
  47         ${CMAKE_SOURCE_DIR}/src/*.c
  48         ${CMAKE_SOURCE_DIR}/src/*.cpp
  49         ${CMAKE_SOURCE_DIR}/src/*.cu)
  50     file(GLOB_RECURSE _files_to_ignore RELATIVE ${CMAKE_SOURCE_DIR}
  51         ${CMAKE_SOURCE_DIR}/src/nb_kernel_Elec*.c
  52         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_blas/*.c
  53         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_lapack/*.c
  54         ${CMAKE_SOURCE_DIR}/src/contrib/*.c
  55         ${CMAKE_SOURCE_DIR}/src/contrib/*.cpp
  56         ${CMAKE_SOURCE_DIR}/src/contrib/*.cu
  57         ${CMAKE_SOURCE_DIR}/src/external/*.c
  58         ${CMAKE_SOURCE_DIR}/src/external/*.cpp
  59         ${CMAKE_SOURCE_DIR}/src/external/*.cu
  60         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/scanner.cpp
  61         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/parser.cpp
  62         ${CMAKE_SOURCE_DIR}/src/gromacs/gpu_utils/ocl_compiler.cpp
  63         )
  64     list(REMOVE_ITEM _inputfiles ${_files_to_ignore})
  65
  66     # Set flags for cppcheck
  67     set(_outputext txt)
  68     set(_outputopt "--template={file}:{line}:{id}: {severity}: {message}")
  69     if (CPPCHECK_XML_OUTPUT)
  70         set(_outputext xml)
  71         set(_outputopt --xml --xml-version=2)
  72     endif()
  73     set(_common_flags
  74         --enable=style -DLINUX -DHAVE_UNISTD_H
  75         -I src
  76         -I src/external/thread_mpi/include
  77         -I src/external/tng_io/include
  78         -I ${CMAKE_BINARY_DIR}/src
  79         --quiet
  80         --inline-suppr
  81         ${_outputopt})
  82     set(_c_flags
  83         --suppress=variableScope
  84         --suppress=unnecessaryForwardDeclaration
  85         --suppress=unusedVariable
  86         --suppress=unreadVariable
  87         --suppress=unusedStructMember
  88         --suppress=invalidscanf
  89         --suppress=sizeofCalculation
  90         --suppress=invalidscanf_libc
  91         --suppress=missingInclude:src/programs/mdrun/gmx_gpu_utils/gmx_gpu_utils.cu
  92         --suppress=*:src/external/Random123-1.08/include/Random123/features/compilerfeatures.h
  93         --suppress=invalidPointerCast:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel.cuh
  94         --suppress=passedByValue:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel.cuh
  95         --suppress=passedByValue:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel_utils.cuh
  96         --suppress=shiftTooManyBits:src/gromacs/gpu_utils/gpu_utils.cu
  97         )
  98     set(_cxx_flags
  99         -D__cplusplus
 100         --suppress=variableScope
 101         --suppress=unnecessaryForwardDeclaration
 102         --suppress=memsetClassFloat  #we assume IEEE754
 103         --suppress=invalidscanf_libc #seems only important for security on non-std libc
 104         --suppress=invalidscanf      #same as last (style and portability checker have the same warning)
 105         --suppress=passedByValue:src/gromacs/simd/tests/*
 106         --suppress=redundantAssignment:src/gromacs/simd/simd_math.h #seems to be a bug in cppcheck
 107         --suppress=noExplicitConstructor # can't be selective about this, see http://sourceforge.net/p/cppcheck/discussion/general/thread/db1e4ba7/
 108         )
 109
 110     # This list will hold the list of all files with cppcheck errors
 111     # (one per input file)
 112     set(_filelist)
 113
 114     foreach (_filename ${_inputfiles})
 115         set(_target_name cppcheck-${_filename}.${_outputext})
 116         string(REPLACE "/" "_" _target_name ${_target_name})
 117         list(APPEND _filelist ${_target_name})
 118         if (_filename MATCHES "\\.cpp$")
 119             set(_lang CXX)
 120             set(_lang_flags ${_cxx_flags})
 121         else()
 122             set(_lang C)
 123             set(_lang_flags ${_c_flags})
 124         endif()
 125         add_custom_command(
 126             OUTPUT ${_target_name}
 127             COMMAND ${CPPCHECK_EXECUTABLE} ${_common_flags} ${_lang_flags}
 128                 ${_filename} 2> ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 129             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 130             IMPLICIT_DEPENDS ${_lang} ${CMAKE_SOURCE_DIR}/${_filename}
 131             COMMENT "Running cppcheck for ${_filename}"
 132             VERBATIM)
 133         if (NOT CPPCHECK_XML_OUTPUT)
 134             add_custom_command(
 135                 OUTPUT ${_target_name}
 136                 COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 137                 VERBATIM APPEND)
 138         endif()
 139     endforeach()
 140     if (NOT CPPCHECK_XML_OUTPUT)
 141         set(_target_name cppcheck-errors.${_outputext})
 142         add_custom_command(
 143             OUTPUT ${_target_name}
 144             COMMAND cat ${_filelist} > ${_target_name}
 145             DEPENDS ${_filelist}
 146             COMMENT "Combining cppcheck results"
 147             VERBATIM)
 148         list(APPEND _filelist ${_target_name})
 149     endif()
 150     add_custom_target(cppcheck DEPENDS ${_filelist})
 151 else()
 152     add_custom_target(cppcheck
 153         COMMAND ${CMAKE_COMMAND} -E echo
 154             "cppcheck was not found by CMake. Rerun CMake specifying CPPCHECK_EXECUTABLE."
 155         VERBATIM)
 156 endif()