CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98 include(gmxBuildTypeThreadSanitizer)
  99
 100 if(NOT CMAKE_BUILD_TYPE)
 101     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 102     # There's no need to offer a user the choice of ThreadSanitizer
 103     # Set the possible values of build type for cmake-gui
 104     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 105         "MinSizeRel" "RelWithDebInfo")
 106 endif(NOT CMAKE_BUILD_TYPE)
 107
 108 enable_language(C)
 109 enable_language(CXX)
 110
 111 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 112 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 113 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 114 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 115 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 116 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 117 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 118 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 119 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 120 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 121 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 122
 123 #must come after all cpack settings!
 124 include(CPack)
 125
 126 # Set a default valgrind suppression file.
 127 # This unfortunately needs to duplicate information from CTest to work as
 128 # expected...
 129 set(MEMORYCHECK_SUPPRESSIONS_FILE
 130     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 131     CACHE FILEPATH
 132     "File that contains suppressions for the memory checker")
 133 include(CTest)
 134
 135 set(SOURCE_IS_GIT_REPOSITORY OFF)
 136 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 137 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 138     set(SOURCE_IS_GIT_REPOSITORY ON)
 139 endif()
 140 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 141     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 142 endif()
 143
 144 ########################################################################
 145 # Check and warn if cache generated on a different host is being reused
 146 ########################################################################
 147 if(CMAKE_HOST_UNIX)
 148     execute_process(COMMAND hostname
 149                     OUTPUT_VARIABLE TMP_HOSTNAME
 150                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 151     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 152         message(WARNING "
 153             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 154             is being reused! This could lead to inconsitencies; therefore, it is
 155             recommended to regenerate the cache!")
 156     endif()
 157     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 158             "Hostname of the machine where the cache was generated.")
 159 endif()
 160
 161 ########################################################################
 162 # User input options                                                   #
 163 ########################################################################
 164 include(gmxOptionUtilities)
 165
 166 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 167
 168 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 169 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 170 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 171 gmx_dependent_option(
 172     GMX_MPI_IN_PLACE
 173     "Enable MPI_IN_PLACE for MPIs that have it defined"
 174     ON
 175     GMX_MPI)
 176 mark_as_advanced(GMX_MPI_IN_PLACE)
 177 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 178 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 179 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 180 mark_as_advanced(GMX_FAHCORE)
 181
 182 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 183 mark_as_advanced(GMX_COOL_QUOTES)
 184 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 185
 186 # decide on GPU settings based on user-settings and GPU/CUDA detection
 187 include(gmxManageGPU)
 188
 189 # Detect the architecture the compiler is targetting, detect
 190 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 191 # to use if none is specified, and populate the cache option for CPU
 192 # SIMD.
 193 include(gmxDetectTargetArchitecture)
 194 gmx_detect_target_architecture()
 195
 196 if(GMX_CPU_ACCELERATION)
 197     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 198     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 199 endif(GMX_CPU_ACCELERATION)
 200
 201 include(gmxDetectSimd)
 202 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 203
 204 gmx_option_multichoice(
 205     GMX_SIMD
 206     "SIMD instruction set for CPU kernels and compiler optimization"
 207     "${GMX_SUGGESTED_SIMD}"
 208     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 209
 210 gmx_option_multichoice(
 211     GMX_FFT_LIBRARY
 212     "FFT library"
 213     "fftw3"
 214     fftw3 mkl "fftpack[built-in]")
 215 gmx_dependent_option(
 216     GMX_BUILD_OWN_FFTW
 217     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 218     OFF
 219     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 220 gmx_dependent_option(
 221     GMX_DISABLE_FFTW_MEASURE
 222     "Do not optimize FFTW setups (not needed with SSE)"
 223     OFF
 224     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 225 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 226 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 227
 228 gmx_option_multichoice(
 229     GMX_QMMM_PROGRAM
 230     "QM package for QM/MM"
 231     None
 232     none gaussian mopac gamess orca)
 233
 234 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 235 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 236
 237 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 238
 239 if("${GMX_SIMD}" STREQUAL "REFERENCE")
 240     if(GMX_DOUBLE)
 241         set(KERNEL_WIDTH ${GMX_SIMD_REF_DOUBLE_WIDTH})
 242     else()
 243         set(KERNEL_WIDTH ${GMX_SIMD_REF_FLOAT_WIDTH})
 244     endif()
 245 endif()
 246
 247 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 248 mark_as_advanced(GMX_BROKEN_CALLOC)
 249 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 250 mark_as_advanced(GMX_LOAD_PLUGINS)
 251
 252 option(GMX_GPU  "Enable GPU acceleration" ON)
 253 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 254
 255 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 256
 257 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 258 mark_as_advanced(GMX_GIT_VERSION_INFO)
 259
 260 if(UNIX)
 261     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 262 endif()
 263 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 264
 265 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 266 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 267
 268 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 269 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 270
 271 option(GMX_BUILD_FOR_COVERAGE
 272        "Tune build for better code coverage metrics (e.g., disable asserts)"
 273        OFF)
 274 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 275
 276
 277 ######################################################################
 278 # Detect OpenMP support
 279 ######################################################################
 280 # The OpenMP detection _must_ come before tests for other CFLAGS.
 281 include(gmxManageOpenMP)
 282
 283
 284
 285 ######################################################################
 286 # Compiler tests
 287 # These need to be done early (before further tests).
 288 #####################################################################
 289
 290 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 291 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 292 # invalid options with the Intel Compilers.
 293 # These files should be removed from the source tree when a CMake version that
 294 # includes the features in question becomes required for building GROMACS.
 295 include(CheckCCompilerFlag)
 296 include(CheckCXXCompilerFlag)
 297
 298
 299 include(gmxCFlags)
 300 gmx_c_flags()
 301
 302 # This variable should be used for additional compiler flags which are not
 303 # generated in gmxCFlags nor are SIMD or MPI related.
 304 set(EXTRA_C_FLAGS "")
 305 set(EXTRA_CXX_FLAGS "")
 306
 307 # Run through a number of tests for buggy compilers and other issues
 308 include(gmxTestCompilerProblems)
 309 gmx_test_compiler_problems()
 310
 311
 312 set(PKG_CFLAGS "")
 313 if(GMX_DOUBLE)
 314     add_definitions(-DGMX_DOUBLE)
 315     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 316 endif(GMX_DOUBLE)
 317 if(GMX_SOFTWARE_INVSQRT)
 318   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 319 endif(GMX_SOFTWARE_INVSQRT)
 320
 321
 322
 323 ########################################################################
 324 # Basic system tests (standard libraries, headers, functions, types)   #
 325 ########################################################################
 326 include(CheckIncludeFiles)
 327 include(CheckIncludeFileCXX)
 328 check_include_files(unistd.h     HAVE_UNISTD_H)
 329 check_include_files(pwd.h        HAVE_PWD_H)
 330 check_include_files(dirent.h     HAVE_DIRENT_H)
 331 check_include_files(time.h       HAVE_TIME_H)
 332 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 333 check_include_files(io.h         HAVE_IO_H)
 334 check_include_files(sched.h      HAVE_SCHED_H)
 335
 336 check_include_files(regex.h      HAVE_POSIX_REGEX)
 337 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 338 # TODO: It could be nice to inform the user if no regex support is found,
 339 # as selections won't be fully functional.
 340
 341 include(CheckFunctionExists)
 342 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 343 check_function_exists(memalign          HAVE_MEMALIGN)
 344 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 345 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 346 check_function_exists(fsync             HAVE_FSYNC)
 347 check_function_exists(_fileno           HAVE__FILENO)
 348 check_function_exists(fileno            HAVE_FILENO)
 349 check_function_exists(_commit           HAVE__COMMIT)
 350 check_function_exists(sigaction         HAVE_SIGACTION)
 351 check_function_exists(sysconf           HAVE_SYSCONF)
 352 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 353 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 354 check_function_exists(rsqrt             HAVE_RSQRT)
 355 check_function_exists(rsqrtf            HAVE_RSQRTF)
 356 check_function_exists(sqrtf             HAVE_SQRTF)
 357
 358 include(CheckLibraryExists)
 359 check_library_exists(m sqrt "" HAVE_LIBM)
 360 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 361
 362 include(TestBigEndian)
 363 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 364
 365 # Management of GROMACS options for specific toolchains should go
 366 # here. Because the initial settings for some of the main options have
 367 # already happened, but things like library detection and MPI compiler
 368 # feature detection have not, the docstrings for any over-rides of
 369 # GROMACS defaults or user settings will make sense. Also, any
 370 # toolchain-related reasons for choosing whether to detect various
 371 # things can be sorted out now, before the detection takes place.
 372 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 373     include(gmxManageBlueGene)
 374 endif()
 375
 376 ########################################################################
 377 #Process MPI settings
 378 ########################################################################
 379 include(gmxManageMPI)
 380
 381
 382 ########################################################################
 383 #Process shared/static library settings
 384 ########################################################################
 385 include(gmxManageSharedLibraries)
 386
 387
 388 ########################################################################
 389 # Find external packages                                               #
 390 ########################################################################
 391
 392 # Unconditionally find the package, as it is also required for unit
 393 # tests. This exports LIBXML2_FOUND, which we should not use because
 394 # it does not tell us that linking will succeed. Instead, we test that
 395 # next.
 396 find_package(LibXml2)
 397 include(gmxTestLibXml2)
 398 gmx_test_libxml2(HAVE_LIBXML2)
 399 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 400 set(PKG_XML "")
 401 mark_as_advanced(GMX_XML)
 402 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 403 #if(GMX_XML AND NOT HAVE_LIBXML2)
 404 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 405 #endif()
 406 #if(GMX_XML)
 407 #    include_directories(${LIBXML2_INCLUDE_DIR})
 408 #    set(PKG_XML libxml-2.0)
 409 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 410 #endif(GMX_XML)
 411
 412 option(GMX_GSL "Add support for gsl" OFF)
 413 if (GMX_GSL)
 414   find_package(GSL)
 415   set(PKG_GSL "")
 416   if(GSL_FOUND)
 417     include_directories(${GSL_INCLUDE_DIR})
 418     set(PKG_GSL gsl)
 419     set(HAVE_LIBGSL 1)
 420   endif(GSL_FOUND)
 421 endif (GMX_GSL)
 422
 423 option(GMX_X11 "Use X window system" OFF)
 424 if (GMX_X11)
 425     find_package(X11)
 426     # X11 includes/libraries are only set in the ngmx subdirectory!
 427     if(NOT X11_FOUND)
 428         message(FATAL_ERROR
 429                 "X11 include files and/or libraries were not found. "
 430                 "Set GMX_X11=OFF to compile without X11 support. "
 431                 "gmx view will not be available.")
 432     endif()
 433     include_directories(${X11_INCLUDE_DIR})
 434 endif(GMX_X11)
 435
 436 include(ThreadMPI)
 437 set(THREAD_MPI_LIB thread_mpi)
 438 # Enable core threading facilities
 439 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 440 # Enable tMPI C++ support
 441 tmpi_enable_cxx()
 442 if(GMX_THREAD_MPI)
 443     # enable MPI functions
 444     tmpi_enable()
 445     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 446     set(GMX_MPI 1)
 447     set(MPI_IN_PLACE_EXISTS 1)
 448 endif(GMX_THREAD_MPI)
 449 tmpi_get_source_list(THREAD_MPI_SRC)
 450 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 451 if (TMPI_ATOMICS_DISABLED)
 452    add_definitions(-DTMPI_ATOMICS_DISABLED)
 453 endif()
 454
 455 if(GMX_GPU)
 456     # now that we have detected the dependencies, do the second configure pass
 457     gmx_gpu_setup()
 458 endif(GMX_GPU)
 459
 460 if(CYGWIN)
 461     set(GMX_CYGWIN 1)
 462 endif(CYGWIN)
 463
 464 if(WIN32 AND NOT CYGWIN)
 465     set(GMX_NATIVE_WINDOWS 1)
 466     # This makes windows.h not declare min/max as macros that would break
 467     # C++ code using std::min/std::max.
 468     add_definitions(-DNOMINMAX)
 469 endif()
 470
 471 # only bother with finding git and using version.h if the source is a git repo
 472 if(GMX_GIT_VERSION_INFO)
 473     if (NOT SOURCE_IS_GIT_REPOSITORY)
 474         message(FATAL_ERROR
 475             "Cannot generate git version information from source tree not under git. "
 476             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 477     endif ()
 478     # We need at least git v1.5.3 be able to parse git's date output. If not
 479     # found or the version is too small, we can't generate version information.
 480     find_package(Git)
 481
 482     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 483         message(FATAL_ERROR
 484             "No compatible git version found (>= 1.5.3 required). "
 485             "Won't be able to generate development version information. "
 486             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 487     endif()
 488 endif()
 489
 490 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 491 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 492 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 493     find_package(Boost 1.44.0)
 494     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 495         set(Boost_FOUND FALSE)
 496     endif()
 497     # Print the notification only on first run, when determining the default
 498     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 499         message("Boost >= 1.44 not found. Using minimal internal version. "
 500                 "This may cause trouble if you plan on compiling/linking other "
 501                 "software that uses Boost against Gromacs.")
 502     endif()
 503 endif()
 504 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 505        ${Boost_FOUND})
 506 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 507     message(FATAL_ERROR
 508         "Boost >= 1.44 not found. "
 509         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 510         "version of Boost included with Gromacs.")
 511 endif()
 512
 513 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 514 mark_as_advanced(GMX_BUILD_UNITTESTS)
 515 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 516 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 517     message(FATAL_ERROR
 518         "Cannot build unit tests without libxml2. "
 519         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 520 endif()
 521
 522 ########################################################################
 523 # Generate development version info for cache
 524 ########################################################################
 525 # set(GEN_VERSION_INFO_INTERNAL "ON")
 526 # include(gmxGenerateVersionString)
 527
 528 ########################################################################
 529 # Our own GROMACS tests
 530 ########################################################################
 531
 532 add_definitions( -DHAVE_CONFIG_H )
 533 include_directories(${CMAKE_SOURCE_DIR}/src)
 534 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 535 include_directories(${CMAKE_BINARY_DIR}/src)
 536 # Required for gmx_header_config_gen.h to be found before installation
 537 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 538 # Required for now to make old code compile
 539 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 540
 541 include(gmxTestInlineASM)
 542 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 543
 544 include(gmxSetBuildInformation)
 545 gmx_set_build_information()
 546 # Turn on RDTSCP if:
 547 # - the build system's CPU supports it
 548 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 549 #   at this point means that the user set it).
 550 # Note: it's better to not use the later set value of GMX_SIMD because
 551 # it reflects the system's capability of both compiling and running AVX code.
 552 # TODO: After merge with 5.0 one could implement a cache variable dependency
 553 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 554 # after the first cmake pass.
 555 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 556     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 557 else()
 558     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 559 endif()
 560 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 561 mark_as_advanced(GMX_USE_RDTSCP)
 562 if(GMX_USE_RDTSCP)
 563     set(HAVE_RDTSCP 1)
 564 endif()
 565
 566 include(gmxTestFloatFormat)
 567 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 568                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 569                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 570
 571 include(gmxTestLargeFiles)
 572 gmx_test_large_files(GMX_LARGEFILES)
 573
 574 include(gmxTestSignal)
 575 gmx_test_sigusr1(HAVE_SIGUSR1)
 576
 577 include(gmxTestInline)
 578 gmx_test_inline(INLINE_KEYWORD)
 579
 580 include(gmxTestRestrict)
 581 gmx_test_restrict(RESTRICT_KEYWORD)
 582
 583 include(gmxTestPipes)
 584 gmx_test_pipes(HAVE_PIPES)
 585
 586 include(gmxTestIsfinite)
 587 gmx_test_isfinite(HAVE_ISFINITE)
 588 gmx_test__isfinite(HAVE__ISFINITE)
 589 gmx_test__finite(HAVE__FINITE)
 590
 591 include(gmxTestCXX11)
 592 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 593 include(CMakeDependentOption)
 594 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 595 # entirely to keep the compilation environment uniform.
 596 cmake_dependent_option(GMX_CXX11
 597     "Use C++11 features"
 598     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 599 mark_as_advanced(GMX_CXX11)
 600 if(GMX_CXX11)
 601     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 602 endif()
 603
 604
 605 include(gmxTestXDR)
 606 gmx_test_xdr(GMX_SYSTEM_XDR)
 607 if(NOT GMX_SYSTEM_XDR)
 608     set(GMX_INTERNAL_XDR 1)
 609 endif(NOT GMX_SYSTEM_XDR)
 610
 611
 612 ##################################################
 613 # Process SIMD instruction settings
 614 ##################################################
 615 # This checks what flags to add in order to
 616 # support the SIMD instructions we need, and sets
 617 # correct defines for the SIMD instructions supported.
 618 include(gmxTestSimd)
 619 gmx_test_simd()
 620
 621
 622 # Process QM/MM Settings
 623 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 624     set(GMX_QMMM_GAUSSIAN 1)
 625 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 626     set(GMX_QMMM_MOPAC 1)
 627 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 628     set(GMX_QMMM_GAMESS 1)
 629 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 630     set(GMX_QMMM_ORCA 1)
 631 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 632     # nothing to do
 633 else()
 634     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 635 endif()
 636
 637
 638 ##################################################
 639 # Process FFT library settings
 640 ##################################################
 641 include(gmxManageFFTLibraries)
 642
 643
 644 include(gmxManageLinearAlgebraLibraries)
 645
 646 # Whether GROMACS will really try to compile support for VMD plugins
 647 set(GMX_USE_PLUGINS OFF)
 648
 649 if(GMX_LOAD_PLUGINS)
 650   if(CYGWIN OR NOT WIN32)
 651     # Native Windows does not have, nor need dlopen
 652     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 653     include(gmxTestdlopen)
 654     gmx_test_dlopen(HAVE_DLOPEN)
 655   endif()
 656
 657   # so, should we use plug-ins?
 658   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 659     if(NOT VMD_QUIETLY)
 660       MESSAGE(STATUS
 661           "Found the ability to use plug-ins when building shared libaries, "
 662           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 663           "formats).")
 664     endif()
 665     if(NOT GMX_VMD_PLUGIN_PATH)
 666       find_package(VMD)
 667     endif()
 668     set(GMX_USE_PLUGINS ON)
 669     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 670     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 671   else()
 672     set(PKG_DL_LIBS)
 673   endif()
 674 endif(GMX_LOAD_PLUGINS)
 675 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 676
 677 # Link real-time library for POSIX timers. The check for clock_gettime
 678 # confirms the linkability of rt.
 679 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 680     list(APPEND GMX_EXTRA_LIBRARIES rt)
 681 endif()
 682
 683 # Math and thread libraries must often come after all others when linking...
 684 if(HAVE_LIBM)
 685     list(APPEND GMX_EXTRA_LIBRARIES m)
 686 endif(HAVE_LIBM)
 687
 688 option(GMX_NACL "Configure for Native Client builds" OFF)
 689 if (GMX_NACL)
 690   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 691   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 692   set(GMX_NO_NICE 1)
 693   set(GMX_NO_RENAME 1)
 694 endif()
 695 mark_as_advanced(GMX_NACL)
 696
 697 if(GMX_FAHCORE)
 698   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 699       "Path to swindirect.h")
 700   include_directories(${COREWRAP_INCLUDE_DIR})
 701 endif(GMX_FAHCORE)
 702
 703 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 704 mark_as_advanced(GMX_BUILD_HELP)
 705 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 706     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 707
 708     message(FATAL_ERROR
 709         "Rebuilding HTML and man pages is not supported for in-source "
 710         "builds from a source distribution. "
 711         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 712 endif()
 713
 714 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 715 # these are set after everything else
 716 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 717     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 718     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 719     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 720     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 721 else()
 722     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 723     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 724     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 725     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 726     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 727     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 728     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 729     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 730     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 731 endif()
 732
 733 if(NOT GMX_OPENMP)
 734     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 735     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 736     unset(OpenMP_C_FLAGS CACHE)
 737     unset(OpenMP_CXX_FLAGS CACHE)
 738 else()
 739     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 740     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 741 endif()
 742 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 743
 744 ########################################################################
 745 # Specify install locations
 746 ########################################################################
 747 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 748     "Library installation directory (default: lib)")
 749 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 750     "Data installation directory under share/ (default: gromacs)")
 751 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 752
 753 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 754 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 755 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 756 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 757 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 758
 759 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 760 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 761
 762 # Binary and library suffix options
 763 include(gmxManageSuffixes)
 764
 765 ##################################################################
 766 # Shared library settings
 767 ##################################################################
 768 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 769     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 770         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 771     endif()
 772     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 773     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 774 else()
 775     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 776         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 777         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 778     else()
 779         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 780     endif()
 781 endif()
 782
 783 #COPYING file: Only necessary for binary distributions.
 784 #Simpler to always install.
 785 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 786
 787 if(GMX_EXTERNAL_BOOST)
 788     include_directories(${Boost_INCLUDE_DIRS})
 789     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 790 else()
 791     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 792     # typeid not supported for minimal internal version
 793     # (would add significant amount of code)
 794     add_definitions(-DBOOST_NO_TYPEID)
 795     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 796     # (from share/template/)
 797     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 798     if (NOT GMX_BUILD_MDRUN_ONLY)
 799         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 800                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 801                 COMPONENT development)
 802     endif ()
 803 endif()
 804
 805 if(GMX_USE_TNG)
 806     find_package(ZLIB)
 807     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 808     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 809     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 810     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 811     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 812     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 813     set(GMX_TNG_LIBRARIES tng_io)
 814 endif()
 815 mark_as_advanced(TNG_BUILD_FORTRAN)
 816 mark_as_advanced(TNG_BUILD_EXAMPLES)
 817 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 818 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 819 mark_as_advanced(TNG_BUILD_TEST)
 820 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 821
 822 if (GMX_BUILD_FOR_COVERAGE)
 823     # Code heavy with asserts makes conditional coverage close to useless metric,
 824     # as by design most of the false branches are impossible to trigger in
 825     # correctly functioning code.  And the benefit of testing those that could
 826     # be triggered by using an API against its specification isn't usually
 827     # worth the effort.
 828     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 829 endif ()
 830
 831 if (BUILD_TESTING)
 832     # "tests" target builds all the separate test binaries.
 833     add_custom_target(tests)
 834     # "run-ctest" is an internal target that actually runs the tests.
 835     # This is necessary to be able to add separate targets that execute as part
 836     # of 'make check', but are ensured to be executed after the actual tests.
 837     add_custom_target(run-ctest
 838                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 839                       COMMENT "Running all tests"
 840                       VERBATIM)
 841     add_dependencies(run-ctest tests)
 842     # "check" target builds and runs all tests.
 843     add_custom_target(check DEPENDS run-ctest)
 844 endif()
 845
 846 if (NOT GMX_BUILD_MDRUN_ONLY)
 847     add_subdirectory(doxygen)
 848     add_subdirectory(share)
 849     add_subdirectory(scripts)
 850 endif ()
 851 add_subdirectory(src)
 852
 853 if (BUILD_TESTING)
 854     add_subdirectory(tests)
 855 endif()
 856
 857 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 858 # Don't bother the user after the first configure pass.
 859 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 860     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 861 endif()
 862 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 863
 864 #######################
 865 ## uninstall target
 866 #######################
 867     CONFIGURE_FILE(
 868                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 869                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 870                    IMMEDIATE @ONLY)
 871 ###########################
 872 ADD_CUSTOM_TARGET(uninstall
 873                   "${CMAKE_COMMAND}" -P
 874                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 875 ###########################
 876
 877 ########################################################################
 878 # Manual                                                               #
 879 ########################################################################
 880
 881 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 882 mark_as_advanced(GMX_BUILD_MANUAL)
 883 if(GMX_BUILD_MANUAL)
 884     # Make sure we only do detection of manual-building dependencies
 885     # when the user opted in for that.
 886     add_subdirectory(manual)
 887 endif()