CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeMSAN)
  69 include(gmxBuildTypeReleaseWithAssert)
  70
  71 if(NOT CMAKE_BUILD_TYPE)
  72     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  73     # There's no need to offer a user the choice of ThreadSanitizer
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135
 136 ########################################################################
 137 # Detect CXX11 support and flags
 138 ########################################################################
 139 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 140 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 141 # invalid options with the Intel Compilers, and we have added a line
 142 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 143 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 144 # a semicolon. Since this is also used as a separator in lists inside CMake,
 145 # that string ends up being split into two separate patterns, and the last
 146 # part is just a single word that also matches other messages. We solved this
 147 # by replacing the semicolon with a period that matches any character.
 148 #
 149 # These files should be removed from the source tree when a CMake version that
 150 # includes the features in question becomes required for building GROMACS.
 151 include(CheckCCompilerFlag)
 152 include(CheckCXXCompilerFlag)
 153
 154 # This must come early, since some of our configuration flag tests
 155 # depend on being able to compile C++11 source files
 156 include(gmxTestCXX11)
 157 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 158 if(NOT GMX_CXX11_SUPPORTED)
 159 message(FATAL_ERROR "This version of GROMACS requires C++11. Please use a newer compiler or use the GROMACS 5.1.x release. Note it might be sufficient to instruct the compiler to use a newer STL version. See the installation guide for details.")
 160 endif()
 161
 162 # Make sure all tests are run in C++11 mode
 163 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 164
 165 ########################################################################
 166 # User input options                                                   #
 167 ########################################################################
 168 include(gmxOptionUtilities)
 169
 170 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 171
 172 # Fujitsu only has SIMD in double precision, so this will be faster
 173 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 174 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 175 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 176 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 177
 178 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 179 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 180 gmx_dependent_option(
 181     GMX_MPI_IN_PLACE
 182     "Enable MPI_IN_PLACE for MPIs that have it defined"
 183     ON
 184     GMX_MPI)
 185 mark_as_advanced(GMX_MPI_IN_PLACE)
 186 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 187 mark_as_advanced(GMX_FAHCORE)
 188
 189 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 190 mark_as_advanced(GMX_COOL_QUOTES)
 191 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 192
 193 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 194
 195 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 196 # GCC 4.6 requires CUDA 5.0 and VS2013 requires CUDA 6.5
 197 if(MSVC)
 198     set(REQUIRED_CUDA_VERSION 6.5)
 199 else()
 200     set(REQUIRED_CUDA_VERSION 5.0)
 201 endif()
 202 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 203
 204 # OpenCL required version: 1.1 or newer
 205 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 206
 207 if(NOT GMX_USE_OPENCL)
 208     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 209     include(gmxManageGPU)
 210     set(GMX_USE_CUDA ${GMX_GPU})
 211     if(GMX_GPU)
 212         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 213     else()
 214         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 215     endif()
 216 else()
 217     #Now the OpenCL path (for both AMD and NVIDIA)
 218     if(GMX_GPU)
 219         include(gmxManageOpenCL)
 220         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 221     else()
 222         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 223     endif()
 224 endif()
 225
 226 include(gmxDetectSimd)
 227 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 228
 229 gmx_option_multichoice(
 230     GMX_SIMD
 231     "SIMD instruction set for CPU kernels and compiler optimization"
 232     "${GMX_SUGGESTED_SIMD}"
 233     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 234
 235 if(GMX_TARGET_MIC)
 236     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 237 else()
 238     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 239 endif()
 240
 241 gmx_option_multichoice(
 242     GMX_FFT_LIBRARY
 243     "FFT library"
 244     "${GMX_FFT_LIBRARY_DEFAULT}"
 245     fftw3 mkl "fftpack[built-in]")
 246 gmx_dependent_option(
 247     GMX_BUILD_OWN_FFTW
 248     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 249     OFF
 250     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 251 gmx_dependent_option(
 252     GMX_DISABLE_FFTW_MEASURE
 253     "Do not optimize FFTW setups (not needed with SSE)"
 254     OFF
 255     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 256 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 257 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 258
 259 gmx_option_multichoice(
 260     GMX_QMMM_PROGRAM
 261     "QM package for QM/MM"
 262     None
 263     none gaussian mopac gamess orca)
 264
 265 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 266 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 267
 268 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 269
 270 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 271 mark_as_advanced(GMX_BROKEN_CALLOC)
 272 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 273 mark_as_advanced(GMX_LOAD_PLUGINS)
 274
 275 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 276
 277 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 278
 279 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 280
 281 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 282 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 283
 284 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 285 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 286
 287 option(GMX_BUILD_FOR_COVERAGE
 288        "Tune build for better code coverage metrics (e.g., disable asserts)"
 289        OFF)
 290 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 291
 292 option(GMX_DEVELOPER_BUILD
 293     "Enable Developer convenience features: always build unit-tests"
 294     OFF)
 295 mark_as_advanced(GMX_DEVELOPER_BUILD)
 296
 297 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 298 option(GMX_COMPILER_WARNINGS
 299     "Enable a default set of compiler warnings"
 300     ${GMX_COMPILER_WARNINGS_DEFAULT})
 301 mark_as_advanced(GMX_COMPILER_WARNINGS)
 302 # Always turn on compiler warnings with a developer build.
 303 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 304
 305 option(GMX_BUILD_SHARED_EXE
 306     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 307     ON)
 308 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 309
 310 ######################################################################
 311 # Detect OpenMP support
 312 ######################################################################
 313 # The OpenMP detection _must_ come before tests for other CFLAGS.
 314 include(gmxManageOpenMP)
 315
 316
 317
 318 ######################################################################
 319 # Compiler tests
 320 # These need to be done early (before further tests).
 321 #####################################################################
 322
 323 include(gmxCFlags)
 324 gmx_c_flags()
 325
 326 # This variable should be used for additional compiler flags which are not
 327 # generated in gmxCFlags nor are SIMD or MPI related.
 328 set(EXTRA_C_FLAGS "")
 329 set(EXTRA_CXX_FLAGS "")
 330
 331 # Run through a number of tests for buggy compilers and other issues
 332 include(gmxTestCompilerProblems)
 333 gmx_test_compiler_problems()
 334 # GMX_SIMD will not be set automatically until the second
 335 # pass (which is not strictly guaranteed to occur), so putting this
 336 # check here among logically-related tests is inefficient, but the
 337 # potential loss is likely zero.
 338 if(GMX_SIMD STREQUAL "AVX_256"
 339         AND CMAKE_COMPILER_IS_GNUCC
 340         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 341             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 342     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 343     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 344 endif()
 345
 346
 347 if(GMX_DOUBLE)
 348     add_definitions(-DGMX_DOUBLE)
 349     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 350     if(GMX_RELAXED_DOUBLE_PRECISION)
 351         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 352     endif()
 353 endif()
 354
 355 if(WIN32)
 356     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 357     add_definitions(-DGMX_HAVE_WINSOCK)
 358 endif()
 359
 360
 361
 362 ########################################################################
 363 # Basic system tests (standard libraries, headers, functions, types)   #
 364 ########################################################################
 365 include(CheckIncludeFiles)
 366 include(CheckIncludeFileCXX)
 367 check_include_files(unistd.h     HAVE_UNISTD_H)
 368 check_include_files(pwd.h        HAVE_PWD_H)
 369 check_include_files(dirent.h     HAVE_DIRENT_H)
 370 check_include_files(time.h       HAVE_TIME_H)
 371 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 372 check_include_files(io.h         HAVE_IO_H)
 373 check_include_files(sched.h      HAVE_SCHED_H)
 374
 375 check_include_files(regex.h      HAVE_POSIX_REGEX)
 376 # TODO: It could be nice to inform the user if no regex support is found,
 377 # as selections won't be fully functional.
 378
 379 include(CheckCXXSymbolExists)
 380 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 381 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 382 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 383 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 384 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 385 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 386 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 387 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 388
 389 # We cannot check for the __builtins as symbols, but check if code compiles
 390 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 391 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 392 if(MSVC)
 393     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 394     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 395 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 396     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 397     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 398 endif()
 399
 400 include(CheckLibraryExists)
 401 find_library(HAVE_LIBM m)
 402 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 403 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 404
 405 include(TestSchedAffinity)
 406 test_sched_affinity(HAVE_SCHED_AFFINITY)
 407
 408 # Aligned memory allocation. We need to check for both mm_malloc(),
 409 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 410 include(gmxTestMMMalloc)
 411 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 412 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 413 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 414 if(MSVC)
 415     # No need to waste time on this test on platforms where it will never be true
 416     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 417 endif()
 418
 419 include(TestBigEndian)
 420 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 421
 422 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 423
 424 # Management of GROMACS options for specific toolchains should go
 425 # here. Because the initial settings for some of the main options have
 426 # already happened, but things like library detection and MPI compiler
 427 # feature detection have not, the docstrings for any over-rides of
 428 # GROMACS defaults or user settings will make sense. Also, any
 429 # toolchain-related reasons for choosing whether to detect various
 430 # things can be sorted out now, before the detection takes place.
 431 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 432     include(gmxManageBlueGene)
 433 endif()
 434
 435 if(GMX_TARGET_FUJITSU_SPARC64)
 436     include(gmxManageFujitsuSparc64)
 437 endif()
 438
 439 ########################################################################
 440 #Process MPI settings
 441 ########################################################################
 442 include(gmxManageMPI)
 443
 444
 445 ########################################################################
 446 #Process shared/static library settings
 447 ########################################################################
 448 include(gmxManageSharedLibraries)
 449
 450
 451 ########################################################################
 452 # Find external packages                                               #
 453 ########################################################################
 454
 455 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 456 find_package(ZLIB QUIET)
 457 include(gmxTestZLib)
 458 gmx_test_zlib(HAVE_ZLIB)
 459
 460 # Unconditionally find the package, as it is also required for unit
 461 # tests. This exports LIBXML2_FOUND, which we should not use because
 462 # it does not tell us that linking will succeed. Instead, we test that
 463 # next.
 464 if(DEFINED LIBXML2_LIBRARIES)
 465   set(LibXml2_FIND_QUIETLY TRUE)
 466 endif()
 467 find_package(LibXml2)
 468 include(gmxTestLibXml2)
 469 gmx_test_libxml2(HAVE_LIBXML2)
 470 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 471 set(PKG_XML "")
 472 mark_as_advanced(GMX_XML)
 473 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 474 #if(GMX_XML AND NOT HAVE_LIBXML2)
 475 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 476 #endif()
 477 #if(GMX_XML)
 478 #    include_directories(${LIBXML2_INCLUDE_DIR})
 479 #    set(PKG_XML libxml-2.0)
 480 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 481 #endif()
 482
 483 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 484 mark_as_advanced(GMX_EXTRAE)
 485
 486 if (GMX_EXTRAE)
 487   find_package(EXTRAE)
 488   if(EXTRAE_FOUND)
 489     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 490     set(HAVE_EXTRAE 1)
 491   else()
 492     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 493   endif()
 494 endif()
 495
 496 option(GMX_X11 "Use X window system" OFF)
 497 if (GMX_X11)
 498     find_package(X11)
 499     # X11 includes/libraries are only set in the ngmx subdirectory!
 500     if(NOT X11_FOUND)
 501         message(FATAL_ERROR
 502                 "X11 include files and/or libraries were not found. "
 503                 "Set GMX_X11=OFF to compile without X11 support. "
 504                 "gmx view will not be available.")
 505     endif()
 506     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 507 endif()
 508
 509 include(ThreadMPI)
 510 # Enable core threading facilities
 511 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 512 # Enable tMPI C++ support
 513 tmpi_enable_cxx()
 514 if(GMX_THREAD_MPI)
 515     # enable MPI functions
 516     tmpi_enable()
 517     set(MPI_IN_PLACE_EXISTS 1)
 518 endif()
 519 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 520 if (TMPI_ATOMICS_DISABLED)
 521    add_definitions(-DTMPI_ATOMICS_DISABLED)
 522 endif()
 523
 524 if(GMX_GPU)
 525     # now that we have detected the dependencies, do the second configure pass
 526     gmx_gpu_setup()
 527 endif()
 528
 529 if(CYGWIN)
 530     set(GMX_CYGWIN 1)
 531 endif()
 532
 533 if(WIN32)
 534     set(GMX_NATIVE_WINDOWS 1)
 535     # This makes windows.h not declare min/max as macros that would break
 536     # C++ code using std::min/std::max.
 537     add_definitions(-DNOMINMAX)
 538 endif()
 539
 540 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 541     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 542         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 543     endif()
 544     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 545         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 546     endif()
 547 endif()
 548
 549 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 550     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 551 endif()
 552 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 553 mark_as_advanced(GMX_BUILD_UNITTESTS)
 554 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 555 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 556     message(FATAL_ERROR
 557         "Cannot build unit tests without libxml2. "
 558         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 559 endif()
 560
 561 ########################################################################
 562 # Our own GROMACS tests
 563 ########################################################################
 564
 565 add_definitions( -DHAVE_CONFIG_H )
 566 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 567 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 568 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 569 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 570
 571 include(gmxTestInlineASM)
 572 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 573
 574 include(gmxSetBuildInformation)
 575 gmx_set_build_information()
 576 # Turn on RDTSCP if:
 577 # - the build system's CPU supports it
 578 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 579 #   at this point means that the user set it).
 580 # Note: it's better to not use the later set value of GMX_SIMD because
 581 # it reflects the system's capability of both compiling and running AVX code.
 582 # TODO: After merge with 5.0 one could implement a cache variable dependency
 583 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 584 # after the first cmake pass.
 585 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 586     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 587 else()
 588     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 589 endif()
 590 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 591 mark_as_advanced(GMX_USE_RDTSCP)
 592 if(GMX_USE_RDTSCP)
 593     set(HAVE_RDTSCP 1)
 594 endif()
 595
 596 include(gmxTestLargeFiles)
 597 gmx_test_large_files(GMX_LARGEFILES)
 598
 599 include(gmxTestSignal)
 600 gmx_test_sigusr1(HAVE_SIGUSR1)
 601
 602 include(gmxTestPipes)
 603 gmx_test_pipes(HAVE_PIPES)
 604
 605 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 606
 607 include(gmxTestXDR)
 608 gmx_test_xdr(GMX_SYSTEM_XDR)
 609 if(NOT GMX_SYSTEM_XDR)
 610     set(GMX_INTERNAL_XDR 1)
 611 endif()
 612
 613
 614 ##################################################
 615 # Process SIMD instruction settings
 616 ##################################################
 617 # This checks what flags to add in order to
 618 # support the SIMD instructions we need, it sets
 619 # correct defines for the SIMD instructions supported,
 620 # and adds advanced options to control accuracy
 621 # for SIMD math operations.
 622 include(gmxManageSimd)
 623 gmx_manage_simd()
 624
 625 # Process QM/MM Settings
 626 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 627     set(GMX_QMMM_GAUSSIAN 1)
 628 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 629     set(GMX_QMMM_MOPAC 1)
 630 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 631     set(GMX_QMMM_GAMESS 1)
 632 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 633     set(GMX_QMMM_ORCA 1)
 634 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 635     # nothing to do
 636 else()
 637     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 638 endif()
 639
 640
 641 ##################################################
 642 # Process FFT library settings
 643 ##################################################
 644 include(gmxManageFFTLibraries)
 645
 646
 647 include(gmxManageLinearAlgebraLibraries)
 648
 649 # Whether GROMACS will really try to compile support for VMD plugins
 650 set(GMX_USE_PLUGINS OFF)
 651
 652 if(GMX_LOAD_PLUGINS)
 653   if(NOT WIN32)
 654     # Native Windows does not have, nor need dlopen
 655     include(gmxTestdlopen)
 656     gmx_test_dlopen(HAVE_DLOPEN)
 657   endif()
 658
 659   # so, should we use plug-ins?
 660   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 661     if(NOT VMD_QUIETLY)
 662       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 663     endif()
 664     if(NOT GMX_VMD_PLUGIN_PATH)
 665       find_package(VMD)
 666     endif()
 667     set(GMX_USE_PLUGINS ON)
 668     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 669     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 670   else()
 671     set(PKG_DL_LIBS)
 672   endif()
 673 endif()
 674 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 675
 676 # Link real-time library for POSIX timers. The check for clock_gettime
 677 # confirms the linkability of rt.
 678 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 679     list(APPEND GMX_EXTRA_LIBRARIES rt)
 680 endif()
 681
 682 # Math and thread libraries must often come after all others when linking...
 683 if(HAVE_LIBM)
 684     list(APPEND GMX_EXTRA_LIBRARIES m)
 685 endif()
 686
 687 option(GMX_NACL "Configure for Native Client builds" OFF)
 688 if (GMX_NACL)
 689   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 690   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 691   # TODO: Is this still necessary with the check for its presence?
 692   set(GMX_USE_NICE 0)
 693   set(GMX_NO_RENAME 1)
 694 endif()
 695 mark_as_advanced(GMX_NACL)
 696
 697 if(GMX_FAHCORE)
 698   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 699       "Path to swindirect.h")
 700   include_directories(${COREWRAP_INCLUDE_DIR})
 701 endif()
 702
 703 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 704 # produce warnings if that fails.
 705 set(build_help_default AUTO)
 706 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 707     set(build_help_default OFF)
 708 endif()
 709 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 710 mark_as_advanced(GMX_BUILD_HELP)
 711 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 712     message(FATAL_ERROR
 713         "Rebuilding shell completions or man pages is not supported for "
 714         "in-source builds from a source distribution. "
 715         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 716 endif()
 717
 718 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 719 # these are set after everything else
 720 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 721     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 722     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 723     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 724     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 725 else()
 726     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 727     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 728     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 729     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 730     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 731     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 732     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 733     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 734     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 735 endif()
 736
 737 if(NOT GMX_OPENMP)
 738     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 739     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 740     unset(OpenMP_C_FLAGS CACHE)
 741     unset(OpenMP_CXX_FLAGS CACHE)
 742 else()
 743     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 744     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 745 endif()
 746
 747 ########################################################################
 748 # Specify install locations
 749 ########################################################################
 750 # Use GNUInstallDirs to set paths on multiarch systems.
 751 include(GNUInstallDirs)
 752
 753 # Customization for the installation tree paths.
 754 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 755     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 756 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 757     "Data installation directory under share/ (default: gromacs)")
 758 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 759
 760 # These variables are used internally to provide a central location for
 761 # customizing the install locations.
 762 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 763 set(BIN_INSTALL_DIR       bin)
 764 # This variable also gets written into config.h for use in finding the data
 765 # directories.
 766 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 767 set(MAN_INSTALL_DIR       share/man)
 768 # If the nesting level wrt. the installation root is changed,
 769 # gromacs-config.cmake.cmakein needs to be adapted.
 770 set(CMAKE_INSTALL_DIR     share/cmake)
 771 # TODO: Make GMXRC adapt if this is changed
 772 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 773 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 774 set(INCL_INSTALL_DIR      include)
 775
 776 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 777
 778 # Binary and library suffix options
 779 include(gmxManageSuffixes)
 780
 781 ################################################################
 782 # Shared library load path settings
 783 ################################################################
 784 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 785 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 786 # was added.
 787
 788 if(NOT GMX_BUILD_SHARED_EXE)
 789     # No rpath
 790     set(CMAKE_SKIP_RPATH TRUE)
 791     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 792     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 793 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 794    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 795     # The build folder always has bin/ and lib/; if we are also going to
 796     # install to lib/, then the installation RPATH works also in the build
 797     # tree.  This makes installation slightly faster (no need to rewrite the
 798     # RPATHs), and makes the binaries in the build tree relocatable.
 799     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 800         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 801     endif()
 802     # Set the RPATH as relative to the executable location to make the
 803     # binaries relocatable.
 804     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 805         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 806     else()
 807         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 808     endif()
 809     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 810     set(CMAKE_MACOSX_RPATH 1)
 811 else()
 812     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 813     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 814         # Set the RPATH options manually.
 815         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 816         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 817     else()
 818         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 819         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 820     endif()
 821 endif()
 822
 823 #COPYING file: Only necessary for binary distributions.
 824 #Simpler to always install.
 825 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 826
 827 if (GMX_BUILD_FOR_COVERAGE)
 828     # Code heavy with asserts makes conditional coverage close to useless metric,
 829     # as by design most of the false branches are impossible to trigger in
 830     # correctly functioning code.  And the benefit of testing those that could
 831     # be triggered by using an API against its specification isn't usually
 832     # worth the effort.
 833     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 834 endif()
 835
 836 if (BUILD_TESTING)
 837     # "tests" target builds all the separate test binaries.
 838     add_custom_target(tests)
 839     # "run-ctest" is an internal target that actually runs the tests.
 840     # This is necessary to be able to add separate targets that execute as part
 841     # of 'make check', but are ensured to be executed after the actual tests.
 842     add_custom_target(run-ctest
 843                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 844                       COMMENT "Running all tests"
 845                       VERBATIM)
 846     add_dependencies(run-ctest tests)
 847     # "check" target builds and runs all tests.
 848     add_custom_target(check DEPENDS run-ctest)
 849 endif()
 850
 851 if (NOT GMX_BUILD_MDRUN_ONLY)
 852     add_subdirectory(docs)
 853     add_subdirectory(share)
 854     add_subdirectory(scripts)
 855 endif()
 856 add_subdirectory(src)
 857
 858 if (BUILD_TESTING)
 859     add_subdirectory(tests)
 860 endif()
 861
 862 gmx_cpack_write_config()
 863
 864 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 865 # Don't bother the user after the first configure pass.
 866 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 867     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 868 endif()
 869 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 870
 871 #######################
 872 ## uninstall target
 873 #######################
 874 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 875                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 876                   IMMEDIATE @ONLY)
 877 ###########################
 878 ADD_CUSTOM_TARGET(uninstall
 879                   "${CMAKE_COMMAND}" -P
 880                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 881 ###########################
 882 set_directory_properties(PROPERTIES
 883             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")