cmake/gmxTestCompilerProblems.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CheckCXXSourceCompiles)
  36
  37 # Macro that runs through a number of tests for buggy compiler
  38 # versions, or other potential problems.
  39 macro(gmx_test_compiler_problems)
  40
  41     # Warn if C and C++ compilers do not match
  42     if(NOT CMAKE_C_COMPILER_ID STREQUAL CMAKE_CXX_COMPILER_ID)
  43         message(WARNING "The ids of the C and C++ compilers do not match (${CMAKE_C_COMPILER_ID} and ${CMAKE_CXX_COMPILER_ID}, respectively). Mixing different C/C++ compilers can cause problems.")
  44     endif()
  45     if(NOT CMAKE_C_COMPILER_VERSION STREQUAL CMAKE_CXX_COMPILER_VERSION)
  46         message(WARNING "The versions of the C and C++ compilers do not match (${CMAKE_C_COMPILER_VERSION} and ${CMAKE_CXX_COMPILER_VERSION}, respectively). Mixing different C/C++ compilers can cause problems.")
  47     endif()
  48
  49     # Error if compiler doesn't support required C++14 features.
  50     # cmake feature detection is currently inconsistent: gitlab.kitware.com/cmake/cmake/issues/18869
  51     # When we use C++17 we might want to switch to using feature test macros.
  52     if(CMAKE_COMPILER_IS_GNUCXX)
  53         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5)
  54             set(cxx_required_version "GCC version 5")
  55         endif()
  56     elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  57         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.15)
  58             set(cxx_required_version "Visual Studio 2017")
  59         endif()
  60     elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  61         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.6) # For feature complete C++14 only 3.4 is needed.
  62             set(cxx_required_version "Clang 3.6")        # But prior version have bugs (e.g. debug symbol support)
  63         endif()
  64     elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  65         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17)
  66             set(cxx_required_version "Intel Compiler 2017")
  67         endif()
  68     else()
  69         message(WARNING "You are using an unsupported compiler. Please make sure it fully supports C++14.")
  70     endif()
  71     if (cxx_required_version)
  72         message(FATAL_ERROR "${cxx_required_version} or later required. "
  73                             "Earlier versions don't have full C++14 support.")
  74     endif()
  75
  76     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "XL")
  77         check_cxx_source_compiles(
  78 "// Test in-class array initalizers used with constructor initializer lists
  79 struct TestStruct
  80 {
  81     float a[3][3] = {{0}}; // in-class initializer
  82     float b; // not initialized until constructor initializer list
  83     TestStruct();
  84 };
  85 TestStruct::TestStruct() : b(0) {}
  86 }" XLC_COMPILES_CORRECTLY)
  87         if (NOT XLC_COMPILES_CORRECTLY)
  88             message(FATAL_ERROR "No known version of xlC can compile the normal C++11 code in GROMACS, highest version checked is 16.1.0")
  89         endif()
  90     endif()
  91     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "PGI")
  92         message(WARNING "Currently tested PGI compiler versions (up to 15.7) generate binaries that do not pass all regression test, and the generated binaries are significantly slower than with GCC, ICC or Clang. For now we do not recommend PGI beyond development testing - make sure to run the regressiontests.")
  93     endif()
  94
  95 endmacro(gmx_test_compiler_problems)