src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 ######################################
  38 # Output compiler and CFLAGS used
  39 ######################################
  40 include(GetCompilerInfo.cmake)
  41 get_compiler_info(C BUILD_C_COMPILER)
  42 get_compiler_info(CXX BUILD_CXX_COMPILER)
  43 if(GMX_USE_CUDA)
  44     if(NOT GMX_CLANG_CUDA)
  45         GMX_SET_CUDA_NVCC_FLAGS()
  46     endif()
  47
  48     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_DEVICE_COMPILER_FLAGS CUDA_HOST_COMPILER_FLAGS)
  49 endif()
  50
  51 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UPPER)
  52 configure_file(config.h.cmakein config.h)
  53 configure_file(gmxpre-config.h.cmakein gmxpre-config.h)
  54 configure_file(buildinfo.h.cmakein buildinfo.h ESCAPE_QUOTES)
  55 # Make a file with compiler flags used for libgromacs for each
  56 # langauge and build configuration.  The one that corresponds to
  57 # CMAKE_BUILD_TYPE is #included into buildinfo.h and populates the
  58 # fields e.g. printed to the log file.
  59 file(GENERATE
  60     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/compilerflaginfo-$<CONFIG>-$<COMPILE_LANGUAGE>.h
  61     INPUT ${CMAKE_CURRENT_SOURCE_DIR}/compilerflaginfo.h.cmakein
  62     CONDITION $<CONFIG:${CMAKE_BUILD_TYPE}>
  63     )
  64
  65 ####
  66 set(IGNORED_CLANG_ALL_WARNINGS
  67     "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  68     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  69     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  70     "-Wno-documentation-unknown-command" #Custom commands are used
  71     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  72     "-Wno-switch-enum" # default statement for enum is OK
  73
  74     # We need to use macros like
  75     # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  76     # if they don't have a semicolon after them, and might confuse
  77     # tools like IDEs also.
  78     "-Wno-extra-semi-stmt"
  79
  80     #Following ones are undecided/TODO
  81     "-Wno-disabled-macro-expansion"
  82     "-Wno-cast-align"
  83     "-Wno-reserved-id-macro"
  84     "-Wno-global-constructors"
  85     "-Wno-exit-time-destructors"
  86     "-Wno-unused-macros"
  87     "-Wno-weak-vtables"
  88     "-Wno-conditional-uninitialized"
  89     "-Wno-format-nonliteral"
  90     "-Wno-shadow"
  91     "-Wno-cast-qual"
  92     "-Wno-documentation"
  93     "-Wno-used-but-marked-unused"
  94     "-Wno-padded"
  95     "-Wno-float-equal"
  96     "-Wno-old-style-cast"
  97     "-Wno-conversion"
  98     "-Wno-double-promotion")
  99 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
 100
 101 option(GMX_CLANG_TIDY "Use clang-tidy" OFF)
 102 if (GMX_CLANG_TIDY)
 103    if("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
 104    elseif("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithAssert")
 105    elseif("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
 106    elseif("${CMAKE_BUILD_TYPE}" STREQUAL "ASAN")
 107    else()
 108        message(FATAL_ERROR "Can only use clang-tidy with build type containing asserts: Debug, RelWithAssert, RelWithDebInfo, ASAN.")
 109    endif()
 110    set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
 111    mark_as_advanced(CMAKE_EXPORT_COMPILE_COMMANDS)
 112    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
 113    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
 114        DOC "Path to clang-tidy executable")
 115    if(NOT CLANG_TIDY_EXE)
 116        message(FATAL_ERROR "clang-tidy not found.")
 117    endif()
 118    mark_as_advanced(CLANG_TIDY)
 119    mark_as_advanced(CLANG_TIDY_EXE)
 120 endif()
 121
 122 add_subdirectory(external)
 123
 124 if (BUILD_TESTING)
 125     if(NOT GMX_DEVELOPER_BUILD)
 126         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
 127     endif()
 128     include(testutils/TestMacros.cmake)
 129     add_subdirectory(testutils)
 130 endif()
 131
 132 add_subdirectory(gromacs)
 133 add_subdirectory(programs)
 134
 135 # Activate targets for new C++ API components and docs.
 136 if(GMX_NATIVE_WINDOWS OR GMX_BUILD_MDRUN_ONLY OR NOT BUILD_SHARED_LIBS)
 137     # GMXAPI has not been tested in Microsoft environments.
 138     # GMXAPI relies on libgromacs and is incompatible with an `mdrun`-only build.
 139     # GMXAPI requires position-independent code
 140     set(_GMXAPI_DEFAULT OFF)
 141 else()
 142     set(_GMXAPI_DEFAULT ON)
 143 endif()
 144 option(GMXAPI "Experimental external interfaces" ${_GMXAPI_DEFAULT})
 145 if (GMXAPI)
 146    if (GMX_BUILD_MDRUN_ONLY)
 147        message(FATAL_ERROR "GMXAPI relies on libgromacs and is incompatible with GMX_BUILD_MDRUN_ONLY.")
 148    endif()
 149    if(NOT ${BUILD_SHARED_LIBS})
 150        # Note: this conditional should check for the existence of a libgromacs target supporting PIC
 151        # using the POSITION_INDEPENDENT_CODE property, but for now the only facility we have is the global
 152        # variable, BUILD_SHARED_LIBS.
 153        # TODO: gmxapi should gracefully build for dynamic linking or static linking for PIC or without.
 154        message(FATAL_ERROR "GMXAPI requires position-independent code. Set -DGMXAPI=OFF or -DBUILD_SHARED_LIBS=ON.")
 155    endif()
 156    add_subdirectory(api)
 157 endif()