CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsistencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 # Permit the user to specify a particular standard library, e.g. compiling
 132 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 133 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 134 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 135 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 136 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 137
 138 ########################################################################
 139 # Detect CXX11 support and flags
 140 ########################################################################
 141 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 142 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 143 # invalid options with the Intel Compilers, and we have added a line
 144 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 145 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 146 # a semicolon. Since this is also used as a separator in lists inside CMake,
 147 # that string ends up being split into two separate patterns, and the last
 148 # part is just a single word that also matches other messages. We solved this
 149 # by replacing the semicolon with a period that matches any character.
 150 #
 151 # These files should be removed from the source tree when a CMake version that
 152 # includes the features in question becomes required for building GROMACS.
 153 include(CheckCCompilerFlag)
 154 include(CheckCXXCompilerFlag)
 155
 156 # This must come early, since some of our configuration flag tests
 157 # depend on being able to compile C++11 source files.
 158 include(gmxTestCXX11)
 159 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 160
 161 # Make sure all C++ code will be compiled in C++11 mode, with the
 162 # expected standard library.
 163 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 164
 165 ########################################################################
 166 # User input options                                                   #
 167 ########################################################################
 168 include(gmxOptionUtilities)
 169
 170 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 171
 172 # Fujitsu only has SIMD in double precision, so this will be faster
 173 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 174 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 175 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 176 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 177
 178 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 179 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 180 gmx_dependent_option(
 181     GMX_MPI_IN_PLACE
 182     "Enable MPI_IN_PLACE for MPIs that have it defined"
 183     ON
 184     GMX_MPI)
 185 mark_as_advanced(GMX_MPI_IN_PLACE)
 186 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 187 mark_as_advanced(GMX_FAHCORE)
 188
 189 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 190 mark_as_advanced(GMX_COOL_QUOTES)
 191 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 192
 193 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 194
 195 # Decide on GPU settings based on user-settings and GPU/CUDA
 196 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 197 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 198 # requires CUDA 8.0
 199 if(MSVC)
 200     set(REQUIRED_CUDA_VERSION 8.0)
 201 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 202     set(REQUIRED_CUDA_VERSION 7.0)
 203 else()
 204     set(REQUIRED_CUDA_VERSION 6.5)
 205 endif()
 206 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 207
 208 # OpenCL required version: 1.1 or newer
 209 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 210
 211 if(NOT GMX_USE_OPENCL)
 212     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 213     include(gmxManageGPU)
 214     set(GMX_USE_CUDA ${GMX_GPU})
 215     if(GMX_GPU)
 216         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 217     else()
 218         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 219     endif()
 220 else()
 221     #Now the OpenCL path (for both AMD and NVIDIA)
 222     if(GMX_GPU)
 223         include(gmxManageOpenCL)
 224         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 225     else()
 226         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 227     endif()
 228 endif()
 229
 230 include(gmxDetectSimd)
 231 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 232
 233 gmx_option_multichoice(
 234     GMX_SIMD
 235     "SIMD instruction set for CPU kernels and compiler optimization"
 236     "${GMX_SUGGESTED_SIMD}"
 237     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 238
 239 if(GMX_TARGET_MIC)
 240     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 241 else()
 242     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 243 endif()
 244
 245 gmx_option_multichoice(
 246     GMX_FFT_LIBRARY
 247     "FFT library"
 248     "${GMX_FFT_LIBRARY_DEFAULT}"
 249     fftw3 mkl "fftpack[built-in]")
 250 gmx_dependent_option(
 251     GMX_BUILD_OWN_FFTW
 252     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 253     OFF
 254     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 255 gmx_dependent_option(
 256     GMX_DISABLE_FFTW_MEASURE
 257     "Do not optimize FFTW setups (not needed with SSE)"
 258     OFF
 259     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 260 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 261 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 262
 263 gmx_option_multichoice(
 264     GMX_QMMM_PROGRAM
 265     "QM package for QM/MM"
 266     None
 267     none gaussian mopac gamess orca)
 268
 269 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 271
 272 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 273
 274 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 275 mark_as_advanced(GMX_BROKEN_CALLOC)
 276 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 277 mark_as_advanced(GMX_LOAD_PLUGINS)
 278
 279 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 280
 281 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 282
 283 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 284
 285 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 286 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 287
 288 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 289 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 290
 291 option(GMX_BUILD_FOR_COVERAGE
 292        "Tune build for better code coverage metrics (e.g., disable asserts)"
 293        OFF)
 294 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 295
 296 option(GMX_DEVELOPER_BUILD
 297     "Enable Developer convenience features: always build unit-tests"
 298     OFF)
 299 mark_as_advanced(GMX_DEVELOPER_BUILD)
 300
 301 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 302 option(GMX_COMPILER_WARNINGS
 303     "Enable a default set of compiler warnings"
 304     ${GMX_COMPILER_WARNINGS_DEFAULT})
 305 mark_as_advanced(GMX_COMPILER_WARNINGS)
 306 # Always turn on compiler warnings with a developer build.
 307 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 308
 309 option(GMX_BUILD_SHARED_EXE
 310     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 311     ON)
 312 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 313
 314 ######################################################################
 315 # Detect OpenMP support
 316 ######################################################################
 317 # The OpenMP detection _must_ come before tests for other CFLAGS.
 318 include(gmxManageOpenMP)
 319
 320
 321
 322 ######################################################################
 323 # Compiler tests
 324 # These need to be done early (before further tests).
 325 #####################################################################
 326
 327 include(gmxCFlags)
 328 gmx_c_flags()
 329
 330 # This variable should be used for additional compiler flags which are not
 331 # generated in gmxCFlags nor are SIMD or MPI related.
 332 set(EXTRA_C_FLAGS "")
 333 set(EXTRA_CXX_FLAGS "")
 334
 335 # Run through a number of tests for buggy compilers and other issues
 336 include(gmxTestCompilerProblems)
 337 gmx_test_compiler_problems()
 338
 339 # Implement double-precision option. This is complicated because we
 340 # need installed headers to use the precision mode of the build that
 341 # produced the library, but cannot use config.h in that case. We also
 342 # want such variables to always have a definition, because #if is more
 343 # robust than #ifdef. So, we put this value on the compiler command
 344 # line in all cases.
 345 #
 346 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 347 # because no installed header needs it
 348 if(GMX_DOUBLE)
 349     set(GMX_DOUBLE_VALUE 1)
 350 else()
 351     set(GMX_DOUBLE_VALUE 0)
 352 endif()
 353 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 354 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 355
 356 if(WIN32)
 357     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 358     add_definitions(-DGMX_HAVE_WINSOCK)
 359 endif()
 360
 361
 362
 363 ########################################################################
 364 # Basic system tests (standard libraries, headers, functions, types)   #
 365 ########################################################################
 366 include(CheckIncludeFiles)
 367 include(CheckIncludeFileCXX)
 368 check_include_files(unistd.h     HAVE_UNISTD_H)
 369 check_include_files(pwd.h        HAVE_PWD_H)
 370 check_include_files(dirent.h     HAVE_DIRENT_H)
 371 check_include_files(time.h       HAVE_TIME_H)
 372 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 373 check_include_files(io.h         HAVE_IO_H)
 374 check_include_files(sched.h      HAVE_SCHED_H)
 375
 376 check_include_files(regex.h      HAVE_POSIX_REGEX)
 377 # TODO: It could be nice to inform the user if no regex support is found,
 378 # as selections won't be fully functional.
 379
 380 include(CheckCXXSymbolExists)
 381 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 382 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 383 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 384 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 385 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 386 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 387 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 388 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 389
 390 # We cannot check for the __builtins as symbols, but check if code compiles
 391 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 392 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 393 if(MSVC)
 394     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 395     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 396 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 397     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 398     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 399 endif()
 400
 401 include(CheckLibraryExists)
 402 find_library(HAVE_LIBM m)
 403 mark_as_advanced(HAVE_LIBM)
 404 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 405 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 406
 407 include(TestSchedAffinity)
 408 test_sched_affinity(HAVE_SCHED_AFFINITY)
 409
 410 # Aligned memory allocation. We need to check for both mm_malloc(),
 411 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 412 include(gmxTestMMMalloc)
 413 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 414 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 415 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 416 if(MSVC)
 417     # No need to waste time on this test on platforms where it will never be true
 418     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 419 endif()
 420
 421 include(TestBigEndian)
 422 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 423
 424 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 425
 426 # Management of GROMACS options for specific toolchains should go
 427 # here. Because the initial settings for some of the main options have
 428 # already happened, but things like library detection and MPI compiler
 429 # feature detection have not, the docstrings for any over-rides of
 430 # GROMACS defaults or user settings will make sense. Also, any
 431 # toolchain-related reasons for choosing whether to detect various
 432 # things can be sorted out now, before the detection takes place.
 433 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 434     include(gmxManageBlueGene)
 435 endif()
 436
 437 if(GMX_TARGET_FUJITSU_SPARC64)
 438     include(gmxManageFujitsuSparc64)
 439 endif()
 440
 441 ########################################################################
 442 #Process MPI settings
 443 ########################################################################
 444 include(gmxManageMPI)
 445
 446
 447 ########################################################################
 448 #Process shared/static library settings
 449 ########################################################################
 450 include(gmxManageSharedLibraries)
 451
 452
 453 ########################################################################
 454 # Find external packages                                               #
 455 ########################################################################
 456
 457 # Unconditionally find the package, as it is also required for unit
 458 # tests. This exports LIBXML2_FOUND, which we should not use because
 459 # it does not tell us that linking will succeed. Instead, we test that
 460 # next.
 461 #if(DEFINED LIBXML2_LIBRARIES)
 462 #  set(LibXml2_FIND_QUIETLY TRUE)
 463 #endif()
 464 #find_package(LibXml2)
 465 #include(gmxTestLibXml2)
 466 #gmx_test_libxml2(HAVE_LIBXML2)
 467 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 468 #set(PKG_XML "")
 469 #mark_as_advanced(GMX_XML)
 470 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 471 #if(GMX_XML AND NOT HAVE_LIBXML2)
 472 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 473 #endif()
 474 #if(GMX_XML)
 475 #    include_directories(${LIBXML2_INCLUDE_DIR})
 476 #    set(PKG_XML libxml-2.0)
 477 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 478 #endif()
 479
 480 if(DEFINED HWLOC_LIBRARIES)
 481   set(Hwloc_FIND_QUIETLY TRUE)
 482 endif()
 483 find_package(Hwloc 1.5)
 484 if(HWLOC_FOUND)
 485     set(GMX_HWLOC_DEFAULT ON)
 486 else()
 487     set(GMX_HWLOC_DEFAULT OFF)
 488 endif()
 489 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 490 if(GMX_HWLOC)
 491     if(HWLOC_FOUND)
 492         include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 493         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 494     else()
 495         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 496     endif()
 497 endif()
 498
 499 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 500 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 501 if(GMX_EXTERNAL_TINYXML2)
 502     # Find an external TinyXML-2 library.
 503     find_package(TinyXML-2 3.0.0)
 504     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 505     if(NOT HAVE_TINYXML2)
 506         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 507     endif()
 508 endif()
 509
 510 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 511 mark_as_advanced(GMX_EXTRAE)
 512
 513 if (GMX_EXTRAE)
 514   find_package(EXTRAE)
 515   if(EXTRAE_FOUND)
 516     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 517     set(HAVE_EXTRAE 1)
 518   else()
 519     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 520   endif()
 521 endif()
 522
 523 option(GMX_X11 "Use X window system" OFF)
 524 if (GMX_X11)
 525     find_package(X11)
 526     # X11 includes/libraries are only set in the ngmx subdirectory!
 527     if(NOT X11_FOUND)
 528         message(FATAL_ERROR
 529                 "X11 include files and/or libraries were not found. "
 530                 "Set GMX_X11=OFF to compile without X11 support. "
 531                 "gmx view will not be available.")
 532     endif()
 533     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 534 endif()
 535
 536 include(ThreadMPI)
 537 # Enable core threading facilities
 538 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 539 # Enable tMPI C++ support
 540 tmpi_enable_cxx()
 541 if(GMX_THREAD_MPI)
 542     # enable MPI functions
 543     tmpi_enable()
 544     set(MPI_IN_PLACE_EXISTS 1)
 545 endif()
 546 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 547 if (TMPI_ATOMICS_DISABLED)
 548    add_definitions(-DTMPI_ATOMICS_DISABLED)
 549 endif()
 550
 551 include(gmxManageTNG)
 552
 553 include(gmxManageLmfit)
 554
 555 if(GMX_GPU)
 556     # now that we have detected the dependencies, do the second configure pass
 557     gmx_gpu_setup()
 558 endif()
 559
 560 if(CYGWIN)
 561     set(GMX_CYGWIN 1)
 562 endif()
 563
 564 if(WIN32)
 565     set(GMX_NATIVE_WINDOWS 1)
 566     # This makes windows.h not declare min/max as macros that would break
 567     # C++ code using std::min/std::max.
 568     add_definitions(-DNOMINMAX)
 569 endif()
 570
 571 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 572     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 573         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 574     endif()
 575     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 576         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 577     endif()
 578 endif()
 579
 580 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 581 mark_as_advanced(GMX_BUILD_UNITTESTS)
 582 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 583
 584 ########################################################################
 585 # Our own GROMACS tests
 586 ########################################################################
 587
 588 add_definitions( -DHAVE_CONFIG_H )
 589 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 590 # TODO required at high level because both libgromacs and progs/mdrun
 591 # require it, both for thread-MPI and its atomics and mutexes.
 592 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 593 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 594 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 595
 596 include(gmxTestInlineASM)
 597 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 598
 599 include(gmxSetBuildInformation)
 600 gmx_set_build_information()
 601 # Turn on RDTSCP if:
 602 # - the build system's CPU supports it
 603 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 604 #   at this point means that the user set it).
 605 # Note: it's better to not use the later set value of GMX_SIMD because
 606 # it reflects the system's capability of both compiling and running AVX code.
 607 # TODO: After merge with 5.0 one could implement a cache variable dependency
 608 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 609 # after the first cmake pass.
 610 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 611     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 612 else()
 613     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 614 endif()
 615 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 616 mark_as_advanced(GMX_USE_RDTSCP)
 617 if(GMX_USE_RDTSCP)
 618     set(HAVE_RDTSCP 1)
 619 endif()
 620
 621 include(gmxTestLargeFiles)
 622 gmx_test_large_files(GMX_LARGEFILES)
 623
 624 include(gmxTestSignal)
 625 gmx_test_sigusr1(HAVE_SIGUSR1)
 626
 627 include(gmxTestPipes)
 628 gmx_test_pipes(HAVE_PIPES)
 629
 630 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 631
 632 include(gmxTestXDR)
 633 gmx_test_xdr(GMX_SYSTEM_XDR)
 634 if(NOT GMX_SYSTEM_XDR)
 635     set(GMX_INTERNAL_XDR 1)
 636 endif()
 637
 638
 639 ##################################################
 640 # Process SIMD instruction settings
 641 ##################################################
 642 # This checks what flags to add in order to
 643 # support the SIMD instructions we need, it sets
 644 # correct defines for the SIMD instructions supported,
 645 # and adds advanced options to control accuracy
 646 # for SIMD math operations.
 647 include(gmxManageSimd)
 648 gmx_manage_simd()
 649
 650 include(gmxManageCycleCounters)
 651 gmx_manage_cycle_counters()
 652
 653 # Process QM/MM Settings
 654 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 655     set(GMX_QMMM_GAUSSIAN 1)
 656 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 657     set(GMX_QMMM_MOPAC 1)
 658 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 659     set(GMX_QMMM_GAMESS 1)
 660 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 661     set(GMX_QMMM_ORCA 1)
 662 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 663     # nothing to do
 664 else()
 665     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 666 endif()
 667
 668
 669 ##################################################
 670 # Process FFT library settings
 671 ##################################################
 672 include(gmxManageFFTLibraries)
 673
 674
 675 include(gmxManageLinearAlgebraLibraries)
 676
 677 # Whether GROMACS will really try to compile support for VMD plugins
 678 set(GMX_USE_PLUGINS OFF)
 679
 680 if(GMX_LOAD_PLUGINS)
 681   if(NOT WIN32)
 682     # Native Windows does not have, nor need dlopen
 683     include(gmxTestdlopen)
 684     gmx_test_dlopen(HAVE_DLOPEN)
 685   endif()
 686
 687   # so, should we use plug-ins?
 688   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 689     if(NOT VMD_QUIETLY)
 690       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 691     endif()
 692     if(NOT GMX_VMD_PLUGIN_PATH)
 693       find_package(VMD)
 694     endif()
 695     set(GMX_USE_PLUGINS ON)
 696     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 697     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 698   else()
 699     set(PKG_DL_LIBS)
 700   endif()
 701 endif()
 702 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 703
 704 # Link real-time library for POSIX timers. The check for clock_gettime
 705 # confirms the linkability of rt.
 706 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 707     list(APPEND GMX_EXTRA_LIBRARIES rt)
 708 endif()
 709
 710 # Math and thread libraries must often come after all others when linking...
 711 if(HAVE_LIBM)
 712     list(APPEND GMX_EXTRA_LIBRARIES m)
 713 endif()
 714
 715 option(GMX_NACL "Configure for Native Client builds" OFF)
 716 if (GMX_NACL)
 717   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 718   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 719   # TODO: Is this still necessary with the check for its presence?
 720   set(GMX_USE_NICE 0)
 721   set(GMX_NO_RENAME 1)
 722 endif()
 723 mark_as_advanced(GMX_NACL)
 724
 725 if(GMX_FAHCORE)
 726   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 727       "Path to swindirect.h")
 728   include_directories(${COREWRAP_INCLUDE_DIR})
 729 endif()
 730
 731 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 732 # produce warnings if that fails.
 733 set(build_help_default AUTO)
 734 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 735     set(build_help_default OFF)
 736 endif()
 737 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 738 mark_as_advanced(GMX_BUILD_HELP)
 739 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 740     message(FATAL_ERROR
 741         "Rebuilding shell completions or man pages is not supported for "
 742         "in-source builds from a source distribution. "
 743         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 744 endif()
 745
 746 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 747 # these are set after everything else
 748 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 749     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 750     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 751     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 752     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 753 else()
 754     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 755     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 756     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 757     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 758     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 759     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 760     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 761     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 762     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 763 endif()
 764
 765 if(NOT GMX_OPENMP)
 766     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 767     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 768     unset(OpenMP_C_FLAGS CACHE)
 769     unset(OpenMP_CXX_FLAGS CACHE)
 770 else()
 771     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 772     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 773 endif()
 774
 775 ########################################################################
 776 # Specify install locations
 777 ########################################################################
 778 # Use GNUInstallDirs to set paths on multiarch systems.
 779 include(GNUInstallDirs)
 780
 781 # Customization for the installation tree paths.
 782 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 783     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 784 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 785     "Data installation directory under share/ (default: gromacs)")
 786 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 787
 788 # These variables are used internally to provide a central location for
 789 # customizing the install locations.
 790 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 791 set(BIN_INSTALL_DIR       bin)
 792 # This variable also gets written into config.h for use in finding the data
 793 # directories.
 794 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 795 set(MAN_INSTALL_DIR       share/man)
 796 # If the nesting level wrt. the installation root is changed,
 797 # gromacs-config.cmake.cmakein needs to be adapted.
 798 set(CMAKE_INSTALL_DIR     share/cmake)
 799 # TODO: Make GMXRC adapt if this is changed
 800 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 801 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 802 set(INCL_INSTALL_DIR      include)
 803
 804 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 805
 806 # Binary and library suffix options
 807 include(gmxManageSuffixes)
 808
 809 ################################################################
 810 # Shared library load path settings
 811 ################################################################
 812 if(NOT GMX_BUILD_SHARED_EXE)
 813     # No rpath
 814     set(CMAKE_SKIP_RPATH TRUE)
 815     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 816     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 817 else()
 818     # The build folder always has bin/ and lib/; if we are also going to
 819     # install to lib/, then the installation RPATH works also in the build
 820     # tree.  This makes installation slightly faster (no need to rewrite the
 821     # RPATHs), and makes the binaries in the build tree relocatable.
 822     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 823         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 824     endif()
 825     # Set the RPATH as relative to the executable location to make the
 826     # binaries relocatable.
 827     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 828         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 829     else()
 830         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 831     endif()
 832     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 833     set(CMAKE_MACOSX_RPATH 1)
 834 endif()
 835
 836 #COPYING file: Only necessary for binary distributions.
 837 #Simpler to always install.
 838 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 839
 840 if (GMX_BUILD_FOR_COVERAGE)
 841     # Code heavy with asserts makes conditional coverage close to useless metric,
 842     # as by design most of the false branches are impossible to trigger in
 843     # correctly functioning code.  And the benefit of testing those that could
 844     # be triggered by using an API against its specification isn't usually
 845     # worth the effort.
 846     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 847 endif()
 848
 849 if (BUILD_TESTING)
 850     include(tests/CheckTarget.cmake)
 851 endif()
 852
 853 if (NOT GMX_BUILD_MDRUN_ONLY)
 854     add_subdirectory(docs)
 855     add_subdirectory(share)
 856     add_subdirectory(scripts)
 857 endif()
 858 add_subdirectory(src)
 859
 860 if (BUILD_TESTING)
 861     add_subdirectory(tests)
 862 endif()
 863
 864 gmx_cpack_write_config()
 865
 866 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 867 # Don't bother the user after the first configure pass.
 868 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 869     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 870 endif()
 871 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 872
 873 #######################
 874 ## uninstall target
 875 #######################
 876 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 877                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 878                   IMMEDIATE @ONLY)
 879 ###########################
 880 ADD_CUSTOM_TARGET(uninstall
 881                   "${CMAKE_COMMAND}" -P
 882                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 883 ###########################
 884 set_directory_properties(PROPERTIES
 885             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")