cmake/gmxManageSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(gmxFindFlagsForSource)
  36
  37 # Macro that manages setting the respective C and C++ toolchain
  38 # variables so that subsequent tests for SIMD support can work.
  39 macro(prepare_x86_toolchain TOOLCHAIN_C_FLAGS_VARIABLE TOOLCHAIN_CXX_FLAGS_VARIABLE)
  40     # On OS X, we often want to use gcc instead of clang, since gcc
  41     # supports OpenMP (until clang 3.8, or so, plus whenever Apple
  42     # support it in their version). However, by default gcc uses the
  43     # external system assembler, which does not support AVX, so we
  44     # need to tell the linker to use the clang compilers assembler
  45     # instead - and this has to happen before we detect AVX flags.
  46     if(APPLE AND CMAKE_C_COMPILER_ID STREQUAL "GNU")
  47         gmx_test_cflag(GNU_C_USE_CLANG_AS "-Wa,-q" ${TOOLCHAIN_C_FLAGS_VARIABLE})
  48     endif()
  49     if(APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  50         gmx_test_cxxflag(GNU_CXX_USE_CLANG_AS "-Wa,-q" ${TOOLCHAIN_CXX_FLAGS_VARIABLE})
  51     endif()
  52 endmacro()
  53
  54 # Macro that manages setting the respective C and C++ toolchain
  55 # variables so that subsequent tests for SIMD support can work.
  56 macro(prepare_power_vsx_toolchain TOOLCHAIN_C_FLAGS_VARIABLE TOOLCHAIN_CXX_FLAGS_VARIABLE)
  57     if(${CMAKE_CXX_COMPILER_ID} MATCHES "GNU" OR ${CMAKE_C_COMPILER_ID} MATCHES "GNU")
  58         # VSX uses the same function API as Altivec/VMX, so make sure we tune for the current CPU and not VMX.
  59         # By putting these flags here rather than in the general compiler flags file we can safely assume
  60         # that we are at least on Power7 since that is when VSX appeared.
  61         if(BUILD_CPU_BRAND MATCHES "POWER7")
  62             gmx_test_cflag(GNU_C_VSX_POWER7   "-mcpu=power7 -mtune=power7" ${TOOLCHAIN_C_FLAGS_VARIABLE})
  63             gmx_test_cflag(GNU_CXX_VSX_POWER7 "-mcpu=power7 -mtune=power7" ${TOOLCHAIN_CXX_FLAGS_VARIABLE})
  64         else()
  65             # Enable power8 vector extensions on all platforms except old Power7.
  66             gmx_test_cflag(GNU_C_VSX_POWER8   "-mcpu=power8 -mpower8-vector -mpower8-fusion -mdirect-move" ${TOOLCHAIN_C_FLAGS_VARIABLE})
  67             gmx_test_cflag(GNU_CXX_VSX_POWER8 "-mcpu=power8 -mpower8-vector -mpower8-fusion -mdirect-move" ${TOOLCHAIN_CXX_FLAGS_VARIABLE})
  68         endif()
  69         # Altivec was originally single-only, and it took a while for compilers
  70         # to support the double-precision features in VSX.
  71         if(GMX_DOUBLE AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  72             message(FATAL_ERROR "Using VSX SIMD in double precision with GCC requires GCC-4.9 or later.")
  73         endif()
  74     endif()
  75 endmacro()
  76
  77 # Issue a fatal error with an appropriate message, when the toolchain
  78 # was not able to compile code for SIMD support.
  79 #
  80 # Inputs:
  81 #  SIMD_STRING              A string describing the kind of SIMD support that didn't work.
  82 #  ALTERNATIVE_SUGGESTION   A string describing anything the user could try other than getting a new compiler.
  83 #  SUGGEST_BINUTILS_UPDATE  True when there's information that the compiler was OK, but something else was not.
  84 function(gmx_give_fatal_error_when_simd_support_not_found SIMD_STRING ALTERNATIVE_SUGGESTION SUGGEST_BINUTILS_UPDATE)
  85     if(SUGGEST_BINUTILS_UPDATE)
  86         set(_msg "Found a compiler flag for ${SIMD_STRING} support, but some other problem exists. Update your assembler and/or linker, e.g. in the binutils package of your distribution.")
  87     else()
  88         set(_msg "Cannot find ${SIMD_STRING} compiler flag. Use a newer compiler, or ${ALTERNATIVE_SUGGESTION}.")
  89     endif()
  90     message(FATAL_ERROR ${_msg})
  91 endfunction()
  92
  93 macro(gmx_manage_simd)
  94
  95 set(GMX_SIMD_ACCURACY_BITS_SINGLE 22 CACHE STRING "Target mantissa bits for SIMD single math")
  96 #
  97 # Note that we typically restrict double precision target accuracy to be twice that
  98 # of single. This means we only need one more N-R iteration for 1/sqrt(x) and 1(x),
  99 # and the first iteration can sometimes be done as a pair in single precision. This should
 100 # be plenty enough for Molecular Dynamics applications. Many of our double precision math
 101 # functions still achieve very close to full double precision, but we do not guarantee that
 102 # they will be able to achieve higher accuracy if you set this beyond 44 bits. GROMACS will
 103 # work - but some unit tests might fail.
 104 #
 105 set(GMX_SIMD_ACCURACY_BITS_DOUBLE 44 CACHE STRING "Target mantissa bits for SIMD double math")
 106 mark_as_advanced(GMX_SIMD_ACCURACY_BITS_SINGLE)
 107 mark_as_advanced(GMX_SIMD_ACCURACY_BITS_DOUBLE)
 108
 109 if(${GMX_SIMD_ACCURACY_BITS_SINGLE} GREATER 22)
 110     message(STATUS "Note: Full mantissa accuracy (including least significant bit) requested for SIMD single math. Presently we cannot get the least significant bit correct since that would require different algorithms - reducing to 22 bits.")
 111     set(GMX_SIMD_ACCURACY_BITS_SINGLE 22 CACHE STRING "Target mantissa bits for SIMD single math" FORCE)
 112 endif()
 113
 114 if(${GMX_SIMD_ACCURACY_BITS_DOUBLE} GREATER 51)
 115     message(STATUS "Note: Full mantissa accuracy (including least significant bit) requested for SIMD double math. Presently we cannot get the least significant bit correct since that would require different algorithms - reducing to 51 bits.")
 116     set(GMX_SIMD_ACCURACY_BITS_DOUBLE 51 CACHE STRING "Target mantissa bits for SIMD double math" FORCE)
 117 endif()
 118
 119 #
 120 # Section to set (and test) compiler flags for SIMD.
 121 #
 122 # The flags will be set based on the GMX_SIMD choice provided by the user.
 123 # Automatic detection of the architecture on the build host is done prior to
 124 # calling this macro.
 125 #
 126
 127 if(GMX_SIMD STREQUAL "NONE")
 128     # nothing to do configuration-wise
 129     set(SIMD_STATUS_MESSAGE "SIMD instructions disabled")
 130 elseif(GMX_SIMD STREQUAL "SSE2")
 131
 132     gmx_find_flags(
 133         "#include<xmmintrin.h>
 134          int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_rsqrt_ps(x);return _mm_movemask_ps(x);}"
 135         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 136         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 137         "-msse2" "/arch:SSE2" "-hgnu")
 138
 139     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 140         gmx_give_fatal_error_when_simd_support_not_found("SSE2" "disable SIMD support (slow)" "${SUGGEST_BINUTILS_UPDATE}")
 141     endif()
 142
 143     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 144     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 145     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 146     set(SIMD_STATUS_MESSAGE "Enabling SSE2 SIMD instructions")
 147
 148 elseif(GMX_SIMD STREQUAL "SSE4.1")
 149
 150     # Note: MSVC enables SSE4.1 with the SSE2 flag, so we include that in testing.
 151     gmx_find_flags(
 152         "#include<smmintrin.h>
 153         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_dp_ps(x,x,0x77);return _mm_movemask_ps(x);}"
 154         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 155         SIMD_SSE_4_1_C_FLAGS SIMD_SSE_4_1_CXX_FLAGS
 156         "-msse4.1" "/arch:SSE4.1" "/arch:SSE2" "-hgnu")
 157
 158     if(NOT SIMD_SSE_4_1_C_FLAGS OR NOT SIMD_SSE_4_1_CXX_FLAGS)
 159         gmx_give_fatal_error_when_simd_support_not_found("SSE4.1" "choose SSE2 SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 160     endif()
 161
 162     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 163     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 164     set(GMX_SIMD_X86_SSE4_1 1)
 165     set(SIMD_STATUS_MESSAGE "Enabling SSE4.1 SIMD instructions")
 166
 167 elseif(GMX_SIMD STREQUAL "AVX_128_FMA")
 168
 169     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 170
 171     # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 172     # so we can't distinguish vanilla from Apple clang versions, but catering for a few rare AMD
 173     # hackintoshes is not worth the effort.
 174     if (APPLE AND (CMAKE_C_COMPILER_ID STREQUAL "Clang" OR
 175                 CMAKE_CXX_COMPILER_ID STREQUAL "Clang"))
 176         message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA SIMD. As we cannot work around this bug on OS X, you will have to select a different compiler or SIMD instruction set.")
 177     endif()
 178
 179     # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 180     # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 181     # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 182     # We can work around this by not using the integrated assembler (except on OS X
 183     # which has an outdated assembler that does not support AVX instructions).
 184     if (CMAKE_C_COMPILER_ID MATCHES "Clang" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "3.3")
 185         # we assume that we have an external assembler that supports AVX
 186         message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 187         set(TOOLCHAIN_C_FLAGS "${TOOLCHAIN_C_FLAGS} -no-integrated-as")
 188     endif()
 189     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "3.3")
 190         # we assume that we have an external assembler that supports AVX
 191         message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 192         set(TOOLCHAIN_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS} -no-integrated-as")
 193     endif()
 194
 195     # AVX128/FMA on AMD is a bit complicated. We need to do detection in three stages:
 196     # 1) Find the flags required for generic AVX support
 197     # 2) Find the flags necessary to enable fused-multiply add support
 198     # 3) Optional: Find a flag to enable the AMD XOP instructions
 199
 200     ### STAGE 1: Find the generic AVX flag
 201     gmx_find_flags(
 202         "#include<immintrin.h>
 203         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_permute_ps(x,1);return 0;}"
 204         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 205         SIMD_GENERIC_AVX_C_FLAGS SIMD_GENERIC_AVX_CXX_FLAGS
 206         "-mavx" "/arch:AVX" "-hgnu")
 207
 208     ### STAGE 2: Find the fused-multiply add flag.
 209     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 210     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${SIMD_C_FLAGS})
 211     check_include_file(intrin.h HAVE_INTRIN_H ${SIMD_C_FLAGS})
 212     if(HAVE_X86INTRIN_H)
 213         set(INCLUDE_X86INTRIN_H "#include <x86intrin.h>")
 214     endif()
 215     if(HAVE_INTRIN_H)
 216         set(INCLUDE_INTRIN_H "#include <xintrin.h>")
 217     endif()
 218
 219     gmx_find_flags(
 220         "#include<immintrin.h>
 221         ${INCLUDE_X86INTRIN_H}
 222         ${INCLUDE_INTRIN_H}
 223         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_macc_ps(x,x,x);return _mm_movemask_ps(x);}"
 224         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 225         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 226         "-mfma4" "-hgnu")
 227
 228     # We only need to check the last (FMA) test; that will always fail if the generic AVX test failed
 229     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 230         gmx_give_fatal_error_when_simd_support_not_found("128-bit AVX with FMA support" "choose SSE4.1 SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 231     endif()
 232
 233     ### STAGE 3: Optional: Find the XOP instruction flag (No point in yelling if this does not work)
 234     gmx_find_flags(
 235         "#include<immintrin.h>
 236         ${INCLUDE_X86INTRIN_H}
 237         ${INCLUDE_INTRIN_H}
 238         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_frcz_ps(x);return _mm_movemask_ps(x);}"
 239         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 240         SIMD_AVX_128_XOP_C_FLAGS SIMD_AVX_128_XOP_CXX_FLAGS
 241         "-mxop")
 242
 243     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 244     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 245     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 246     set(SIMD_STATUS_MESSAGE "Enabling 128-bit AVX SIMD GROMACS SIMD (with fused-multiply add)")
 247
 248 elseif(GMX_SIMD STREQUAL "AVX_256")
 249
 250     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 251
 252     gmx_find_flags(
 253         "#include<immintrin.h>
 254          int main(){__m256 x=_mm256_set1_ps(0.5);x=_mm256_add_ps(x,x);return _mm256_movemask_ps(x);}"
 255         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 256         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 257         "-mavx" "/arch:AVX" "-hgnu")
 258
 259     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 260         gmx_give_fatal_error_when_simd_support_not_found("AVX" "choose SSE4.1 SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 261     endif()
 262
 263     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 264     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 265     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 266     set(SIMD_STATUS_MESSAGE "Enabling 256-bit AVX SIMD instructions")
 267
 268 elseif(GMX_SIMD STREQUAL "AVX2_256")
 269
 270     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 271
 272     gmx_find_flags(
 273         "#include<immintrin.h>
 274          int main(){__m256i x=_mm256_set1_epi32(5);x=_mm256_add_epi32(x,x);return _mm256_movemask_epi8(x);}"
 275         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 276         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 277         "-march=core-avx2" "-mavx2" "/arch:AVX" "-hgnu") # no AVX2-specific flag for MSVC yet
 278
 279     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 280         gmx_give_fatal_error_when_simd_support_not_found("AVX2" "choose AVX SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 281     endif()
 282
 283     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 284     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 285     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 286     set(SIMD_STATUS_MESSAGE "Enabling 256-bit AVX2 SIMD instructions")
 287
 288 elseif(GMX_SIMD STREQUAL "MIC")
 289
 290     # No flags needed. Not testing.
 291     set(GMX_SIMD_X86_MIC 1)
 292     set(SIMD_STATUS_MESSAGE "Enabling MIC (Xeon Phi) SIMD instructions")
 293
 294 elseif(GMX_SIMD STREQUAL "AVX_512")
 295
 296     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 297
 298     gmx_find_flags(
 299         "#include<immintrin.h>
 300          int main(){__m512 y,x=_mm512_set1_ps(0.5);y=_mm512_fmadd_ps(x,x,x);return (int)_mm512_cmp_ps_mask(x,y,_CMP_LT_OS);}"
 301         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 302         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 303         "-xMIC-AVX512" "-mavx512f -mfma" "-mavx512f" "/arch:AVX" "-hgnu") # no AVX_512F flags known for MSVC yet
 304
 305     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 306         gmx_give_fatal_error_when_simd_support_not_found("AVX 512F" "choose a lower level of SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 307     endif()
 308
 309     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 310     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 311     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 312     set(SIMD_STATUS_MESSAGE "Enabling 512-bit AVX-512 SIMD instructions")
 313
 314 elseif(GMX_SIMD STREQUAL "AVX_512_KNL")
 315
 316     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 317
 318     gmx_find_flags(
 319         "#include<immintrin.h>
 320         int main(){__m512 y,x=_mm512_set1_ps(0.5);y=_mm512_rsqrt28_ps(x);return (int)_mm512_cmp_ps_mask(x,y,_CMP_LT_OS);}"
 321         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 322         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 323         "-xMIC-AVX512" "-mavx512er -mfma" "-mavx512er" "/arch:AVX" "-hgnu") # no AVX_512ER flags known for MSVC yet
 324
 325     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 326         gmx_give_fatal_error_when_simd_support_not_found("AVX 512ER" "choose a lower level of SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 327     endif()
 328
 329     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 330     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 331     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 332     set(SIMD_STATUS_MESSAGE "Enabling 512-bit AVX-512-KNL SIMD instructions")
 333
 334 elseif(GMX_SIMD STREQUAL "ARM_NEON")
 335
 336     gmx_find_flags(
 337         "#include<arm_neon.h>
 338          int main(){float32x4_t x=vdupq_n_f32(0.5);x=vmlaq_f32(x,x,x);return vgetq_lane_f32(x,0)>0;}"
 339         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 340         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 341         "-mfpu=neon-vfpv4" "-mfpu=neon" "")
 342
 343     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 344         gmx_give_fatal_error_when_simd_support_not_found("ARM NEON" "disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 345     endif()
 346
 347     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 348     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 349     set(GMX_SIMD_${GMX_SIMD} 1)
 350     set(SIMD_STATUS_MESSAGE "Enabling 32-bit ARM NEON SIMD instructions")
 351
 352 elseif(GMX_SIMD STREQUAL "ARM_NEON_ASIMD")
 353
 354     gmx_find_flags(
 355         "#include<arm_neon.h>
 356          int main(){float64x2_t x=vdupq_n_f64(0.5);x=vfmaq_f64(x,x,x);x=vrndnq_f64(x);return vgetq_lane_f64(x,0)>0;}"
 357         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 358         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 359         "")
 360
 361     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 362         gmx_give_fatal_error_when_simd_support_not_found("ARM (AArch64) NEON Advanced SIMD" "particularly gcc version 4.9 or later, or disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 363     endif()
 364
 365     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 366     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 367     set(GMX_SIMD_${GMX_SIMD} 1)
 368     set(SIMD_STATUS_MESSAGE "Enabling ARM (AArch64) NEON Advanced SIMD instructions")
 369
 370 elseif(GMX_SIMD STREQUAL "IBM_QPX")
 371
 372     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 373         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 374
 375     if (TEST_QPX)
 376         message(WARNING "IBM QPX SIMD instructions selected. This will work, but SIMD kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 377         set(GMX_SIMD_${GMX_SIMD} 1)
 378         set(SIMD_STATUS_MESSAGE "Enabling IBM QPX SIMD instructions")
 379
 380     else()
 381         gmx_give_fatal_error_when_simd_support_not_found("IBM QPX" "or 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-bgclang-CXX' to set up the tool chain" "${SUGGEST_BINUTILS_UPDATE}")
 382     endif()
 383
 384 elseif(GMX_SIMD STREQUAL "IBM_VMX")
 385
 386     gmx_find_flags(
 387         "#include<altivec.h>
 388          int main(){vector float x,y=vec_ctf(vec_splat_s32(1),0);x=vec_madd(y,y,y);return vec_all_ge(y,x);}"
 389         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 390         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 391         "-maltivec -mabi=altivec" "-qarch=auto -qaltivec")
 392
 393     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 394         gmx_give_fatal_error_when_simd_support_not_found("IBM VMX" "disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 395     endif()
 396
 397     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 398     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 399     set(GMX_SIMD_${GMX_SIMD} 1)
 400     set(SIMD_STATUS_MESSAGE "Enabling IBM VMX SIMD instructions")
 401
 402 elseif(GMX_SIMD STREQUAL "IBM_VSX")
 403
 404     prepare_power_vsx_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 405
 406     gmx_find_flags(
 407         "#include<altivec.h>
 408          int main(){vector double x,y=vec_splats(1.0);x=vec_madd(y,y,y);return vec_all_ge(y,x);}"
 409         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 410         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 411         "-mvsx" "-maltivec -mabi=altivec" "-qarch=auto -qaltivec")
 412
 413     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 414         gmx_give_fatal_error_when_simd_support_not_found("IBM VSX" "disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 415     endif()
 416
 417     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 418     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 419     set(GMX_SIMD_${GMX_SIMD} 1)
 420     set(SIMD_STATUS_MESSAGE "Enabling IBM VSX SIMD instructions")
 421
 422 elseif(GMX_SIMD STREQUAL "SPARC64_HPC_ACE")
 423
 424     # Note that GMX_RELAXED_DOUBLE_PRECISION is enabled by default in the top-level CMakeLists.txt
 425
 426     set(GMX_SIMD_${GMX_SIMD} 1)
 427     set(SIMD_STATUS_MESSAGE "Enabling Sparc64 HPC-ACE SIMD instructions")
 428
 429 elseif(GMX_SIMD STREQUAL "REFERENCE")
 430
 431     # NB: This file handles settings for the SIMD module, so in the interest
 432     # of proper modularization, please do NOT put any verlet kernel settings in this file.
 433
 434     if(GMX_SIMD_REF_FLOAT_WIDTH)
 435         add_definitions(-DGMX_SIMD_REF_FLOAT_WIDTH=${GMX_SIMD_REF_FLOAT_WIDTH})
 436     endif()
 437     if(GMX_SIMD_REF_DOUBLE_WIDTH)
 438         add_definitions(-DGMX_SIMD_REF_DOUBLE_WIDTH=${GMX_SIMD_REF_DOUBLE_WIDTH})
 439     endif()
 440
 441     set(GMX_SIMD_${GMX_SIMD} 1)
 442     set(SIMD_STATUS_MESSAGE "Enabling reference (emulated) SIMD instructions.")
 443
 444 else()
 445     gmx_invalid_option_value(GMX_SIMD)
 446 endif()
 447
 448
 449 gmx_check_if_changed(SIMD_CHANGED GMX_SIMD)
 450 if (SIMD_CHANGED AND DEFINED SIMD_STATUS_MESSAGE)
 451     message(STATUS "${SIMD_STATUS_MESSAGE}")
 452 endif()
 453
 454 # By default, 32-bit windows cannot pass SIMD (SSE/AVX) arguments in registers,
 455 # and even on 64-bit (all platforms) it is only used for a handful of arguments.
 456 # The __vectorcall (MSVC, from MSVC2013) or __regcall (ICC) calling conventions
 457 # enable this, which is critical to enable 32-bit SIMD and improves performance
 458 # for 64-bit SIMD.
 459 # Check if the compiler supports one of these, and in that case set gmx_simdcall
 460 # to that string. If we do not have any such calling convention modifier, set it
 461 # to an empty string.
 462 #
 463 # Update 2015-11-04: As of version 3.6, clang has added support for __vectorcall
 464 # (also on Linux). This appears to be buggy for the reference SIMD
 465 # implementation when using the Debug build (when functions are not inlined)
 466 # while it seems works fine for the actual SIMD implementations. This is likely
 467 # because the reference build ends up passing lots of structures with arrays
 468 # rather than actual vector data. For now we disable __vectorcall with clang
 469 # when using the reference build.
 470 #
 471 if(NOT DEFINED GMX_SIMD_CALLING_CONVENTION)
 472     if(GMX_TARGET_BGQ)
 473         set(CALLCONV_LIST " ")
 474     elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND GMX_SIMD STREQUAL "REFERENCE")
 475         set(CALLCONV_LIST __regcall " ")
 476     else()
 477         set(CALLCONV_LIST __vectorcall __regcall " ")
 478     endif()
 479     foreach(callconv ${CALLCONV_LIST})
 480         set(callconv_compile_var "_callconv_${callconv}")
 481         check_c_source_compiles("int ${callconv} f(int i) {return i;} int main(void) {return f(0);}" ${callconv_compile_var})
 482         if(${callconv_compile_var})
 483             set(GMX_SIMD_CALLING_CONVENTION "${callconv}" CACHE INTERNAL "Calling convention for SIMD routines" FORCE)
 484             break()
 485         endif()
 486     endforeach()
 487 endif()
 488
 489 endmacro()
 490