CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.2)
   2
   3 project(Gromacs)
   4 set(PROJECT_VERSION "4.0.99-dev-20100305"
   5     CACHE STRING "Gromacs version string")
   6
   7 # Cmake modules/macros are in a subdirectory to keep this file cleaner
   8 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
   9
  10 ########################################################################
  11 # User input options                                                   #
  12 ########################################################################
  13 option(GMX_DOUBLE "Use double precision" OFF)
  14 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  15 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" ON)
  16 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  17 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  18 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  19 set(GMX_ACCELERATION "none"
  20     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  21
  22 set(GMX_FFT_LIBRARY "fftw3"
  23     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  24 option(GMX_DISABLE_FFTW_MEASURE
  25        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  26 set(GMX_QMMM_PROGRAM "none"
  27     CACHE STRING "QM package choices: none,gaussian,mopac,gamess")
  28 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  29 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  30 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  31 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  32 mark_as_advanced(GMX_MPI_IN_PLACE)
  33
  34 enable_language(C)
  35
  36 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  37 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  38
  39 #######################################################################
  40 # Check for options incompatible with OpenMM build                    #
  41 #######################################################################
  42 if(GMX_OPENMM)
  43     # we'll use the built-in fft to avoid unnecessary dependencies
  44     set (GMX_FFT_LIBRARY "fftpack")
  45     if(GMX_MPI)
  46         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
  47     endif(GMX_MPI)
  48     if(GMX_THREADS)
  49         message(WARNING "Threads have been disabled, not compatible with OpenMM build!")
  50         set(GMX_THREADS OFF)
  51     endif(GMX_THREADS)
  52     if(GMX_SOFTWARE_INVSQRT)
  53         set(GMX_SOFTWARE_INVSQRT OFF)
  54     endif(GMX_SOFTWARE_INVSQRT)
  55     if(NOT GMX_ACCELERATION MATCHES "none")
  56         message(WARNING "The OpenMM build does not support other acceleration modes!")
  57         set(GMX_ACCELERATION "none")
  58     endif()
  59     if(GMX_FAHCORE)
  60         message(FATAL_ERROR "The OpenMM build does not support the FAH option!")
  61     endif(GMX_FAHCORE)
  62 endif(GMX_OPENMM)
  63
  64
  65 ########################################################################
  66 # Fix stupid flags on MSVC
  67 ########################################################################
  68 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  69     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  70     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  71     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  72     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  73 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  74
  75 set(GMX_EXTRA_LIBRARIES)
  76
  77 ########################################################################
  78 #Process MPI settings
  79 ########################################################################
  80 if(GMX_MPI)
  81     if(GMX_THREADS)
  82         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  83         set(GMX_THREADS OFF CACHE BOOL
  84             "Thread-based parallelization conflicts with MPI." FORCE)
  85     endif(GMX_THREADS)
  86     find_package(MPI)
  87     if(MPI_FOUND)
  88         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  89         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  90
  91         include_directories(${MPI_INCLUDE_PATH})
  92         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  93         add_definitions( -DMPI ) #for FAHCORE
  94         include(gmxTestMPI_IN_PLACE)
  95         if (GMX_MPI_IN_PLACE)
  96             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  97         endif (GMX_MPI_IN_PLACE)
  98     else(MPI_FOUND)
  99         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 100     endif(MPI_FOUND)
 101     include(gmxTestCatamount)
 102     gmx_test_catamount(GMX_CRAY_XT3)
 103     if(GMX_CRAY_XT3)
 104         set(GMX_NO_SYSTEM 1)
 105         set(GMX_NO_NICE 1)
 106     endif(GMX_CRAY_XT3)
 107     set(GMX_LIB_MPI 1)
 108 endif(GMX_MPI)
 109
 110 ########################################################################
 111 # Basic system tests (standard libraries, headers, functions, types)   #
 112 ########################################################################
 113 include(CheckIncludeFiles)
 114 check_include_files(string.h     HAVE_STRING_H)
 115 check_include_files(limits.h     HAVE_LIMITS_H)
 116 check_include_files(memory.h     HAVE_MEMORY_H)
 117 check_include_files(unistd.h     HAVE_UNISTD_H)
 118 check_include_files(pwd.h        HAVE_PWD_H)
 119 check_include_files(stdint.h     HAVE_STDINT_H)
 120 check_include_files(stdlib.h     HAVE_STDLIB_H)
 121 check_include_files(pthread.h    HAVE_PTHREAD_H)
 122 check_include_files(dirent.h     HAVE_DIRENT_H)
 123 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 124 check_include_files(regex.h      HAVE_REGEX_H)
 125 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 126 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 127 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 128 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 129 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 130 # SSE support
 131 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 132 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 133 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 134 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 135
 136 include(CheckFunctionExists)
 137 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 138 check_function_exists(strdup            HAVE_STRDUP)
 139 check_function_exists(vprintf           HAVE_VPRINTF)
 140 check_function_exists(memcmp            HAVE_MEMCMP)
 141 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 142 check_function_exists(isnan             HAVE_ISNAN)
 143 check_function_exists(_isnan            HAVE__ISNAN)
 144 check_function_exists(isfinite          HAVE_ISFINITE)
 145 check_function_exists(_isfinite         HAVE__ISFINITE)
 146 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 147
 148 include(CheckLibraryExists)
 149 check_library_exists(m sqrt "" HAVE_LIBM)
 150
 151 include(CheckTypeSize)
 152 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 153 check_type_size("int"           SIZEOF_INT)
 154 check_type_size("long int"      SIZEOF_LONG_INT)
 155 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 156 check_type_size("off_t"         SIZEOF_OFF_T)
 157 check_type_size("void *"        SIZEOF_VOIDP)
 158
 159 # Check for some basic types that we *need*, so set these to int if they are not present
 160 check_type_size(uid_t uid_t)
 161 if(NOT uid_t)
 162   set(uid_t int)
 163 else(NOT uid_t)
 164   set(uid_t 0)
 165 endif(NOT uid_t)
 166
 167 check_type_size(gid_t gid_t)
 168 if(NOT gid_t)
 169   set(gid_t 1)
 170 else(NOT gid_t)
 171   set(gid_t 0)
 172 endif(NOT gid_t)
 173
 174 check_type_size(size_t size_t)
 175 if(NOT size_t)
 176   set(size_t int)
 177 else(NOT size_t)
 178   set(size_t 0)
 179 endif(NOT size_t)
 180
 181 check_type_size(off_t off_t)
 182 if(NOT off_t)
 183   set(off_t int)
 184 else(NOT off_t)
 185   set(off_t 0)
 186 endif(NOT off_t)
 187
 188 include(TestBigEndian)
 189 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 190
 191
 192
 193 ########################################################################
 194 # Find external packages                                               #
 195 ########################################################################
 196
 197 find_package(LibXml2)
 198 if(LIBXML2_FOUND)
 199     include_directories(${LIBXML2_INCLUDE_DIR})
 200     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 201     set(HAVE_LIBXML2 1)
 202 endif(LIBXML2_FOUND)
 203
 204 find_package(X11)
 205 # X11 includes/libraries are only set in the ngmx subdirectory!
 206 if(X11_FOUND)
 207     set(HAVE_X11 1)
 208 endif(X11_FOUND)
 209
 210 if(GMX_THREADS)
 211     include(ThreadMPI)
 212     set(THREAD_MPI_LIB thread_mpi)
 213     set(GMX_MPI 1)
 214     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 215     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 216         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 217     endif()
 218 endif(GMX_THREADS)
 219
 220 if(GMX_OPENMM)
 221     set(CUDA_BUILD_EMULATION OFF)
 222     find_package(CUDA 2.3 EXACT REQUIRED)   # TODO what are we compatible with?
 223     add_definitions(-DGMX_OPENMM)
 224     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 225         set(CUDA_VERBOSE_BUILD ON)
 226     endif()
 227     find_package(OpenMM)
 228 endif(GMX_OPENMM)
 229
 230 if(APPLE)
 231    find_library(ACCELERATE_FRAMEWORK Accelerate)
 232    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 233 endif(APPLE)
 234
 235 ########################################################################
 236 # Our own GROMACS tests
 237 ########################################################################
 238
 239 include(gmxCFlags)
 240 gmx_c_flags()
 241
 242 add_definitions( -DHAVE_CONFIG_H )
 243 include_directories(${CMAKE_BINARY_DIR}/src)
 244 include_directories(${CMAKE_SOURCE_DIR}/include)
 245
 246 include(gmxCheckBuildUserTime)
 247 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 248
 249 include(gmxTestFloatFormat)
 250 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 251                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 252                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 253
 254 include(gmxTestLargeFiles)
 255 gmx_test_large_files(GMX_LARGEFILES)
 256
 257 include(gmxTestSignal)
 258 gmx_test_retsigtype(RETSIGTYPE)
 259
 260 include(gmxTestInline)
 261 gmx_test_inline(INLINE_KEYWORD)
 262
 263 include(gmxTestPipes)
 264 gmx_test_pipes(HAVE_PIPES)
 265
 266 include(gmxTestInlineASM)
 267 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 268 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 269
 270 include(gmxTestXDR)
 271 gmx_test_xdr(GMX_SYSTEM_XDR)
 272 if(NOT GMX_SYSTEM_XDR)
 273     set(GMX_INTERNAL_XDR 1)
 274 endif(NOT GMX_SYSTEM_XDR)
 275
 276 if(GMX_FORTRAN OR GMX_POWER6)
 277     enable_language(Fortran)
 278     include(FortranCInterface)
 279     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 280     if(extra_under_score)
 281         set(extrasuffix "_")
 282     endif(extra_under_score)
 283
 284     if(isupper)
 285         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 286         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 287     else(isupper)
 288         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 289         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 290     endif(isupper)
 291 else(GMX_FORTRAN OR GMX_POWER6)
 292         set(F77_FUNCDEF   "name ## _")
 293         set(F77_FUNCDEF_  "name ## _")
 294 endif(GMX_FORTRAN OR GMX_POWER6)
 295
 296
 297 # Process nonbonded accelerated kernels settings
 298 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 299 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 300 if(${GMX_ACCELERATION} STREQUAL "NONE")
 301   # nothing to do
 302 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 303     if(HAVE_XMMINTRIN_H)
 304         set(GMX_SSE 1)
 305         if(GMX_IA32_ASM)
 306           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 307           set(GMX_IA32_SSE 1)
 308         endif(GMX_IA32_ASM)
 309     endif(HAVE_XMMINTRIN_H)
 310     if(HAVE_EMMINTRIN_H)
 311         if(GMX_X86_64_ASM)
 312           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 313           set(GMX_X86_64_SSE 1)
 314         else(GMX_X86_64_ASM)  #only use intrinsic if not using the ASM loops
 315           set(GMX_SSE2 1)
 316         endif(GMX_X86_64_ASM)
 317     endif(HAVE_EMMINTRIN_H)
 318 #    if(HAVE_PMMINTRIN_H)
 319 #        set(GMX_SSE3 1)
 320 #    endif(HAVE_PMMINTRIN_H)
 321 #    if(HAVE_SMMINTRIN_H)
 322 #        set(GMX_SSE4_1 1)
 323 #    endif(HAVE_SMMINTRIN_H)
 324
 325 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 326     set(GMX_FORTRAN 1)
 327 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 328     set(GMX_BLUEGENE 1)
 329 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 330     set(GMX_POWER6 1)
 331 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 332     set(GMX_IA64_ASM 1)
 333     set(DISABLE_WATERWATER_NLIST 1)
 334     set(DISABLE_WATER_NLIST 1)
 335 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 336     check_include_files(altivec.h HAVE_ALTIVEC_H)
 337     if(HAVE_ALTIVEC_H)
 338         set(GMX_PPC_ALTIVEC 1)
 339     endif(HAVE_ALTIVEC_H)
 340 else(${GMX_ACCELERATION} STREQUAL "NONE")
 341     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 342 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 343
 344
 345
 346
 347
 348
 349
 350 # Process QM/MM Settings
 351 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 352 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 353     set(GMX_QMMM_GAUSSIAN 1)
 354 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 355     set(GMX_QMMM_MOPAC 1)
 356 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 357     set(GMX_QMMM_GAMESS 1)
 358 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 359     # nothing to do
 360 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 361     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, None")
 362 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 363
 364 # Process FFT library settings - if not OpenMM build
 365 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 366 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 367 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 368     if(GMX_DOUBLE)
 369         find_package(FFTW3 REQUIRED)
 370     else(GMX_DOUBLE)
 371         find_package(FFTW3F REQUIRED)
 372     endif(GMX_DOUBLE)
 373
 374     if(NOT FFTW3_FOUND)
 375         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 376     endif(NOT FFTW3_FOUND)
 377
 378     set(GMX_FFT_FFTW3 1)
 379     include_directories(${FFTW3_INCLUDE_DIR})
 380     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 381
 382 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 383 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 384     if(GMX_DOUBLE)
 385         find_package(FFTW2 REQUIRED)
 386     else(GMX_DOUBLE)
 387         find_package(FFTW2F REQUIRED)
 388     endif(GMX_DOUBLE)
 389
 390     if(NOT FFTW2_FOUND)
 391            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 392     endif(NOT FFTW2_FOUND)
 393     include_directories(${FFTW2_INCLUDE_DIR})
 394     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 395
 396     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 397         set(FFTW2_NAME_DFFTW 1)
 398     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 399         set(FFTW2_NAME_SFFTW 1)
 400     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 401         set(FFTW2_NAME_FFTW 1)
 402     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 403
 404     set(GMX_FFT_FFTW2 1)
 405 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 406 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 407     find_package(MKL REQUIRED)
 408     include_directories(${MKL_INCLUDE_DIR})
 409     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 410
 411     set(GMX_FFT_MKL 1)
 412     set(HAVE_MKL 1)
 413
 414 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 415 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 416 #    set(GMX_FFT_ACML 1)
 417 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 418     MESSAGE(STATUS "Using internal FFT library - fftpack")
 419     set(GMX_FFT_FFTPACK 1)
 420 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 421     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 422 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 423
 424 # MKL has BLAS/LAPACK routines
 425 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 426   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 427   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 428 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 429   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 430   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 431 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 432
 433 # Math and thread libraries must often come after all others when linking...
 434 if(HAVE_LIBM)
 435     list(APPEND GMX_EXTRA_LIBRARIES m)
 436 endif(HAVE_LIBM)
 437
 438
 439
 440 if(GMX_FAHCORE)
 441   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 442       "Path to swindirect.h")
 443   include_directories(${COREWRAP_INCLUDE_DIR})
 444 endif(GMX_FAHCORE)
 445
 446 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 447 set(CMAKE_C_FLAGS ${GROMACS_C_FLAGS} CACHE STRING "Compiler flags")
 448 set(CMAKE_EXE_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} CACHE STRING "Linker flags")
 449
 450 ########################################################################
 451 # Specify install locations and which subdirectories to process        #
 452 ########################################################################
 453 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 454 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 455 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 456 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 457
 458 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 459
 460
 461 add_subdirectory(share)
 462 add_subdirectory(include)
 463 add_subdirectory(man)
 464
 465 add_subdirectory(src)
 466
 467