CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.5-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "5")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_DLOPEN)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(USE_VERSION_H "Generate development version string/information" ON)
 137 mark_as_advanced(USE_VERSION_H)
 138
 139 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 140
 141 if(UNIX AND NOT APPLE)
 142     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 143     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 144 endif()
 145
 146 ########################################################################
 147 # Set up binary and library suffixing
 148 ########################################################################
 149 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 150 set(GMX_LIBS_SUFFIX ""
 151   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 if (GMX_DEFAULT_SUFFIX)
 153   set(GMX_BINARY_SUFFIX "")
 154   set(GMX_LIBS_SUFFIX "")
 155   if (GMX_MPI)
 156     set(GMX_BINARY_SUFFIX "_mpi")
 157     set(GMX_LIBS_SUFFIX "_mpi")
 158   endif(GMX_MPI)
 159   if (GMX_DOUBLE)
 160     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 161     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 162   endif(GMX_DOUBLE)
 163   if (GMX_OPENMM)
 164     set (GMX_BINARY_SUFFIX "-gpu")
 165     set (GMX_LIBS_SUFFIX "_gpu")
 166   endif(GMX_OPENMM)
 167   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 168   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 169   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 170 else(GMX_DEFAULT_SUFFIX)
 171   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 172   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 173   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 174 endif(GMX_DEFAULT_SUFFIX)
 175
 176 set(PKG_CFLAGS "")
 177 if(GMX_DOUBLE)
 178     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 179 endif(GMX_DOUBLE)
 180 if(GMX_SOFTWARE_INVSQRT)
 181   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 182 endif(GMX_SOFTWARE_INVSQRT)
 183 if(GMX_POWERPC_INVSQRT)
 184   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 185 endif(GMX_POWERPC_INVSQRT)
 186
 187 ########################################################################
 188 #Process MPI settings
 189 ########################################################################
 190 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 191 if(GMX_MPI)
 192     if(GMX_THREADS)
 193         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 194         set(GMX_THREADS OFF CACHE BOOL
 195             "Thread-based parallelization conflicts with MPI." FORCE)
 196     endif(GMX_THREADS)
 197     find_package(MPI)
 198     if(MPI_FOUND)
 199         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 200         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 201
 202         include_directories(${MPI_INCLUDE_PATH})
 203         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 204         if(GMX_FAHCORE)
 205             add_definitions( -DMPI ) #for FAHCORE
 206         endif(GMX_FAHCORE)
 207         include(gmxTestMPI_IN_PLACE)
 208         if (GMX_MPI_IN_PLACE)
 209             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 210         endif (GMX_MPI_IN_PLACE)
 211
 212         # test for unsuitable versions of OpenMPI
 213         exec_program(${MPIEXEC}
 214           ARGS --version
 215           OUTPUT_VARIABLE MPI_TYPE
 216           RETURN_VALUE MPI_EXEC_RETURN)
 217         if(MPI_EXEC_RETURN EQUAL 0)
 218           if(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 219             string(REGEX MATCH "[0-9]+\\.[0-9]*\\.?[0-9]*" MPI_VERSION ${MPI_TYPE})
 220             if(MPI_VERSION VERSION_LESS "1.4.1")
 221               MESSAGE(WARNING "
 222             There are known problems with OpenMPI version < 1.4.1.
 223             Please consider updating your OpenMPI.")
 224             endif(MPI_VERSION VERSION_LESS "1.4.1")
 225             unset(MPI_VERSION)
 226           else(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 227             # This is not OpenMPI, so give the old generic warning message
 228             MESSAGE(WARNING "
 229             There are known problems with some MPI implementations:
 230                      MVAPICH2 version <= 1.4.1
 231             Please consider updating your MPI if applicable.")
 232           endif(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 233           unset(MPI_TYPE)
 234         endif(MPI_EXEC_RETURN EQUAL 0)
 235     else(MPI_FOUND)
 236         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 237     endif(MPI_FOUND)
 238     include(gmxTestCatamount)
 239     gmx_test_catamount(GMX_CRAY_XT3)
 240     if(GMX_CRAY_XT3)
 241         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 242         set(GMX_NO_SYSTEM 1)
 243         set(GMX_NO_NICE 1)
 244     endif(GMX_CRAY_XT3)
 245     set(GMX_LIB_MPI 1)
 246     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 247 endif(GMX_MPI)
 248
 249
 250 #######################################################################
 251 # Check for options incompatible with OpenMM build                    #
 252 #######################################################################
 253 if(GMX_OPENMM)
 254     cmake_minimum_required(VERSION 2.6.4)
 255     # we'll use the built-in fft to avoid unnecessary dependencies
 256     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 257     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 258         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 259         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 260                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 261     endif()
 262     if(GMX_MPI)
 263         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 264     endif(GMX_MPI)
 265     if(GMX_THREADS)
 266         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 267         set(GMX_THREADS OFF CACHE BOOL
 268                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 269     endif(GMX_THREADS)
 270     if(GMX_SOFTWARE_INVSQRT)
 271         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 272                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 273     endif(GMX_SOFTWARE_INVSQRT)
 274     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 275     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 276         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 277         set(GMX_ACCELERATION "none" CACHE STRING
 278                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 279     endif()
 280     if(GMX_FAHCORE)
 281         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 282     endif(GMX_FAHCORE)
 283     if(GMX_DOUBLE)
 284         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 285     endif()
 286     # mark as advanced the unused variables
 287     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 288         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 289 else(GMX_OPENMM)
 290      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 291         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 292 endif(GMX_OPENMM)
 293
 294
 295 ########################################################################
 296 # Basic system tests (standard libraries, headers, functions, types)   #
 297 ########################################################################
 298 include(CheckIncludeFiles)
 299 check_include_files(string.h     HAVE_STRING_H)
 300 check_include_files(math.h       HAVE_MATH_H)
 301 check_include_files(limits.h     HAVE_LIMITS_H)
 302 check_include_files(memory.h     HAVE_MEMORY_H)
 303 check_include_files(unistd.h     HAVE_UNISTD_H)
 304 check_include_files(direct.h     HAVE_DIRECT_H)
 305 check_include_files(pwd.h        HAVE_PWD_H)
 306 check_include_files(stdint.h     HAVE_STDINT_H)
 307 check_include_files(stdlib.h     HAVE_STDLIB_H)
 308 check_include_files(pthread.h    HAVE_PTHREAD_H)
 309 check_include_files(dirent.h     HAVE_DIRENT_H)
 310 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 311 check_include_files(regex.h      HAVE_REGEX_H)
 312 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 313 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 314 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 315 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 316 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 317 # SSE support
 318 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 319 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 320 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 321 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 322 check_include_files(io.h                 HAVE_IO_H)
 323
 324
 325 include(CheckFunctionExists)
 326 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 327 check_function_exists(strdup            HAVE_STRDUP)
 328 check_function_exists(vprintf           HAVE_VPRINTF)
 329 check_function_exists(memcmp            HAVE_MEMCMP)
 330 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 331 check_function_exists(memalign          HAVE_MEMALIGN)
 332 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 333 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 334 check_function_exists(isnan             HAVE_ISNAN)
 335 check_function_exists(_isnan            HAVE__ISNAN)
 336 check_function_exists(fsync             HAVE_FSYNC)
 337 check_function_exists(_fileno           HAVE__FILENO)
 338 check_function_exists(fileno            HAVE_FILENO)
 339 check_function_exists(_commit           HAVE__COMMIT)
 340
 341 include(CheckLibraryExists)
 342 check_library_exists(m sqrt "" HAVE_LIBM)
 343 check_library_exists(m cbrt "" HAVE_CBRT)
 344
 345
 346 include(CheckTypeSize)
 347
 348 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 349 check_type_size("int"           SIZEOF_INT)
 350 check_type_size("long int"      SIZEOF_LONG_INT)
 351 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 352 check_type_size("off_t"         SIZEOF_OFF_T)
 353 check_type_size("void *"        SIZEOF_VOIDP)
 354
 355 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 356     set(GMX_64_BIT TRUE)
 357 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 358     set(GMX_64_BIT FALSE)
 359 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 360
 361 # Check for some basic types that we *need*, so set these to int if they are not present
 362 check_type_size(uid_t uid_t)
 363 if(NOT uid_t)
 364   set(uid_t int)
 365 else(NOT uid_t)
 366   set(uid_t 0)
 367 endif(NOT uid_t)
 368
 369 check_type_size(gid_t gid_t)
 370 if(NOT gid_t)
 371   set(gid_t 1)
 372 else(NOT gid_t)
 373   set(gid_t 0)
 374 endif(NOT gid_t)
 375
 376 check_type_size(size_t size_t)
 377 if(NOT size_t)
 378   set(size_t int)
 379 else(NOT size_t)
 380   set(size_t 0)
 381 endif(NOT size_t)
 382
 383 check_type_size(off_t off_t)
 384 if(NOT off_t)
 385   set(off_t int)
 386 else(NOT off_t)
 387   set(off_t 0)
 388 endif(NOT off_t)
 389
 390 include(TestBigEndian)
 391 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 392
 393
 394
 395
 396 ########################################################################
 397 # Find external packages                                               #
 398 ########################################################################
 399 if(UNIX AND NOT APPLE)
 400     if(GMX_PREFER_STATIC_LIBS)
 401         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 402         if(BUILD_SHARED_LIBS)
 403             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 404             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 405         endif()
 406     endif()
 407 endif()
 408
 409 option(GMX_XML "Use libxml2 to parse xml files" ON)
 410 if (GMX_XML)
 411   find_package(LibXml2)
 412   set(PKG_XML "")
 413   if(LIBXML2_FOUND)
 414     include_directories(${LIBXML2_INCLUDE_DIR})
 415     set(PKG_XML libxml-2.0)
 416     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 417     set(HAVE_LIBXML2 1)
 418   endif(LIBXML2_FOUND)
 419 endif(GMX_XML)
 420
 421 option(GMX_GSL "Add support for gsl" OFF)
 422 if (GMX_GSL)
 423   find_package(gsl)
 424   set(PKG_GSL "")
 425   if(GSL_FOUND)
 426     include_directories(${GSL_INCLUDE_DIR})
 427     set(PKG_GSL gsl)
 428     set(HAVE_LIBGSL 1)
 429   endif(GSL_FOUND)
 430 endif (GMX_GSL)
 431
 432 option(GMX_X11 "Use X window system" OFF)
 433 if (GMX_X11)
 434         find_package(X11)
 435         # X11 includes/libraries are only set in the ngmx subdirectory!
 436         if(X11_FOUND)
 437         set(HAVE_X11 1)
 438         endif(X11_FOUND)
 439 endif(GMX_X11)
 440
 441 if(GMX_THREADS)
 442     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 443     include(ThreadMPI)
 444     set(THREAD_MPI_LIB thread_mpi)
 445     set(GMX_MPI 1)
 446     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 447     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 448         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 449     endif()
 450 endif(GMX_THREADS)
 451
 452 if(GMX_OPENMM)
 453     set(CUDA_BUILD_EMULATION OFF)
 454     find_package(CUDA 3.1 REQUIRED)
 455     add_definitions(-DGMX_OPENMM)
 456     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 457         set(CUDA_VERBOSE_BUILD ON)
 458     endif()
 459     find_package(OpenMM)
 460 endif(GMX_OPENMM)
 461
 462 if(APPLE)
 463    find_library(ACCELERATE_FRAMEWORK Accelerate)
 464    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 465 endif(APPLE)
 466
 467 if(CYGWIN)
 468     set(GMX_CYGWIN 1)
 469 endif(CYGWIN)
 470
 471 # only bother with finding git and using version.h if the source is a git repo
 472 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 473     if(USE_VERSION_H)
 474         # We need at least git v1.5.1 be able to parse git's date output. If not
 475         # fund or the version is too small, we can't generate version information.
 476         find_package(Git 1.5.1)
 477         # this should at some point become VERSION_LESS
 478         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 479             message("No compatible git version found, won't be able to generate proper development version information.")
 480             set(USE_VERSION_H OFF)
 481         endif()
 482     endif()
 483 else()
 484     set(USE_VERSION_H OFF)
 485 endif()
 486
 487 if (GMX_DLOPEN)
 488     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 489     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 490 else(GMX_DLOPEN)
 491     set(PKG_DL_LIBS)
 492 endif (GMX_DLOPEN)
 493
 494 ########################################################################
 495 # Generate development version info for cache
 496 ########################################################################
 497 # set(GEN_VERSION_INFO_INTERNAL "ON")
 498 # include(gmxGenerateVersionString)
 499
 500 ########################################################################
 501 # Our own GROMACS tests
 502 ########################################################################
 503
 504 add_definitions( -DHAVE_CONFIG_H )
 505 include_directories(${CMAKE_BINARY_DIR}/src)
 506 include_directories(${CMAKE_SOURCE_DIR}/include)
 507
 508 include(gmxCheckBuildUserTime)
 509 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 510
 511 include(gmxTestFloatFormat)
 512 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 513                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 514                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 515
 516 include(gmxTestLargeFiles)
 517 gmx_test_large_files(GMX_LARGEFILES)
 518 check_function_exists(fseeko     HAVE_FSEEKO)
 519
 520 include(gmxTestSignal)
 521 gmx_test_retsigtype(RETSIGTYPE)
 522 gmx_test_sigusr1(HAVE_SIGUSR1)
 523
 524 include(gmxTestInline)
 525 gmx_test_inline(INLINE_KEYWORD)
 526
 527 include(gmxTestRestrict)
 528 gmx_test_inline(RESTRICT_KEYWORD)
 529
 530 include(gmxTestPipes)
 531 gmx_test_pipes(HAVE_PIPES)
 532
 533 include(gmxTestIsfinite)
 534 gmx_test_isfinite(HAVE_ISFINITE)
 535 gmx_test__isfinite(HAVE__ISFINITE)
 536 gmx_test__finite(HAVE__FINITE)
 537
 538 include(gmxTestInlineASM)
 539 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 540 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 541
 542 # turn on SSE if supported with reasonable defaults.
 543 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 544   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 545
 546     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 547
 548     # Determine the assembler/compiler to use
 549   else()
 550     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 551   endif()
 552 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 553
 554 include(gmxTestXDR)
 555 gmx_test_xdr(GMX_SYSTEM_XDR)
 556 if(NOT GMX_SYSTEM_XDR)
 557     set(GMX_INTERNAL_XDR 1)
 558     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 559 endif(NOT GMX_SYSTEM_XDR)
 560
 561 # Process nonbonded accelerated kernels settings
 562 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 563 if(${GMX_ACCELERATION} STREQUAL "NONE")
 564   # nothing to do
 565 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 566
 567     if (GMX_64_BIT)
 568       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 569     else (GMX_64_BIT)
 570       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 571     endif (GMX_64_BIT)
 572
 573     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 574       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 575     else()
 576       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 577     endif()
 578         mark_as_advanced(GMX_ASM_USEASM-NASM)
 579
 580     if (NOT GMX_64_BIT)
 581         # for 32-bit compiles, we might need to turn on sse
 582         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 583         if (XFLAGS_SSE)
 584             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 585         endif (XFLAGS_SSE)
 586         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 587         if (XXFLAGS_SSE)
 588             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 589         endif (XXFLAGS_SSE)
 590     endif (NOT GMX_64_BIT)
 591
 592     if(GMX_IA32_ASM)
 593       if(GMX_DOUBLE)
 594         set(GMX_IA32_SSE2 1)
 595       else()
 596        set(GMX_IA32_SSE 1)
 597       endif()
 598     elseif(GMX_X86_64_ASM)
 599       if(GMX_DOUBLE)
 600        set(GMX_X86_64_SSE2 1)
 601       else()
 602         set(GMX_X86_64_SSE 1)
 603       endif()
 604     endif()
 605
 606 #    if(HAVE_PMMINTRIN_H)
 607 #        set(GMX_SSE3 1)
 608 #    endif(HAVE_PMMINTRIN_H)
 609 #    if(HAVE_SMMINTRIN_H)
 610 #        set(GMX_SSE4_1 1)
 611 #    endif(HAVE_SMMINTRIN_H)
 612
 613 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 614     set(GMX_FORTRAN 1)
 615     #these are switch on by default sometimes
 616     set(GMX_IA32_ASM 0)
 617     set(GMX_GMX_X86_64_ASM 0)
 618 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 619 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 620     message(STATUS "Configuring for BlueGene")
 621     set(GMX_BLUEGENE 1)
 622     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 623         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 624         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 625     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 626     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 627     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 628     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 629     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 630     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 631 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 632     set(GMX_POWER6 1)
 633     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 634     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 635 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 636     set(GMX_IA64_ASM 1)
 637     set(DISABLE_WATERWATER_NLIST 1)
 638     set(DISABLE_WATER_NLIST 1)
 639 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 640     check_include_files(altivec.h HAVE_ALTIVEC_H)
 641     if(HAVE_ALTIVEC_H)
 642         set(GMX_PPC_ALTIVEC 1)
 643     endif(HAVE_ALTIVEC_H)
 644 else(${GMX_ACCELERATION} STREQUAL "NONE")
 645     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 646 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 647
 648 if(GMX_FORTRAN OR GMX_POWER6)
 649     if (GMX_THREADS)
 650         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 651     endif(GMX_THREADS)
 652     enable_language(Fortran)
 653     include(FortranCInterface)
 654     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 655     if(extra_under_score)
 656         set(extrasuffix "_")
 657     endif(extra_under_score)
 658     if(prefix)
 659       set(prefix "${prefix} ##")
 660     endif(prefix)
 661     if(suffix)
 662       set(suffix "## ${suffix}")
 663       if(extrasuffix)
 664         set(extrasuffix "${suffix}${extrasuffix}")
 665       endif(extrasuffix)
 666     else(suffix)
 667       if(extrasuffix)
 668         # Don't know if this is needed, but it can't hurt
 669         set(extrasuffix "## ${extrasuffix}")
 670       endif(extrasuffix)
 671     endif(suffix)
 672
 673     if(isupper)
 674         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 675         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 676     else(isupper)
 677         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 678         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 679     endif(isupper)
 680 else(GMX_FORTRAN OR GMX_POWER6)
 681         set(F77_FUNCDEF   "name ## _")
 682         set(F77_FUNCDEF_  "name ## _")
 683 endif(GMX_FORTRAN OR GMX_POWER6)
 684
 685 # Process QM/MM Settings
 686 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 687 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 688     set(GMX_QMMM_GAUSSIAN 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 690     set(GMX_QMMM_MOPAC 1)
 691 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 692     set(GMX_QMMM_GAMESS 1)
 693 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 694     set(GMX_QMMM_ORCA 1)
 695 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 696     # nothing to do
 697 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 698     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 699 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 700
 701 # Process FFT library settings - if not OpenMM build
 702 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 703 set(PKG_FFT "")
 704 set(PKG_FFT_LIBS "")
 705 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 706 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 707     if(GMX_DOUBLE)
 708         find_package(FFTW3 REQUIRED)
 709                 include_directories(${FFTW3_INCLUDE_DIR})
 710         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 711         set(PKG_FFT "fftw3")
 712     else(GMX_DOUBLE)
 713         find_package(FFTW3F REQUIRED)
 714         include_directories(${FFTW3F_INCLUDE_DIR})
 715         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 716         set(PKG_FFT "fftw3f")
 717     endif(GMX_DOUBLE)
 718
 719     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 720         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 721     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 722
 723     set(GMX_FFT_FFTW3 1)
 724
 725 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 726 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 727     if(GMX_DOUBLE)
 728         find_package(FFTW2 REQUIRED)
 729     else(GMX_DOUBLE)
 730         find_package(FFTW2F REQUIRED)
 731     endif(GMX_DOUBLE)
 732
 733     if(NOT FFTW2_FOUND)
 734            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 735     endif(NOT FFTW2_FOUND)
 736     include_directories(${FFTW2_INCLUDE_DIR})
 737     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 738     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 739
 740     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 741         set(FFTW2_NAME_DFFTW 1)
 742     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 743         set(FFTW2_NAME_SFFTW 1)
 744     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 745         set(FFTW2_NAME_FFTW 1)
 746     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 747
 748     set(GMX_FFT_FFTW2 1)
 749 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 750 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 751     find_package(MKL REQUIRED)
 752     include_directories(${MKL_INCLUDE_DIR})
 753     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 754     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 755
 756     set(GMX_FFT_MKL 1)
 757     set(HAVE_MKL 1)
 758
 759 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 760 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 761 #    set(GMX_FFT_ACML 1)
 762 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 763     MESSAGE(STATUS "Using internal FFT library - fftpack")
 764     set(GMX_FFT_FFTPACK 1)
 765 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 766     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 767 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 768
 769 # MKL has BLAS/LAPACK routines
 770 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 771   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 772   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 773 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 774   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 775   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 776   if(GMX_EXTERNAL_BLAS)
 777     #FindBLAS needs Fortran
 778     enable_language(Fortran)
 779     if (GMX_BLAS_USER)
 780         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 781     else(GMX_BLAS_USER)
 782         find_package(BLAS REQUIRED)
 783         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 784     endif(GMX_BLAS_USER)
 785   endif(GMX_EXTERNAL_BLAS)
 786   if(GMX_EXTERNAL_LAPACK)
 787     #FindLAPACK needs Fortran
 788     enable_language(Fortran)
 789         if (GMX_LAPACK_USER)
 790         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 791         else(GMX_LAPACK_USER)
 792         find_package(LAPACK REQUIRED)
 793         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 794     endif(GMX_LAPACK_USER)
 795   endif(GMX_EXTERNAL_LAPACK)
 796 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 797 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 798 mark_as_advanced(GMX_EXTERNAL_BLAS)
 799
 800 # Math and thread libraries must often come after all others when linking...
 801 if(HAVE_LIBM)
 802     list(APPEND GMX_EXTRA_LIBRARIES m)
 803 endif(HAVE_LIBM)
 804
 805 if(GMX_FAHCORE)
 806   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 807       "Path to swindirect.h")
 808   include_directories(${COREWRAP_INCLUDE_DIR})
 809 endif(GMX_FAHCORE)
 810
 811 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 812 # these are set after everything else
 813 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 814     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 815         FORCE)
 816     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 817         "Flags used by the compiler during all build types" FORCE)
 818     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 819         "Flags used by the compiler during all build types" FORCE)
 820     set(CMAKE_EXE_LINKER_FLAGS
 821         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 822         CACHE STRING "Linker flags" FORCE)
 823 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 824
 825 ########################################################################
 826 # Specify install locations and which subdirectories to process        #
 827 ########################################################################
 828 if ( DEFINED GMXLIB )
 829     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 830 else()
 831     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 832 endif()
 833 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 834 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 835 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 836 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 837
 838 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 839
 840 ##################################################################
 841 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 842 ##################################################################
 843 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 844     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 845     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 846     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 847     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 848 endif()
 849
 850 add_subdirectory(share)
 851 add_subdirectory(include)
 852 add_subdirectory(man)
 853 add_subdirectory(src)
 854 add_subdirectory(scripts)
 855
 856 #######################
 857 ## uninstall target
 858 #######################
 859     CONFIGURE_FILE(
 860                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 861                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 862                    IMMEDIATE @ONLY)
 863 ###########################
 864 ADD_CUSTOM_TARGET(uninstall
 865                   "${CMAKE_COMMAND}" -P
 866                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 867 ###########################
 868
 869
 870 ########################################################################
 871 # Tests                                                                #
 872 ########################################################################
 873
 874 include(CTest)
 875 mark_as_advanced(BUILD_TESTING)
 876 IF(BUILD_TESTING)
 877         enable_testing()
 878         add_subdirectory(tests)
 879 ENDIF()
 880