cmake/gmxDetectSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Check the username performing the build, as well as date and time
  36 #
  37 # gmx_detect_simd(GMX_SUGGESTED_SIMD)
  38 #
  39 # Try to detect CPU information and suggest SIMD instruction set
  40 # that fits the current CPU. This should work on all architectures
  41 # where we are not cross-compiling; depending on the architecture the
  42 # detection will either use special assembly instructions (like cpuid),
  43 # preprocessor defines, or probing /proc/cpuinfo on Linux.
  44 #
  45 # This assumes gmx_detect_target_architecture() has already been run,
  46 # so that things like GMX_TARGET_X86 are already available.
  47 # (otherwise we cannot use inline ASM on x86).
  48 #
  49 # Sets ${GMX_SUGGESTED_SIMD} in the parent scope if
  50 # GMX_SIMD is not set (e.g. by the user, or a previous run
  51 # of CMake).
  52 #
  53
  54 # we rely on inline asm support for GNU!
  55 include(gmxTestInlineASM)
  56
  57 function(gmx_suggest_simd _suggested_simd)
  58
  59     # for x86 we need inline asm to use cpuid
  60     gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
  61
  62     if(GMX_X86_GCC_INLINE_ASM)
  63         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM")
  64     else()
  65         set(GCC_INLINE_ASM_DEFINE "")
  66     endif()
  67
  68     message(STATUS "Detecting best SIMD instructions for this CPU")
  69
  70     # Get CPU SIMD properties information
  71     set(_compile_definitions "${GCC_INLINE_ASM_DEFINE} -I${CMAKE_SOURCE_DIR}/src -DGMX_CPUID_STANDALONE")
  72     if(GMX_TARGET_X86)
  73         set(_compile_definitions "${_compile_definitions} -DGMX_TARGET_X86")
  74     endif()
  75
  76     # We need to execute the binary, so this only works if not cross-compiling.
  77     # However, note that we are NOT limited to x86.
  78     if(NOT CMAKE_CROSSCOMPILING)
  79         try_run(GMX_CPUID_RUN_SIMD GMX_CPUID_COMPILED
  80                 ${CMAKE_BINARY_DIR}
  81                 ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/gmx_cpuid.c
  82                 COMPILE_DEFINITIONS ${_compile_definitions}
  83                 RUN_OUTPUT_VARIABLE OUTPUT_TMP
  84                 COMPILE_OUTPUT_VARIABLE GMX_CPUID_COMPILE_OUTPUT
  85                 ARGS "-simd")
  86
  87         if(NOT GMX_CPUID_COMPILED)
  88             message(WARNING "Cannot compile CPUID code, which means no SIMD instructions.")
  89             message(STATUS "Compile output: ${GMX_CPUID_COMPILE_OUTPUT}")
  90             set(OUTPUT_TMP "None")
  91         elseif(NOT GMX_CPUID_RUN_SIMD EQUAL 0)
  92             message(WARNING "Cannot run CPUID code, which means no SIMD instructions.")
  93             message(STATUS "Run output: ${OUTPUT_TMP}")
  94             set(OUTPUT_TMP "None")
  95         endif(NOT GMX_CPUID_COMPILED)
  96
  97         string(STRIP "${OUTPUT_TMP}" OUTPUT_SIMD)
  98
  99         set(${_suggested_simd} "${OUTPUT_SIMD}" PARENT_SCOPE)
 100         message(STATUS "Detected best SIMD instructions for this CPU - ${OUTPUT_SIMD}")
 101     else()
 102         set(${_suggested_simd} "None" PARENT_SCOPE)
 103         message(WARNING "Cannot detect SIMD architecture for this cross-compile; you should check it manually.")
 104     endif()
 105 endfunction()
 106
 107 function(gmx_detect_simd _suggested_simd)
 108     if(NOT DEFINED GMX_SIMD)
 109         if(GMX_TARGET_BGQ)
 110             set(${_suggested_simd} "IBM_QPX")
 111         elseif(GMX_TARGET_FUJITSU_SPARC64)
 112             # HPC-ACE is always present. In the future we
 113             # should add detection for HPC-ACE2 here.
 114             set(${_suggested_simd} "Sparc64_HPC_ACE")
 115         elseif(GMX_TARGET_MIC)
 116             set(${_suggested_simd} "MIC")
 117         else()
 118             gmx_suggest_simd(${_suggested_simd})
 119         endif()
 120
 121         set(${_suggested_simd} ${${_suggested_simd}} PARENT_SCOPE)
 122     endif()
 123 endfunction()