docs/SphinxMacros.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CMakeParseArguments)
  36
  37 macro(gmx_init_sphinx_setup SPHINX_INPUT_DIR)
  38     set(_SPHINX_INPUT_ROOT ${SPHINX_INPUT_DIR})
  39     set(_SPHINX_INPUT_FILES)
  40 endmacro()
  41
  42 macro(gmx_add_sphinx_input_file FILEPATH)
  43     list(APPEND _SPHINX_INPUT_FILES ${FILEPATH})
  44 endmacro()
  45
  46 function(gmx_add_sphinx_source_files)
  47     set(_one_value_args FROM TO PREFIX)
  48     cmake_parse_arguments(ARG "" "${_one_value_args}" "FILES" ${ARGN})
  49     if (NOT ARG_FROM)
  50         set(ARG_FROM ${CMAKE_CURRENT_SOURCE_DIR})
  51     endif()
  52     if (ARG_TO)
  53         set(ARG_TO ${ARG_TO}/)
  54     endif()
  55     foreach(_file ${ARG_FILES})
  56         set(_source ${ARG_FROM}/${_file})
  57         set(_target ${_SPHINX_INPUT_ROOT}/${ARG_TO}${_file})
  58         add_custom_command(
  59             OUTPUT  ${_target}
  60             COMMAND ${CMAKE_COMMAND} -E copy ${_source} ${_target}
  61             DEPENDS ${_source}
  62             COMMENT "Copying Sphinx input file ${ARG_PREFIX}${_file}"
  63             VERBATIM)
  64         list(APPEND _SPHINX_INPUT_FILES ${_target})
  65     endforeach()
  66     set(_SPHINX_INPUT_FILES "${_SPHINX_INPUT_FILES}" PARENT_SCOPE)
  67 endfunction()
  68
  69 macro(gmx_remove_obsolete_sphinx_input_files IGNORE_PATTERN)
  70     file(GLOB_RECURSE _obsolete_sources ${_SPHINX_INPUT_ROOT}/*.rst)
  71     list(REMOVE_ITEM _obsolete_sources ${_SPHINX_INPUT_FILES})
  72     foreach(_file ${_obsolete_sources})
  73         file(RELATIVE_PATH _rel_path ${_SPHINX_INPUT_ROOT} ${_file})
  74         if (NOT _rel_path MATCHES "${IGNORE_PATTERN}")
  75             message(STATUS "Removing obsolete Sphinx input ${_rel_path}")
  76             file(REMOVE ${_file})
  77         endif()
  78     endforeach()
  79 endmacro()
  80
  81 macro(gmx_add_sphinx_input_target TARGETNAME)
  82     gmx_add_custom_output_target(${TARGETNAME} OUTPUT STAMP
  83         DEPENDS ${_SPHINX_INPUT_FILES})
  84 endmacro()