src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 ######################################
  36 # Output compiler and CFLAGS used
  37 ######################################
  38 include(GetCompilerInfo.cmake)
  39 get_compiler_info(C BUILD_C_COMPILER)
  40 get_compiler_info(CXX BUILD_CXX_COMPILER)
  41 if(GMX_USE_CUDA)
  42     if(NOT GMX_CLANG_CUDA)
  43         GMX_SET_CUDA_NVCC_FLAGS()
  44     endif()
  45
  46     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_DEVICE_COMPILER_FLAGS CUDA_HOST_COMPILER_FLAGS)
  47 endif()
  48
  49 # Make a file with compiler flags used for libgromacs for each
  50 # langauge and build configuration.  The one that corresponds to
  51 # CMAKE_BUILD_TYPE is #included into buildinfo.h and populates the
  52 # fields e.g. printed to the log file.
  53 file(GENERATE
  54     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/compilerflaginfo-$<CONFIG>-$<COMPILE_LANGUAGE>.h
  55     INPUT ${CMAKE_CURRENT_SOURCE_DIR}/compilerflaginfo.h.cmakein
  56     CONDITION $<CONFIG:${CMAKE_BUILD_TYPE}>
  57     )
  58
  59 ####
  60 set(IGNORED_CLANG_ALL_WARNINGS
  61     "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  62     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  63     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  64     "-Wno-documentation-unknown-command" #Custom commands are used
  65     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  66     "-Wno-switch-enum" # default statement for enum is OK
  67
  68     # TODO uncomment the next few ignore lines when we upgrade to test with clang 8 in Jenkins
  69
  70     # The barriers we use for tMPI and Nbnxm are sufficient, but it's
  71     # not known whether they're excessive. We assume they not
  72     # excessive.
  73     # "-Wno-atomic-implicit-seq-cst"
  74
  75     # We need to use macros like
  76     # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  77     # if they don't have a semicolon after them, and might confuse
  78     # tools like IDEs also.
  79     # "-Wno-extra-semi-stmt"
  80
  81     #Following ones are undecided/TODO
  82     "-Wno-disabled-macro-expansion"
  83     "-Wno-cast-align"
  84     "-Wno-reserved-id-macro"
  85     "-Wno-global-constructors"
  86     "-Wno-exit-time-destructors"
  87     "-Wno-unused-macros"
  88     "-Wno-weak-vtables"
  89     "-Wno-conditional-uninitialized"
  90     "-Wno-format-nonliteral"
  91     "-Wno-shadow"
  92     "-Wno-cast-qual"
  93     "-Wno-documentation"
  94     "-Wno-used-but-marked-unused"
  95     "-Wno-padded"
  96     "-Wno-float-equal"
  97     "-Wno-old-style-cast"
  98     "-Wno-conversion"
  99     "-Wno-double-promotion")
 100 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
 101
 102 if (GMX_CLANG_TIDY)
 103    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
 104    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
 105        DOC "Path to clang-tidy executable")
 106    if(NOT CLANG_TIDY_EXE)
 107        message(FATAL_ERROR "clang-tidy not found.")
 108    endif()
 109 endif()
 110 #####
 111
 112 add_subdirectory(external)
 113
 114 if (BUILD_TESTING)
 115     if(NOT GMX_DEVELOPER_BUILD)
 116         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
 117     endif()
 118     include(testutils/TestMacros.cmake)
 119     add_subdirectory(testutils)
 120 endif()
 121
 122 add_subdirectory(gromacs)
 123 add_subdirectory(programs)
 124
 125 # Activate targets for new C++ API components and docs.
 126 if(GMX_NATIVE_WINDOWS OR GMX_BUILD_MDRUN_ONLY OR NOT BUILD_SHARED_LIBS)
 127     # GMXAPI has not been tested in Microsoft environments.
 128     # GMXAPI relies on libgromacs and is incompatible with an `mdrun`-only build.
 129     # GMXAPI requires position-independent code
 130     set(_GMXAPI_DEFAULT OFF)
 131 else()
 132     set(_GMXAPI_DEFAULT ON)
 133 endif()
 134 option(GMXAPI "Experimental external interfaces" ${_GMXAPI_DEFAULT})
 135 if (GMXAPI)
 136    if (GMX_BUILD_MDRUN_ONLY)
 137        message(FATAL_ERROR "GMXAPI relies on libgromacs and is incompatible with GMX_BUILD_MDRUN_ONLY.")
 138    endif()
 139    if(NOT ${BUILD_SHARED_LIBS})
 140        # Note: this conditional should check for the existence of a libgromacs target supporting PIC
 141        # using the POSITION_INDEPENDENT_CODE property, but for now the only facility we have is the global
 142        # variable, BUILD_SHARED_LIBS.
 143        # TODO: gmxapi should gracefully build for dynamic linking or static linking for PIC or without.
 144        message(FATAL_ERROR "GMXAPI requires position-independent code. Set -DGMXAPI=OFF or -DBUILD_SHARED_LIBS=ON.")
 145    endif()
 146    add_subdirectory(api)
 147 endif()
 148
 149 # Configure header files with configuration-specific values. This step
 150 # should follow all introspection e.g. looking for headers and
 151 # libraries. If not, cmake will need to change the contents of the
 152 # file upon subsequent runs of cmake. This can mean that
 153 #
 154 #  cmake $src && make && make test
 155 #
 156 # requires building all the source files that depend on the changed
 157 # header file in both of the make stages. That's slow, and is useless
 158 # busy work for ccache, too.
 159 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UPPER)
 160 configure_file(config.h.cmakein config.h)
 161 configure_file(gmxpre-config.h.cmakein gmxpre-config.h)
 162 configure_file(buildinfo.h.cmakein buildinfo.h ESCAPE_QUOTES)