cmake/gmxManageSharedLibraries.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2018,2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Manage the GROMACS shared library setup.
  36
  37 ########################################################################
  38 # Shared/static library settings
  39 ########################################################################
  40 # Determine the defaults (this block has no effect if the variables have
  41 # already been set)
  42 if((APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD|GNU") AND NOT GMX_BUILD_MDRUN_ONLY)
  43     # Maybe Solaris should be here? Patch this if you know!
  44     SET(SHARED_LIBS_DEFAULT ON)
  45 elseif(WIN32)
  46     # Support for shared libs on native Windows is a bit new. Its
  47     # default might change later if/when we sort things out. Also,
  48     # Cray should go here. What variable value can detect it?
  49     SET(SHARED_LIBS_DEFAULT OFF)
  50 else()
  51     if (NOT DEFINED BUILD_SHARED_LIBS)
  52         message(STATUS "Defaulting to building static libraries")
  53     endif()
  54     SET(SHARED_LIBS_DEFAULT OFF)
  55 endif()
  56 if (GMX_PREFER_STATIC_LIBS)
  57     if (NOT DEFINED BUILD_SHARED_LIBS AND SHARED_LIBS_DEFAULT)
  58         message("Searching for static libraries requested, so the GROMACS libraries will also be static (BUILD_SHARED_LIBS=OFF)")
  59     endif()
  60     set(SHARED_LIBS_DEFAULT OFF)
  61 endif()
  62 if (NOT GMX_BUILD_SHARED_EXE)
  63     set(GMX_PREFER_STATIC_LIBS_DEFAULT ON)
  64     set(SHARED_LIBS_DEFAULT OFF)
  65 endif()
  66
  67 # Declare the user-visible options
  68 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
  69
  70 set(GMX_PREFER_STATIC_LIBS_DEFAULT OFF)
  71 if (WIN32 OR NOT BUILD_SHARED_LIBS)
  72     set(GMX_PREFER_STATIC_LIBS_DEFAULT ON)
  73 endif()
  74
  75 if(BUILD_SHARED_LIBS AND GMX_BUILD_MDRUN_ONLY)
  76     message(WARNING "Both BUILD_SHARED_LIBS and GMX_BUILD_MDRUN_ONLY are set. Generally, an mdrun-only build should prefer to use static libraries, which is the default if you make a fresh build tree. You may be re-using an old build tree, and so may wish to set BUILD_SHARED_LIBS=off yourself.")
  77 endif()
  78
  79 if (UNIX)
  80     set(GMX_PREFER_STATIC_LIBS_DESCRIPTION
  81         "When finding libraries prefer static archives (it will only work if static versions of external dependencies are available and found)")
  82 elseif (WIN32)
  83     set(GMX_PREFER_STATIC_LIBS_DESCRIPTION
  84         "When finding libraries prefer static system libraries (MT instead of MD)")
  85 endif()
  86 option(GMX_PREFER_STATIC_LIBS "${GMX_PREFER_STATIC_LIBS_DESCRIPTION}"
  87        ${GMX_PREFER_STATIC_LIBS_DEFAULT})
  88 mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  89
  90 # Act on the set values
  91 if (UNIX AND GMX_PREFER_STATIC_LIBS)
  92     if(BUILD_SHARED_LIBS)
  93         # Warn the user about the combination. But don't overwrite the request.
  94         message(WARNING "Searching for static libraries requested, and building shared GROMACS libraries requested. This might cause problems linking later.")
  95     endif()
  96     # On Linux .a is the static library suffix, on Mac OS X .lib can also
  97     # be used, so we'll add both to the preference list.
  98     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
  99 endif()
 100
 101 # ==========
 102 # Only things for managing shared libraries and build types on Windows follow
 103
 104 # Change the real CMake variables so we prefer static linking. This
 105 # should be a function so we can have proper local variables while
 106 # avoiding duplicating code.
 107 function(gmx_manage_prefer_static_libs_flags build_type)
 108     if("${build_type}" STREQUAL "")
 109         set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
 110     else()
 111         set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
 112     endif()
 113
 114     # Change the real CMake variables for the given build type in each
 115     # language, in the parent scope.
 116     foreach(language C CXX)
 117         string(REPLACE /MD /MT CMAKE_${language}_FLAGS${punctuation}${build_type} ${CMAKE_${language}_FLAGS${punctuation}${build_type}})
 118         set(CMAKE_${language}_FLAGS${punctuation}${build_type} ${CMAKE_${language}_FLAGS${punctuation}${build_type}} PARENT_SCOPE)
 119     endforeach()
 120 endfunction()
 121
 122 IF( WIN32)
 123   if (NOT BUILD_SHARED_LIBS)
 124       if(NOT GMX_PREFER_STATIC_LIBS)
 125           message(WARNING "Shared system libraries requested, and static GROMACS libraries requested.")
 126       endif()
 127   else()
 128       if(MINGW)
 129           set(CMAKE_SHARED_LINKER_FLAGS "-Wl,--export-all-symbols ${CMAKE_SHARED_LINKER_FLAGS}")
 130       else()
 131           message(FATAL_ERROR "BUILD_SHARED_LIBS=ON not yet working for Windows in the master branch")
 132       endif()
 133       if(GMX_PREFER_STATIC_LIBS)
 134           #this combination segfaults (illegal passing of file handles)
 135           message(FATAL_ERROR "Static system libraries requested, and shared GROMACS libraries requested.")
 136       endif()
 137       # Visibility not yet implemented
 138       # add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 139       # set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 140   endif()
 141
 142   IF (GMX_PREFER_STATIC_LIBS)
 143       foreach(build_type "" ${build_types_with_explicit_flags})
 144           gmx_manage_prefer_static_libs_flags("${build_type}")
 145       endforeach()
 146   ENDIF()
 147   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 148     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 149         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 150         set(CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS} PARENT_SCOPE)
 151     endif()
 152   ENDIF()
 153 ENDIF()