src/gromacs/gpu_utils/vectype_ops.cuh

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2012,2015,2016,2019,2020, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35
  36 #ifndef VECTYPE_OPS_CUH
  37 #define VECTYPE_OPS_CUH
  38
  39 /**** float3 ****/
  40 __forceinline__ __host__ __device__ float3 make_float3(float s)
  41 {
  42     return make_float3(s, s, s);
  43 }
  44 __forceinline__ __host__ __device__ float3 make_float3(float4 a)
  45 {
  46     return make_float3(a.x, a.y, a.z);
  47 }
  48 __forceinline__ __host__ __device__ float3 operator-(float3& a)
  49 {
  50     return make_float3(-a.x, -a.y, -a.z);
  51 }
  52 __forceinline__ __host__ __device__ float3 operator+(float3 a, float3 b)
  53 {
  54     return make_float3(a.x + b.x, a.y + b.y, a.z + b.z);
  55 }
  56 __forceinline__ __host__ __device__ float3 operator-(float3 a, float3 b)
  57 {
  58     return make_float3(a.x - b.x, a.y - b.y, a.z - b.z);
  59 }
  60 __forceinline__ __host__ __device__ float3 operator*(float3 a, float k)
  61 {
  62     return make_float3(k * a.x, k * a.y, k * a.z);
  63 }
  64 __forceinline__ __host__ __device__ float3 operator*(float k, float3 a)
  65 {
  66     return make_float3(k * a.x, k * a.y, k * a.z);
  67 }
  68 __forceinline__ __host__ __device__ void operator+=(float3& a, float3 b)
  69 {
  70     a.x += b.x;
  71     a.y += b.y;
  72     a.z += b.z;
  73 }
  74 __forceinline__ __host__ __device__ void operator+=(float3& a, float4 b)
  75 {
  76     a.x += b.x;
  77     a.y += b.y;
  78     a.z += b.z;
  79 }
  80 __forceinline__ __host__ __device__ void operator-=(float3& a, float3 b)
  81 {
  82     a.x -= b.x;
  83     a.y -= b.y;
  84     a.z -= b.z;
  85 }
  86 __forceinline__ __host__ __device__ float norm(float3 a)
  87 {
  88     return sqrt(a.x * a.x + a.y * a.y + a.z * a.z);
  89 }
  90 __forceinline__ __host__ __device__ float norm2(float3 a)
  91 {
  92     return (a.x * a.x + a.y * a.y + a.z * a.z);
  93 }
  94 __forceinline__ __host__ __device__ float dist3(float3 a, float3 b)
  95 {
  96     return norm(b - a);
  97 }
  98 __forceinline__ __host__ __device__ float3 operator*(float3 a, float3 b)
  99 {
 100     return make_float3(a.x * b.x, a.y * b.y, a.z * b.z);
 101 }
 102 __forceinline__ __host__ __device__ void operator*=(float3& a, float3 b)
 103 {
 104     a.x *= b.x;
 105     a.y *= b.y;
 106     a.z *= b.z;
 107 }
 108 __forceinline__ __host__ __device__ void operator*=(float3& a, float b)
 109 {
 110     a.x *= b;
 111     a.y *= b;
 112     a.z *= b;
 113 }
 114 __forceinline__ __device__ void atomicAdd(float3* addr, float3 val)
 115 {
 116     atomicAdd(&addr->x, val.x);
 117     atomicAdd(&addr->y, val.y);
 118     atomicAdd(&addr->z, val.z);
 119 }
 120 /****************************************************************/
 121
 122 /**** float4 ****/
 123 __forceinline__ __host__ __device__ float4 make_float4(float s)
 124 {
 125     return make_float4(s, s, s, s);
 126 }
 127 __forceinline__ __host__ __device__ float4 make_float4(float3 a)
 128 {
 129     return make_float4(a.x, a.y, a.z, 0.0f);
 130 }
 131 __forceinline__ __host__ __device__ float4 operator+(float4 a, float4 b)
 132 {
 133     return make_float4(a.x + b.x, a.y + b.y, a.z + b.z, a.w + b.w);
 134 }
 135 __forceinline__ __host__ __device__ float4 operator+(float4 a, float3 b)
 136 {
 137     return make_float4(a.x + b.x, a.y + b.y, a.z + b.z, a.w);
 138 }
 139 __forceinline__ __host__ __device__ float4 operator-(float4 a, float4 b)
 140 {
 141     return make_float4(a.x - b.x, a.y - b.y, a.z - b.z, a.w - b.w);
 142 }
 143 __forceinline__ __host__ __device__ float4 operator*(float4 a, float k)
 144 {
 145     return make_float4(k * a.x, k * a.y, k * a.z, k * a.w);
 146 }
 147 __forceinline__ __host__ __device__ void operator+=(float4& a, float4 b)
 148 {
 149     a.x += b.x;
 150     a.y += b.y;
 151     a.z += b.z;
 152     a.w += b.w;
 153 }
 154 __forceinline__ __host__ __device__ void operator+=(float4& a, float3 b)
 155 {
 156     a.x += b.x;
 157     a.y += b.y;
 158     a.z += b.z;
 159 }
 160 __forceinline__ __host__ __device__ void operator-=(float4& a, float3 b)
 161 {
 162     a.x -= b.x;
 163     a.y -= b.y;
 164     a.z -= b.z;
 165 }
 166
 167 __forceinline__ __host__ __device__ float norm(float4 a)
 168 {
 169     return sqrt(a.x * a.x + a.y * a.y + a.z * a.z + a.w * a.w);
 170 }
 171
 172 __forceinline__ __host__ __device__ float dist3(float4 a, float4 b)
 173 {
 174     return norm(b - a);
 175 }
 176
 177 /* \brief Compute the scalar product of two vectors.
 178  *
 179  * \param[in] a  First vector.
 180  * \param[in] b  Second vector.
 181  * \returns Scalar product.
 182  */
 183 __forceinline__ __device__ float iprod(const float3 a, const float3 b)
 184 {
 185     return a.x * b.x + a.y * b.y + a.z * b.z;
 186 }
 187
 188 /* \brief Compute the vector product of two vectors.
 189  *
 190  * \param[in] a  First vector.
 191  * \param[in] b  Second vector.
 192  * \returns Vector product.
 193  */
 194 __forceinline__ __device__ float3 cprod(const float3 a, const float3 b)
 195 {
 196     float3 c;
 197     c.x = a.y * b.z - a.z * b.y;
 198     c.y = a.z * b.x - a.x * b.z;
 199     c.z = a.x * b.y - a.y * b.x;
 200     return c;
 201 }
 202
 203 /* \brief Cosine of an angle between two vectors.
 204  *
 205  * Computes cosine using the following formula:
 206  *
 207  *                  ax*bx + ay*by + az*bz
 208  * cos-vec (a,b) =  ---------------------
 209  *                      ||a|| * ||b||
 210  *
 211  * This function also makes sure that the cosine does not leave the [-1, 1]
 212  * interval, which can happen due to numerical errors.
 213  *
 214  * \param[in] a  First vector.
 215  * \param[in] b  Second vector.
 216  * \returns Cosine between a and b.
 217  */
 218 __forceinline__ __device__ float cos_angle(const float3 a, const float3 b)
 219 {
 220     float cosval;
 221
 222     float ipa  = norm2(a);
 223     float ipb  = norm2(b);
 224     float ip   = iprod(a, b);
 225     float ipab = ipa * ipb;
 226     if (ipab > 0.0f)
 227     {
 228         cosval = ip * rsqrt(ipab);
 229     }
 230     else
 231     {
 232         cosval = 1.0f;
 233     }
 234     if (cosval > 1.0f)
 235     {
 236         return 1.0f;
 237     }
 238     if (cosval < -1.0f)
 239     {
 240         return -1.0f;
 241     }
 242
 243     return cosval;
 244 }
 245
 246 /* \brief Compute the angle between two vectors.
 247  *
 248  * Uses atan( |axb| / a.b ) formula.
 249  *
 250  * \param[in] a  First vector.
 251  * \param[in] b  Second vector.
 252  * \returns Angle between vectors in radians.
 253  */
 254 __forceinline__ __device__ float gmx_angle(const float3 a, const float3 b)
 255 {
 256     float3 w = cprod(a, b);
 257
 258     float wlen = norm(w);
 259     float s    = iprod(a, b);
 260
 261     return atan2f(wlen, s); // requires float
 262 }
 263
 264 /* \brief Atomically add components of the vector.
 265  *
 266  * Executes atomicAdd one-by-one on all components of the float3 vector.
 267  *
 268  * \param[in] a  First vector.
 269  * \param[in] b  Second vector.
 270  * \returns Angle between vectors.
 271  */
 272 __forceinline__ __device__ void atomicAdd(float3& a, const float3 b)
 273 {
 274     atomicAdd(&a.x, b.x);
 275     atomicAdd(&a.y, b.y);
 276     atomicAdd(&a.z, b.z);
 277 }
 278
 279 #endif /* VECTYPE_OPS_CUH */