CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.0.99-dev-20100315"
   8     CACHE STRING "Gromacs version string")
   9
  10 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  11 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  12
  13 if(NOT CMAKE_BUILD_TYPE)
  14     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  15 endif(NOT CMAKE_BUILD_TYPE)
  16
  17 enable_language(C)
  18
  19
  20 ########################################################################
  21 # Fix stupid flags on MSVC
  22 ########################################################################
  23 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  24     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  25     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  26     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  27     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  28 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  29
  30 set(GMX_EXTRA_LIBRARIES)
  31
  32 ######################################################################
  33 # compiler tests
  34 # these need ot be done early (before further tests).
  35 #####################################################################
  36
  37 include(CheckCCompilerFlag)
  38 include(CheckCXXCompilerFlag)
  39
  40 # check for buggy GCC 4.1.x
  41 include(gmxCheckGCCVersion)
  42
  43 include(gmxCFlags)
  44 gmx_c_flags()
  45
  46 ########################################################################
  47 # User input options                                                   #
  48 ########################################################################
  49 option(GMX_DOUBLE "Use double precision" OFF)
  50 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  51 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" ON)
  52 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  53 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  54 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  55 set(GMX_ACCELERATION "none"
  56     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  57
  58 set(GMX_FFT_LIBRARY "fftw3"
  59     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  60 option(GMX_DISABLE_FFTW_MEASURE
  61        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  62 set(GMX_QMMM_PROGRAM "none"
  63     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  64 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  65 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  66 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  67 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  68 mark_as_advanced(GMX_MPI_IN_PLACE)
  69
  70
  71 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  72 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  73 option(USE_VERSION_H "Generate development version string/information" ON)
  74 option(GMX_DISABLE_GCC41_CHECK "Disable check for (buggy) gcc 4.1.x" OFF)
  75
  76 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries.")
  77
  78
  79
  80 ########################################################################
  81 #Process MPI settings
  82 ########################################################################
  83 if(GMX_MPI)
  84     if(GMX_THREADS)
  85         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  86         set(GMX_THREADS OFF CACHE BOOL
  87             "Thread-based parallelization conflicts with MPI." FORCE)
  88     endif(GMX_THREADS)
  89     find_package(MPI)
  90     if(MPI_FOUND)
  91         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  92         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  93
  94         include_directories(${MPI_INCLUDE_PATH})
  95         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  96         add_definitions( -DMPI ) #for FAHCORE
  97         include(gmxTestMPI_IN_PLACE)
  98         if (GMX_MPI_IN_PLACE)
  99             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 100         endif (GMX_MPI_IN_PLACE)
 101     else(MPI_FOUND)
 102         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 103     endif(MPI_FOUND)
 104     include(gmxTestCatamount)
 105     gmx_test_catamount(GMX_CRAY_XT3)
 106     if(GMX_CRAY_XT3)
 107         set(GMX_NO_SYSTEM 1)
 108         set(GMX_NO_NICE 1)
 109     endif(GMX_CRAY_XT3)
 110     set(GMX_LIB_MPI 1)
 111 endif(GMX_MPI)
 112
 113
 114 #######################################################################
 115 # Check for options incompatible with OpenMM build                    #
 116 #######################################################################
 117 if(GMX_OPENMM)
 118     cmake_minimum_required(VERSION 2.6.4)
 119     # we'll use the built-in fft to avoid unnecessary dependencies
 120     set (GMX_FFT_LIBRARY "fftpack")
 121     if(GMX_MPI)
 122         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 123     endif(GMX_MPI)
 124     if(GMX_THREADS)
 125         message(STATUS "Threads not compatible with OpenMM build, disabled")
 126         set(GMX_THREADS OFF)
 127     endif(GMX_THREADS)
 128     if(GMX_SOFTWARE_INVSQRT)
 129         set(GMX_SOFTWARE_INVSQRT OFF)
 130     endif(GMX_SOFTWARE_INVSQRT)
 131     if(NOT GMX_ACCELERATION MATCHES "none|None|NONE" OR NOT ${GMX_ACCELERATION} STREQUAL "")
 132         message(WARNING "The OpenMM build does not support other acceleration modes!")
 133         set(GMX_ACCELERATION "none")
 134     endif()
 135     if(GMX_FAHCORE)
 136         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 137     endif(GMX_FAHCORE)
 138 endif(GMX_OPENMM)
 139
 140
 141
 142 ########################################################################
 143 # Basic system tests (standard libraries, headers, functions, types)   #
 144 ########################################################################
 145 include(CheckIncludeFiles)
 146 check_include_files(string.h     HAVE_STRING_H)
 147 check_include_files(math.h       HAVE_MATH_H)
 148 check_include_files(limits.h     HAVE_LIMITS_H)
 149 check_include_files(memory.h     HAVE_MEMORY_H)
 150 check_include_files(unistd.h     HAVE_UNISTD_H)
 151 check_include_files(pwd.h        HAVE_PWD_H)
 152 check_include_files(stdint.h     HAVE_STDINT_H)
 153 check_include_files(stdlib.h     HAVE_STDLIB_H)
 154 check_include_files(pthread.h    HAVE_PTHREAD_H)
 155 check_include_files(dirent.h     HAVE_DIRENT_H)
 156 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 157 check_include_files(regex.h      HAVE_REGEX_H)
 158 check_include_files(copyfile.h   HAVE_COPYFILE_H)
 159 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 160 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 161 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 162 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 163 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 164 # SSE support
 165 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 166 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 167 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 168 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 169 check_include_files(io.h                 HAVE_IO_H)
 170
 171
 172 include(CheckFunctionExists)
 173 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 174 check_function_exists(strdup            HAVE_STRDUP)
 175 check_function_exists(vprintf           HAVE_VPRINTF)
 176 check_function_exists(memcmp            HAVE_MEMCMP)
 177 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 178 check_function_exists(memalign          HAVE_MEMALIGN)
 179 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 180 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 181 check_function_exists(isnan             HAVE_ISNAN)
 182 check_function_exists(_isnan            HAVE__ISNAN)
 183 check_function_exists(isfinite          HAVE_ISFINITE)
 184 check_function_exists(_isfinite         HAVE__ISFINITE)
 185 check_function_exists(fsync             HAVE_FSYNC)
 186 check_function_exists(_fileno           HAVE__FILENO)
 187 check_function_exists(fileno            HAVE_FILENO)
 188 check_function_exists(_commit           HAVE__COMMIT)
 189 check_function_exists(copyfile          HAVE_COPYFILE)
 190 # check_function_exists(CopyFile          HAVE_WIN_COPYFILE)
 191 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 192
 193 include(CheckLibraryExists)
 194 check_library_exists(m sqrt "" HAVE_LIBM)
 195 check_library_exists(m cbrt "" HAVE_CBRT)
 196
 197 include(CheckTypeSize)
 198 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 199 check_type_size("int"           SIZEOF_INT)
 200 check_type_size("long int"      SIZEOF_LONG_INT)
 201 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 202 check_type_size("off_t"         SIZEOF_OFF_T)
 203 check_type_size("void *"        SIZEOF_VOIDP)
 204
 205 if (SIZEOF_VOIDP LESS 8)
 206     set(GMX_64_BIT FALSE)
 207 else (SIZEOF_VOIDP LESS 8)
 208     set(GMX_64_BIT TRUE)
 209 endif (SIZEOF_VOIDP LESS 8)
 210
 211 # Check for some basic types that we *need*, so set these to int if they are not present
 212 check_type_size(uid_t uid_t)
 213 if(NOT uid_t)
 214   set(uid_t int)
 215 else(NOT uid_t)
 216   set(uid_t 0)
 217 endif(NOT uid_t)
 218
 219 check_type_size(gid_t gid_t)
 220 if(NOT gid_t)
 221   set(gid_t 1)
 222 else(NOT gid_t)
 223   set(gid_t 0)
 224 endif(NOT gid_t)
 225
 226 check_type_size(size_t size_t)
 227 if(NOT size_t)
 228   set(size_t int)
 229 else(NOT size_t)
 230   set(size_t 0)
 231 endif(NOT size_t)
 232
 233 check_type_size(off_t off_t)
 234 if(NOT off_t)
 235   set(off_t int)
 236 else(NOT off_t)
 237   set(off_t 0)
 238 endif(NOT off_t)
 239
 240 include(TestBigEndian)
 241 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 242
 243
 244
 245
 246 ########################################################################
 247 # Find external packages                                               #
 248 ########################################################################
 249
 250 find_package(LibXml2)
 251 if(LIBXML2_FOUND)
 252     include_directories(${LIBXML2_INCLUDE_DIR})
 253     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 254     set(HAVE_LIBXML2 1)
 255 endif(LIBXML2_FOUND)
 256
 257 find_package(X11)
 258 # X11 includes/libraries are only set in the ngmx subdirectory!
 259 if(X11_FOUND)
 260     set(HAVE_X11 1)
 261 endif(X11_FOUND)
 262
 263 if(GMX_THREADS)
 264     include(ThreadMPI)
 265     set(THREAD_MPI_LIB thread_mpi)
 266     set(GMX_MPI 1)
 267     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 268     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 269         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 270     endif()
 271 endif(GMX_THREADS)
 272
 273 if(GMX_OPENMM)
 274     set(CUDA_BUILD_EMULATION OFF)
 275     find_package(CUDA 2.3 REQUIRED)
 276     add_definitions(-DGMX_OPENMM)
 277     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 278         set(CUDA_VERBOSE_BUILD ON)
 279     endif()
 280     find_package(OpenMM)
 281 endif(GMX_OPENMM)
 282
 283 if(APPLE)
 284    find_library(ACCELERATE_FRAMEWORK Accelerate)
 285    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 286 endif(APPLE)
 287
 288 # only bother with finding git and using version.h if the source is a git repo
 289 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 290     if(USE_VERSION_H)
 291         # We need at least git v1.5.1 be able to parse git's date output. If not
 292         # fund or the version is too small, we can't generate version information.
 293         find_package(Git 1.5.1)
 294         # this should at some point become VERSION_LESS
 295         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 296             message("No compatible git version found, won't be able to generate proper development version information.")
 297         endif()
 298     endif()
 299 else()
 300     set(USE_VERSION_H OFF)
 301 endif()
 302
 303 if (GMX_DLOPEN)
 304     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 305 endif (GMX_DLOPEN)
 306
 307 ########################################################################
 308 # Generate development version info for cache
 309 ########################################################################
 310 # set(GEN_VERSION_INFO_INTERNAL "ON")
 311 # include(gmxGenerateVersionString)
 312
 313 ########################################################################
 314 # Our own GROMACS tests
 315 ########################################################################
 316
 317 add_definitions( -DHAVE_CONFIG_H )
 318 include_directories(${CMAKE_BINARY_DIR}/src)
 319 include_directories(${CMAKE_SOURCE_DIR}/include)
 320
 321 include(gmxCheckBuildUserTime)
 322 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 323
 324 include(gmxTestFloatFormat)
 325 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 326                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 327                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 328
 329 include(gmxTestLargeFiles)
 330 gmx_test_large_files(GMX_LARGEFILES)
 331
 332 include(gmxTestSignal)
 333 gmx_test_retsigtype(RETSIGTYPE)
 334
 335 include(gmxTestInline)
 336 gmx_test_inline(INLINE_KEYWORD)
 337
 338 include(gmxTestPipes)
 339 gmx_test_pipes(HAVE_PIPES)
 340
 341 include(gmxTestInlineASM)
 342 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 343 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 344
 345 # reasonable defaults for fast binaries.
 346 if (NOT DEFINED GMX_SSE_SET)
 347     if (GMX_X86_GCC_INLINE_ASM)
 348         set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec" FORCE)
 349         if (GMX_64_BIT)
 350             set(GMX_X86_64_ASM ON CACHE BOOL
 351                 "Add SSE assembly files for x86_64" FORCE)
 352         else (GMX_64_BIT)
 353             set(GMX_IA32_ASM ON CACHE BOOL
 354                 "Add SSE assembly files for IA32" FORCE)
 355         endif (GMX_64_BIT)
 356     endif (GMX_X86_GCC_INLINE_ASM)
 357     set (GMX_SSE_SET true CACHE INTERNAL "SSE is set" FORCE)
 358 endif (NOT DEFINED GMX_SSE_SET)
 359
 360
 361
 362
 363 include(gmxTestXDR)
 364 gmx_test_xdr(GMX_SYSTEM_XDR)
 365 if(NOT GMX_SYSTEM_XDR)
 366     set(GMX_INTERNAL_XDR 1)
 367 endif(NOT GMX_SYSTEM_XDR)
 368
 369 if(GMX_FORTRAN OR GMX_POWER6)
 370     enable_language(Fortran)
 371     include(FortranCInterface)
 372     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 373     if(extra_under_score)
 374         set(extrasuffix "_")
 375     endif(extra_under_score)
 376
 377     if(isupper)
 378         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 379         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 380     else(isupper)
 381         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 382         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 383     endif(isupper)
 384 else(GMX_FORTRAN OR GMX_POWER6)
 385         set(F77_FUNCDEF   "name ## _")
 386         set(F77_FUNCDEF_  "name ## _")
 387 endif(GMX_FORTRAN OR GMX_POWER6)
 388
 389
 390 # Process nonbonded accelerated kernels settings
 391 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 392 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 393 if(${GMX_ACCELERATION} STREQUAL "NONE")
 394   # nothing to do
 395 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 396     if (NOT GMX_64_BIT)
 397         # for 32-bit compiles, we might need to turn on sse
 398         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 399         if (XFLAGS_SSE)
 400             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 401         endif (XFLAGS_SSE)
 402         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 403         if (XXFLAGS_SSE)
 404             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 405         endif (XXFLAGS_SSE)
 406     endif (NOT GMX_64_BIT)
 407     if(HAVE_XMMINTRIN_H)
 408         if(GMX_IA32_ASM)
 409           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 410           set(GMX_IA32_SSE 1)
 411         else(GMX_IA32_ASM) #only use intrinsic if not using the ASM loops
 412           set(GMX_SSE 1)
 413         endif(GMX_IA32_ASM)
 414     endif(HAVE_XMMINTRIN_H)
 415     if(HAVE_EMMINTRIN_H)
 416         if(GMX_X86_64_ASM)
 417           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 418           set(GMX_X86_64_SSE 1)
 419         else(GMX_X86_64_ASM)  #only use intrinsic if not using the ASM loops
 420           if(NOT GMX_IA32_ASM)
 421             set(GMX_SSE2 1)
 422           endif(NOT GMX_IA32_ASM)
 423         endif(GMX_X86_64_ASM)
 424     endif(HAVE_EMMINTRIN_H)
 425 #    if(HAVE_PMMINTRIN_H)
 426 #        set(GMX_SSE3 1)
 427 #    endif(HAVE_PMMINTRIN_H)
 428 #    if(HAVE_SMMINTRIN_H)
 429 #        set(GMX_SSE4_1 1)
 430 #    endif(HAVE_SMMINTRIN_H)
 431
 432 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 433     set(GMX_FORTRAN 1)
 434 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 435     set(GMX_BLUEGENE 1)
 436 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 437     set(GMX_POWER6 1)
 438 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 439     set(GMX_IA64_ASM 1)
 440     set(DISABLE_WATERWATER_NLIST 1)
 441     set(DISABLE_WATER_NLIST 1)
 442 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 443     check_include_files(altivec.h HAVE_ALTIVEC_H)
 444     if(HAVE_ALTIVEC_H)
 445         set(GMX_PPC_ALTIVEC 1)
 446     endif(HAVE_ALTIVEC_H)
 447 else(${GMX_ACCELERATION} STREQUAL "NONE")
 448     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 449 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 450
 451
 452
 453
 454
 455
 456
 457 # Process QM/MM Settings
 458 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 459 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 460     set(GMX_QMMM_GAUSSIAN 1)
 461 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 462     set(GMX_QMMM_MOPAC 1)
 463 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 464     set(GMX_QMMM_GAMESS 1)
 465 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 466     set(GMX_QMMM_ORCA 1)
 467 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 468     # nothing to do
 469 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 470     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 471 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 472
 473 # Process FFT library settings - if not OpenMM build
 474 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 475 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 476 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 477     if(GMX_DOUBLE)
 478         find_package(FFTW3 REQUIRED)
 479     else(GMX_DOUBLE)
 480         find_package(FFTW3F REQUIRED)
 481     endif(GMX_DOUBLE)
 482
 483     if(NOT FFTW3_FOUND)
 484         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 485     endif(NOT FFTW3_FOUND)
 486
 487     set(GMX_FFT_FFTW3 1)
 488     include_directories(${FFTW3_INCLUDE_DIR})
 489     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 490
 491 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 492 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 493     if(GMX_DOUBLE)
 494         find_package(FFTW2 REQUIRED)
 495     else(GMX_DOUBLE)
 496         find_package(FFTW2F REQUIRED)
 497     endif(GMX_DOUBLE)
 498
 499     if(NOT FFTW2_FOUND)
 500            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 501     endif(NOT FFTW2_FOUND)
 502     include_directories(${FFTW2_INCLUDE_DIR})
 503     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 504
 505     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 506         set(FFTW2_NAME_DFFTW 1)
 507     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 508         set(FFTW2_NAME_SFFTW 1)
 509     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 510         set(FFTW2_NAME_FFTW 1)
 511     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 512
 513     set(GMX_FFT_FFTW2 1)
 514 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 515 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 516     find_package(MKL REQUIRED)
 517     include_directories(${MKL_INCLUDE_DIR})
 518     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 519
 520     set(GMX_FFT_MKL 1)
 521     set(HAVE_MKL 1)
 522
 523 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 524 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 525 #    set(GMX_FFT_ACML 1)
 526 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 527     MESSAGE(STATUS "Using internal FFT library - fftpack")
 528     set(GMX_FFT_FFTPACK 1)
 529 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 530     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 531 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 532
 533 # MKL has BLAS/LAPACK routines
 534 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 535   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 536   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 537 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 538   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 539   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 540 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 541
 542 # Math and thread libraries must often come after all others when linking...
 543 if(HAVE_LIBM)
 544     list(APPEND GMX_EXTRA_LIBRARIES m)
 545 endif(HAVE_LIBM)
 546
 547
 548
 549 if(GMX_FAHCORE)
 550   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 551       "Path to swindirect.h")
 552   include_directories(${COREWRAP_INCLUDE_DIR})
 553 endif(GMX_FAHCORE)
 554
 555 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 556 # these are set after everything else
 557 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 558     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 559         FORCE)
 560     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 561         "Flags used by the compiler during all build types" FORCE)
 562     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 563         "Flags used by the compiler during all build types" FORCE)
 564     set(CMAKE_EXE_LINKER_FLAGS
 565         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 566         CACHE STRING "Linker flags" FORCE)
 567 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 568
 569 ########################################################################
 570 # Specify install locations and which subdirectories to process        #
 571 ########################################################################
 572 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 573 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 574 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 575 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 576
 577 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 578
 579
 580 add_subdirectory(share)
 581 add_subdirectory(include)
 582 add_subdirectory(man)
 583
 584 add_subdirectory(src)
 585
 586 ########################################################################
 587 # Tests                                                                #
 588 ########################################################################
 589
 590 enable_testing()
 591 add_test(TestBuildAll make)
 592
 593 add_subdirectory(tests)