CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36 if(POLICY CMP0074) #3.12
  37     cmake_policy(SET CMP0074 NEW)
  38 endif()
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.9 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.9 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags."
  50         FORCE)
  51     # By default, limit the binary architecture to a single 64-bit build.
  52     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  53         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  54         FORCE)
  55 endif()
  56
  57 project(Gromacs)
  58
  59 set(CMAKE_CXX_STANDARD 14)
  60 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  61 set(CMAKE_CXX_EXTENSIONS OFF)
  62
  63 include(gmxManageCcache)
  64
  65 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  67 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  68
  69 find_package(LibStdCpp)
  70
  71 # Set up common version variables, as well as general information about
  72 # the build tree (whether the build is from a source package or from a git
  73 # repository).  Also declares a few functions that will be used for generating
  74 # version info files later.
  75 include(gmxBuildTreeInfo)
  76 include(gmxVersionInfo)
  77
  78 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  79     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  80 endif()
  81 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  82     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  83 endif()
  84
  85 include(gmxBuildTypeReference)
  86 include(gmxBuildTypeProfile)
  87 include(gmxBuildTypeTSAN)
  88 include(gmxBuildTypeASAN)
  89 include(gmxBuildTypeMSAN)
  90 include(gmxBuildTypeReleaseWithAssert)
  91
  92 if(NOT CMAKE_BUILD_TYPE)
  93     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  94     # Set the possible values of build type for cmake-gui
  95     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  96         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  97 endif()
  98 if(CMAKE_CONFIGURATION_TYPES)
  99     # Add appropriate GROMACS-specific build types for the Visual
 100     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 101     # are already present by default).
 102     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 103     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 104     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 105         "List of configuration types"
 106         FORCE)
 107 endif()
 108 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 109
 110 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 111
 112 include(gmxCTestUtilities)
 113 gmx_ctest_init()
 114
 115 include(gmxCPackUtilities)
 116 gmx_cpack_init()
 117
 118 # Variables that accumulate stuff influencing the installed headers
 119 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 120 set(INSTALLED_HEADER_DEFINITIONS "")
 121
 122 ########################################################################
 123 # Global non-cache variables for implementing the build system
 124 ########################################################################
 125
 126 # These variables collect libraries that GROMACS requires for
 127 # linking. They should be appended to with list(APPEND ${name}
 128 # new-library) calls. They are:
 129 #  - Libraries that are required for libgromacs (only)
 130 set(GMX_EXTRA_LIBRARIES "")
 131 #  - Libraries that are required for all code in the repository
 132 set(GMX_COMMON_LIBRARIES "")
 133 #  - Libraries that all code linked against libgromacs needs
 134 #    (i.e., something that is exposed in installed headers).
 135 set(GMX_PUBLIC_LIBRARIES "")
 136
 137 ########################################################################
 138 # Check and warn if cache generated on a different host is being reused
 139 ########################################################################
 140 if(CMAKE_HOST_UNIX)
 141     execute_process(COMMAND hostname
 142                     OUTPUT_VARIABLE TMP_HOSTNAME
 143                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 144     # Only check for host name if not running in a CI environment, as the cache might
 145     # be reused there between different machines in different stages
 146     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 147             AND NOT DEFINED ENV{CI_JOB_ID})
 148         message(WARNING "
 149             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 150             is being reused! This could lead to inconsistencies; therefore, it is
 151             recommended to regenerate the cache!")
 152     endif()
 153     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 154             "Hostname of the machine where the cache was generated.")
 155 endif()
 156
 157 ########################################################################
 158 # Detect architecture before setting options so we can alter defaults
 159 ########################################################################
 160 # Detect the architecture the compiler is targetting, detect
 161 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 162 # to use if none is specified, and populate the cache option for CPU
 163 # SIMD.
 164 include(gmxDetectTargetArchitecture)
 165 gmx_detect_target_architecture()
 166
 167 ########################################################################
 168 # User input options                                                   #
 169 ########################################################################
 170 include(gmxOptionUtilities)
 171
 172 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 173
 174 # Fujitsu only has SIMD in double precision, so this will be faster
 175 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 176 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 177 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 178 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 179
 180 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 181 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 182 gmx_dependent_option(
 183     GMX_MPI_IN_PLACE
 184     "Enable MPI_IN_PLACE for MPIs that have it defined"
 185     ON
 186     GMX_MPI)
 187 mark_as_advanced(GMX_MPI_IN_PLACE)
 188
 189 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 190
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 199
 200 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 201
 202 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 203 set(REQUIRED_CUDA_VERSION 9.0)
 204 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 205
 206 # OpenCL required version: 1.2 or newer
 207 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 208 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 209 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 210
 211 if(NOT GMX_USE_OPENCL)
 212     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 213     include(gmxManageGPU)
 214     set(GMX_USE_CUDA ${GMX_GPU})
 215     if(GMX_GPU)
 216         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 217     else()
 218         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 219     endif()
 220 else()
 221     #Now the OpenCL path (for both AMD and NVIDIA)
 222     if(GMX_GPU)
 223         include(gmxManageOpenCL)
 224         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 225     else()
 226         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 227     endif()
 228 endif()
 229
 230 gmx_option_multichoice(
 231     GMX_SIMD
 232     "SIMD instruction set for CPU kernels and compiler optimization"
 233     "AUTO"
 234     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 235
 236 if(GMX_TARGET_MIC)
 237     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 238 else()
 239     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 240 endif()
 241
 242 gmx_option_multichoice(
 243     GMX_FFT_LIBRARY
 244     "FFT library"
 245     "${GMX_FFT_LIBRARY_DEFAULT}"
 246     fftw3 mkl "fftpack[built-in]")
 247 gmx_dependent_option(
 248     GMX_BUILD_OWN_FFTW
 249     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 250     OFF
 251     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 252 gmx_dependent_option(
 253     GMX_DISABLE_FFTW_MEASURE
 254     "Do not optimize FFTW setups (not needed with SSE)"
 255     OFF
 256     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 257 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 258 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 259
 260 gmx_option_multichoice(
 261     GMX_QMMM_PROGRAM
 262     "QM package for QM/MM"
 263     None
 264     none gaussian mopac gamess orca)
 265
 266 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 267 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 268
 269 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 270
 271 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 272 mark_as_advanced(GMX_BROKEN_CALLOC)
 273
 274 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 275
 276 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 277
 278 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 279
 280 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 281 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 282
 283 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 284 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 285
 286 option(GMX_BUILD_FOR_COVERAGE
 287        "Tune build for better code coverage metrics (e.g., disable asserts)"
 288        OFF)
 289 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 290
 291 option(GMX_DEVELOPER_BUILD
 292     "Enable Developer convenience features: always build unit-tests"
 293     OFF)
 294 mark_as_advanced(GMX_DEVELOPER_BUILD)
 295
 296 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 297 option(GMX_COMPILER_WARNINGS
 298     "Enable a default set of compiler warnings"
 299     ${GMX_COMPILER_WARNINGS_DEFAULT})
 300 mark_as_advanced(GMX_COMPILER_WARNINGS)
 301 # Always turn on compiler warnings with a developer build.
 302 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 303
 304 option(GMX_BUILD_SHARED_EXE
 305     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 306     ON)
 307 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 308
 309 option(GMX_PHYSICAL_VALIDATION
 310        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 311        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 312        OFF)
 313 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 314
 315 ######################################################################
 316 # Detect OpenMP support
 317 ######################################################################
 318 # The OpenMP detection _must_ come before tests for other CFLAGS.
 319 include(gmxManageOpenMP)
 320
 321
 322
 323 ######################################################################
 324 # Compiler tests
 325 # These need to be done early (before further tests).
 326 #####################################################################
 327
 328 include(gmxCFlags)
 329 gmx_c_flags()
 330
 331 # These variables should be used for CMake-style lists (ie. separated
 332 # by semicolons) of additional compiler flags which are not generated
 333 # in gmxCFlags nor are SIMD or MPI related.
 334 #
 335 # TODO These variables should be consolidated into
 336 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 337 # things that work in C compilation (e.g. merging from old branches)
 338 # might not also work for C++ compilation.
 339 set(EXTRA_C_FLAGS "")
 340 set(EXTRA_CXX_FLAGS "")
 341
 342 # Run through a number of tests for buggy compilers and other issues
 343 include(gmxTestCompilerProblems)
 344 gmx_test_compiler_problems()
 345
 346 # Implement double-precision option. This is complicated because we
 347 # need installed headers to use the precision mode of the build that
 348 # produced the library, but cannot use config.h in that case. We also
 349 # want such variables to always have a definition, because #if is more
 350 # robust than #ifdef. So, we put this value on the compiler command
 351 # line in all cases.
 352 #
 353 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 354 # because no installed header needs it
 355 if(GMX_DOUBLE)
 356     set(GMX_DOUBLE_VALUE 1)
 357 else()
 358     set(GMX_DOUBLE_VALUE 0)
 359 endif()
 360 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 361 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 362
 363 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 364 if(GMX_IMD AND WIN32)
 365     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 366 endif()
 367
 368
 369
 370 ########################################################################
 371 # Basic system tests (standard libraries, headers, functions, types)   #
 372 ########################################################################
 373 include(CheckIncludeFiles)
 374 include(CheckIncludeFileCXX)
 375 check_include_files(unistd.h     HAVE_UNISTD_H)
 376 check_include_files(pwd.h        HAVE_PWD_H)
 377 check_include_files(dirent.h     HAVE_DIRENT_H)
 378 check_include_files(time.h       HAVE_TIME_H)
 379 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 380 check_include_files(io.h         HAVE_IO_H)
 381 check_include_files(sched.h      HAVE_SCHED_H)
 382 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 383
 384 include(CheckCXXSymbolExists)
 385 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 386 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 387 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 388 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 389 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 390 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 391 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 392 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 393
 394 # We cannot check for the __builtins as symbols, but check if code compiles
 395 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 396 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 397 if(MSVC)
 398     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 399     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 400 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 401     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 402     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 403 endif()
 404
 405 include(CheckLibraryExists)
 406 find_library(HAVE_LIBM m)
 407 mark_as_advanced(HAVE_LIBM)
 408 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 409 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 410 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 411
 412 include(TestSchedAffinity)
 413 test_sched_affinity(HAVE_SCHED_AFFINITY)
 414
 415 # Aligned memory allocation. We need to check for both mm_malloc(),
 416 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 417 include(gmxTestMMMalloc)
 418 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 419 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 420 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 421 if(MSVC)
 422     # No need to waste time on this test on platforms where it will never be true
 423     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 424 endif()
 425
 426 include(TestBigEndian)
 427 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 428
 429 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 430
 431 # Management of GROMACS options for specific toolchains should go
 432 # here. Because the initial settings for some of the main options have
 433 # already happened, but things like library detection and MPI compiler
 434 # feature detection have not, the docstrings for any over-rides of
 435 # GROMACS defaults or user settings will make sense. Also, any
 436 # toolchain-related reasons for choosing whether to detect various
 437 # things can be sorted out now, before the detection takes place.
 438 if(GMX_TARGET_FUJITSU_SPARC64)
 439     include(gmxManageFujitsuSparc64)
 440 endif()
 441
 442 ########################################################################
 443 #Process MPI settings
 444 ########################################################################
 445 include(gmxManageMPI)
 446
 447 ########################################################################
 448 #Process MiMiC settings
 449 ########################################################################
 450 include(gmxManageMimic)
 451
 452 ########################################################################
 453 #Process shared/static library settings
 454 ########################################################################
 455 include(gmxManageSharedLibraries)
 456
 457
 458 ########################################################################
 459 # Find external packages                                               #
 460 ########################################################################
 461
 462 # Unconditionally find the package, as it is also required for unit
 463 # tests. This exports LIBXML2_FOUND, which we should not use because
 464 # it does not tell us that linking will succeed. Instead, we test that
 465 # next.
 466 #if(DEFINED LIBXML2_LIBRARIES)
 467 #  set(LibXml2_FIND_QUIETLY TRUE)
 468 #endif()
 469 #find_package(LibXml2)
 470 #include(gmxTestLibXml2)
 471 #gmx_test_libxml2(HAVE_LIBXML2)
 472 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 473 #set(PKG_XML "")
 474 #mark_as_advanced(GMX_XML)
 475 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 476 #if(GMX_XML AND NOT HAVE_LIBXML2)
 477 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 478 #endif()
 479 #if(GMX_XML)
 480 #    include_directories(${LIBXML2_INCLUDE_DIR})
 481 #    set(PKG_XML libxml-2.0)
 482 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 483 #endif()
 484
 485 gmx_option_trivalue(
 486     GMX_HWLOC
 487     "Use hwloc portable hardware locality library"
 488     "AUTO")
 489
 490 if (GMX_HWLOC)
 491     # Find quietly the second time.
 492     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 493         set(HWLOC_FIND_QUIETLY TRUE)
 494     endif()
 495     find_package(HWLOC 1.5)
 496
 497     if (HWLOC_FOUND)
 498         if (HWLOC_LIBRARIES MATCHES ".a$")
 499             set(_STATIC_HWLOC TRUE)
 500         endif()
 501
 502         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 503         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 504             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 505             set(GMX_USE_HWLOC OFF)
 506         else()
 507             set(GMX_USE_HWLOC ON)
 508         endif()
 509
 510         if (GMX_USE_HWLOC)
 511             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 512             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 513         endif()
 514     elseif(GMX_HWLOC_FORCE)
 515         message(FATAL_ERROR "HWLOC package support required, but not found.")
 516     endif()
 517
 518     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 519 endif()
 520
 521 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 522 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 523 if(GMX_EXTERNAL_TINYXML2)
 524     # Find an external TinyXML-2 library.
 525     find_package(TinyXML-2 3.0.0)
 526     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 527     if(NOT HAVE_TINYXML2)
 528         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 529     endif()
 530 endif()
 531
 532 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 533 mark_as_advanced(GMX_EXTRAE)
 534
 535 if (GMX_EXTRAE)
 536   find_package(EXTRAE)
 537   if(EXTRAE_FOUND)
 538     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 539     set(HAVE_EXTRAE 1)
 540   else()
 541     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 542   endif()
 543 endif()
 544
 545 option(GMX_X11 "Use X window system" OFF)
 546 if (GMX_X11)
 547     find_package(X11)
 548     # X11 includes/libraries are only set in the ngmx subdirectory!
 549     if(NOT X11_FOUND)
 550         message(FATAL_ERROR
 551                 "X11 include files and/or libraries were not found. "
 552                 "Set GMX_X11=OFF to compile without X11 support. "
 553                 "gmx view will not be available.")
 554     endif()
 555     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 556 endif()
 557
 558 include(ThreadMPI)
 559 # Enable core threading facilities
 560 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 561 if(GMX_THREAD_MPI)
 562     # enable MPI functions
 563     tmpi_enable()
 564     set(MPI_IN_PLACE_EXISTS 1)
 565 endif()
 566 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 567 if (TMPI_ATOMICS_DISABLED)
 568    add_definitions(-DTMPI_ATOMICS_DISABLED)
 569 endif()
 570
 571 include(gmxManageTNG)
 572
 573 include(gmxManageLmfit)
 574
 575 if(GMX_GPU)
 576     # now that we have detected the dependencies, do the second configure pass
 577     gmx_gpu_setup()
 578     if (GMX_CLANG_CUDA)
 579         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 580         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 581     endif()
 582 endif()
 583
 584 if(CYGWIN)
 585     set(GMX_CYGWIN 1)
 586 endif()
 587
 588 if(WIN32)
 589     set(GMX_NATIVE_WINDOWS 1)
 590     # This makes windows.h not declare min/max as macros that would break
 591     # C++ code using std::min/std::max.
 592     add_definitions(-DNOMINMAX)
 593 endif()
 594
 595 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 596 mark_as_advanced(GMX_BUILD_UNITTESTS)
 597 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 598
 599 ########################################################################
 600 # Our own GROMACS tests
 601 ########################################################################
 602
 603 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 604 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 605 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 606
 607 include(gmxTestInlineASM)
 608 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 609
 610 include(gmxSetBuildInformation)
 611 gmx_set_build_information()
 612
 613 gmx_option_multichoice(
 614     GMX_USE_RDTSCP
 615     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 616     "AUTO"
 617     OFF ON AUTO DETECT)
 618 mark_as_advanced(GMX_USE_RDTSCP)
 619
 620 macro(gmx_check_rdtscp)
 621     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 622         set(HAVE_RDTSCP 1)
 623         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 624     else()
 625         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 626     endif()
 627 endmacro()
 628
 629 set(HAVE_RDTSCP 0)
 630 if (GMX_USE_RDTSCP STREQUAL "ON")
 631     set(HAVE_RDTSCP 1)
 632 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 633     gmx_check_rdtscp()
 634 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 635     # If the user specified automated SIMD selection, that the choice
 636     # is made based on detection on the build host. If so, then RDTSCP
 637     # should be chosen the same way.
 638     #
 639     # If the user specified an AVX SIMD level (e.g. when
 640     # cross-compiling GROMACS) then they will get our best guess, ie
 641     # that in practice AVX mostly correlates with rdtscp (and anyway
 642     # is only relevant in rather old x86 hardware).
 643     if (GMX_SIMD STREQUAL "AUTO")
 644         gmx_check_rdtscp()
 645     elseif (GMX_SIMD MATCHES "AVX")
 646         set(HAVE_RDTSCP 1)
 647     endif()
 648 endif()
 649 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 650 if (HAVE_RDTSCP_CHANGED)
 651     if (HAVE_RDTSCP)
 652         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 653     else()
 654         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 655     endif()
 656 endif()
 657
 658 include(gmxTestLargeFiles)
 659 gmx_test_large_files(GMX_LARGEFILES)
 660
 661 include(gmxTestSignal)
 662 gmx_test_sigusr1(HAVE_SIGUSR1)
 663
 664 include(gmxTestPipes)
 665 gmx_test_pipes(HAVE_PIPES)
 666
 667 include(gmxTestXDR)
 668 gmx_test_xdr(GMX_SYSTEM_XDR)
 669 # Darwin has system XDR, but it uses a three-argument flavour of
 670 # xdrproc_t that it guarantees will still work if you pass the normal
 671 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 672 # to do that, so it's simpler to just use our own XDR library.
 673 #
 674 # TODO It would be better to craft a cmake test which fails if such
 675 # XDR operations cause warnings, and succeeds otherwise, because it is
 676 # generally preferable to use system libraries where possible.
 677 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 678     set(GMX_INTERNAL_XDR 1)
 679 endif()
 680
 681
 682 ##################################################
 683 # Process SIMD instruction settings
 684 ##################################################
 685 # This checks what flags to add in order to
 686 # support the SIMD instructions we need, it sets
 687 # correct defines for the SIMD instructions supported,
 688 # and adds advanced options to control accuracy
 689 # for SIMD math operations.
 690 include(gmxManageSimd)
 691 gmx_manage_simd()
 692
 693 include(gmxManageCycleCounters)
 694 gmx_manage_cycle_counters()
 695
 696 # Process QM/MM Settings
 697 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 698     set(GMX_QMMM_GAUSSIAN 1)
 699 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 700     set(GMX_QMMM_MOPAC 1)
 701 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 702     set(GMX_QMMM_GAMESS 1)
 703 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 704     set(GMX_QMMM_ORCA 1)
 705 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 706     # nothing to do
 707 else()
 708     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 709 endif()
 710
 711
 712 ##################################################
 713 # Process FFT library settings
 714 ##################################################
 715 include(gmxManageFFTLibraries)
 716
 717
 718 include(gmxManageLinearAlgebraLibraries)
 719
 720 include(gmxManagePluginSupport)
 721
 722 if (GMX_USE_PLUGINS)
 723     if(NOT GMX_VMD_PLUGIN_PATH)
 724         find_package(VMD)
 725     endif()
 726 endif()
 727
 728 # Link real-time library for POSIX timers. The check for clock_gettime
 729 # confirms the linkability of rt.
 730 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 731     list(APPEND GMX_EXTRA_LIBRARIES rt)
 732 endif()
 733
 734 # Math and thread libraries must often come after all others when linking...
 735 if (HAVE_LIBM)
 736     list(APPEND GMX_PUBLIC_LIBRARIES m)
 737 endif()
 738
 739 option(GMX_NACL "Configure for Native Client builds" OFF)
 740 if (GMX_NACL)
 741   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 742   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 743   # TODO: Is this still necessary with the check for its presence?
 744   set(GMX_USE_NICE 0)
 745   set(GMX_NO_RENAME 1)
 746 endif()
 747 mark_as_advanced(GMX_NACL)
 748
 749 if(GMX_FAHCORE)
 750   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 751       "Path to swindirect.h")
 752   include_directories(${COREWRAP_INCLUDE_DIR})
 753 endif()
 754
 755 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 756 # produce warnings if that fails.
 757 set(build_help_default AUTO)
 758 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 759     set(build_help_default OFF)
 760 endif()
 761 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 762 mark_as_advanced(GMX_BUILD_HELP)
 763 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 764     message(FATAL_ERROR
 765         "Rebuilding shell completions or man pages is not supported for "
 766         "in-source builds from a source distribution. "
 767         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 768 endif()
 769
 770 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 771 # these are set after everything else
 772 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 773     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 774     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 775 else()
 776     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 777     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 778     foreach(build_type ${build_types_with_explicit_flags})
 779         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 780     endforeach()
 781     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 782     foreach(build_type ${build_types_with_explicit_flags})
 783         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 784     endforeach()
 785     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 786     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 787 endif()
 788
 789 ########################################################################
 790 # Specify install locations
 791 ########################################################################
 792 # Use GNUInstallDirs to set paths on multiarch systems.
 793 include(GNUInstallDirs)
 794
 795 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 796 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 797
 798 # Internal convenience so we do not have to join two path segments in the code
 799 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 800
 801 # If the nesting level wrt. the installation root is changed,
 802 # gromacs-config.cmake.cmakein needs to be adapted.
 803 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 804
 805 # TODO: Make GMXRC adapt if this is changed
 806 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 807 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 808
 809 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 810
 811 # Binary and library suffix options
 812 include(gmxManageSuffixes)
 813
 814 ################################################################
 815 # Shared library load path settings
 816 ################################################################
 817 if(NOT GMX_BUILD_SHARED_EXE)
 818     # No rpath
 819     set(CMAKE_SKIP_RPATH TRUE)
 820     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 821     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 822 else()
 823     # The build folder always has bin/ and lib/; if we are also going to
 824     # install to lib/, then the installation RPATH works also in the build
 825     # tree.  This makes installation slightly faster (no need to rewrite the
 826     # RPATHs), and makes the binaries in the build tree relocatable.
 827     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 828         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 829         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 830     endif()
 831     # Set the RPATH as relative to the executable location to make the
 832     # binaries relocatable.
 833     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 834         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 835         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 836     else()
 837         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 838     endif()
 839     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 840     set(CMAKE_MACOSX_RPATH 1)
 841 endif()
 842
 843 #COPYING file: Only necessary for binary distributions.
 844 #Simpler to always install.
 845 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 846
 847 if (GMX_BUILD_FOR_COVERAGE)
 848     # Code heavy with asserts makes conditional coverage close to useless metric,
 849     # as by design most of the false branches are impossible to trigger in
 850     # correctly functioning code.  And the benefit of testing those that could
 851     # be triggered by using an API against its specification isn't usually
 852     # worth the effort.
 853     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 854 endif()
 855
 856 if (BUILD_TESTING)
 857     include(tests/CheckTarget.cmake)
 858 endif()
 859
 860 # TODO: Determine control flow and defaults for package installation and testing use cases.
 861 # Ref: http://redmine.gromacs.org/issues/2896
 862 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 863 mark_as_advanced(GMX_PYTHON_PACKAGE)
 864
 865 if (NOT GMX_BUILD_MDRUN_ONLY)
 866     # Note: Though only documented as an output variable, PYTHON_EXECUTABLE is
 867     # also effective as a CMake input variable to effectively hint the location
 868     # of the Python interpreter. This may be helpful in environments with both
 869     # Python 2 and Python 3 on the default PATH.
 870     # Ref: https://cmake.org/cmake/help/latest/module/FindPythonInterp.html
 871     if(FIND_PACKAGE_MESSAGE_DETAILS_PythonInterp)
 872         # Keep quiet on subsequent runs of cmake
 873         set(PythonInterp_FIND_QUIETLY ON)
 874     endif()
 875     # Older CMake versions might not search for Python newer than 3.7.
 876     set(Python_ADDITIONAL_VERSIONS 3.8)
 877     if(GMX_PYTHON_PACKAGE)
 878         find_package(PythonInterp 3.5 REQUIRED)
 879         # Note: PythonLibs will be found later by pybind11.
 880         # TODO: (issue #2998) When CMake >= 3.12 is required, update detection.
 881         # I.e.  find_package(Python3 3.5 COMPONENTS Interpreter Development REQUIRED)
 882     else()
 883         find_package(PythonInterp 3.5)
 884     endif()
 885     find_package(ImageMagick QUIET COMPONENTS convert)
 886     include(gmxTestImageMagick)
 887     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 888     # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 889     add_subdirectory(docs)
 890     add_subdirectory(share)
 891     add_subdirectory(scripts)
 892 endif()
 893 add_subdirectory(src)
 894
 895 if (BUILD_TESTING)
 896     add_subdirectory(tests)
 897 endif()
 898
 899 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 900     add_subdirectory(python_packaging)
 901 endif()
 902
 903 gmx_cpack_write_config()
 904
 905 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 906 # Don't bother the user after the first configure pass.
 907 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 908     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 909 endif()
 910 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 911
 912 #######################
 913 ## uninstall target
 914 #######################
 915 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 916                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 917                   IMMEDIATE @ONLY)
 918 ###########################
 919 ADD_CUSTOM_TARGET(uninstall
 920                   "${CMAKE_COMMAND}" -P
 921                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 922 ###########################
 923 set_directory_properties(PROPERTIES
 924             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")