CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsistencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 include(gmxDetectSimd)
 176 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 177
 178 gmx_option_multichoice(
 179     GMX_SIMD
 180     "SIMD instruction set for CPU kernels and compiler optimization"
 181     "${GMX_SUGGESTED_SIMD}"
 182     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 183
 184 if(GMX_TARGET_MIC)
 185     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 186 else()
 187     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 188 endif()
 189
 190 gmx_option_multichoice(
 191     GMX_FFT_LIBRARY
 192     "FFT library"
 193     "${GMX_FFT_LIBRARY_DEFAULT}"
 194     fftw3 mkl "fftpack[built-in]")
 195 gmx_dependent_option(
 196     GMX_BUILD_OWN_FFTW
 197     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 198     OFF
 199     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 200 gmx_dependent_option(
 201     GMX_DISABLE_FFTW_MEASURE
 202     "Do not optimize FFTW setups (not needed with SSE)"
 203     OFF
 204     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 205 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 206 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 207
 208 gmx_option_multichoice(
 209     GMX_QMMM_PROGRAM
 210     "QM package for QM/MM"
 211     None
 212     none gaussian mopac gamess orca)
 213
 214 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 215 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 216
 217 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 218
 219 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 220 mark_as_advanced(GMX_BROKEN_CALLOC)
 221 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 222 mark_as_advanced(GMX_LOAD_PLUGINS)
 223
 224 option(GMX_GPU  "Enable GPU acceleration" ON)
 225 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 226
 227 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 228
 229 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 230
 231 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 232 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 233
 234 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 235 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 236
 237 option(GMX_BUILD_FOR_COVERAGE
 238        "Tune build for better code coverage metrics (e.g., disable asserts)"
 239        OFF)
 240 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 241
 242 option(GMX_DEVELOPER_BUILD
 243     "Enable Developer convenience features: always build unit-tests"
 244     OFF)
 245 mark_as_advanced(GMX_DEVELOPER_BUILD)
 246
 247 ######################################################################
 248 # Detect OpenMP support
 249 ######################################################################
 250 # The OpenMP detection _must_ come before tests for other CFLAGS.
 251 include(gmxManageOpenMP)
 252
 253
 254
 255 ######################################################################
 256 # Compiler tests
 257 # These need to be done early (before further tests).
 258 #####################################################################
 259
 260 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 261 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 262 # invalid options with the Intel Compilers, and we have added a line
 263 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 264 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 265 # a semicolon. Since this is also used as a separator in lists inside CMake,
 266 # that string ends up being split into two separate patterns, and the last
 267 # part is just a single word that also matches other messages. We solved this
 268 # by replacing the semicolon with a period that matches any character.
 269 #
 270 # These files should be removed from the source tree when a CMake version that
 271 # includes the features in question becomes required for building GROMACS.
 272 include(CheckCCompilerFlag)
 273 include(CheckCXXCompilerFlag)
 274
 275 include(gmxCFlags)
 276 gmx_c_flags()
 277
 278 # This variable should be used for additional compiler flags which are not
 279 # generated in gmxCFlags nor are SIMD or MPI related.
 280 set(EXTRA_C_FLAGS "")
 281 set(EXTRA_CXX_FLAGS "")
 282
 283 # Run through a number of tests for buggy compilers and other issues
 284 include(gmxTestCompilerProblems)
 285 gmx_test_compiler_problems()
 286 # GMX_SIMD will not be set automatically until the second
 287 # pass (which is not strictly guaranteed to occur), so putting this
 288 # check here among logically-related tests is inefficient, but the
 289 # potential loss is likely zero.
 290 if(GMX_SIMD STREQUAL "AVX_256"
 291         AND CMAKE_COMPILER_IS_GNUCC
 292         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 293             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 294     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 295     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 296 endif()
 297
 298
 299 if(GMX_DOUBLE)
 300     add_definitions(-DGMX_DOUBLE)
 301     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 302     if(GMX_RELAXED_DOUBLE_PRECISION)
 303         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 304     endif()
 305 endif()
 306 if(GMX_SOFTWARE_INVSQRT)
 307     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 308 endif()
 309
 310 if(WIN32)
 311     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 312     add_definitions(-DGMX_HAVE_WINSOCK)
 313 endif()
 314
 315
 316
 317 ########################################################################
 318 # Basic system tests (standard libraries, headers, functions, types)   #
 319 ########################################################################
 320 include(CheckIncludeFiles)
 321 include(CheckIncludeFileCXX)
 322 check_include_files(unistd.h     HAVE_UNISTD_H)
 323 check_include_files(pwd.h        HAVE_PWD_H)
 324 check_include_files(dirent.h     HAVE_DIRENT_H)
 325 check_include_files(time.h       HAVE_TIME_H)
 326 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 327 check_include_files(io.h         HAVE_IO_H)
 328 check_include_files(sched.h      HAVE_SCHED_H)
 329
 330 check_include_files(regex.h      HAVE_POSIX_REGEX)
 331 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 332 # TODO: It could be nice to inform the user if no regex support is found,
 333 # as selections won't be fully functional.
 334
 335 include(CheckFunctionExists)
 336 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 337 check_function_exists(memalign          HAVE_MEMALIGN)
 338 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 339 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 340 check_function_exists(fsync             HAVE_FSYNC)
 341 check_function_exists(_fileno           HAVE__FILENO)
 342 check_function_exists(fileno            HAVE_FILENO)
 343 check_function_exists(_commit           HAVE__COMMIT)
 344 check_function_exists(sigaction         HAVE_SIGACTION)
 345 check_function_exists(sysconf           HAVE_SYSCONF)
 346 check_function_exists(rsqrt             HAVE_RSQRT)
 347 check_function_exists(rsqrtf            HAVE_RSQRTF)
 348 check_function_exists(sqrtf             HAVE_SQRTF)
 349 check_function_exists(nice              HAVE_NICE)
 350
 351 include(CheckLibraryExists)
 352 check_library_exists(m sqrt "" HAVE_LIBM)
 353 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 354 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 355
 356 include(TestSchedAffinity)
 357 test_sched_affinity(HAVE_SCHED_AFFINITY)
 358
 359 include(TestBigEndian)
 360 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 361
 362 set(GMX_USE_NICE 0)
 363 if (HAVE_UNISTD_H AND HAVE_NICE)
 364     set(GMX_USE_NICE 1)
 365 endif()
 366
 367 # Management of GROMACS options for specific toolchains should go
 368 # here. Because the initial settings for some of the main options have
 369 # already happened, but things like library detection and MPI compiler
 370 # feature detection have not, the docstrings for any over-rides of
 371 # GROMACS defaults or user settings will make sense. Also, any
 372 # toolchain-related reasons for choosing whether to detect various
 373 # things can be sorted out now, before the detection takes place.
 374 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 375     include(gmxManageBlueGene)
 376 endif()
 377
 378 if(GMX_TARGET_FUJITSU_SPARC64)
 379     include(gmxManageFujitsuSparc64)
 380 endif()
 381
 382 ########################################################################
 383 #Process MPI settings
 384 ########################################################################
 385 include(gmxManageMPI)
 386
 387
 388 ########################################################################
 389 #Process shared/static library settings
 390 ########################################################################
 391 include(gmxManageSharedLibraries)
 392
 393
 394 ########################################################################
 395 # Find external packages                                               #
 396 ########################################################################
 397
 398 # Unconditionally find the package, as it is also required for unit
 399 # tests. This exports LIBXML2_FOUND, which we should not use because
 400 # it does not tell us that linking will succeed. Instead, we test that
 401 # next.
 402 if(DEFINED LIBXML2_LIBRARIES)
 403   set(LibXml2_FIND_QUIETLY TRUE)
 404 endif()
 405 find_package(LibXml2)
 406 include(gmxTestLibXml2)
 407 gmx_test_libxml2(HAVE_LIBXML2)
 408 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 409 set(PKG_XML "")
 410 mark_as_advanced(GMX_XML)
 411 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 412 #if(GMX_XML AND NOT HAVE_LIBXML2)
 413 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 414 #endif()
 415 #if(GMX_XML)
 416 #    include_directories(${LIBXML2_INCLUDE_DIR})
 417 #    set(PKG_XML libxml-2.0)
 418 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 419 #endif()
 420
 421 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 422 mark_as_advanced(GMX_EXTRAE)
 423
 424 if (GMX_EXTRAE)
 425   find_package(EXTRAE)
 426   if(EXTRAE_FOUND)
 427     include_directories(${EXTRAE_INCLUDE_DIR})
 428     set(HAVE_EXTRAE 1)
 429   else()
 430     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 431   endif()
 432 endif()
 433
 434 option(GMX_X11 "Use X window system" OFF)
 435 if (GMX_X11)
 436     find_package(X11)
 437     # X11 includes/libraries are only set in the ngmx subdirectory!
 438     if(NOT X11_FOUND)
 439         message(FATAL_ERROR
 440                 "X11 include files and/or libraries were not found. "
 441                 "Set GMX_X11=OFF to compile without X11 support. "
 442                 "gmx view will not be available.")
 443     endif()
 444     include_directories(${X11_INCLUDE_DIR})
 445 endif()
 446
 447 include(ThreadMPI)
 448 # Enable core threading facilities
 449 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 450 # Enable tMPI C++ support
 451 tmpi_enable_cxx()
 452 if(GMX_THREAD_MPI)
 453     # enable MPI functions
 454     tmpi_enable()
 455     set(MPI_IN_PLACE_EXISTS 1)
 456 endif()
 457 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 458 if (TMPI_ATOMICS_DISABLED)
 459    add_definitions(-DTMPI_ATOMICS_DISABLED)
 460 endif()
 461
 462 if(GMX_GPU)
 463     # now that we have detected the dependencies, do the second configure pass
 464     gmx_gpu_setup()
 465 endif()
 466
 467 if(CYGWIN)
 468     set(GMX_CYGWIN 1)
 469 endif()
 470
 471 if(WIN32)
 472     set(GMX_NATIVE_WINDOWS 1)
 473     # This makes windows.h not declare min/max as macros that would break
 474     # C++ code using std::min/std::max.
 475     add_definitions(-DNOMINMAX)
 476 endif()
 477
 478 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 479 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 480 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 481     if(DEFINED Boost_INCLUDE_DIR)
 482         set(Boost_FIND_QUIETLY TRUE)
 483     endif()
 484     find_package(Boost 1.44.0)
 485     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 486         set(Boost_FOUND FALSE)
 487     endif()
 488     # Print the notification only on first run, when determining the default
 489     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 490         message("Boost >= 1.44 not found. Using minimal internal version. "
 491                 "This may cause trouble if you plan on compiling/linking other "
 492                 "software that uses Boost against Gromacs.")
 493     endif()
 494 endif()
 495 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 496        ${Boost_FOUND})
 497 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 498     message(FATAL_ERROR
 499         "Boost >= 1.44 not found. "
 500         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 501         "version of Boost included with Gromacs.")
 502 endif()
 503
 504 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 505     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 506 endif()
 507 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 508 mark_as_advanced(GMX_BUILD_UNITTESTS)
 509 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 510 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 511     message(FATAL_ERROR
 512         "Cannot build unit tests without libxml2. "
 513         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 514 endif()
 515
 516 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 517     # TNG wants zlib if it is available
 518     find_package(ZLIB QUIET)
 519     include(gmxTestZLib)
 520     gmx_test_zlib(HAVE_ZLIB)
 521 endif()
 522
 523 ########################################################################
 524 # Our own GROMACS tests
 525 ########################################################################
 526
 527 add_definitions( -DHAVE_CONFIG_H )
 528 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 529 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 530 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 531 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 532
 533 include(gmxTestInlineASM)
 534 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 535
 536 include(gmxSetBuildInformation)
 537 gmx_set_build_information()
 538 # Turn on RDTSCP if:
 539 # - the build system's CPU supports it
 540 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 541 #   at this point means that the user set it).
 542 # Note: it's better to not use the later set value of GMX_SIMD because
 543 # it reflects the system's capability of both compiling and running AVX code.
 544 # TODO: After merge with 5.0 one could implement a cache variable dependency
 545 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 546 # after the first cmake pass.
 547 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 548     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 549 else()
 550     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 551 endif()
 552 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 553 mark_as_advanced(GMX_USE_RDTSCP)
 554 if(GMX_USE_RDTSCP)
 555     set(HAVE_RDTSCP 1)
 556 endif()
 557
 558 include(gmxTestFloatFormat)
 559 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 560                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 561                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 562
 563 include(gmxTestLargeFiles)
 564 gmx_test_large_files(GMX_LARGEFILES)
 565
 566 include(gmxTestSignal)
 567 gmx_test_sigusr1(HAVE_SIGUSR1)
 568
 569 include(gmxTestPipes)
 570 gmx_test_pipes(HAVE_PIPES)
 571
 572 include(gmxTestIsfinite)
 573 gmx_test_isfinite(HAVE_ISFINITE)
 574 gmx_test__isfinite(HAVE__ISFINITE)
 575 gmx_test__finite(HAVE__FINITE)
 576
 577 include(gmxTestCXX11)
 578 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 579 include(CMakeDependentOption)
 580 # clang with some older versions of boost fail to work with C++11
 581 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 582     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 583     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 584 endif()
 585 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 586 # entirely to keep the compilation environment uniform.
 587 cmake_dependent_option(GMX_CXX11
 588     "Use C++11 features"
 589     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 590 mark_as_advanced(GMX_CXX11)
 591 if(GMX_CXX11)
 592     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 593 endif()
 594
 595
 596 include(gmxTestXDR)
 597 gmx_test_xdr(GMX_SYSTEM_XDR)
 598 if(NOT GMX_SYSTEM_XDR)
 599     set(GMX_INTERNAL_XDR 1)
 600 endif()
 601
 602
 603 ##################################################
 604 # Process SIMD instruction settings
 605 ##################################################
 606 # This checks what flags to add in order to
 607 # support the SIMD instructions we need, and sets
 608 # correct defines for the SIMD instructions supported.
 609 include(gmxTestSimd)
 610 gmx_test_simd()
 611
 612
 613 # Process QM/MM Settings
 614 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 615     set(GMX_QMMM_GAUSSIAN 1)
 616 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 617     set(GMX_QMMM_MOPAC 1)
 618 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 619     set(GMX_QMMM_GAMESS 1)
 620 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 621     set(GMX_QMMM_ORCA 1)
 622 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 623     # nothing to do
 624 else()
 625     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 626 endif()
 627
 628
 629 ##################################################
 630 # Process FFT library settings
 631 ##################################################
 632 include(gmxManageFFTLibraries)
 633
 634
 635 include(gmxManageLinearAlgebraLibraries)
 636
 637 # Whether GROMACS will really try to compile support for VMD plugins
 638 set(GMX_USE_PLUGINS OFF)
 639
 640 if(GMX_LOAD_PLUGINS)
 641   if(NOT WIN32)
 642     # Native Windows does not have, nor need dlopen
 643     include(gmxTestdlopen)
 644     gmx_test_dlopen(HAVE_DLOPEN)
 645   endif()
 646
 647   # so, should we use plug-ins?
 648   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 649     if(NOT VMD_QUIETLY)
 650       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 651     endif()
 652     if(NOT GMX_VMD_PLUGIN_PATH)
 653       find_package(VMD)
 654     endif()
 655     set(GMX_USE_PLUGINS ON)
 656     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 657     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 658   else()
 659     set(PKG_DL_LIBS)
 660   endif()
 661 endif()
 662 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 663
 664 # Link real-time library for POSIX timers. The check for clock_gettime
 665 # confirms the linkability of rt.
 666 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 667     list(APPEND GMX_EXTRA_LIBRARIES rt)
 668 endif()
 669
 670 # Math and thread libraries must often come after all others when linking...
 671 if(HAVE_LIBM)
 672     list(APPEND GMX_EXTRA_LIBRARIES m)
 673 endif()
 674
 675 option(GMX_NACL "Configure for Native Client builds" OFF)
 676 if (GMX_NACL)
 677   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 678   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 679   # TODO: Is this still necessary with the check for its presence?
 680   set(GMX_USE_NICE 0)
 681   set(GMX_NO_RENAME 1)
 682 endif()
 683 mark_as_advanced(GMX_NACL)
 684
 685 if(GMX_FAHCORE)
 686   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 687       "Path to swindirect.h")
 688   include_directories(${COREWRAP_INCLUDE_DIR})
 689 endif()
 690
 691 # Value of AUTO tries to generate things, but will only produce warnings if
 692 # that fails.
 693 set(build_help_default AUTO)
 694 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 695     set(build_help_default OFF)
 696 endif()
 697 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 698 mark_as_advanced(GMX_BUILD_HELP)
 699 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 700     message(FATAL_ERROR
 701         "Rebuilding shell completions or man pages is not supported for "
 702         "in-source builds from a source distribution. "
 703         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 704 endif()
 705
 706 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 707 # these are set after everything else
 708 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 709     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 710     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 711     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 712     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 713 else()
 714     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 715     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 716     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 717     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 718     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 719     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 720     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 721     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 722     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 723 endif()
 724
 725 if(NOT GMX_OPENMP)
 726     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 727     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 728     unset(OpenMP_C_FLAGS CACHE)
 729     unset(OpenMP_CXX_FLAGS CACHE)
 730 else()
 731     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 732     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 733 endif()
 734
 735 ########################################################################
 736 # Specify install locations
 737 ########################################################################
 738 # Use GNUInstallDirs to set paths on multiarch systems.
 739 include(GNUInstallDirs)
 740
 741 # Customization for the installation tree paths.
 742 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 743     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 744 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 745     "Data installation directory under share/ (default: gromacs)")
 746 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 747
 748 # These variables are used internally to provide a central location for
 749 # customizing the install locations.
 750 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 751 set(BIN_INSTALL_DIR       bin)
 752 # This variable also gets written into config.h for use in finding the data
 753 # directories.
 754 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 755 set(MAN_INSTALL_DIR       share/man)
 756 # If the nesting level wrt. the installation root is changed,
 757 # gromacs-config.cmake.cmakein needs to be adapted.
 758 set(CMAKE_INSTALL_DIR     share/cmake)
 759 # TODO: Make GMXRC adapt if this is changed
 760 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 761 set(INCL_INSTALL_DIR      include)
 762
 763 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 764
 765 # Binary and library suffix options
 766 include(gmxManageSuffixes)
 767
 768 ################################################################
 769 # Shared library load path settings
 770 ################################################################
 771 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 772 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 773 # was added.
 774 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 775    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 776     # The build folder always has bin/ and lib/; if we are also going to
 777     # install to lib/, then the installation RPATH works also in the build
 778     # tree.  This makes installation slightly faster (no need to rewrite the
 779     # RPATHs), and makes the binaries in the build tree relocatable.
 780     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 781         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 782     endif()
 783     # Set the RPATH as relative to the executable location to make the
 784     # binaries relocatable.
 785     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 786         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 787     else()
 788         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 789     endif()
 790     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 791     set(CMAKE_MACOSX_RPATH 1)
 792 else()
 793     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 794     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 795         # Set the RPATH options manually.
 796         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 797         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 798     else()
 799         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 800         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 801     endif()
 802 endif()
 803
 804 #COPYING file: Only necessary for binary distributions.
 805 #Simpler to always install.
 806 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 807
 808 if(GMX_EXTERNAL_BOOST)
 809     include_directories(${Boost_INCLUDE_DIRS})
 810     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 811 else()
 812     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 813     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 814     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 815     # typeid not supported for minimal internal version
 816     # (would add significant amount of code)
 817     add_definitions(-DBOOST_NO_TYPEID)
 818     if (NOT GMX_BUILD_MDRUN_ONLY)
 819         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 820                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 821                 COMPONENT development)
 822     endif()
 823 endif()
 824
 825 if (GMX_BUILD_FOR_COVERAGE)
 826     # Code heavy with asserts makes conditional coverage close to useless metric,
 827     # as by design most of the false branches are impossible to trigger in
 828     # correctly functioning code.  And the benefit of testing those that could
 829     # be triggered by using an API against its specification isn't usually
 830     # worth the effort.
 831     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 832 endif()
 833
 834 if (BUILD_TESTING)
 835     # "tests" target builds all the separate test binaries.
 836     add_custom_target(tests)
 837     # "run-ctest" is an internal target that actually runs the tests.
 838     # This is necessary to be able to add separate targets that execute as part
 839     # of 'make check', but are ensured to be executed after the actual tests.
 840     add_custom_target(run-ctest
 841                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 842                       COMMENT "Running all tests"
 843                       VERBATIM)
 844     add_dependencies(run-ctest tests)
 845     # "check" target builds and runs all tests.
 846     add_custom_target(check DEPENDS run-ctest)
 847 endif()
 848
 849 if (NOT GMX_BUILD_MDRUN_ONLY)
 850     add_subdirectory(docs)
 851     add_subdirectory(share)
 852     add_subdirectory(scripts)
 853 endif()
 854 add_subdirectory(src)
 855
 856 if (BUILD_TESTING)
 857     add_subdirectory(tests)
 858 endif()
 859
 860 gmx_cpack_write_config()
 861
 862 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 863 # Don't bother the user after the first configure pass.
 864 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 865     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 866 endif()
 867 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 868
 869 #######################
 870 ## uninstall target
 871 #######################
 872 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 873                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 874                   IMMEDIATE @ONLY)
 875 ###########################
 876 ADD_CUSTOM_TARGET(uninstall
 877                   "${CMAKE_COMMAND}" -P
 878                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 879 ###########################
 880 set_directory_properties(PROPERTIES
 881             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")