tests/CppCheck.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 find_program(CPPCHECK_EXECUTABLE
  36     NAMES cppcheck
  37     DOC "cppcheck executable")
  38 mark_as_advanced(CPPCHECK_EXECUTABLE)
  39 option(CPPCHECK_XML_OUTPUT "Whether to produce XML output from cppcheck (mainly for Jenkins)"
  40        OFF)
  41 mark_as_advanced(CPPCHECK_XML_OUTPUT)
  42
  43 # Depends on stderr redirection and cat
  44 if (CPPCHECK_EXECUTABLE AND UNIX)
  45     # Produce the list of files to check
  46     file(GLOB_RECURSE _inputfiles RELATIVE ${CMAKE_SOURCE_DIR}
  47         ${CMAKE_SOURCE_DIR}/src/*.c
  48         ${CMAKE_SOURCE_DIR}/src/*.cpp
  49         ${CMAKE_SOURCE_DIR}/src/*.cu)
  50     file(GLOB_RECURSE _files_to_ignore RELATIVE ${CMAKE_SOURCE_DIR}
  51         ${CMAKE_SOURCE_DIR}/src/nb_kernel_Elec*.c
  52         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_blas/*.c
  53         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_lapack/*.c
  54         ${CMAKE_SOURCE_DIR}/src/external/*.c
  55         ${CMAKE_SOURCE_DIR}/src/external/*.cpp
  56         ${CMAKE_SOURCE_DIR}/src/external/*.cu
  57         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/scanner.cpp
  58         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/parser.cpp
  59         ${CMAKE_SOURCE_DIR}/src/gromacs/gpu_utils/ocl_compiler.cpp
  60         ${CMAKE_SOURCE_DIR}/src/*\#* #ignore emacs lock files throwing of cmake
  61         )
  62     list(REMOVE_ITEM _inputfiles ${_files_to_ignore})
  63
  64     # Set flags for cppcheck
  65     set(_outputext txt)
  66     set(_outputopt "--template={file}:{line}:{id}: {severity}: {message}")
  67     if (CPPCHECK_XML_OUTPUT)
  68         set(_outputext xml)
  69         set(_outputopt --xml --xml-version=2)
  70     endif()
  71     set(_common_flags
  72         --enable=style -DLINUX -DHAVE_UNISTD_H
  73         -I src
  74         -I src/external/thread_mpi/include
  75         -I src/external/tng_io/include
  76         -I ${CMAKE_BINARY_DIR}/src
  77         --quiet
  78         --inline-suppr
  79         ${_outputopt})
  80     set(_c_flags
  81         --suppress=variableScope
  82         --suppress=unnecessaryForwardDeclaration
  83         --suppress=unusedVariable
  84         --suppress=unreadVariable
  85         --suppress=unusedStructMember
  86         --suppress=invalidscanf
  87         --suppress=sizeofCalculation
  88         --suppress=invalidscanf_libc
  89         --suppress=*:src/external/Random123-1.08/include/Random123/features/compilerfeatures.h
  90         )
  91     set(_cxx_flags
  92         --language=c++ # particularly useful for CUDA files
  93         -D__cplusplus
  94         --suppress=variableScope
  95         --suppress=unnecessaryForwardDeclaration
  96         --suppress=memsetClassFloat  #we assume IEEE754
  97         --suppress=invalidscanf_libc #seems only important for security on non-std libc
  98         --suppress=invalidscanf      #same as last (style and portability checker have the same warning)
  99         --suppress=passedByValue:src/gromacs/simd/tests/*
 100         --suppress=redundantAssignment:src/gromacs/simd/simd_math.h #seems to be a bug in cppcheck
 101         --suppress=noExplicitConstructor # can't be selective about this, see http://sourceforge.net/p/cppcheck/discussion/general/thread/db1e4ba7/
 102         --suppress=unusedStructMember:src/gromacs/onlinehelp/tests/helpmanager.cpp
 103         --suppress=unusedStructMember:src/gromacs/commandline/cmdlinehelpmodule.cpp
 104         --suppress=unusedStructMember:src/gromacs/selection/selhelp.cpp
 105         --suppress=redundantPointerOp:src/gromacs/fileio/gmxfio-xdr.cpp
 106         --suppress=passedByValue # See comment below
 107         --suppress=shiftTooManyBits:src/gromacs/gpu_utils/gpu_utils.cu # CUDA kernel launch false positive
 108         )
 109         # Passing non-trivial objects by value is rarely a problem for
 110         # GROMACS in performance-sensitive code, and shouldn't be
 111         # enforced for types that are intended to be used like value
 112         # types (e.g. SIMD wrapper types, ArrayRef) , nor for
 113         # move-enabled types. cppcheck isn't sensitive to these
 114         # subtleties yet.
 115
 116     # This list will hold the list of all files with cppcheck errors
 117     # (one per input file)
 118     set(_filelist)
 119
 120     foreach (_filename ${_inputfiles})
 121         set(_target_name cppcheck-${_filename}.${_outputext})
 122         string(REPLACE "/" "_" _target_name ${_target_name})
 123         list(APPEND _filelist ${_target_name})
 124         if (_filename MATCHES "\\.cpp$" OR _filename MATCHES "\\.cu$")
 125             set(_lang CXX)
 126             set(_lang_flags ${_cxx_flags})
 127         else()
 128             set(_lang C)
 129             set(_lang_flags ${_c_flags})
 130         endif()
 131         add_custom_command(
 132             OUTPUT ${_target_name}
 133             COMMAND ${CPPCHECK_EXECUTABLE} ${_common_flags} ${_lang_flags}
 134                 ${_filename} 2> ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 135             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 136             IMPLICIT_DEPENDS ${_lang} ${CMAKE_SOURCE_DIR}/${_filename}
 137             COMMENT "Running cppcheck for ${_filename}"
 138             VERBATIM)
 139         if (NOT CPPCHECK_XML_OUTPUT)
 140             add_custom_command(
 141                 OUTPUT ${_target_name}
 142                 COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 143                 VERBATIM APPEND)
 144         endif()
 145     endforeach()
 146     if (NOT CPPCHECK_XML_OUTPUT)
 147         set(_target_name cppcheck-errors.${_outputext})
 148         add_custom_command(
 149             OUTPUT ${_target_name}
 150             COMMAND cat ${_filelist} > ${_target_name}
 151             DEPENDS ${_filelist}
 152             COMMENT "Combining cppcheck results"
 153             VERBATIM)
 154         list(APPEND _filelist ${_target_name})
 155     endif()
 156     add_custom_target(cppcheck DEPENDS ${_filelist})
 157 else()
 158     add_custom_target(cppcheck
 159         COMMAND ${CMAKE_COMMAND} -E echo
 160             "cppcheck was not found by CMake. Rerun CMake specifying CPPCHECK_EXECUTABLE."
 161         VERBATIM)
 162 endif()