CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 include(gmxManageCcache)
  44
  45 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  46 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  47 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  48
  49 # Set up common version variables, as well as general information about
  50 # the build tree (whether the build is from a source package or from a git
  51 # repository).  Also declares a few functions that will be used for generating
  52 # version info files later.
  53 include(gmxBuildTreeInfo)
  54 include(gmxVersionInfo)
  55
  56 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  57     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  58 endif()
  59 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  60     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  61 endif()
  62
  63 include(gmxBuildTypeReference)
  64 include(gmxBuildTypeProfile)
  65 include(gmxBuildTypeTSAN)
  66 include(gmxBuildTypeASAN)
  67 include(gmxBuildTypeMSAN)
  68 include(gmxBuildTypeReleaseWithAssert)
  69
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  72     # Set the possible values of build type for cmake-gui
  73     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  74         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  75 endif()
  76 if(CMAKE_CONFIGURATION_TYPES)
  77     # Add appropriate GROMACS-specific build types for the Visual
  78     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  79     # are already present by default).
  80     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  81     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  82     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  83         "List of configuration types"
  84         FORCE)
  85 endif()
  86 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  87
  88 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  89
  90 include(gmxCTestUtilities)
  91 gmx_ctest_init()
  92
  93 include(gmxCPackUtilities)
  94 gmx_cpack_init()
  95
  96 # Variables that accumulate stuff influencing the installed headers
  97 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  98 set(INSTALLED_HEADER_DEFINITIONS "")
  99
 100 ########################################################################
 101 # Global non-cache variables for implementing the build system
 102 ########################################################################
 103
 104 # These variables collect libraries that GROMACS requires for
 105 # linking. They should be appended to with list(APPEND ${name}
 106 # new-library) calls. They are:
 107 #  - Libraries that are required for libgromacs (only)
 108 set(GMX_EXTRA_LIBRARIES "")
 109 #  - Libraries that are required for all code in the repository
 110 set(GMX_COMMON_LIBRARIES "")
 111 #  - Libraries that all code linked against libgromacs needs
 112 #    (i.e., something that is exposed in installed headers).
 113 set(GMX_PUBLIC_LIBRARIES "")
 114
 115 ########################################################################
 116 # Check and warn if cache generated on a different host is being reused
 117 ########################################################################
 118 if(CMAKE_HOST_UNIX)
 119     execute_process(COMMAND hostname
 120                     OUTPUT_VARIABLE TMP_HOSTNAME
 121                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 122     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 123         message(WARNING "
 124             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 125             is being reused! This could lead to inconsistencies; therefore, it is
 126             recommended to regenerate the cache!")
 127     endif()
 128     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 129             "Hostname of the machine where the cache was generated.")
 130 endif()
 131
 132 ########################################################################
 133 # Detect architecture before setting options so we can alter defaults
 134 ########################################################################
 135 # Detect the architecture the compiler is targetting, detect
 136 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 137 # to use if none is specified, and populate the cache option for CPU
 138 # SIMD.
 139 include(gmxDetectTargetArchitecture)
 140 gmx_detect_target_architecture()
 141
 142 # Permit the user to specify a particular standard library, e.g. compiling
 143 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 144 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 145 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 146 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 147 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 148
 149 ########################################################################
 150 # Detect CXX11 support and flags
 151 ########################################################################
 152 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 153 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 154 # invalid options with the Intel Compilers, and we have added a line
 155 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 156 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 157 # a semicolon. Since this is also used as a separator in lists inside CMake,
 158 # that string ends up being split into two separate patterns, and the last
 159 # part is just a single word that also matches other messages. We solved this
 160 # by replacing the semicolon with a period that matches any character.
 161 #
 162 # These files should be removed from the source tree when a CMake version that
 163 # includes the features in question becomes required for building GROMACS.
 164 include(CheckCCompilerFlag)
 165 include(CheckCXXCompilerFlag)
 166
 167 # This must come early, since some of our configuration flag tests
 168 # depend on being able to compile C++11 source files.
 169 include(gmxTestCXX11)
 170 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 171
 172 # Make sure all C++ code will be compiled in C++11 mode, with the
 173 # expected standard library.
 174 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 175
 176 ########################################################################
 177 # User input options                                                   #
 178 ########################################################################
 179 include(gmxOptionUtilities)
 180
 181 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 182
 183 # Fujitsu only has SIMD in double precision, so this will be faster
 184 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 185 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 186 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 187 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 188
 189 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 190 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 191 gmx_dependent_option(
 192     GMX_MPI_IN_PLACE
 193     "Enable MPI_IN_PLACE for MPIs that have it defined"
 194     ON
 195     GMX_MPI)
 196 mark_as_advanced(GMX_MPI_IN_PLACE)
 197
 198 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 199
 200 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 201 mark_as_advanced(GMX_FAHCORE)
 202
 203 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 204 mark_as_advanced(GMX_COOL_QUOTES)
 205 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 206
 207 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 208
 209 # Decide on GPU settings based on user-settings and GPU/CUDA
 210 # detection. VS2017 requires CUDA 9.0, for the other arch/compilers
 211 # rest we require CUDA 7.0 or later (including for clang-CUDA).
 212 if(MSVC)
 213     set(REQUIRED_CUDA_VERSION 9.0)
 214 else()
 215     set(REQUIRED_CUDA_VERSION 7.0)
 216 endif()
 217 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 218
 219 # OpenCL required version: 1.2 or newer
 220 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 221 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 222 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 223
 224 if(NOT GMX_USE_OPENCL)
 225     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 226     include(gmxManageGPU)
 227     set(GMX_USE_CUDA ${GMX_GPU})
 228     if(GMX_GPU)
 229         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 230     else()
 231         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 232     endif()
 233 else()
 234     #Now the OpenCL path (for both AMD and NVIDIA)
 235     if(GMX_GPU)
 236         include(gmxManageOpenCL)
 237         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 238     else()
 239         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 240     endif()
 241 endif()
 242
 243 gmx_option_multichoice(
 244     GMX_SIMD
 245     "SIMD instruction set for CPU kernels and compiler optimization"
 246     "AUTO"
 247     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 248
 249 if(GMX_TARGET_MIC)
 250     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 251 else()
 252     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 253 endif()
 254
 255 gmx_option_multichoice(
 256     GMX_FFT_LIBRARY
 257     "FFT library"
 258     "${GMX_FFT_LIBRARY_DEFAULT}"
 259     fftw3 mkl "fftpack[built-in]")
 260 gmx_dependent_option(
 261     GMX_BUILD_OWN_FFTW
 262     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 263     OFF
 264     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 265 gmx_dependent_option(
 266     GMX_DISABLE_FFTW_MEASURE
 267     "Do not optimize FFTW setups (not needed with SSE)"
 268     OFF
 269     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 270 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 271 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 272
 273 gmx_option_multichoice(
 274     GMX_QMMM_PROGRAM
 275     "QM package for QM/MM"
 276     None
 277     none gaussian mopac gamess orca)
 278
 279 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 280 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 281
 282 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 283
 284 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 285 mark_as_advanced(GMX_BROKEN_CALLOC)
 286
 287 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 288
 289 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 290
 291 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 292
 293 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 294 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 295
 296 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 297 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 298
 299 option(GMX_BUILD_FOR_COVERAGE
 300        "Tune build for better code coverage metrics (e.g., disable asserts)"
 301        OFF)
 302 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 303
 304 option(GMX_DEVELOPER_BUILD
 305     "Enable Developer convenience features: always build unit-tests"
 306     OFF)
 307 mark_as_advanced(GMX_DEVELOPER_BUILD)
 308
 309 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 310 option(GMX_COMPILER_WARNINGS
 311     "Enable a default set of compiler warnings"
 312     ${GMX_COMPILER_WARNINGS_DEFAULT})
 313 mark_as_advanced(GMX_COMPILER_WARNINGS)
 314 # Always turn on compiler warnings with a developer build.
 315 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 316
 317 option(GMX_BUILD_SHARED_EXE
 318     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 319     ON)
 320 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 321
 322 option(GMX_PHYSICAL_VALIDATION
 323        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 324        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 325        OFF)
 326 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 327
 328 ######################################################################
 329 # Detect OpenMP support
 330 ######################################################################
 331 # The OpenMP detection _must_ come before tests for other CFLAGS.
 332 include(gmxManageOpenMP)
 333
 334
 335
 336 ######################################################################
 337 # Compiler tests
 338 # These need to be done early (before further tests).
 339 #####################################################################
 340
 341 include(gmxCFlags)
 342 gmx_c_flags()
 343
 344 # This variable should be used for additional compiler flags which are not
 345 # generated in gmxCFlags nor are SIMD or MPI related.
 346 #
 347 # TODO These variables should be consolidated into
 348 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 349 # things that work in C compilation (e.g. merging from old branches)
 350 # also work for C++ compilation.
 351 set(EXTRA_C_FLAGS "")
 352 set(EXTRA_CXX_FLAGS "")
 353
 354 # Run through a number of tests for buggy compilers and other issues
 355 include(gmxTestCompilerProblems)
 356 gmx_test_compiler_problems()
 357
 358 # Implement double-precision option. This is complicated because we
 359 # need installed headers to use the precision mode of the build that
 360 # produced the library, but cannot use config.h in that case. We also
 361 # want such variables to always have a definition, because #if is more
 362 # robust than #ifdef. So, we put this value on the compiler command
 363 # line in all cases.
 364 #
 365 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 366 # because no installed header needs it
 367 if(GMX_DOUBLE)
 368     set(GMX_DOUBLE_VALUE 1)
 369 else()
 370     set(GMX_DOUBLE_VALUE 0)
 371 endif()
 372 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 373 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 374
 375 if(WIN32)
 376     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 377     add_definitions(-DGMX_HAVE_WINSOCK)
 378 endif()
 379
 380
 381
 382 ########################################################################
 383 # Basic system tests (standard libraries, headers, functions, types)   #
 384 ########################################################################
 385 include(CheckIncludeFiles)
 386 include(CheckIncludeFileCXX)
 387 check_include_files(unistd.h     HAVE_UNISTD_H)
 388 check_include_files(pwd.h        HAVE_PWD_H)
 389 check_include_files(dirent.h     HAVE_DIRENT_H)
 390 check_include_files(time.h       HAVE_TIME_H)
 391 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 392 check_include_files(io.h         HAVE_IO_H)
 393 check_include_files(sched.h      HAVE_SCHED_H)
 394
 395 check_include_files(regex.h      HAVE_POSIX_REGEX)
 396 # TODO: It could be nice to inform the user if no regex support is found,
 397 # as selections won't be fully functional.
 398
 399 include(CheckCXXSymbolExists)
 400 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 401 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 402 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 403 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 404 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 405 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 406 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 407 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 408
 409 # We cannot check for the __builtins as symbols, but check if code compiles
 410 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 411 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 412 if(MSVC)
 413     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 414     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 415 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 416     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 417     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 418 endif()
 419
 420 include(CheckLibraryExists)
 421 find_library(HAVE_LIBM m)
 422 mark_as_advanced(HAVE_LIBM)
 423 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 424 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 425 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 426
 427 include(TestSchedAffinity)
 428 test_sched_affinity(HAVE_SCHED_AFFINITY)
 429
 430 # Aligned memory allocation. We need to check for both mm_malloc(),
 431 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 432 include(gmxTestMMMalloc)
 433 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 434 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 435 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 436 if(MSVC)
 437     # No need to waste time on this test on platforms where it will never be true
 438     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 439 endif()
 440
 441 include(TestBigEndian)
 442 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 443
 444 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 445
 446 # Management of GROMACS options for specific toolchains should go
 447 # here. Because the initial settings for some of the main options have
 448 # already happened, but things like library detection and MPI compiler
 449 # feature detection have not, the docstrings for any over-rides of
 450 # GROMACS defaults or user settings will make sense. Also, any
 451 # toolchain-related reasons for choosing whether to detect various
 452 # things can be sorted out now, before the detection takes place.
 453 if(GMX_TARGET_FUJITSU_SPARC64)
 454     include(gmxManageFujitsuSparc64)
 455 endif()
 456
 457 ########################################################################
 458 #Process MPI settings
 459 ########################################################################
 460 include(gmxManageMPI)
 461
 462 ########################################################################
 463 #Process MiMiC settings
 464 ########################################################################
 465 include(gmxManageMimic)
 466
 467 ########################################################################
 468 #Process shared/static library settings
 469 ########################################################################
 470 include(gmxManageSharedLibraries)
 471
 472
 473 ########################################################################
 474 # Find external packages                                               #
 475 ########################################################################
 476
 477 # Unconditionally find the package, as it is also required for unit
 478 # tests. This exports LIBXML2_FOUND, which we should not use because
 479 # it does not tell us that linking will succeed. Instead, we test that
 480 # next.
 481 #if(DEFINED LIBXML2_LIBRARIES)
 482 #  set(LibXml2_FIND_QUIETLY TRUE)
 483 #endif()
 484 #find_package(LibXml2)
 485 #include(gmxTestLibXml2)
 486 #gmx_test_libxml2(HAVE_LIBXML2)
 487 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 488 #set(PKG_XML "")
 489 #mark_as_advanced(GMX_XML)
 490 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 491 #if(GMX_XML AND NOT HAVE_LIBXML2)
 492 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 493 #endif()
 494 #if(GMX_XML)
 495 #    include_directories(${LIBXML2_INCLUDE_DIR})
 496 #    set(PKG_XML libxml-2.0)
 497 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 498 #endif()
 499
 500 gmx_option_trivalue(
 501     GMX_HWLOC
 502     "Use hwloc portable hardware locality library"
 503     "AUTO")
 504
 505 if (GMX_HWLOC)
 506     # Find quietly the second time.
 507     if(DEFINED HWLOC_LIBRARIES)
 508         set(Hwloc_FIND_QUIETLY TRUE)
 509     endif()
 510     find_package(Hwloc 1.5)
 511
 512     if (HWLOC_FOUND)
 513         if (HWLOC_LIBRARIES MATCHES ".a$")
 514             set(_STATIC_HWLOC TRUE)
 515         endif()
 516
 517         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 518         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 519             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 520             set(GMX_USE_HWLOC OFF)
 521         else()
 522             set(GMX_USE_HWLOC ON)
 523         endif()
 524
 525         if (GMX_USE_HWLOC)
 526             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 527             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 528         endif()
 529     elseif(GMX_HWLOC_FORCE)
 530         message(FATAL_ERROR "Hwloc package support required, but not found.")
 531     endif()
 532 endif()
 533
 534 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 535 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 536 if(GMX_EXTERNAL_TINYXML2)
 537     # Find an external TinyXML-2 library.
 538     find_package(TinyXML-2 3.0.0)
 539     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 540     if(NOT HAVE_TINYXML2)
 541         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 542     endif()
 543 endif()
 544
 545 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 546 mark_as_advanced(GMX_EXTRAE)
 547
 548 if (GMX_EXTRAE)
 549   find_package(EXTRAE)
 550   if(EXTRAE_FOUND)
 551     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 552     set(HAVE_EXTRAE 1)
 553   else()
 554     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 555   endif()
 556 endif()
 557
 558 option(GMX_X11 "Use X window system" OFF)
 559 if (GMX_X11)
 560     find_package(X11)
 561     # X11 includes/libraries are only set in the ngmx subdirectory!
 562     if(NOT X11_FOUND)
 563         message(FATAL_ERROR
 564                 "X11 include files and/or libraries were not found. "
 565                 "Set GMX_X11=OFF to compile without X11 support. "
 566                 "gmx view will not be available.")
 567     endif()
 568     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 569 endif()
 570
 571 include(ThreadMPI)
 572 # Enable core threading facilities
 573 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 574 if(GMX_THREAD_MPI)
 575     # enable MPI functions
 576     tmpi_enable()
 577     set(MPI_IN_PLACE_EXISTS 1)
 578 endif()
 579 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 580 if (TMPI_ATOMICS_DISABLED)
 581    add_definitions(-DTMPI_ATOMICS_DISABLED)
 582 endif()
 583
 584 include(gmxManageTNG)
 585
 586 include(gmxManageLmfit)
 587
 588 if(GMX_GPU)
 589     # now that we have detected the dependencies, do the second configure pass
 590     gmx_gpu_setup()
 591     if (GMX_CLANG_CUDA)
 592         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 593         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 594     endif()
 595 endif()
 596
 597 if(CYGWIN)
 598     set(GMX_CYGWIN 1)
 599 endif()
 600
 601 if(WIN32)
 602     set(GMX_NATIVE_WINDOWS 1)
 603     # This makes windows.h not declare min/max as macros that would break
 604     # C++ code using std::min/std::max.
 605     add_definitions(-DNOMINMAX)
 606 endif()
 607
 608 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 609     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 610         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 611     endif()
 612     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 613         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 614     endif()
 615 endif()
 616
 617 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 618 mark_as_advanced(GMX_BUILD_UNITTESTS)
 619 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 620
 621 ########################################################################
 622 # Our own GROMACS tests
 623 ########################################################################
 624
 625 add_definitions( -DHAVE_CONFIG_H )
 626 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 627 # TODO required at high level because both libgromacs and progs/mdrun
 628 # require it, both for thread-MPI and its atomics and mutexes.
 629 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 630 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 631 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 632
 633 include(gmxTestInlineASM)
 634 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 635
 636 include(gmxSetBuildInformation)
 637 gmx_set_build_information()
 638
 639 gmx_option_multichoice(
 640     GMX_USE_RDTSCP
 641     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 642     "AUTO"
 643     OFF ON AUTO DETECT)
 644 mark_as_advanced(GMX_USE_RDTSCP)
 645
 646 macro(gmx_check_rdtscp)
 647     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 648         set(HAVE_RDTSCP 1)
 649         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 650     else()
 651         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 652     endif()
 653 endmacro()
 654
 655 set(HAVE_RDTSCP 0)
 656 if (GMX_USE_RDTSCP STREQUAL "ON")
 657     set(HAVE_RDTSCP 1)
 658 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 659     gmx_check_rdtscp()
 660 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 661     # If the user specified automated SIMD selection, that the choice
 662     # is made based on detection on the build host. If so, then RDTSCP
 663     # should be chosen the same way.
 664     #
 665     # If the user specified an AVX SIMD level (e.g. when
 666     # cross-compiling GROMACS) then they will get our best guess, ie
 667     # that in practice AVX mostly correlates with rdtscp (and anyway
 668     # is only relevant in rather old x86 hardware).
 669     if (GMX_SIMD STREQUAL "AUTO")
 670         gmx_check_rdtscp()
 671     elseif (GMX_SIMD MATCHES "AVX")
 672         set(HAVE_RDTSCP 1)
 673     endif()
 674 endif()
 675 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 676 if (HAVE_RDTSCP_CHANGED)
 677     if (HAVE_RDTSCP)
 678         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 679     else()
 680         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 681     endif()
 682 endif()
 683
 684 include(gmxTestLargeFiles)
 685 gmx_test_large_files(GMX_LARGEFILES)
 686
 687 include(gmxTestSignal)
 688 gmx_test_sigusr1(HAVE_SIGUSR1)
 689
 690 include(gmxTestPipes)
 691 gmx_test_pipes(HAVE_PIPES)
 692
 693 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 694
 695 include(gmxTestXDR)
 696 gmx_test_xdr(GMX_SYSTEM_XDR)
 697 # Darwin has system XDR, but it uses a three-argument flavour of
 698 # xdrproc_t that it guarantees will still work if you pass the normal
 699 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 700 # to do that, so it's simpler to just use our own XDR library.
 701 #
 702 # TODO It would be better to craft a cmake test which fails if such
 703 # XDR operations cause warnings, and succeeds otherwise, because it is
 704 # generally preferable to use system libraries where possible.
 705 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 706     set(GMX_INTERNAL_XDR 1)
 707 endif()
 708
 709
 710 ##################################################
 711 # Process SIMD instruction settings
 712 ##################################################
 713 # This checks what flags to add in order to
 714 # support the SIMD instructions we need, it sets
 715 # correct defines for the SIMD instructions supported,
 716 # and adds advanced options to control accuracy
 717 # for SIMD math operations.
 718 include(gmxManageSimd)
 719 gmx_manage_simd()
 720
 721 include(gmxManageCycleCounters)
 722 gmx_manage_cycle_counters()
 723
 724 # Process QM/MM Settings
 725 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 726     set(GMX_QMMM_GAUSSIAN 1)
 727 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 728     set(GMX_QMMM_MOPAC 1)
 729 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 730     set(GMX_QMMM_GAMESS 1)
 731 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 732     set(GMX_QMMM_ORCA 1)
 733 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 734     # nothing to do
 735 else()
 736     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 737 endif()
 738
 739
 740 ##################################################
 741 # Process FFT library settings
 742 ##################################################
 743 include(gmxManageFFTLibraries)
 744
 745
 746 include(gmxManageLinearAlgebraLibraries)
 747
 748 include(gmxManagePluginSupport)
 749
 750 if (GMX_USE_PLUGINS)
 751     if(NOT GMX_VMD_PLUGIN_PATH)
 752         find_package(VMD)
 753     endif()
 754 endif()
 755
 756 # Link real-time library for POSIX timers. The check for clock_gettime
 757 # confirms the linkability of rt.
 758 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 759     list(APPEND GMX_EXTRA_LIBRARIES rt)
 760 endif()
 761
 762 # Math and thread libraries must often come after all others when linking...
 763 if (HAVE_LIBM)
 764     list(APPEND GMX_PUBLIC_LIBRARIES m)
 765 endif()
 766
 767 option(GMX_NACL "Configure for Native Client builds" OFF)
 768 if (GMX_NACL)
 769   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 770   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 771   # TODO: Is this still necessary with the check for its presence?
 772   set(GMX_USE_NICE 0)
 773   set(GMX_NO_RENAME 1)
 774 endif()
 775 mark_as_advanced(GMX_NACL)
 776
 777 if(GMX_FAHCORE)
 778   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 779       "Path to swindirect.h")
 780   include_directories(${COREWRAP_INCLUDE_DIR})
 781 endif()
 782
 783 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 784 # produce warnings if that fails.
 785 set(build_help_default AUTO)
 786 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 787     set(build_help_default OFF)
 788 endif()
 789 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 790 mark_as_advanced(GMX_BUILD_HELP)
 791 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 792     message(FATAL_ERROR
 793         "Rebuilding shell completions or man pages is not supported for "
 794         "in-source builds from a source distribution. "
 795         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 796 endif()
 797
 798 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 799 # these are set after everything else
 800 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 801     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 802     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 803     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 804     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 805 else()
 806     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 807     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 808     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 809     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 810     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 811     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 812     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 813     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 814     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 815 endif()
 816
 817 if(NOT GMX_OPENMP)
 818     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 819     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 820     unset(OpenMP_C_FLAGS CACHE)
 821     unset(OpenMP_CXX_FLAGS CACHE)
 822 else()
 823     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 824     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 825 endif()
 826
 827
 828 ########################################################################
 829 # Specify install locations
 830 ########################################################################
 831 # Use GNUInstallDirs to set paths on multiarch systems.
 832 include(GNUInstallDirs)
 833
 834 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 835 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 836
 837 # Internal convenience so we do not have to join two path segments in the code
 838 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 839
 840 # If the nesting level wrt. the installation root is changed,
 841 # gromacs-config.cmake.cmakein needs to be adapted.
 842 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 843
 844 # TODO: Make GMXRC adapt if this is changed
 845 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 846 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 847
 848 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 849
 850 # Binary and library suffix options
 851 include(gmxManageSuffixes)
 852
 853 ################################################################
 854 # Shared library load path settings
 855 ################################################################
 856 if(NOT GMX_BUILD_SHARED_EXE)
 857     # No rpath
 858     set(CMAKE_SKIP_RPATH TRUE)
 859     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 860     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 861 else()
 862     # The build folder always has bin/ and lib/; if we are also going to
 863     # install to lib/, then the installation RPATH works also in the build
 864     # tree.  This makes installation slightly faster (no need to rewrite the
 865     # RPATHs), and makes the binaries in the build tree relocatable.
 866     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 867         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 868         if(POLICY CMP0068)
 869             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 870             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 871         endif()
 872     endif()
 873     # Set the RPATH as relative to the executable location to make the
 874     # binaries relocatable.
 875     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 876         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 877         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 878     else()
 879         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 880     endif()
 881     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 882     set(CMAKE_MACOSX_RPATH 1)
 883 endif()
 884
 885 #COPYING file: Only necessary for binary distributions.
 886 #Simpler to always install.
 887 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 888
 889 if (GMX_BUILD_FOR_COVERAGE)
 890     # Code heavy with asserts makes conditional coverage close to useless metric,
 891     # as by design most of the false branches are impossible to trigger in
 892     # correctly functioning code.  And the benefit of testing those that could
 893     # be triggered by using an API against its specification isn't usually
 894     # worth the effort.
 895     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 896 endif()
 897
 898 if (BUILD_TESTING)
 899     include(tests/CheckTarget.cmake)
 900 endif()
 901
 902 if (NOT GMX_BUILD_MDRUN_ONLY)
 903     find_package(ImageMagick QUIET COMPONENTS convert)
 904     include(gmxTestImageMagick)
 905     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 906     add_subdirectory(docs)
 907     add_subdirectory(share)
 908     add_subdirectory(scripts)
 909 endif()
 910 add_subdirectory(src)
 911
 912 if (BUILD_TESTING)
 913     add_subdirectory(tests)
 914 endif()
 915
 916 gmx_cpack_write_config()
 917
 918 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 919 # Don't bother the user after the first configure pass.
 920 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 921     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 922 endif()
 923 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 924
 925 #######################
 926 ## uninstall target
 927 #######################
 928 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 929                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 930                   IMMEDIATE @ONLY)
 931 ###########################
 932 ADD_CUSTOM_TARGET(uninstall
 933                   "${CMAKE_COMMAND}" -P
 934                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 935 ###########################
 936 set_directory_properties(PROPERTIES
 937             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")