CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # If this is not a released tarball, "-dev" will be present in
  68 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  69 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  70 # code contains all recent fixes from the corresponding code branch.
  71 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  72
  73 set(CUSTOM_VERSION_STRING ""
  74     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  75 mark_as_advanced(CUSTOM_VERSION_STRING)
  76 if (CUSTOM_VERSION_STRING)
  77     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  78 endif()
  79 set(LIBRARY_SOVERSION 0)
  80 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  81 # It is a bit irritating, but this has to be set separately for now!
  82 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  83 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  84 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  85
  86 # The numerical gromacs version. It is 40600 for 4.6.0.
  87 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  88 math(EXPR NUM_VERSION
  89     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  90 if(CPACK_PACKAGE_VERSION_PATCH)
  91     math(EXPR NUM_VERSION
  92          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  93 endif()
  94
  95 # The API version tracks the numerical Gromacs version (for now).
  96 # It is potentially different from the Gromacs version in the future, if
  97 # the programs/libraries diverge from the presumably more stable API.
  98 # The #define GMX_API_VERSION in version.h is set to this value to
  99 # provide backward compatibility of software written against the Gromacs API.
 100 set(API_VERSION ${NUM_VERSION})
 101
 102 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 103     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 104 endif()
 105
 106 include(gmxBuildTypeReference)
 107 include(gmxBuildTypeTSAN)
 108 include(gmxBuildTypeASAN)
 109 include(gmxBuildTypeReleaseWithAssert)
 110
 111 if(NOT CMAKE_BUILD_TYPE)
 112     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 113     # There's no need to offer a user the choice of ThreadSanitizer
 114     # Set the possible values of build type for cmake-gui
 115     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 116         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 117 endif()
 118 if(CMAKE_CONFIGURATION_TYPES)
 119     # Add appropriate GROMACS-specific build types for the Visual
 120     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 121     # are already present by default).
 122     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 123     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 124     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 125         "List of configuration types"
 126         FORCE)
 127 endif()
 128 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 129
 130 enable_language(C)
 131 enable_language(CXX)
 132
 133 set(CPACK_PACKAGE_NAME "gromacs")
 134 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 135 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 136 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 137 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 138 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 139 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 140 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 141 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 142 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 143 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 144 # CPack source archives include only the directories we list here.
 145 # This variable is a list of pairs of names of source and destination
 146 # directories. Most of these are used for content GROMACS generates as
 147 # part of the configuration or build.
 148 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 149 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 150 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 151
 152 #must come after all cpack settings!
 153 include(CPack)
 154
 155 # Set a default valgrind suppression file.
 156 # This unfortunately needs to duplicate information from CTest to work as
 157 # expected...
 158 set(MEMORYCHECK_SUPPRESSIONS_FILE
 159     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 160     CACHE FILEPATH
 161     "File that contains suppressions for the memory checker")
 162 include(CTest)
 163
 164 set(SOURCE_IS_GIT_REPOSITORY OFF)
 165 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 166 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 167     set(SOURCE_IS_GIT_REPOSITORY ON)
 168 endif()
 169 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 170     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 171 endif()
 172
 173 ########################################################################
 174 # Check and warn if cache generated on a different host is being reused
 175 ########################################################################
 176 if(CMAKE_HOST_UNIX)
 177     execute_process(COMMAND hostname
 178                     OUTPUT_VARIABLE TMP_HOSTNAME
 179                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 180     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 181         message(WARNING "
 182             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 183             is being reused! This could lead to inconsitencies; therefore, it is
 184             recommended to regenerate the cache!")
 185     endif()
 186     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 187             "Hostname of the machine where the cache was generated.")
 188 endif()
 189
 190 ########################################################################
 191 # User input options                                                   #
 192 ########################################################################
 193 include(gmxOptionUtilities)
 194
 195 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 196
 197 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 198 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 199 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 200 gmx_dependent_option(
 201     GMX_MPI_IN_PLACE
 202     "Enable MPI_IN_PLACE for MPIs that have it defined"
 203     ON
 204     GMX_MPI)
 205 mark_as_advanced(GMX_MPI_IN_PLACE)
 206 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 207 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 208 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 209 mark_as_advanced(GMX_FAHCORE)
 210
 211 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 212 mark_as_advanced(GMX_COOL_QUOTES)
 213 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 214
 215 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 216 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 217 if(MSVC)
 218     set(REQUIRED_CUDA_VERSION 4.1)
 219 else()
 220     set(REQUIRED_CUDA_VERSION 4.0)
 221 endif()
 222 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 223 include(gmxManageGPU)
 224
 225 # Detect the architecture the compiler is targetting, detect
 226 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 227 # to use if none is specified, and populate the cache option for CPU
 228 # SIMD.
 229 include(gmxDetectTargetArchitecture)
 230 gmx_detect_target_architecture()
 231
 232 if(GMX_CPU_ACCELERATION)
 233     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 234     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 235     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 236     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 237 endif()
 238
 239 if(NOT GMX_TARGET_MIC)
 240     include(gmxDetectSimd)
 241     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 242 else()
 243     set(GMX_SUGGESTED_SIMD "None")
 244 endif()
 245
 246 gmx_option_multichoice(
 247     GMX_SIMD
 248     "SIMD instruction set for CPU kernels and compiler optimization"
 249     "${GMX_SUGGESTED_SIMD}"
 250     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 251
 252 gmx_option_multichoice(
 253     GMX_FFT_LIBRARY
 254     "FFT library"
 255     "fftw3"
 256     fftw3 mkl "fftpack[built-in]")
 257 gmx_dependent_option(
 258     GMX_BUILD_OWN_FFTW
 259     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 260     OFF
 261     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 262 gmx_dependent_option(
 263     GMX_DISABLE_FFTW_MEASURE
 264     "Do not optimize FFTW setups (not needed with SSE)"
 265     OFF
 266     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 267 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 268 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 269
 270 gmx_option_multichoice(
 271     GMX_QMMM_PROGRAM
 272     "QM package for QM/MM"
 273     None
 274     none gaussian mopac gamess orca)
 275
 276 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 277 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 278
 279 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 280
 281 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 282 mark_as_advanced(GMX_BROKEN_CALLOC)
 283 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 284 mark_as_advanced(GMX_LOAD_PLUGINS)
 285
 286 option(GMX_GPU  "Enable GPU acceleration" ON)
 287 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 288
 289 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 290
 291 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 292 mark_as_advanced(GMX_GIT_VERSION_INFO)
 293
 294 if(UNIX)
 295     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 296 endif()
 297 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 298
 299 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 300 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 301
 302 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 303 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 304
 305 option(GMX_BUILD_FOR_COVERAGE
 306        "Tune build for better code coverage metrics (e.g., disable asserts)"
 307        OFF)
 308 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 309
 310
 311 ######################################################################
 312 # Detect OpenMP support
 313 ######################################################################
 314 # The OpenMP detection _must_ come before tests for other CFLAGS.
 315 include(gmxManageOpenMP)
 316
 317
 318
 319 ######################################################################
 320 # Compiler tests
 321 # These need to be done early (before further tests).
 322 #####################################################################
 323
 324 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 325 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 326 # invalid options with the Intel Compilers.
 327 # These files should be removed from the source tree when a CMake version that
 328 # includes the features in question becomes required for building GROMACS.
 329 include(CheckCCompilerFlag)
 330 include(CheckCXXCompilerFlag)
 331
 332
 333 include(gmxCFlags)
 334 gmx_c_flags()
 335
 336 # This variable should be used for additional compiler flags which are not
 337 # generated in gmxCFlags nor are SIMD or MPI related.
 338 set(EXTRA_C_FLAGS "")
 339 set(EXTRA_CXX_FLAGS "")
 340
 341 # Run through a number of tests for buggy compilers and other issues
 342 include(gmxTestCompilerProblems)
 343 gmx_test_compiler_problems()
 344 # GMX_SIMD will not be set automatically until the second
 345 # pass (which is not strictly guaranteed to occur), so putting this
 346 # check here among logically-related tests is inefficient, but the
 347 # potential loss is likely zero.
 348 if(GMX_SIMD STREQUAL "AVX_256"
 349         AND CMAKE_COMPILER_IS_GNUCC
 350         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 351             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 352     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 353     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 354 endif()
 355
 356
 357
 358 set(PKG_CFLAGS "")
 359 if(GMX_DOUBLE)
 360     add_definitions(-DGMX_DOUBLE)
 361     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 362 endif()
 363 if(GMX_SOFTWARE_INVSQRT)
 364   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 365 endif()
 366
 367 if(WIN32 AND NOT CYGWIN)
 368     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 369     mark_as_advanced(GMX_WSOCKLIB_PATH)
 370     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 371     if(WSOCK32_LIBRARY)
 372         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 373         add_definitions(-DGMX_HAVE_WINSOCK)
 374     else()
 375         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 376     endif(WSOCK32_LIBRARY)
 377 endif()
 378
 379
 380
 381 ########################################################################
 382 # Basic system tests (standard libraries, headers, functions, types)   #
 383 ########################################################################
 384 include(CheckIncludeFiles)
 385 include(CheckIncludeFileCXX)
 386 check_include_files(unistd.h     HAVE_UNISTD_H)
 387 check_include_files(pwd.h        HAVE_PWD_H)
 388 check_include_files(dirent.h     HAVE_DIRENT_H)
 389 check_include_files(time.h       HAVE_TIME_H)
 390 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 391 check_include_files(io.h         HAVE_IO_H)
 392 check_include_files(sched.h      HAVE_SCHED_H)
 393
 394 check_include_files(regex.h      HAVE_POSIX_REGEX)
 395 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 396 # TODO: It could be nice to inform the user if no regex support is found,
 397 # as selections won't be fully functional.
 398
 399 include(CheckFunctionExists)
 400 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 401 check_function_exists(memalign          HAVE_MEMALIGN)
 402 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 403 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 404 check_function_exists(fsync             HAVE_FSYNC)
 405 check_function_exists(_fileno           HAVE__FILENO)
 406 check_function_exists(fileno            HAVE_FILENO)
 407 check_function_exists(_commit           HAVE__COMMIT)
 408 check_function_exists(sigaction         HAVE_SIGACTION)
 409 check_function_exists(sysconf           HAVE_SYSCONF)
 410 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 411 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 412 check_function_exists(rsqrt             HAVE_RSQRT)
 413 check_function_exists(rsqrtf            HAVE_RSQRTF)
 414 check_function_exists(sqrtf             HAVE_SQRTF)
 415
 416 include(CheckLibraryExists)
 417 check_library_exists(m sqrt "" HAVE_LIBM)
 418 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 419
 420 include(TestBigEndian)
 421 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 422
 423 # Management of GROMACS options for specific toolchains should go
 424 # here. Because the initial settings for some of the main options have
 425 # already happened, but things like library detection and MPI compiler
 426 # feature detection have not, the docstrings for any over-rides of
 427 # GROMACS defaults or user settings will make sense. Also, any
 428 # toolchain-related reasons for choosing whether to detect various
 429 # things can be sorted out now, before the detection takes place.
 430 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 431     include(gmxManageBlueGene)
 432 endif()
 433
 434 ########################################################################
 435 #Process MPI settings
 436 ########################################################################
 437 include(gmxManageMPI)
 438
 439
 440 ########################################################################
 441 #Process shared/static library settings
 442 ########################################################################
 443 include(gmxManageSharedLibraries)
 444
 445
 446 ########################################################################
 447 # Find external packages                                               #
 448 ########################################################################
 449
 450 # Unconditionally find the package, as it is also required for unit
 451 # tests. This exports LIBXML2_FOUND, which we should not use because
 452 # it does not tell us that linking will succeed. Instead, we test that
 453 # next.
 454 if(DEFINED LIBXML2_LIBRARIES)
 455   set(LibXml2_FIND_QUIETLY TRUE)
 456 endif()
 457 find_package(LibXml2)
 458 include(gmxTestLibXml2)
 459 gmx_test_libxml2(HAVE_LIBXML2)
 460 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 461 set(PKG_XML "")
 462 mark_as_advanced(GMX_XML)
 463 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 464 #if(GMX_XML AND NOT HAVE_LIBXML2)
 465 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 466 #endif()
 467 #if(GMX_XML)
 468 #    include_directories(${LIBXML2_INCLUDE_DIR})
 469 #    set(PKG_XML libxml-2.0)
 470 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 471 #endif()
 472
 473 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 474 mark_as_advanced(GMX_EXTRAE)
 475
 476 if (GMX_EXTRAE)
 477   find_package(EXTRAE)
 478   if(EXTRAE_FOUND)
 479     include_directories(${EXTRAE_INCLUDE_DIR})
 480     set(HAVE_EXTRAE 1)
 481   else()
 482     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 483   endif()
 484 endif()
 485
 486 option(GMX_X11 "Use X window system" OFF)
 487 if (GMX_X11)
 488     find_package(X11)
 489     # X11 includes/libraries are only set in the ngmx subdirectory!
 490     if(NOT X11_FOUND)
 491         message(FATAL_ERROR
 492                 "X11 include files and/or libraries were not found. "
 493                 "Set GMX_X11=OFF to compile without X11 support. "
 494                 "gmx view will not be available.")
 495     endif()
 496     include_directories(${X11_INCLUDE_DIR})
 497 endif()
 498
 499 include(ThreadMPI)
 500 # Enable core threading facilities
 501 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 502 # Enable tMPI C++ support
 503 tmpi_enable_cxx()
 504 if(GMX_THREAD_MPI)
 505     # enable MPI functions
 506     tmpi_enable()
 507     set(GMX_MPI 1)
 508     set(MPI_IN_PLACE_EXISTS 1)
 509 endif()
 510 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 511 if (TMPI_ATOMICS_DISABLED)
 512    add_definitions(-DTMPI_ATOMICS_DISABLED)
 513 endif()
 514
 515 if(GMX_GPU)
 516     # now that we have detected the dependencies, do the second configure pass
 517     gmx_gpu_setup()
 518 endif()
 519
 520 if(CYGWIN)
 521     set(GMX_CYGWIN 1)
 522 endif()
 523
 524 if(WIN32 AND NOT CYGWIN)
 525     set(GMX_NATIVE_WINDOWS 1)
 526     # This makes windows.h not declare min/max as macros that would break
 527     # C++ code using std::min/std::max.
 528     add_definitions(-DNOMINMAX)
 529 endif()
 530
 531 # only bother with finding git and using version.h if the source is a git repo
 532 if(GMX_GIT_VERSION_INFO)
 533     if (NOT SOURCE_IS_GIT_REPOSITORY)
 534         message(FATAL_ERROR
 535             "Cannot generate git version information from source tree not under git. "
 536             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 537     endif()
 538     # We need at least git v1.5.3 be able to parse git's date output. If not
 539     # found or the version is too small, we can't generate version information.
 540     find_package(Git)
 541
 542     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 543         message(FATAL_ERROR
 544             "No compatible git version found (>= 1.5.3 required). "
 545             "Won't be able to generate development version information. "
 546             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 547     endif()
 548 endif()
 549
 550 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 551 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 552 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 553     find_package(Boost 1.44.0)
 554     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 555         set(Boost_FOUND FALSE)
 556     endif()
 557     # Print the notification only on first run, when determining the default
 558     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 559         message("Boost >= 1.44 not found. Using minimal internal version. "
 560                 "This may cause trouble if you plan on compiling/linking other "
 561                 "software that uses Boost against Gromacs.")
 562     endif()
 563 endif()
 564 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 565        ${Boost_FOUND})
 566 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 567     message(FATAL_ERROR
 568         "Boost >= 1.44 not found. "
 569         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 570         "version of Boost included with Gromacs.")
 571 endif()
 572
 573 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 574     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 575 endif()
 576 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 577 mark_as_advanced(GMX_BUILD_UNITTESTS)
 578 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 579 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 580     message(FATAL_ERROR
 581         "Cannot build unit tests without libxml2. "
 582         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 583 endif()
 584
 585 ########################################################################
 586 # Generate development version info for cache
 587 ########################################################################
 588 # set(GEN_VERSION_INFO_INTERNAL "ON")
 589 # include(gmxGenerateVersionString)
 590
 591 ########################################################################
 592 # Our own GROMACS tests
 593 ########################################################################
 594
 595 add_definitions( -DHAVE_CONFIG_H )
 596 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 597 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 598 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 599 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 600 # Required for gmx_header_config_gen.h to be found before installation
 601 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 602 # Required for now to make old code compile
 603 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 604
 605 include(gmxTestInlineASM)
 606 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 607
 608 include(gmxSetBuildInformation)
 609 gmx_set_build_information()
 610 # Turn on RDTSCP if:
 611 # - the build system's CPU supports it
 612 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 613 #   at this point means that the user set it).
 614 # Note: it's better to not use the later set value of GMX_SIMD because
 615 # it reflects the system's capability of both compiling and running AVX code.
 616 # TODO: After merge with 5.0 one could implement a cache variable dependency
 617 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 618 # after the first cmake pass.
 619 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 620     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 621 else()
 622     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 623 endif()
 624 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 625 mark_as_advanced(GMX_USE_RDTSCP)
 626 if(GMX_USE_RDTSCP)
 627     set(HAVE_RDTSCP 1)
 628 endif()
 629
 630 include(gmxTestFloatFormat)
 631 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 632                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 633                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 634
 635 include(gmxTestLargeFiles)
 636 gmx_test_large_files(GMX_LARGEFILES)
 637
 638 include(gmxTestSignal)
 639 gmx_test_sigusr1(HAVE_SIGUSR1)
 640
 641 include(gmxTestPipes)
 642 gmx_test_pipes(HAVE_PIPES)
 643
 644 include(gmxTestIsfinite)
 645 gmx_test_isfinite(HAVE_ISFINITE)
 646 gmx_test__isfinite(HAVE__ISFINITE)
 647 gmx_test__finite(HAVE__FINITE)
 648
 649 include(gmxTestCXX11)
 650 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 651 include(CMakeDependentOption)
 652 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 653 # entirely to keep the compilation environment uniform.
 654 cmake_dependent_option(GMX_CXX11
 655     "Use C++11 features"
 656     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 657 mark_as_advanced(GMX_CXX11)
 658 if(GMX_CXX11)
 659     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 660 endif()
 661
 662
 663 include(gmxTestXDR)
 664 gmx_test_xdr(GMX_SYSTEM_XDR)
 665 if(NOT GMX_SYSTEM_XDR)
 666     set(GMX_INTERNAL_XDR 1)
 667 endif()
 668
 669
 670 ##################################################
 671 # Process SIMD instruction settings
 672 ##################################################
 673 # This checks what flags to add in order to
 674 # support the SIMD instructions we need, and sets
 675 # correct defines for the SIMD instructions supported.
 676 include(gmxTestSimd)
 677 gmx_test_simd()
 678
 679
 680 # Process QM/MM Settings
 681 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 682     set(GMX_QMMM_GAUSSIAN 1)
 683 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 684     set(GMX_QMMM_MOPAC 1)
 685 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 686     set(GMX_QMMM_GAMESS 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 688     set(GMX_QMMM_ORCA 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 690     # nothing to do
 691 else()
 692     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 693 endif()
 694
 695
 696 ##################################################
 697 # Process FFT library settings
 698 ##################################################
 699 include(gmxManageFFTLibraries)
 700
 701
 702 include(gmxManageLinearAlgebraLibraries)
 703
 704 # Whether GROMACS will really try to compile support for VMD plugins
 705 set(GMX_USE_PLUGINS OFF)
 706
 707 if(GMX_LOAD_PLUGINS)
 708   if(CYGWIN OR NOT WIN32)
 709     # Native Windows does not have, nor need dlopen
 710     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 711     include(gmxTestdlopen)
 712     gmx_test_dlopen(HAVE_DLOPEN)
 713   endif()
 714
 715   # so, should we use plug-ins?
 716   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 717     if(NOT VMD_QUIETLY)
 718       MESSAGE(STATUS
 719           "Found the ability to use plug-ins when building shared libaries, "
 720           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 721           "formats).")
 722     endif()
 723     if(NOT GMX_VMD_PLUGIN_PATH)
 724       find_package(VMD)
 725     endif()
 726     set(GMX_USE_PLUGINS ON)
 727     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 728     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 729   else()
 730     set(PKG_DL_LIBS)
 731   endif()
 732 endif()
 733 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 734
 735 # Link real-time library for POSIX timers. The check for clock_gettime
 736 # confirms the linkability of rt.
 737 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 738     list(APPEND GMX_EXTRA_LIBRARIES rt)
 739 endif()
 740
 741 # Math and thread libraries must often come after all others when linking...
 742 if(HAVE_LIBM)
 743     list(APPEND GMX_EXTRA_LIBRARIES m)
 744 endif()
 745
 746 option(GMX_NACL "Configure for Native Client builds" OFF)
 747 if (GMX_NACL)
 748   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 749   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 750   set(GMX_NO_NICE 1)
 751   set(GMX_NO_RENAME 1)
 752 endif()
 753 mark_as_advanced(GMX_NACL)
 754
 755 if(GMX_FAHCORE)
 756   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 757       "Path to swindirect.h")
 758   include_directories(${COREWRAP_INCLUDE_DIR})
 759 endif()
 760
 761 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 762 mark_as_advanced(GMX_BUILD_HELP)
 763 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 764     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 765
 766     message(FATAL_ERROR
 767         "Rebuilding HTML and man pages is not supported for in-source "
 768         "builds from a source distribution. "
 769         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 770 endif()
 771
 772 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 773 # these are set after everything else
 774 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 775     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 776     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 777     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 778     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 779 else()
 780     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 781     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 782     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 783     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 784     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 785     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 786     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 787     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 788     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 789 endif()
 790
 791 if(NOT GMX_OPENMP)
 792     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 793     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 794     unset(OpenMP_C_FLAGS CACHE)
 795     unset(OpenMP_CXX_FLAGS CACHE)
 796 else()
 797     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 798     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 799 endif()
 800 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 801
 802 ########################################################################
 803 # Specify install locations
 804 ########################################################################
 805 # Use GNUInstallDirs to set paths on multiarch systems.
 806 include(GNUInstallDirs)
 807
 808 # Customization for the installation tree paths.
 809 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 810     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 811 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 812     "Data installation directory under share/ (default: gromacs)")
 813 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 814
 815 # These variables are used internally to provide a central location for
 816 # customizing the install locations.
 817 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 818 set(BIN_INSTALL_DIR  bin)
 819 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 820 set(MAN_INSTALL_DIR  share/man)
 821 set(INCL_INSTALL_DIR include)
 822
 823 # These variables get written into config.h for use in finding the data
 824 # directories.
 825 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 826 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 827
 828 # Binary and library suffix options
 829 include(gmxManageSuffixes)
 830
 831 ################################################################
 832 # Shared library load path settings
 833 ################################################################
 834 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 835 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 836 # was added.
 837 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 838    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 839     # The build folder always has bin/ and lib/; if we are also going to
 840     # install to lib/, then the installation RPATH works also in the build
 841     # tree.  This makes installation slightly faster (no need to rewrite the
 842     # RPATHs), and makes the binaries in the build tree relocatable.
 843     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 844         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 845     endif()
 846     # Set the RPATH as relative to the executable location to make the
 847     # binaries relocatable.
 848     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 849         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 850     else()
 851         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 852     endif()
 853     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 854     set(CMAKE_MACOSX_RPATH 1)
 855 else()
 856     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 857     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 858         # Set the RPATH options manually.
 859         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 860         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 861     else()
 862         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 863         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 864     endif()
 865 endif()
 866
 867 #COPYING file: Only necessary for binary distributions.
 868 #Simpler to always install.
 869 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 870
 871 if(GMX_EXTERNAL_BOOST)
 872     include_directories(${Boost_INCLUDE_DIRS})
 873     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 874 else()
 875     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 876     # typeid not supported for minimal internal version
 877     # (would add significant amount of code)
 878     add_definitions(-DBOOST_NO_TYPEID)
 879     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 880     # (from share/template/)
 881     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 882     if (NOT GMX_BUILD_MDRUN_ONLY)
 883         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 884                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 885                 COMPONENT development)
 886     endif()
 887 endif()
 888
 889 if (GMX_BUILD_FOR_COVERAGE)
 890     # Code heavy with asserts makes conditional coverage close to useless metric,
 891     # as by design most of the false branches are impossible to trigger in
 892     # correctly functioning code.  And the benefit of testing those that could
 893     # be triggered by using an API against its specification isn't usually
 894     # worth the effort.
 895     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 896 endif()
 897
 898 if (BUILD_TESTING)
 899     # "tests" target builds all the separate test binaries.
 900     add_custom_target(tests)
 901     # "run-ctest" is an internal target that actually runs the tests.
 902     # This is necessary to be able to add separate targets that execute as part
 903     # of 'make check', but are ensured to be executed after the actual tests.
 904     add_custom_target(run-ctest
 905                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 906                       COMMENT "Running all tests"
 907                       VERBATIM)
 908     add_dependencies(run-ctest tests)
 909     # "check" target builds and runs all tests.
 910     add_custom_target(check DEPENDS run-ctest)
 911 endif()
 912
 913 if (NOT GMX_BUILD_MDRUN_ONLY)
 914     add_subdirectory(doxygen)
 915     add_subdirectory(install-guide)
 916     add_subdirectory(share)
 917     add_subdirectory(scripts)
 918 endif()
 919 add_subdirectory(src)
 920
 921 if (BUILD_TESTING)
 922     add_subdirectory(tests)
 923 endif()
 924
 925 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 926 # Don't bother the user after the first configure pass.
 927 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 928     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 929 endif()
 930 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 931
 932 #######################
 933 ## uninstall target
 934 #######################
 935 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 936                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 937                   IMMEDIATE @ONLY)
 938 ###########################
 939 ADD_CUSTOM_TARGET(uninstall
 940                   "${CMAKE_COMMAND}" -P
 941                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 942 ###########################
 943 set_directory_properties(PROPERTIES
 944             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 945
 946 ########################################################################
 947 # Manual                                                               #
 948 ########################################################################
 949
 950 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 951 mark_as_advanced(GMX_BUILD_MANUAL)
 952 if(GMX_BUILD_MANUAL)
 953     # Make sure we only do detection of manual-building dependencies
 954     # when the user opted in for that.
 955     add_subdirectory(manual)
 956 endif()