CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(SOVERSION 8)
  68 # It is a bit irritating, but this has to be set separately for now!
  69 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  70 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  71 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  72
  73 # The numerical gromacs version. It is 40600 for 4.6.0.
  74 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  75 math(EXPR NUM_VERSION
  76     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  77 if(CPACK_PACKAGE_VERSION_PATCH)
  78     math(EXPR NUM_VERSION
  79          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  80 endif()
  81
  82 # The API version tracks the numerical Gromacs version (for now).
  83 # It is potentially different from the Gromacs version in the future, if
  84 # the programs/libraries diverge from the presumably more stable API.
  85 # The #define GMX_API_VERSION in version.h is set to this value to
  86 # provide backward compatibility of software written against the Gromacs API.
  87 set(API_VERSION ${NUM_VERSION})
  88
  89 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  90     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  91 endif()
  92
  93 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  94 mark_as_advanced(GMX_INSTALL_PREFIX)
  95
  96 include(gmxBuildTypeReference)
  97
  98 if(NOT CMAKE_BUILD_TYPE)
  99     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 100     # Set the possible values of build type for cmake-gui
 101     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 102         "MinSizeRel" "RelWithDebInfo")
 103 endif(NOT CMAKE_BUILD_TYPE)
 104
 105 enable_language(C)
 106 enable_language(CXX)
 107
 108 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 109 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 110 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 111 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 112 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 113 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 114 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 115 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 116 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 117 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html")
 118 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 119
 120 #must come after all cpack settings!
 121 include(CPack)
 122
 123 # Set a default valgrind suppression file.
 124 # This unfortunately needs to duplicate information from CTest to work as
 125 # expected...
 126 set(MEMORYCHECK_SUPPRESSIONS_FILE
 127     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 128     CACHE FILEPATH
 129     "File that contains suppressions for the memory checker")
 130 include(CTest)
 131
 132 set(SOURCE_IS_GIT_REPOSITORY OFF)
 133 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 134 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 135     set(SOURCE_IS_GIT_REPOSITORY ON)
 136 endif()
 137 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 138     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 139 endif()
 140
 141 ########################################################################
 142 # Check and warn if cache generated on a different host is being reused
 143 ########################################################################
 144 if(CMAKE_HOST_UNIX)
 145     execute_process(COMMAND hostname
 146                     OUTPUT_VARIABLE TMP_HOSTNAME
 147                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 148     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 149         message(WARNING "
 150             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 151             is being reused! This could lead to inconsitencies; therefore, it is
 152             recommended to regenerate the cache!")
 153     endif()
 154     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 155             "Hostname of the machine where the cache was generated.")
 156 endif()
 157
 158 ########################################################################
 159 # User input options                                                   #
 160 ########################################################################
 161 include(gmxOptionUtilities)
 162
 163 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 164
 165 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 166 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 167 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 168 gmx_dependent_option(
 169     GMX_MPI_IN_PLACE
 170     "Enable MPI_IN_PLACE for MPIs that have it defined"
 171     ON
 172     GMX_MPI)
 173 mark_as_advanced(GMX_MPI_IN_PLACE)
 174 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 175 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 176 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 177 mark_as_advanced(GMX_FAHCORE)
 178
 179 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 180 mark_as_advanced(GMX_COOL_QUOTES)
 181 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 182
 183 # decide on GPU settings based on user-settings and GPU/CUDA detection
 184 include(gmxManageGPU)
 185
 186 # Detect the architecture the compiler is targetting, detect
 187 # acceleration possibilities on that hardware, suggest an acceleration
 188 # to use if none is specified, and populate the cache option for CPU
 189 # accleration.
 190 include(gmxDetectTargetArchitecture)
 191 gmx_detect_target_architecture()
 192 include(gmxDetectAcceleration)
 193 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 194
 195 gmx_option_multichoice(
 196     GMX_CPU_ACCELERATION
 197     "Acceleration for CPU kernels and compiler optimization"
 198     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 199     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 200
 201 gmx_option_multichoice(
 202     GMX_FFT_LIBRARY
 203     "FFT library"
 204     "fftw3"
 205     fftw3 mkl "fftpack[built-in]")
 206 gmx_dependent_option(
 207     GMX_BUILD_OWN_FFTW
 208     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 209     OFF
 210     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 211 gmx_dependent_option(
 212     GMX_DISABLE_FFTW_MEASURE
 213     "Do not optimize FFTW setups (not needed with SSE)"
 214     OFF
 215     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 216 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 217 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 218
 219 gmx_option_multichoice(
 220     GMX_QMMM_PROGRAM
 221     "QM package for QM/MM"
 222     None
 223     none gaussian mopac gamess orca)
 224
 225 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 226 mark_as_advanced(GMX_BROKEN_CALLOC)
 227 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 228 mark_as_advanced(GMX_LOAD_PLUGINS)
 229
 230 option(GMX_GPU  "Enable GPU acceleration" ON)
 231 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 232
 233 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 234 mark_as_advanced(GMX_GIT_VERSION_INFO)
 235
 236 if(UNIX)
 237     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 238 endif()
 239 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 240
 241 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 242 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 243
 244 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 245 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 246
 247 option(GMX_BUILD_FOR_COVERAGE
 248        "Tune build for better code coverage metrics (e.g., disable asserts)"
 249        OFF)
 250 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 251
 252
 253 ######################################################################
 254 # Detect OpenMP support
 255 ######################################################################
 256 # The OpenMP detection _must_ come before tests for other CFLAGS.
 257 include(gmxManageOpenMP)
 258
 259
 260
 261 ######################################################################
 262 # Compiler tests
 263 # These need to be done early (before further tests).
 264 #####################################################################
 265
 266 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 267 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 268 # invalid options with the Intel Compilers.
 269 # These files should be removed from the source tree when a CMake version that
 270 # includes the features in question becomes required for building GROMACS.
 271 include(CheckCCompilerFlag)
 272 include(CheckCXXCompilerFlag)
 273
 274
 275 include(gmxCFlags)
 276 gmx_c_flags()
 277
 278 # This variable should be used for additional compiler flags which are not
 279 # generated in gmxCFlags nor are acceleration or MPI related.
 280 set(EXTRA_C_FLAGS "")
 281 set(EXTRA_CXX_FLAGS "")
 282
 283 # Run through a number of tests for buggy compilers and other issues
 284 include(gmxTestCompilerProblems)
 285 gmx_test_compiler_problems()
 286
 287
 288 set(PKG_CFLAGS "")
 289 if(GMX_DOUBLE)
 290     add_definitions(-DGMX_DOUBLE)
 291     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 292 endif(GMX_DOUBLE)
 293 if(GMX_SOFTWARE_INVSQRT)
 294   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 295 endif(GMX_SOFTWARE_INVSQRT)
 296
 297
 298
 299 ########################################################################
 300 # Basic system tests (standard libraries, headers, functions, types)   #
 301 ########################################################################
 302 include(CheckIncludeFiles)
 303 include(CheckIncludeFileCXX)
 304 check_include_files(unistd.h     HAVE_UNISTD_H)
 305 check_include_files(pwd.h        HAVE_PWD_H)
 306 check_include_files(dirent.h     HAVE_DIRENT_H)
 307 check_include_files(time.h       HAVE_TIME_H)
 308 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 309 check_include_files(io.h         HAVE_IO_H)
 310 check_include_files(sched.h      HAVE_SCHED_H)
 311
 312 check_include_files(regex.h      HAVE_POSIX_REGEX)
 313 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 314 # TODO: It could be nice to inform the user if no regex support is found,
 315 # as selections won't be fully functional.
 316
 317 include(CheckFunctionExists)
 318 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 319 check_function_exists(memalign          HAVE_MEMALIGN)
 320 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 321 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 322 check_function_exists(fsync             HAVE_FSYNC)
 323 check_function_exists(_fileno           HAVE__FILENO)
 324 check_function_exists(fileno            HAVE_FILENO)
 325 check_function_exists(_commit           HAVE__COMMIT)
 326 check_function_exists(sigaction         HAVE_SIGACTION)
 327 check_function_exists(sysconf           HAVE_SYSCONF)
 328 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 329 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 330 check_function_exists(rsqrt             HAVE_RSQRT)
 331 check_function_exists(rsqrtf            HAVE_RSQRTF)
 332 check_function_exists(sqrtf             HAVE_SQRTF)
 333
 334 include(CheckLibraryExists)
 335 check_library_exists(m sqrt "" HAVE_LIBM)
 336 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 337
 338
 339 include(CheckTypeSize)
 340
 341 check_type_size("int"           SIZEOF_INT)
 342 check_type_size("long int"      SIZEOF_LONG_INT)
 343 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 344 check_type_size("off_t"         SIZEOF_OFF_T)
 345 check_type_size("void *"        SIZEOF_VOIDP)
 346
 347 include(TestBigEndian)
 348 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 349
 350 # Management of GROMACS options for specific toolchains should go
 351 # here. Because the initial settings for some of the main options have
 352 # already happened, but things like library detection and MPI compiler
 353 # feature detection have not, the docstrings for any over-rides of
 354 # GROMACS defaults or user settings will make sense. Also, any
 355 # toolchain-related reasons for choosing whether to detect various
 356 # things can be sorted out now, before the detection takes place.
 357 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 358     include(gmxManageBlueGene)
 359 endif()
 360
 361 ########################################################################
 362 #Process MPI settings
 363 ########################################################################
 364 include(gmxManageMPI)
 365
 366
 367 ########################################################################
 368 #Process shared/static library settings
 369 ########################################################################
 370 include(gmxManageSharedLibraries)
 371
 372
 373 ########################################################################
 374 # Find external packages                                               #
 375 ########################################################################
 376
 377 # Unconditionally find the package, as it is also required for unit tests
 378 find_package(LibXml2)
 379 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 380 set(PKG_XML "")
 381 mark_as_advanced(GMX_XML)
 382 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 383 #if(GMX_XML AND NOT LIBXML2_FOUND)
 384 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 385 #endif()
 386 #if(GMX_XML)
 387 #    include_directories(${LIBXML2_INCLUDE_DIR})
 388 #    set(PKG_XML libxml-2.0)
 389 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 390 #endif(GMX_XML)
 391
 392 option(GMX_GSL "Add support for gsl" OFF)
 393 if (GMX_GSL)
 394   find_package(GSL)
 395   set(PKG_GSL "")
 396   if(GSL_FOUND)
 397     include_directories(${GSL_INCLUDE_DIR})
 398     set(PKG_GSL gsl)
 399     set(HAVE_LIBGSL 1)
 400   endif(GSL_FOUND)
 401 endif (GMX_GSL)
 402
 403 option(GMX_X11 "Use X window system" OFF)
 404 if (GMX_X11)
 405     find_package(X11)
 406     # X11 includes/libraries are only set in the ngmx subdirectory!
 407     if(NOT X11_FOUND)
 408         message(FATAL_ERROR
 409                 "X11 include files and/or libraries were not found. "
 410                 "Set GMX_X11=OFF to compile without X11 support. "
 411                 "gmx view will not be available.")
 412     endif()
 413     include_directories(${X11_INCLUDE_DIR})
 414 endif(GMX_X11)
 415
 416 include(ThreadMPI)
 417 set(THREAD_MPI_LIB thread_mpi)
 418 # Enable core threading facilities
 419 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 420 # Enable tMPI C++ support
 421 tmpi_enable_cxx()
 422 if(GMX_THREAD_MPI)
 423     # enable MPI functions
 424     tmpi_enable()
 425     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 426     set(GMX_MPI 1)
 427     set(MPI_IN_PLACE_EXISTS 1)
 428 endif(GMX_THREAD_MPI)
 429 tmpi_get_source_list(THREAD_MPI_SRC)
 430
 431 if(GMX_GPU)
 432     # now that we have detected the dependencies, do the second configure pass
 433     gmx_gpu_setup()
 434 endif(GMX_GPU)
 435
 436 if(CYGWIN)
 437     set(GMX_CYGWIN 1)
 438 endif(CYGWIN)
 439
 440 if(WIN32 AND NOT CYGWIN)
 441     set(GMX_NATIVE_WINDOWS 1)
 442     # This makes windows.h not declare min/max as macros that would break
 443     # C++ code using std::min/std::max.
 444     add_definitions(-DNOMINMAX)
 445 endif()
 446
 447 # only bother with finding git and using version.h if the source is a git repo
 448 if(GMX_GIT_VERSION_INFO)
 449     if (NOT SOURCE_IS_GIT_REPOSITORY)
 450         message(FATAL_ERROR
 451             "Cannot generate git version information from source tree not under git. "
 452             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 453     endif ()
 454     # We need at least git v1.5.3 be able to parse git's date output. If not
 455     # found or the version is too small, we can't generate version information.
 456     find_package(Git)
 457
 458     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 459         message(FATAL_ERROR
 460             "No compatible git version found (>= 1.5.3 required). "
 461             "Won't be able to generate development version information. "
 462             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 463     endif()
 464 endif()
 465
 466 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 467 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 468 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 469     find_package(Boost 1.44.0)
 470     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 471         set(Boost_FOUND FALSE)
 472     endif()
 473     # Print the notification only on first run, when determining the default
 474     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 475         message("Boost >= 1.44 not found. Using minimal internal version. "
 476                 "This may cause trouble if you plan on compiling/linking other "
 477                 "software that uses Boost against Gromacs.")
 478     endif()
 479 endif()
 480 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 481        ${Boost_FOUND})
 482 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 483     message(FATAL_ERROR
 484         "Boost >= 1.44 not found. "
 485         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 486         "version of Boost included with Gromacs.")
 487 endif()
 488
 489 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 490 mark_as_advanced(GMX_BUILD_UNITTESTS)
 491 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 492 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 493     message(FATAL_ERROR
 494         "Cannot build unit tests without libxml2. "
 495         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 496 endif()
 497
 498 ########################################################################
 499 # Generate development version info for cache
 500 ########################################################################
 501 # set(GEN_VERSION_INFO_INTERNAL "ON")
 502 # include(gmxGenerateVersionString)
 503
 504 ########################################################################
 505 # Our own GROMACS tests
 506 ########################################################################
 507
 508 add_definitions( -DHAVE_CONFIG_H )
 509 include_directories(${CMAKE_SOURCE_DIR}/src)
 510 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 511 include_directories(${CMAKE_BINARY_DIR}/src)
 512 # Required for gmx_header_config_gen.h to be found before installation
 513 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 514 # Required for now to make old code compile
 515 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 516
 517 include(gmxTestInlineASM)
 518 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 519
 520 include(gmxSetBuildInformation)
 521 gmx_set_build_information()
 522 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 523     set(HAVE_RDTSCP 1)
 524 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 525
 526 include(gmxTestFloatFormat)
 527 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 528                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 529                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 530
 531 include(gmxTestLargeFiles)
 532 gmx_test_large_files(GMX_LARGEFILES)
 533
 534 include(gmxTestSignal)
 535 gmx_test_sigusr1(HAVE_SIGUSR1)
 536
 537 include(gmxTestInline)
 538 gmx_test_inline(INLINE_KEYWORD)
 539
 540 include(gmxTestRestrict)
 541 gmx_test_restrict(RESTRICT_KEYWORD)
 542
 543 include(gmxTestPipes)
 544 gmx_test_pipes(HAVE_PIPES)
 545
 546 include(gmxTestIsfinite)
 547 gmx_test_isfinite(HAVE_ISFINITE)
 548 gmx_test__isfinite(HAVE__ISFINITE)
 549 gmx_test__finite(HAVE__FINITE)
 550
 551 include(gmxTestCXX11)
 552 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 553 if(CXX11_FLAG AND GMX_GPU)
 554     #FIXME: add proper solution for progate all but cxx11 flag
 555     set(CUDA_PROPAGATE_HOST_FLAGS no)
 556     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 557 endif()
 558
 559 include(gmxTestXDR)
 560 gmx_test_xdr(GMX_SYSTEM_XDR)
 561 if(NOT GMX_SYSTEM_XDR)
 562     set(GMX_INTERNAL_XDR 1)
 563 endif(NOT GMX_SYSTEM_XDR)
 564
 565 # include avx test source, used if the AVX flags are set below
 566 include(gmxTestAVXMaskload)
 567
 568 # Process nonbonded accelerated kernels settings
 569 #
 570 # Note that for the backward-compatible x86 SIMD architectures, the
 571 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 572 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 573 # SSE2). Accordingly, there are a set of CMake variables
 574 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 575 # CPU features that should be used. This means that the logic for
 576 # requiring such backward compatibility is all located here.
 577 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 578     # nothing to do
 579     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 580
 581 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 582
 583     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 584     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 585         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 586     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 587
 588     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 589     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 590         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 591     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 592
 593     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 594
 595     # Only test the include after we have tried to add the correct flag for SSE2 support
 596     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 597
 598     if(NOT HAVE_EMMINTRIN_H)
 599         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 600     endif(NOT HAVE_EMMINTRIN_H)
 601
 602     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 603     # The user should not be able to set this orthogonally to the acceleration
 604     set(GMX_X86_SSE2 1)
 605     set(ACCELERATION_STATUS_MESSAGE
 606         "Enabling SSE2 Gromacs acceleration")
 607
 608 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 609
 610     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 611     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 612         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 613     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 614     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 615         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 616         # intrinsics when SSE2 support is enabled, so we try that instead first.
 617         if (GMX_NATIVE_WINDOWS)
 618             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 619             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 620         else()
 621             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 622         endif()
 623     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 624
 625     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 626     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 627         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 628     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 629     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 630         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 631         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 632         # intrinsics when SSE2 support is enabled, so we try that instead.
 633         if (GMX_NATIVE_WINDOWS)
 634             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 635         endif()
 636     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 637
 638     # This must come after we have added the -msse4.1 flag on some platforms.
 639     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 640
 641     if(NOT HAVE_SMMINTRIN_H)
 642         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 643     endif(NOT HAVE_SMMINTRIN_H)
 644
 645     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 646         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 647     endif()
 648
 649     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 650     # The user should not be able to set this orthogonally to the acceleration
 651     set(GMX_X86_SSE4_1 1)
 652     set(GMX_X86_SSE2   1)
 653     set(ACCELERATION_STATUS_MESSAGE
 654         "Enabling SSE4.1 Gromacs acceleration")
 655
 656 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 657
 658     # Set the AVX compiler flag for both these choices!
 659
 660     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 661     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 662         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 663     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 664     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 665         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 666     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 667
 668     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 669     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 670         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 671     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 672     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 673         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 674     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 675
 676     # Set the FMA4 flags (MSVC doesn't require any)
 677     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 678         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 679         if (NOT GNU_FMA_CFLAG)
 680             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 681         endif(NOT GNU_FMA_CFLAG)
 682         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 683         # No big deal if we do not have xop, so no point yelling warnings about it.
 684         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 685         if (NOT GNU_FMA_CXXFLAG)
 686             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 687         endif (NOT GNU_FMA_CXXFLAG)
 688         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 689         # No big deal if we do not have xop, so no point yelling warnings about it.
 690     endif()
 691
 692     # Only test the header after we have tried to add the flag for AVX support
 693     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 694
 695     if(NOT HAVE_IMMINTRIN_H)
 696         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 697     endif(NOT HAVE_IMMINTRIN_H)
 698
 699     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 700         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 701             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 702             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 703         if(NOT TEST_AVX)
 704             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 705         endif()
 706     endif()
 707
 708     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 709     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 710     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 711
 712     # The user should not be able to set this orthogonally to the acceleration
 713     set(GMX_X86_SSE4_1 1)
 714     set(GMX_X86_SSE2   1)
 715
 716     # But just enable one of the choices internally...
 717     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 718         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 719         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 720         # hackintoshes is not worth the effort.
 721         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 722                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 723             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 724         endif()
 725
 726         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 727             # we assume that we have an external assembler that supports AVX
 728             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 729             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 730         endif()
 731         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 732             # we assume that we have an external assembler that supports AVX
 733             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 734             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 735         endif()
 736
 737         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 738         set(GMX_X86_AVX_128_FMA 1)
 739         set(ACCELERATION_STATUS_MESSAGE
 740             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 741
 742     else()
 743         # If we are not doing AVX_128, it must be AVX_256...
 744         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 745         set(GMX_X86_AVX_256 1)
 746         set(ACCELERATION_STATUS_MESSAGE
 747             "Enabling 256-bit AVX Gromacs acceleration")
 748     endif()
 749
 750     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 751     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 752     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 753
 754 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 755     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 756         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 757
 758     if (TEST_QPX)
 759         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 760         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 761     else()
 762         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 763     endif()
 764 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 765     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 766 else()
 767     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 768 endif()
 769 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 770 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 771     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 772 endif()
 773
 774 # Process QM/MM Settings
 775 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 776     set(GMX_QMMM_GAUSSIAN 1)
 777 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 778     set(GMX_QMMM_MOPAC 1)
 779 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 780     set(GMX_QMMM_GAMESS 1)
 781 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 782     set(GMX_QMMM_ORCA 1)
 783 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 784     # nothing to do
 785 else()
 786     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 787 endif()
 788
 789
 790 ##################################################
 791 # Process FFT library settings
 792 ##################################################
 793 include(gmxManageFFTLibraries)
 794
 795
 796 include(gmxManageLinearAlgebraLibraries)
 797
 798 # Whether GROMACS will really try to compile support for VMD plugins
 799 set(GMX_USE_PLUGINS OFF)
 800
 801 if(GMX_LOAD_PLUGINS)
 802   if(CYGWIN OR NOT WIN32)
 803     # Native Windows does not have, nor need dlopen
 804     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 805     include(gmxTestdlopen)
 806     gmx_test_dlopen(HAVE_DLOPEN)
 807   endif()
 808
 809   # so, should we use plug-ins?
 810   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 811     if(NOT VMD_QUIETLY)
 812       MESSAGE(STATUS
 813           "Found the ability to use plug-ins when building shared libaries, "
 814           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 815           "formats).")
 816     endif()
 817     if(NOT GMX_VMD_PLUGIN_PATH)
 818       find_package(VMD)
 819     endif()
 820     set(GMX_USE_PLUGINS ON)
 821     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 822     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 823   else()
 824     set(PKG_DL_LIBS)
 825   endif()
 826 endif(GMX_LOAD_PLUGINS)
 827 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 828
 829 # Link real-time library for POSIX timers. The check for clock_gettime
 830 # confirms the linkability of rt.
 831 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 832     list(APPEND GMX_EXTRA_LIBRARIES rt)
 833 endif()
 834
 835 # Math and thread libraries must often come after all others when linking...
 836 if(HAVE_LIBM)
 837     list(APPEND GMX_EXTRA_LIBRARIES m)
 838 endif(HAVE_LIBM)
 839 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 840     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 841     if(HAVE_MASS_SIMD)
 842         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 843     else()
 844         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 845     endif()
 846 endif()
 847
 848 if(GMX_FAHCORE)
 849   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 850       "Path to swindirect.h")
 851   include_directories(${COREWRAP_INCLUDE_DIR})
 852 endif(GMX_FAHCORE)
 853
 854 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 855 # these are set after everything else
 856 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 857     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 858     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 859     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 860     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 861 else()
 862     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 863     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 864     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 865     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 866     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 867     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 868     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 869     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 870     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 871 endif()
 872
 873 if(NOT GMX_OPENMP)
 874     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 875     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 876     unset(OpenMP_C_FLAGS CACHE)
 877     unset(OpenMP_CXX_FLAGS CACHE)
 878 else()
 879     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 880     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 881 endif()
 882 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 883
 884 ########################################################################
 885 # Specify install locations
 886 ########################################################################
 887 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 888     "Library installation directory (default: lib)")
 889 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 890     "Data installation directory under share/ (default: gromacs)")
 891 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 892
 893 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 894 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 895 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 896 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 897 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 898
 899 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 900 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 901
 902 ########################################################################
 903 # Set up binary and library suffixing
 904 ########################################################################
 905 option(
 906     GMX_DEFAULT_SUFFIX
 907     "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)"
 908     ON)
 909 gmx_dependent_cache_variable(
 910     GMX_BINARY_SUFFIX
 911     "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double)."
 912     STRING ""
 913     "NOT GMX_DEFAULT_SUFFIX")
 914 gmx_dependent_cache_variable(
 915     GMX_LIBS_SUFFIX
 916     "Suffix for GROMACS libraries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double)."
 917     STRING ""
 918     "NOT GMX_DEFAULT_SUFFIX")
 919 if (GMX_DEFAULT_SUFFIX)
 920   gmx_check_if_changed(SUFFIXES_CHANGED GMX_DEFAULT_SUFFIX)
 921   set(GMX_BINARY_SUFFIX "")
 922   set(GMX_LIBS_SUFFIX "")
 923   if (GMX_LIB_MPI)
 924     set(GMX_BINARY_SUFFIX "_mpi")
 925     set(GMX_LIBS_SUFFIX "_mpi")
 926   endif()
 927   if (GMX_DOUBLE)
 928     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 929     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 930   endif(GMX_DOUBLE)
 931   if (SUFFIXES_CHANGED)
 932     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 933     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 934   endif ()
 935 else(GMX_DEFAULT_SUFFIX)
 936   gmx_check_if_changed(SUFFIXES_CHANGED
 937                        GMX_DEFAULT_SUFFIX GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 938   if (SUFFIXES_CHANGED)
 939     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 940     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 941   endif ()
 942 endif(GMX_DEFAULT_SUFFIX)
 943 if (GMX_BUILD_MDRUN_ONLY)
 944     set(GMX_LIBS_SUFFIX "_mdrun${GMX_LIBS_SUFFIX}")
 945 endif ()
 946
 947 ##################################################################
 948 # Shared library settings
 949 ##################################################################
 950 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 951     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 952     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 953     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 954     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 955 else()
 956     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 957         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 958         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
 959     else()
 960         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 961     endif()
 962 endif()
 963
 964 #COPYING file: Only necessary for binary distributions.
 965 #Simpler to always install.
 966 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 967
 968 if(GMX_EXTERNAL_BOOST)
 969     include_directories(${Boost_INCLUDE_DIRS})
 970 else()
 971     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 972     # typeid not supported for minimal internal version
 973     # (would add significant amount of code)
 974     add_definitions(-DBOOST_NO_TYPEID)
 975     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 976     # (from share/template/)
 977     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${INCL_INSTALL_DIR}/gromacs/external/boost")
 978     if (NOT GMX_BUILD_MDRUN_ONLY)
 979         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 980                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 981                 COMPONENT development)
 982     endif ()
 983 endif()
 984
 985 if (GMX_BUILD_FOR_COVERAGE)
 986     # Code heavy with asserts makes conditional coverage close to useless metric,
 987     # as by design most of the false branches are impossible to trigger in
 988     # correctly functioning code.  And the benefit of testing those that could
 989     # be triggered by using an API against its specification isn't usually
 990     # worth the effort.
 991     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 992 endif ()
 993
 994 if (NOT GMX_BUILD_MDRUN_ONLY)
 995     add_subdirectory(doxygen)
 996     add_subdirectory(share)
 997     add_subdirectory(scripts)
 998 endif ()
 999 add_subdirectory(src)
1000
1001 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1002 # Don't bother the user after the first configure pass.
1003 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1004     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1005 endif()
1006 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1007
1008 #######################
1009 ## uninstall target
1010 #######################
1011     CONFIGURE_FILE(
1012                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1013                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1014                    IMMEDIATE @ONLY)
1015 ###########################
1016 ADD_CUSTOM_TARGET(uninstall
1017                   "${CMAKE_COMMAND}" -P
1018                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1019 ###########################
1020
1021 ########################################################################
1022 # Tests                                                                #
1023 ########################################################################
1024
1025 IF(BUILD_TESTING)
1026     enable_testing()
1027     #"check" target builds and runs all tests
1028     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1029     add_dependencies(check tests)
1030     # TODO: This would be better within tests/CMakeLists.txt
1031     if (NOT GMX_BUILD_MDRUN_ONLY)
1032         #gmxtests target builds all binaries required for running gmxtest
1033         add_custom_target(gmxtests DEPENDS gmx links)
1034         add_dependencies(check gmxtests)
1035         add_subdirectory(tests)
1036     endif()
1037     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1038 ENDIF()
1039
1040 ########################################################################
1041 # Manual                                                               #
1042 ########################################################################
1043
1044 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1045 mark_as_advanced(GMX_BUILD_MANUAL)
1046 if(GMX_BUILD_MANUAL)
1047     # Make sure we only do detection of manual-building dependencies
1048     # when the user opted in for that.
1049     add_subdirectory(manual)
1050 endif()