CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36 if(POLICY CMP0074) #3.12
  37     cmake_policy(SET CMP0074 NEW)
  38 endif()
  39
  40 # CMake modules/macros are in a subdirectory to keep this file cleaner
  41 # This needs to be set before project() in order to pick up toolchain files
  42 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  43
  44 project(Gromacs)
  45
  46 set(CMAKE_CXX_STANDARD 14)
  47 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  48 set(CMAKE_CXX_EXTENSIONS OFF)
  49
  50 include(gmxManageCcache)
  51
  52 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  53 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  54 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  55
  56 find_package(LibStdCpp)
  57
  58 # Set up common version variables, as well as general information about
  59 # the build tree (whether the build is from a source package or from a git
  60 # repository).  Also declares a few functions that will be used for generating
  61 # version info files later.
  62 include(gmxBuildTreeInfo)
  63 include(gmxVersionInfo)
  64
  65 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  66     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  67 endif()
  68 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  69     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  70 endif()
  71
  72 include(gmxBuildTypeReference)
  73 include(gmxBuildTypeProfile)
  74 include(gmxBuildTypeTSAN)
  75 include(gmxBuildTypeASAN)
  76 include(gmxBuildTypeMSAN)
  77 include(gmxBuildTypeReleaseWithAssert)
  78
  79 if(NOT CMAKE_BUILD_TYPE)
  80     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  81     # Set the possible values of build type for cmake-gui
  82     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  83         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  84 endif()
  85 if(CMAKE_CONFIGURATION_TYPES)
  86     # Add appropriate GROMACS-specific build types for the Visual
  87     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  88     # are already present by default).
  89     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  90     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  91     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  92         "List of configuration types"
  93         FORCE)
  94 endif()
  95 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  96
  97 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  98
  99 include(gmxCTestUtilities)
 100 gmx_ctest_init()
 101
 102 include(gmxCPackUtilities)
 103 gmx_cpack_init()
 104
 105 # Variables that accumulate stuff influencing the installed headers
 106 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 107 set(INSTALLED_HEADER_DEFINITIONS "")
 108
 109 ########################################################################
 110 # Global non-cache variables for implementing the build system
 111 ########################################################################
 112
 113 # These variables collect libraries that GROMACS requires for
 114 # linking. They should be appended to with list(APPEND ${name}
 115 # new-library) calls. They are:
 116 #  - Libraries that are required for libgromacs (only)
 117 set(GMX_EXTRA_LIBRARIES "")
 118 #  - Libraries that are required for all code in the repository
 119 set(GMX_COMMON_LIBRARIES "")
 120 #  - Libraries that all code linked against libgromacs needs
 121 #    (i.e., something that is exposed in installed headers).
 122 set(GMX_PUBLIC_LIBRARIES "")
 123
 124 ########################################################################
 125 # Check and warn if cache generated on a different host is being reused
 126 ########################################################################
 127 if(CMAKE_HOST_UNIX)
 128     execute_process(COMMAND hostname
 129                     OUTPUT_VARIABLE TMP_HOSTNAME
 130                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 131     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 132         message(WARNING "
 133             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 134             is being reused! This could lead to inconsistencies; therefore, it is
 135             recommended to regenerate the cache!")
 136     endif()
 137     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 138             "Hostname of the machine where the cache was generated.")
 139 endif()
 140
 141 ########################################################################
 142 # Detect architecture before setting options so we can alter defaults
 143 ########################################################################
 144 # Detect the architecture the compiler is targetting, detect
 145 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 146 # to use if none is specified, and populate the cache option for CPU
 147 # SIMD.
 148 include(gmxDetectTargetArchitecture)
 149 gmx_detect_target_architecture()
 150
 151 ########################################################################
 152 # User input options                                                   #
 153 ########################################################################
 154 include(gmxOptionUtilities)
 155
 156 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 157
 158 # Fujitsu only has SIMD in double precision, so this will be faster
 159 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 160 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 161 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 162 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 163
 164 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 165 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 166 gmx_dependent_option(
 167     GMX_MPI_IN_PLACE
 168     "Enable MPI_IN_PLACE for MPIs that have it defined"
 169     ON
 170     GMX_MPI)
 171 mark_as_advanced(GMX_MPI_IN_PLACE)
 172
 173 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 174
 175 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 176 mark_as_advanced(GMX_FAHCORE)
 177
 178 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 179 mark_as_advanced(GMX_COOL_QUOTES)
 180 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 181
 182 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 183
 184 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 185
 186 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 187 set(REQUIRED_CUDA_VERSION 9.0)
 188 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 189
 190 # OpenCL required version: 1.2 or newer
 191 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 192 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 193 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 194
 195 if(NOT GMX_USE_OPENCL)
 196     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 197     include(gmxManageGPU)
 198     set(GMX_USE_CUDA ${GMX_GPU})
 199     if(GMX_GPU)
 200         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 201     else()
 202         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 203     endif()
 204 else()
 205     #Now the OpenCL path (for both AMD and NVIDIA)
 206     if(GMX_GPU)
 207         include(gmxManageOpenCL)
 208         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 209     else()
 210         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 211     endif()
 212 endif()
 213
 214 gmx_option_multichoice(
 215     GMX_SIMD
 216     "SIMD instruction set for CPU kernels and compiler optimization"
 217     "AUTO"
 218     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 219
 220 if(GMX_TARGET_MIC)
 221     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 222 else()
 223     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 224 endif()
 225
 226 gmx_option_multichoice(
 227     GMX_FFT_LIBRARY
 228     "FFT library"
 229     "${GMX_FFT_LIBRARY_DEFAULT}"
 230     fftw3 mkl "fftpack[built-in]")
 231 gmx_dependent_option(
 232     GMX_BUILD_OWN_FFTW
 233     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 gmx_dependent_option(
 237     GMX_DISABLE_FFTW_MEASURE
 238     "Do not optimize FFTW setups (not needed with SSE)"
 239     OFF
 240     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 241 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 242 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 243
 244 gmx_option_multichoice(
 245     GMX_QMMM_PROGRAM
 246     "QM package for QM/MM"
 247     None
 248     none gaussian mopac gamess orca)
 249
 250 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 251 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 252
 253 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 254
 255 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 256 mark_as_advanced(GMX_BROKEN_CALLOC)
 257
 258 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 259
 260 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 261
 262 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 263
 264 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 265 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 266
 267 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 268 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 269
 270 option(GMX_BUILD_FOR_COVERAGE
 271        "Tune build for better code coverage metrics (e.g., disable asserts)"
 272        OFF)
 273 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 274
 275 option(GMX_DEVELOPER_BUILD
 276     "Enable Developer convenience features: always build unit-tests"
 277     OFF)
 278 mark_as_advanced(GMX_DEVELOPER_BUILD)
 279
 280 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 281 option(GMX_COMPILER_WARNINGS
 282     "Enable a default set of compiler warnings"
 283     ${GMX_COMPILER_WARNINGS_DEFAULT})
 284 mark_as_advanced(GMX_COMPILER_WARNINGS)
 285 # Always turn on compiler warnings with a developer build.
 286 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 287
 288 option(GMX_BUILD_SHARED_EXE
 289     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 290     ON)
 291 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 292
 293 option(GMX_PHYSICAL_VALIDATION
 294        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 295        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 296        OFF)
 297 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 298
 299 ######################################################################
 300 # Detect OpenMP support
 301 ######################################################################
 302 # The OpenMP detection _must_ come before tests for other CFLAGS.
 303 include(gmxManageOpenMP)
 304
 305
 306
 307 ######################################################################
 308 # Compiler tests
 309 # These need to be done early (before further tests).
 310 #####################################################################
 311
 312 include(gmxCFlags)
 313 gmx_c_flags()
 314
 315 # These variables should be used for CMake-style lists (ie. separated
 316 # by semicolons) of additional compiler flags which are not generated
 317 # in gmxCFlags nor are SIMD or MPI related.
 318 #
 319 # TODO These variables should be consolidated into
 320 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 321 # things that work in C compilation (e.g. merging from old branches)
 322 # might not also work for C++ compilation.
 323 set(EXTRA_C_FLAGS "")
 324 set(EXTRA_CXX_FLAGS "")
 325
 326 # Run through a number of tests for buggy compilers and other issues
 327 include(gmxTestCompilerProblems)
 328 gmx_test_compiler_problems()
 329
 330 # Implement double-precision option. This is complicated because we
 331 # need installed headers to use the precision mode of the build that
 332 # produced the library, but cannot use config.h in that case. We also
 333 # want such variables to always have a definition, because #if is more
 334 # robust than #ifdef. So, we put this value on the compiler command
 335 # line in all cases.
 336 #
 337 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 338 # because no installed header needs it
 339 if(GMX_DOUBLE)
 340     set(GMX_DOUBLE_VALUE 1)
 341 else()
 342     set(GMX_DOUBLE_VALUE 0)
 343 endif()
 344 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 345 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 346
 347 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 348 if(GMX_IMD AND WIN32)
 349     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 350 endif()
 351
 352
 353
 354 ########################################################################
 355 # Basic system tests (standard libraries, headers, functions, types)   #
 356 ########################################################################
 357 include(CheckIncludeFiles)
 358 include(CheckIncludeFileCXX)
 359 check_include_files(unistd.h     HAVE_UNISTD_H)
 360 check_include_files(pwd.h        HAVE_PWD_H)
 361 check_include_files(dirent.h     HAVE_DIRENT_H)
 362 check_include_files(time.h       HAVE_TIME_H)
 363 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 364 check_include_files(io.h         HAVE_IO_H)
 365 check_include_files(sched.h      HAVE_SCHED_H)
 366 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 367
 368 include(CheckCXXSymbolExists)
 369 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 370 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 371 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 372 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 373 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 374 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 375 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 376 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 377
 378 # We cannot check for the __builtins as symbols, but check if code compiles
 379 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 380 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 381 if(MSVC)
 382     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 383     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 384 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 385     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 386     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 387 endif()
 388
 389 include(CheckLibraryExists)
 390 find_library(HAVE_LIBM m)
 391 mark_as_advanced(HAVE_LIBM)
 392 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 393 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 394 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 395
 396 include(TestSchedAffinity)
 397 test_sched_affinity(HAVE_SCHED_AFFINITY)
 398
 399 # Aligned memory allocation. We need to check for both mm_malloc(),
 400 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 401 include(gmxTestMMMalloc)
 402 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 403 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 404 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 405 if(MSVC)
 406     # No need to waste time on this test on platforms where it will never be true
 407     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 408 endif()
 409
 410 include(TestBigEndian)
 411 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 412
 413 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 414
 415 # Management of GROMACS options for specific toolchains should go
 416 # here. Because the initial settings for some of the main options have
 417 # already happened, but things like library detection and MPI compiler
 418 # feature detection have not, the docstrings for any over-rides of
 419 # GROMACS defaults or user settings will make sense. Also, any
 420 # toolchain-related reasons for choosing whether to detect various
 421 # things can be sorted out now, before the detection takes place.
 422 if(GMX_TARGET_FUJITSU_SPARC64)
 423     include(gmxManageFujitsuSparc64)
 424 endif()
 425
 426 ########################################################################
 427 #Process MPI settings
 428 ########################################################################
 429 include(gmxManageMPI)
 430
 431 ########################################################################
 432 #Process MiMiC settings
 433 ########################################################################
 434 include(gmxManageMimic)
 435
 436 ########################################################################
 437 #Process shared/static library settings
 438 ########################################################################
 439 include(gmxManageSharedLibraries)
 440
 441
 442 ########################################################################
 443 # Find external packages                                               #
 444 ########################################################################
 445
 446 # Unconditionally find the package, as it is also required for unit
 447 # tests. This exports LIBXML2_FOUND, which we should not use because
 448 # it does not tell us that linking will succeed. Instead, we test that
 449 # next.
 450 #if(DEFINED LIBXML2_LIBRARIES)
 451 #  set(LibXml2_FIND_QUIETLY TRUE)
 452 #endif()
 453 #find_package(LibXml2)
 454 #include(gmxTestLibXml2)
 455 #gmx_test_libxml2(HAVE_LIBXML2)
 456 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 457 #set(PKG_XML "")
 458 #mark_as_advanced(GMX_XML)
 459 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 460 #if(GMX_XML AND NOT HAVE_LIBXML2)
 461 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 462 #endif()
 463 #if(GMX_XML)
 464 #    include_directories(${LIBXML2_INCLUDE_DIR})
 465 #    set(PKG_XML libxml-2.0)
 466 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 467 #endif()
 468
 469 gmx_option_trivalue(
 470     GMX_HWLOC
 471     "Use hwloc portable hardware locality library"
 472     "AUTO")
 473
 474 if (GMX_HWLOC)
 475     # Find quietly the second time.
 476     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 477         set(HWLOC_FIND_QUIETLY TRUE)
 478     endif()
 479     find_package(HWLOC 1.5)
 480
 481     if (HWLOC_FOUND)
 482         if (HWLOC_LIBRARIES MATCHES ".a$")
 483             set(_STATIC_HWLOC TRUE)
 484         endif()
 485
 486         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 487         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 488             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 489             set(GMX_USE_HWLOC OFF)
 490         else()
 491             set(GMX_USE_HWLOC ON)
 492         endif()
 493
 494         if (GMX_USE_HWLOC)
 495             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 496             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 497         endif()
 498     elseif(GMX_HWLOC_FORCE)
 499         message(FATAL_ERROR "HWLOC package support required, but not found.")
 500     endif()
 501
 502     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 503 endif()
 504
 505 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 506 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 507 if(GMX_EXTERNAL_TINYXML2)
 508     # Find an external TinyXML-2 library.
 509     find_package(TinyXML-2 3.0.0)
 510     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 511     if(NOT HAVE_TINYXML2)
 512         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 513     endif()
 514 endif()
 515
 516 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 517 mark_as_advanced(GMX_EXTRAE)
 518
 519 if (GMX_EXTRAE)
 520   find_package(EXTRAE)
 521   if(EXTRAE_FOUND)
 522     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 523     set(HAVE_EXTRAE 1)
 524   else()
 525     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 526   endif()
 527 endif()
 528
 529 option(GMX_X11 "Use X window system" OFF)
 530 if (GMX_X11)
 531     find_package(X11)
 532     # X11 includes/libraries are only set in the ngmx subdirectory!
 533     if(NOT X11_FOUND)
 534         message(FATAL_ERROR
 535                 "X11 include files and/or libraries were not found. "
 536                 "Set GMX_X11=OFF to compile without X11 support. "
 537                 "gmx view will not be available.")
 538     endif()
 539     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 540 endif()
 541
 542 include(ThreadMPI)
 543 # Enable core threading facilities
 544 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 545 if(GMX_THREAD_MPI)
 546     # enable MPI functions
 547     tmpi_enable()
 548     set(MPI_IN_PLACE_EXISTS 1)
 549 endif()
 550 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 551 if (TMPI_ATOMICS_DISABLED)
 552    add_definitions(-DTMPI_ATOMICS_DISABLED)
 553 endif()
 554
 555 include(gmxManageTNG)
 556
 557 include(gmxManageLmfit)
 558
 559 if(GMX_GPU)
 560     # now that we have detected the dependencies, do the second configure pass
 561     gmx_gpu_setup()
 562     if (GMX_CLANG_CUDA)
 563         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 564         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 565     endif()
 566 endif()
 567
 568 if(CYGWIN)
 569     set(GMX_CYGWIN 1)
 570 endif()
 571
 572 if(WIN32)
 573     set(GMX_NATIVE_WINDOWS 1)
 574     # This makes windows.h not declare min/max as macros that would break
 575     # C++ code using std::min/std::max.
 576     add_definitions(-DNOMINMAX)
 577 endif()
 578
 579 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 580 mark_as_advanced(GMX_BUILD_UNITTESTS)
 581 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 582
 583 ########################################################################
 584 # Our own GROMACS tests
 585 ########################################################################
 586
 587 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 588 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 589 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 590
 591 include(gmxTestInlineASM)
 592 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 593
 594 include(gmxSetBuildInformation)
 595 gmx_set_build_information()
 596
 597 gmx_option_multichoice(
 598     GMX_USE_RDTSCP
 599     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 600     "AUTO"
 601     OFF ON AUTO DETECT)
 602 mark_as_advanced(GMX_USE_RDTSCP)
 603
 604 macro(gmx_check_rdtscp)
 605     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 606         set(HAVE_RDTSCP 1)
 607         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 608     else()
 609         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 610     endif()
 611 endmacro()
 612
 613 set(HAVE_RDTSCP 0)
 614 if (GMX_USE_RDTSCP STREQUAL "ON")
 615     set(HAVE_RDTSCP 1)
 616 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 617     gmx_check_rdtscp()
 618 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 619     # If the user specified automated SIMD selection, that the choice
 620     # is made based on detection on the build host. If so, then RDTSCP
 621     # should be chosen the same way.
 622     #
 623     # If the user specified an AVX SIMD level (e.g. when
 624     # cross-compiling GROMACS) then they will get our best guess, ie
 625     # that in practice AVX mostly correlates with rdtscp (and anyway
 626     # is only relevant in rather old x86 hardware).
 627     if (GMX_SIMD STREQUAL "AUTO")
 628         gmx_check_rdtscp()
 629     elseif (GMX_SIMD MATCHES "AVX")
 630         set(HAVE_RDTSCP 1)
 631     endif()
 632 endif()
 633 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 634 if (HAVE_RDTSCP_CHANGED)
 635     if (HAVE_RDTSCP)
 636         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 637     else()
 638         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 639     endif()
 640 endif()
 641
 642 include(gmxTestLargeFiles)
 643 gmx_test_large_files(GMX_LARGEFILES)
 644
 645 include(gmxTestSignal)
 646 gmx_test_sigusr1(HAVE_SIGUSR1)
 647
 648 include(gmxTestPipes)
 649 gmx_test_pipes(HAVE_PIPES)
 650
 651 include(gmxTestXDR)
 652 gmx_test_xdr(GMX_SYSTEM_XDR)
 653 # Darwin has system XDR, but it uses a three-argument flavour of
 654 # xdrproc_t that it guarantees will still work if you pass the normal
 655 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 656 # to do that, so it's simpler to just use our own XDR library.
 657 #
 658 # TODO It would be better to craft a cmake test which fails if such
 659 # XDR operations cause warnings, and succeeds otherwise, because it is
 660 # generally preferable to use system libraries where possible.
 661 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 662     set(GMX_INTERNAL_XDR 1)
 663 endif()
 664
 665
 666 ##################################################
 667 # Process SIMD instruction settings
 668 ##################################################
 669 # This checks what flags to add in order to
 670 # support the SIMD instructions we need, it sets
 671 # correct defines for the SIMD instructions supported,
 672 # and adds advanced options to control accuracy
 673 # for SIMD math operations.
 674 include(gmxManageSimd)
 675 gmx_manage_simd()
 676
 677 include(gmxManageCycleCounters)
 678 gmx_manage_cycle_counters()
 679
 680 # Process QM/MM Settings
 681 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 682     set(GMX_QMMM_GAUSSIAN 1)
 683 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 684     set(GMX_QMMM_MOPAC 1)
 685 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 686     set(GMX_QMMM_GAMESS 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 688     set(GMX_QMMM_ORCA 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 690     # nothing to do
 691 else()
 692     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 693 endif()
 694
 695
 696 ##################################################
 697 # Process FFT library settings
 698 ##################################################
 699 include(gmxManageFFTLibraries)
 700
 701
 702 include(gmxManageLinearAlgebraLibraries)
 703
 704 include(gmxManagePluginSupport)
 705
 706 if (GMX_USE_PLUGINS)
 707     if(NOT GMX_VMD_PLUGIN_PATH)
 708         find_package(VMD)
 709     endif()
 710 endif()
 711
 712 # Link real-time library for POSIX timers. The check for clock_gettime
 713 # confirms the linkability of rt.
 714 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 715     list(APPEND GMX_EXTRA_LIBRARIES rt)
 716 endif()
 717
 718 # Math and thread libraries must often come after all others when linking...
 719 if (HAVE_LIBM)
 720     list(APPEND GMX_PUBLIC_LIBRARIES m)
 721 endif()
 722
 723 option(GMX_NACL "Configure for Native Client builds" OFF)
 724 if (GMX_NACL)
 725   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 726   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 727   # TODO: Is this still necessary with the check for its presence?
 728   set(GMX_USE_NICE 0)
 729   set(GMX_NO_RENAME 1)
 730 endif()
 731 mark_as_advanced(GMX_NACL)
 732
 733 if(GMX_FAHCORE)
 734   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 735       "Path to swindirect.h")
 736   include_directories(${COREWRAP_INCLUDE_DIR})
 737 endif()
 738
 739 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 740 # produce warnings if that fails.
 741 set(build_help_default AUTO)
 742 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 743     set(build_help_default OFF)
 744 endif()
 745 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 746 mark_as_advanced(GMX_BUILD_HELP)
 747 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 748     message(FATAL_ERROR
 749         "Rebuilding shell completions or man pages is not supported for "
 750         "in-source builds from a source distribution. "
 751         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 752 endif()
 753
 754 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 755 # these are set after everything else
 756 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 757     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 758     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 759 else()
 760     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 761     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 762     foreach(build_type ${build_types_with_explicit_flags})
 763         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 764     endforeach()
 765     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 766     foreach(build_type ${build_types_with_explicit_flags})
 767         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 768     endforeach()
 769     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 770     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 771 endif()
 772
 773 ########################################################################
 774 # Specify install locations
 775 ########################################################################
 776 # Use GNUInstallDirs to set paths on multiarch systems.
 777 include(GNUInstallDirs)
 778
 779 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 780 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 781
 782 # Internal convenience so we do not have to join two path segments in the code
 783 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 784
 785 # If the nesting level wrt. the installation root is changed,
 786 # gromacs-config.cmake.cmakein needs to be adapted.
 787 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 788
 789 # TODO: Make GMXRC adapt if this is changed
 790 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 791 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 792
 793 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 794
 795 # Binary and library suffix options
 796 include(gmxManageSuffixes)
 797
 798 ################################################################
 799 # Shared library load path settings
 800 ################################################################
 801 if(NOT GMX_BUILD_SHARED_EXE)
 802     # No rpath
 803     set(CMAKE_SKIP_RPATH TRUE)
 804     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 805     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 806 else()
 807     # The build folder always has bin/ and lib/; if we are also going to
 808     # install to lib/, then the installation RPATH works also in the build
 809     # tree.  This makes installation slightly faster (no need to rewrite the
 810     # RPATHs), and makes the binaries in the build tree relocatable.
 811     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 812         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 813         if(POLICY CMP0068)
 814             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 815             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 816         endif()
 817     endif()
 818     # Set the RPATH as relative to the executable location to make the
 819     # binaries relocatable.
 820     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 821         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 822         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 823     else()
 824         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 825     endif()
 826     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 827     set(CMAKE_MACOSX_RPATH 1)
 828 endif()
 829
 830 #COPYING file: Only necessary for binary distributions.
 831 #Simpler to always install.
 832 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 833
 834 if (GMX_BUILD_FOR_COVERAGE)
 835     # Code heavy with asserts makes conditional coverage close to useless metric,
 836     # as by design most of the false branches are impossible to trigger in
 837     # correctly functioning code.  And the benefit of testing those that could
 838     # be triggered by using an API against its specification isn't usually
 839     # worth the effort.
 840     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 841 endif()
 842
 843 if (BUILD_TESTING)
 844     include(tests/CheckTarget.cmake)
 845 endif()
 846
 847 # TODO: Determine control flow and defaults for package installation and testing use cases.
 848 # Ref: http://redmine.gromacs.org/issues/2896
 849 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 850 mark_as_advanced(GMX_PYTHON_PACKAGE)
 851
 852 if (NOT GMX_BUILD_MDRUN_ONLY)
 853     # Note: Though only documented as an output variable, PYTHON_EXECUTABLE is
 854     # also effective as a CMake input variable to effectively hint the location
 855     # of the Python interpreter. This may be helpful in environments with both
 856     # Python 2 and Python 3 on the default PATH.
 857     # Ref: https://cmake.org/cmake/help/latest/module/FindPythonInterp.html
 858     if(FIND_PACKAGE_MESSAGE_DETAILS_PythonInterp)
 859         # Keep quiet on subsequent runs of cmake
 860         set(PythonInterp_FIND_QUIETLY ON)
 861     endif()
 862     # Older CMake versions might not search for Python newer than 3.7.
 863     set(Python_ADDITIONAL_VERSIONS 3.8)
 864     if(GMX_PYTHON_PACKAGE)
 865         find_package(PythonInterp 3.5 REQUIRED)
 866         # Note: PythonLibs will be found later by pybind11.
 867         # TODO: (issue #2998) When CMake >= 3.12 is required, update detection.
 868         # I.e.  find_package(Python3 3.5 COMPONENTS Interpreter Development REQUIRED)
 869     else()
 870         find_package(PythonInterp 3.5)
 871     endif()
 872     find_package(ImageMagick QUIET COMPONENTS convert)
 873     include(gmxTestImageMagick)
 874     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 875     add_subdirectory(docs)
 876     add_subdirectory(share)
 877     add_subdirectory(scripts)
 878 endif()
 879 add_subdirectory(src)
 880
 881 if (BUILD_TESTING)
 882     add_subdirectory(tests)
 883 endif()
 884
 885 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 886     add_subdirectory(python_packaging)
 887 endif()
 888
 889 gmx_cpack_write_config()
 890
 891 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 892 # Don't bother the user after the first configure pass.
 893 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 894     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 895 endif()
 896 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 897
 898 #######################
 899 ## uninstall target
 900 #######################
 901 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 902                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 903                   IMMEDIATE @ONLY)
 904 ###########################
 905 ADD_CUSTOM_TARGET(uninstall
 906                   "${CMAKE_COMMAND}" -P
 907                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 908 ###########################
 909 set_directory_properties(PROPERTIES
 910             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")