src/gromacs/InstallLibInfo.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2016,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 function (do_pkgconfig)
  36     set(PKG_CFLAGS "")
  37     foreach (_dir ${INSTALLED_HEADER_INCLUDE_DIRS})
  38         if (IS_ABSOLUTE ${_dir})
  39             set(PKG_CFLAGS "${PKG_CFLAGS} -I${_dir}")
  40         else()
  41             set(PKG_CFLAGS "${PKG_CFLAGS} -I${CMAKE_INSTALL_PREFIX}/${_dir}")
  42         endif()
  43     endforeach()
  44     if (INSTALLED_HEADER_DEFINITIONS)
  45         foreach (_def ${INSTALLED_HEADER_DEFINITIONS})
  46             set(PKG_CFLAGS "${PKG_CFLAGS} ${_def}")
  47         endforeach()
  48     endif()
  49     set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
  50
  51     configure_file(libgromacs.pc.cmakein
  52                    libgromacs.pc @ONLY)
  53     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
  54             DESTINATION ${GMX_INSTALL_PKGCONFIGDIR}
  55             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
  56             COMPONENT development)
  57 endfunction()
  58
  59 function (do_cmake_config)
  60     # Install everything into a subdirectory, because
  61     #  1. CMake expects things to be there for CMAKE_PREFIX_PATH to work, and
  62     #  2. This nicely isolates files for different suffixes from each other.
  63     set(GMX_INSTALL_CMAKEPKGDIR ${GMX_INSTALL_CMAKEDIR}/gromacs${GMX_LIBS_SUFFIX})
  64
  65     # Install import definitions that take care of the library locations and
  66     # library dependencies.
  67     set(EXPORT_FILE_NAME libgromacs.cmake)
  68     if (NOT BUILD_SHARED_LIBS)
  69         set(EXPORT_FILE_NAME libgromacs_static.cmake)
  70     endif()
  71     install(EXPORT libgromacs
  72             FILE ${EXPORT_FILE_NAME}
  73             DESTINATION ${GMX_INSTALL_CMAKEPKGDIR}
  74             COMPONENT libraries)
  75
  76     get_filename_component(GROMACS_CXX_COMPILER ${CMAKE_CXX_COMPILER} REALPATH)
  77     configure_file(gromacs-config.cmake.cmakein
  78                    gromacs-config.cmake @ONLY)
  79     configure_file(gromacs-config-version.cmake.cmakein
  80                    gromacs-config-version.cmake @ONLY)
  81     configure_file(gromacs-toolchain.cmake.cmakein
  82                    gromacs-toolchain.cmake @ONLY)
  83     option(GMX_REQUIRE_VALID_TOOLCHAIN "Force CMake error if generated toolchain file is not usable." OFF)
  84     mark_as_advanced(GMX_REQUIRE_VALID_TOOLCHAIN)
  85     if (GMX_REQUIRE_VALID_TOOLCHAIN)
  86         # Test the generated toolchain file.
  87         set(TEMPDIR "${CMAKE_CURRENT_BINARY_DIR}/cmake-configure-test")
  88         file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/cmake-configure-test)
  89         execute_process(COMMAND
  90                             ${CMAKE_COMMAND}
  91                             -G "${CMAKE_GENERATOR}"
  92                             -DCMAKE_TOOLCHAIN_FILE=${CMAKE_CURRENT_BINARY_DIR}/gromacs-toolchain.cmake
  93                             -DGMX_REQUIRE_VALID_TOOLCHAIN=FALSE
  94                             ${CMAKE_SOURCE_DIR}
  95                         RESULT_VARIABLE result
  96                         OUTPUT_VARIABLE output
  97                         OUTPUT_STRIP_TRAILING_WHITESPACE
  98                         ERROR_VARIABLE output
  99                         ERROR_STRIP_TRAILING_WHITESPACE
 100                         WORKING_DIRECTORY ${TEMPDIR})
 101         if (result)
 102             message(FATAL_ERROR "Generated gromacs-toolchain.cmake does not produce a valid CMake environment: ${output}")
 103         else()
 104             message(STATUS "Verified gromacs-toolchain.cmake")
 105             # We clean up after ourselves
 106             FILE(REMOVE_RECURSE ${TEMPDIR})
 107         endif ()
 108     endif ()
 109
 110     # The configuration files are also installed with the suffix, even though
 111     # the directory already contains the suffix. This allows simple
 112     # find_package(GROMACS NAMES gromacs_d) to find them, without also
 113     # specifying CONFIGS.
 114     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gromacs-config.cmake
 115             DESTINATION ${GMX_INSTALL_CMAKEPKGDIR}
 116             RENAME "gromacs${GMX_LIBS_SUFFIX}-config.cmake"
 117             COMPONENT development)
 118     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gromacs-config-version.cmake
 119             DESTINATION ${GMX_INSTALL_CMAKEPKGDIR}
 120             RENAME "gromacs${GMX_LIBS_SUFFIX}-config-version.cmake"
 121             COMPONENT development)
 122     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gromacs-toolchain.cmake
 123             DESTINATION ${GMX_INSTALL_CMAKEPKGDIR}
 124             RENAME "gromacs-toolchain${GMX_LIBS_SUFFIX}.cmake"
 125             COMPONENT development)
 126 endfunction()
 127
 128 do_pkgconfig()
 129 do_cmake_config()