cmake/BuildManPages.cmake

   1 MACRO(TODAY RESULT)
   2     IF(UNIX)
   3         EXECUTE_PROCESS(COMMAND "date" "+%F" OUTPUT_VARIABLE ${RESULT} OUTPUT_STRIP_TRAILING_WHITESPACE)
   4     ELSE()
   5         set(${RESULT} "????-??-??")
   6     ENDIF()
   7 ENDMACRO(TODAY)
   8
   9 if(GMX_BUILD_MANPAGES)
  10     set(MAN1_PATH ${CMAKE_BINARY_DIR}/man/man1)
  11     file(MAKE_DIRECTORY ${MAN1_PATH})
  12
  13     #create gromacs.7
  14     FILE(READ "${CMAKE_SOURCE_DIR}/admin/programs.txt" contents)
  15
  16     # Convert file contents into a CMake list. First escape ;
  17     STRING(REGEX REPLACE ";" "\\\\;" contents "${contents}")
  18     STRING(REGEX REPLACE "\n" ";" contents "${contents}")
  19
  20     set(PROGMANPAGES "")
  21     foreach(line ${contents})
  22         if (${line} MATCHES "^HEAD\\|")
  23             string(REGEX REPLACE "^HEAD\\|" "" DESC ${line})
  24             set(PROGMANPAGES "${PROGMANPAGES}.Sh \"${DESC}\"\n.IX Subsection \"${DESC}\"\n.Vb\n.ta 16n\n")
  25         elseif(${line} MATCHES "^END$")
  26             set(PROGMANPAGES "${PROGMANPAGES}.Ve\n")
  27         elseif(${line} MATCHES "\\|")
  28             string(REGEX REPLACE "\\|" "\t" line ${line})
  29             set(PROGMANPAGES "${PROGMANPAGES}\\&  ${line}\n")
  30         else()
  31             message(WARNING "Incorrectly formated line \"${line}\" in programs.txt")
  32         endif()
  33     endforeach()
  34     TODAY(TODAYS_DATE)
  35     configure_file(${CMAKE_SOURCE_DIR}/man/man7/gromacs.7.cmakein ${CMAKE_BINARY_DIR}/man/man7/gromacs.7)
  36     install(FILES ${CMAKE_BINARY_DIR}/man/man7/gromacs.7 DESTINATION
  37         ${MAN_INSTALL_DIR}/man7)
  38 endif()
  39
  40 function (gmx_add_man_page EXENAME)
  41     if(GMX_BUILD_MANPAGES)
  42         file(STRINGS ${CMAKE_SOURCE_DIR}/admin/programs.txt DESC
  43             REGEX "^${EXENAME}\\|")
  44         #Regex breaks with a "|" in description. Cmake doesn't support
  45         #non-greedy regex.
  46         string(REGEX REPLACE "^.*\\|" "" DESC "${DESC}")
  47         if(DESC STREQUAL "")
  48             message(WARNING "Missing description for ${EXENAME}")
  49         endif()
  50         add_custom_command(TARGET ${EXENAME} POST_BUILD
  51             #The redirect is a hack to avoid showing copyright.
  52             #Ideally -quiet would also cause programs to not print copyright.
  53             COMMAND ${EXENAME} -quiet -man nroff 2>${EXENAME}.err
  54             COMMAND ${CMAKE_COMMAND} -DINFILE=${EXENAME}${GMX_BINARY_SUFFIX}.nroff
  55                 -DOUTFILE=${MAN1_PATH}/${EXENAME}.1 -DDESC=" - ${DESC}"
  56                 -P ${CMAKE_SOURCE_DIR}/cmake/Filter.cmake)
  57         install(FILES ${MAN1_PATH}/${EXENAME}.1 DESTINATION
  58             ${MAN_INSTALL_DIR}/man1)
  59     endif()
  60 endfunction ()