cmake/gmxTestCompilerProblems.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Macro that runs through a number of tests for buggy compiler
  36 # versions, or other potential problems.
  37 macro(gmx_test_compiler_problems)
  38
  39     # Warn if C and C++ compilers do not match
  40     if(NOT CMAKE_C_COMPILER_ID STREQUAL CMAKE_CXX_COMPILER_ID)
  41         message(WARNING "The ids of the C and C++ compilers do not match (${CMAKE_C_COMPILER_ID} and ${CMAKE_CXX_COMPILER_ID}, respectively). Mixing different C/C++ compilers can cause problems.")
  42     endif()
  43     if(NOT CMAKE_C_COMPILER_VERSION STREQUAL CMAKE_CXX_COMPILER_VERSION)
  44         message(WARNING "The versions of the C and C++ compilers do not match (${CMAKE_C_COMPILER_VERSION} and ${CMAKE_CXX_COMPILER_VERSION}, respectively). Mixing different C/C++ compilers can cause problems.")
  45     endif()
  46
  47     # clang 3.0 is buggy for some unknown reason detected during adding
  48     # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
  49     # that is, we should replace these tests with a compiler feature test,
  50     # update GROMACS Redmine task #1039 and perhaps report a clang bug.
  51     #
  52     # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
  53     # the compiler version for us. So we need a manual check for clang 3.0.
  54     include(gmxDetectClang30)
  55     gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
  56     if(COMPILER_IS_CLANG_3_0)
  57         message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
  58     endif()
  59
  60     # clang <=3.2 contains a bug that causes incorrect code to be generated for the
  61     # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
  62     # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
  63     # We can work around this by not using the integrated assembler (except on OS X
  64     # which has an outdated assembler that does not support AVX instructions).
  65     if (CMAKE_C_COMPILER_ID MATCHES "Clang" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "3.3")
  66         set(GMX_USE_CLANG_C_FMA_BUG_WORKAROUND TRUE)
  67     endif()
  68     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "3.3")
  69         set(GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND TRUE)
  70     endif()
  71
  72     if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
  73         message(WARNING "Currently tested PGI compiler versions (up to 15.7) generate binaries that do not pass all regression test, and the generated binaries are significantly slower than with GCC, ICC or Clang. For now we do not recommend PGI beyond development testing - make sure to run the regressiontests.")
  74     endif()
  75
  76     if(CMAKE_COMPILER_IS_GNUCC AND
  77             (CMAKE_C_COMPILER_VERSION VERSION_LESS "4.9.0" OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  78             AND (WIN32 OR CYGWIN)
  79             AND GMX_SIMD MATCHES "AVX" AND NOT GMX_SIMD STREQUAL AVX_128_FMA)
  80         message(WARNING "GCC on Windows (GCC older than 4.9 or any version when compiling for 64bit) with AVX (other than AVX_128_FMA) crashes. Choose a different GMX_SIMD or a different compiler.") # GCC bug 49001, 54412.
  81     endif()
  82
  83     if(CMAKE_C_COMPILER_ID MATCHES "Clang" AND WIN32)
  84         if(CMAKE_VERSION VERSION_LESS 3.0.0)
  85             message(WARNING "Clang on Windows requires cmake 3.0.0")
  86         endif()
  87         if(CMAKE_C_COMPILER_VERSION VERSION_LESS 3.5.0)
  88             message(WARNING "Clang on Windows requires clang 3.5.0")
  89         endif()
  90     endif()
  91
  92 endmacro(gmx_test_compiler_problems)