cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Currently unused, but we plan to use -Wno-array-bounds
  72         # in Release to work around gcc-4.8 being a little too vocal
  73         # about some perfectly good code, while using RelWithAssert
  74         # (ie. without that suppression) in Jenkins.
  75         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  76
  77         # Modify the real CMake variables for compiler flags for all
  78         # builds and language types, and also those common to all
  79         # build types.
  80         foreach(build_type "" ${build_types_with_explicit_flags})
  81             if("${build_type}" STREQUAL "")
  82                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  83             else()
  84                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  85             endif()
  86
  87             # Append to the variables for the given build type for
  88             # each language, in the parent scope. We add our new variables at the end, so
  89             # compiler-specific choices are more likely to override default CMake choices.
  90             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  91             # set of our optimization flags detected in this file, rather than having -O2 override them.
  92             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  93                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  94                 PARENT_SCOPE)
  95         endforeach()
  96     endforeach()
  97 endfunction()
  98
  99 # This is the actual exported function to be called
 100 MACRO(gmx_c_flags)
 101
 102     include(CheckCCompilerFlag)
 103     include(CheckCXXCompilerFlag)
 104
 105     # gcc
 106     if(CMAKE_COMPILER_IS_GNUCC)
 107         #flags are added in reverse order and -Wno* need to appear after -Wall
 108         if(NOT GMX_OPENMP)
 109             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 110         endif()
 111         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 112         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 113         if(NOT GMX_GPU) #TODO: Fix that CUDA code has warnings
 114             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 115         endif()
 116         # Since 4.8 on by default. For previous version disabling is a no-op. Only disabling for Release because with assert
 117         # the warnings are OK.
 118         GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 119         if(CYGWIN)
 120             GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 121         endif()
 122         # new in gcc 4.5
 123         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 124         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 125                        GMXC_CFLAGS_RELEASE)
 126         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 127     endif()
 128     # g++
 129     if(CMAKE_COMPILER_IS_GNUCXX)
 130         if(NOT GMX_OPENMP)
 131             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 132         endif()
 133         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 134         # Problematic with CUDA
 135         # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 136         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 137         if(NOT GMX_GPU)
 138             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 139         endif()
 140         GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 141         # new in gcc 4.5
 142         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 143         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 144                          GMXC_CXXFLAGS_RELEASE)
 145         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 146     endif()
 147
 148     # icc
 149     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 150         if (NOT WIN32)
 151             if(NOT GMX_OPENMP)
 152                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 153 # 3180: unrecognized OpenMP #pragma
 154                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 155                 else()
 156 # 161: unrecognized #pragma
 157                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd161" GMXC_CFLAGS)
 158                 endif()
 159             endif()
 160             if(CMAKE_C_COMPILER_VERSION VERSION_LESS 15.00.00)
 161 # 193: zero used for undefined preprocessing identifier ".."
 162                 GMX_TEST_CFLAG(CFLAGS_WARN_OLD -wd193 GMXC_CFLAGS)
 163             endif()
 164 # 177: function/variable ".." was declared but never referenced
 165 # 271: trailing comma is nonstandard
 166 # 304: access control not specified ("public" by default)
 167 # 383: value copied to temporary, reference to temporary used
 168 # 424: extra ";" ignored
 169 # 444: destructor for base class ".." is not virtual
 170 # 522: function ".." redeclared "inline" after being called
 171 # 593: variable ".." was set but never used
 172 # 869: parameter ".." was never referenced
 173 # 981: operands are evaluated in unspecified order
 174 #1418: external function definition with no prior declaration
 175 #1419: external declaration in primary source file
 176 #1572: floating-point equality and inequality comparisons are unreliable
 177 #1599: declaration hides variable ".."
 178 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 179 #2415: variable ".." of static storage duration was declared but never referenced
 180 #2547: ".." was specified as both a system and non-system include directory
 181 #2557: comparison between signed and unsigned operands
 182 #3280: declaration hides member ".."
 183 #3346: dynamic exception specifications are deprecated
 184 #11074: Inlining inhibited by limit max-size(/max-total-size)
 185 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 186             GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd177 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076" GMXC_CFLAGS)
 187             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 188             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CFLAGS_RELEASE)
 189             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 190             GMX_TEST_CFLAG(CFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CFLAGS_RELWITHASSERT)
 191         else()
 192             if(NOT GMX_OPENMP)
 193                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 194                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 195                 else()
 196                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd161" GMXC_CFLAGS)
 197                 endif()
 198             endif()
 199             if(CMAKE_C_COMPILER_VERSION VERSION_LESS 15.00.00)
 200                 GMX_TEST_CFLAG(CFLAGS_WARN_OLD /wd193 GMXC_CFLAGS)
 201             endif()
 202             GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd177 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346" GMXC_CFLAGS)
 203             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 204         endif()
 205     endif()
 206
 207     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 208         if (NOT WIN32)
 209             if(NOT GMX_OPENMP)
 210                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 211                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 212                 else()
 213                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd161" GMXC_CXXFLAGS)
 214                 endif()
 215             endif()
 216             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 15.00.00)
 217                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_OLD -wd193 GMXC_CXXFLAGS)
 218             endif()
 219 #All but the following warnings are identical for the C-compiler (see above)
 220 #1782: #pragma once is obsolete
 221 #2282: unrecognized GCC pragma
 222             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd177 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076 -wd1782 -wd2282" GMXC_CXXFLAGS)
 223             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CXXFLAGS_RELEASE)
 224             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 225             GMX_TEST_CXXFLAG(CXXFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CXXFLAGS_RELWITHASSERT)
 226         else()
 227             if(NOT GMX_OPENMP)
 228                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 229                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 230                 else()
 231                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd161" GMXC_CXXFLAGS)
 232                 endif()
 233             endif()
 234             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 15.00.00)
 235                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_OLD /wd193 GMXC_CXXFLAGS)
 236             endif()
 237             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd177 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346 /wd1782 /wd2282" GMXC_CXXFLAGS)
 238             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 239         endif()
 240     endif()
 241
 242     # PGI
 243     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 244     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 245         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 246     endif()
 247     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 248         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 249     endif()
 250
 251     # Pathscale
 252     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 253         if(NOT GMX_OPENMP)
 254             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 255         endif()
 256         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 257         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 258                          GMXC_CFLAGS_RELEASE)
 259         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 260     endif()
 261     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 262         if(NOT GMX_OPENMP)
 263             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 264         endif()
 265         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 266         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 267                          GMXC_CXXFLAGS_RELEASE)
 268     endif()
 269
 270     # xlc
 271     # The suppressions below stop
 272     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 273     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 274     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 275     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 276         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 277         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 278         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 279         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CFLAGS)
 280     endif()
 281     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 282         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 283         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 284         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CXXFLAGS)
 285     endif()
 286
 287     # msvc
 288     if (MSVC)
 289         # disable warnings for:
 290         #      forcing value to bool
 291         #      "this" in initializer list
 292         #      deprecated (posix, secure) functions
 293         #      truncation (double -> float)
 294         #      conversion from 'double' to 'real', possible loss of data
 295         #      unreferenced local variable (only C)
 296         #      conversion from 'size_t' to 'int', possible loss of data
 297         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 298         if(NOT CMAKE_CONFIGURATION_TYPES)
 299             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CFLAGS)
 300             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267" GMXC_CXXFLAGS)
 301         else() #Projects only use the C++ flags
 302             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CXXFLAGS)
 303         endif()
 304     endif()
 305
 306     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 307         if(NOT GMX_OPENMP)
 308             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 309         endif()
 310         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 311         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 312     endif()
 313
 314     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 315         if(NOT GMX_OPENMP)
 316             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 317         endif()
 318         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 319         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 320     endif()
 321
 322     # Fujitsu compilers on PrimeHPC/Sparc64
 323     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 324        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 325         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 326         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 327     endif()
 328
 329     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 330        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 331         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 332         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 333     endif()
 334
 335     # now actually set the flags:
 336     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 337         gmx_set_cmake_compiler_flags()
 338     endif()
 339 ENDMACRO(gmx_c_flags)
 340