CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5-beta3"
   8     CACHE STRING "Gromacs version string")
   9
  10 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  11 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  12
  13 if(NOT CMAKE_BUILD_TYPE)
  14     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  15 endif(NOT CMAKE_BUILD_TYPE)
  16
  17 enable_language(C)
  18
  19 ########################################################################
  20 # Fix stupid flags on MSVC
  21 ########################################################################
  22 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  23     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  24     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  25     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  26     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  27 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  28
  29 set(GMX_EXTRA_LIBRARIES)
  30
  31 ######################################################################
  32 # compiler tests
  33 # these need ot be done early (before further tests).
  34 #####################################################################
  35
  36 include(CheckCCompilerFlag)
  37 include(CheckCXXCompilerFlag)
  38
  39 include(gmxCFlags)
  40 gmx_c_flags()
  41
  42 ########################################################################
  43 # User input options                                                   #
  44 ########################################################################
  45 option(GMX_DOUBLE "Use double precision" OFF)
  46 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  47 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS)" ON)
  48 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  49 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  50 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  51 set(GMX_ACCELERATION "auto"
  52     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  53
  54 set(GMX_FFT_LIBRARY "fftw3"
  55     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  56 option(GMX_DISABLE_FFTW_MEASURE
  57        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  58 set(GMX_QMMM_PROGRAM "none"
  59     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  60 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  61 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  62 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  63 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  64 mark_as_advanced(GMX_MPI_IN_PLACE)
  65
  66
  67 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  68 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  69
  70 option(USE_VERSION_H "Generate development version string/information" ON)
  71 # --- REMOVED as bugzilla 431 turned out to be a bug in GB
  72 # and there is no confirmed case in which gcc causes a crash
  73 # option(GMX_DISABLE_GCC41_CHECK "Disable check for (buggy) gcc 4.1.x" OFF)
  74
  75 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries.")
  76
  77
  78
  79 ########################################################################
  80 #Process MPI settings
  81 ########################################################################
  82 if(GMX_MPI)
  83     if(GMX_THREADS)
  84         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  85         set(GMX_THREADS OFF CACHE BOOL
  86             "Thread-based parallelization conflicts with MPI." FORCE)
  87     endif(GMX_THREADS)
  88     find_package(MPI)
  89     if(MPI_FOUND)
  90         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  91         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  92
  93         include_directories(${MPI_INCLUDE_PATH})
  94         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  95         add_definitions( -DMPI ) #for FAHCORE
  96         include(gmxTestMPI_IN_PLACE)
  97         if (GMX_MPI_IN_PLACE)
  98             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  99         endif (GMX_MPI_IN_PLACE)
 100     else(MPI_FOUND)
 101         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 102     endif(MPI_FOUND)
 103     include(gmxTestCatamount)
 104     gmx_test_catamount(GMX_CRAY_XT3)
 105     if(GMX_CRAY_XT3)
 106         set(GMX_NO_SYSTEM 1)
 107         set(GMX_NO_NICE 1)
 108     endif(GMX_CRAY_XT3)
 109     set(GMX_LIB_MPI 1)
 110 endif(GMX_MPI)
 111
 112
 113 #######################################################################
 114 # Check for options incompatible with OpenMM build                    #
 115 #######################################################################
 116 if(GMX_OPENMM)
 117     cmake_minimum_required(VERSION 2.6.4)
 118     # we'll use the built-in fft to avoid unnecessary dependencies
 119     set (GMX_FFT_LIBRARY "fftpack")
 120     if(GMX_MPI)
 121         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 122     endif(GMX_MPI)
 123     if(GMX_THREADS)
 124         message(STATUS "Threads not compatible with OpenMM build, disabled")
 125         set(GMX_THREADS OFF)
 126     endif(GMX_THREADS)
 127     if(GMX_SOFTWARE_INVSQRT)
 128         set(GMX_SOFTWARE_INVSQRT OFF)
 129     endif(GMX_SOFTWARE_INVSQRT)
 130     if(NOT GMX_ACCELERATION MATCHES "auto|none|None|NONE" OR NOT ${GMX_ACCELERATION} STREQUAL "")
 131         message(WARNING "The OpenMM build does not support other acceleration modes!")
 132         set(GMX_ACCELERATION "none")
 133     endif()
 134     if(GMX_FAHCORE)
 135         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 136     endif(GMX_FAHCORE)
 137 endif(GMX_OPENMM)
 138
 139
 140
 141 ########################################################################
 142 # Basic system tests (standard libraries, headers, functions, types)   #
 143 ########################################################################
 144 include(CheckIncludeFiles)
 145 check_include_files(string.h     HAVE_STRING_H)
 146 check_include_files(math.h       HAVE_MATH_H)
 147 check_include_files(limits.h     HAVE_LIMITS_H)
 148 check_include_files(memory.h     HAVE_MEMORY_H)
 149 check_include_files(unistd.h     HAVE_UNISTD_H)
 150 check_include_files(pwd.h        HAVE_PWD_H)
 151 check_include_files(stdint.h     HAVE_STDINT_H)
 152 check_include_files(stdlib.h     HAVE_STDLIB_H)
 153 check_include_files(pthread.h    HAVE_PTHREAD_H)
 154 check_include_files(dirent.h     HAVE_DIRENT_H)
 155 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 156 check_include_files(regex.h      HAVE_REGEX_H)
 157 check_include_files(copyfile.h   HAVE_COPYFILE_H)
 158 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 159 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 160 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 161 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 162 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 163 # SSE support
 164 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 165 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 166 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 167 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 168 check_include_files(io.h                 HAVE_IO_H)
 169
 170
 171 include(CheckFunctionExists)
 172 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 173 check_function_exists(strdup            HAVE_STRDUP)
 174 check_function_exists(vprintf           HAVE_VPRINTF)
 175 check_function_exists(memcmp            HAVE_MEMCMP)
 176 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 177 check_function_exists(memalign          HAVE_MEMALIGN)
 178 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 179 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 180 check_function_exists(isnan             HAVE_ISNAN)
 181 check_function_exists(_isnan            HAVE__ISNAN)
 182 check_function_exists(isfinite          HAVE_ISFINITE)
 183 check_function_exists(_isfinite         HAVE__ISFINITE)
 184 check_function_exists(fsync             HAVE_FSYNC)
 185 check_function_exists(_fileno           HAVE__FILENO)
 186 check_function_exists(fileno            HAVE_FILENO)
 187 check_function_exists(_commit           HAVE__COMMIT)
 188 check_function_exists(copyfile          HAVE_COPYFILE)
 189 # check_function_exists(CopyFile          HAVE_WIN_COPYFILE)
 190 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 191
 192 include(CheckLibraryExists)
 193 check_library_exists(m sqrt "" HAVE_LIBM)
 194 check_library_exists(m cbrt "" HAVE_CBRT)
 195
 196 include(CheckTypeSize)
 197 set(CMAKE_REQUIRED_FLAGS ${CMAKE_C_FLAGS_RELEASE})
 198
 199 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 200 check_type_size("int"           SIZEOF_INT)
 201 check_type_size("long int"      SIZEOF_LONG_INT)
 202 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 203 check_type_size("off_t"         SIZEOF_OFF_T)
 204 check_type_size("void *"        SIZEOF_VOIDP)
 205
 206 if (SIZEOF_VOIDP LESS 8)
 207     set(GMX_64_BIT FALSE)
 208 else (SIZEOF_VOIDP LESS 8)
 209     set(GMX_64_BIT TRUE)
 210 endif (SIZEOF_VOIDP LESS 8)
 211
 212 # Check for some basic types that we *need*, so set these to int if they are not present
 213 check_type_size(uid_t uid_t)
 214 if(NOT uid_t)
 215   set(uid_t int)
 216 else(NOT uid_t)
 217   set(uid_t 0)
 218 endif(NOT uid_t)
 219
 220 check_type_size(gid_t gid_t)
 221 if(NOT gid_t)
 222   set(gid_t 1)
 223 else(NOT gid_t)
 224   set(gid_t 0)
 225 endif(NOT gid_t)
 226
 227 check_type_size(size_t size_t)
 228 if(NOT size_t)
 229   set(size_t int)
 230 else(NOT size_t)
 231   set(size_t 0)
 232 endif(NOT size_t)
 233
 234 check_type_size(off_t off_t)
 235 if(NOT off_t)
 236   set(off_t int)
 237 else(NOT off_t)
 238   set(off_t 0)
 239 endif(NOT off_t)
 240
 241 include(TestBigEndian)
 242 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 243
 244
 245
 246
 247 ########################################################################
 248 # Find external packages                                               #
 249 ########################################################################
 250
 251 find_package(LibXml2)
 252 set(PKG_XML "")
 253 if(LIBXML2_FOUND)
 254     include_directories(${LIBXML2_INCLUDE_DIR})
 255     set(PKG_XML libxml-2.0)
 256     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 257     set(HAVE_LIBXML2 1)
 258 endif(LIBXML2_FOUND)
 259
 260 find_package(X11)
 261 # X11 includes/libraries are only set in the ngmx subdirectory!
 262 if(X11_FOUND)
 263     set(HAVE_X11 1)
 264 endif(X11_FOUND)
 265
 266 if(GMX_THREADS)
 267     include(ThreadMPI)
 268     set(THREAD_MPI_LIB thread_mpi)
 269     set(GMX_MPI 1)
 270     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 271     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 272         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 273     endif()
 274 endif(GMX_THREADS)
 275
 276 if(GMX_OPENMM)
 277     set(CUDA_BUILD_EMULATION OFF)
 278     find_package(CUDA 3.1 REQUIRED)
 279     add_definitions(-DGMX_OPENMM)
 280     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 281         set(CUDA_VERBOSE_BUILD ON)
 282     endif()
 283     find_package(OpenMM)
 284 endif(GMX_OPENMM)
 285
 286 if(APPLE)
 287    find_library(ACCELERATE_FRAMEWORK Accelerate)
 288    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 289 endif(APPLE)
 290
 291 # only bother with finding git and using version.h if the source is a git repo
 292 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 293     if(USE_VERSION_H)
 294         # We need at least git v1.5.1 be able to parse git's date output. If not
 295         # fund or the version is too small, we can't generate version information.
 296         find_package(Git 1.5.1)
 297         # this should at some point become VERSION_LESS
 298         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 299             message("No compatible git version found, won't be able to generate proper development version information.")
 300         endif()
 301     endif()
 302 else()
 303     set(USE_VERSION_H OFF)
 304 endif()
 305
 306 if (GMX_DLOPEN)
 307     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 308 endif (GMX_DLOPEN)
 309
 310 ########################################################################
 311 # Generate development version info for cache
 312 ########################################################################
 313 # set(GEN_VERSION_INFO_INTERNAL "ON")
 314 # include(gmxGenerateVersionString)
 315
 316 ########################################################################
 317 # Our own GROMACS tests
 318 ########################################################################
 319
 320 add_definitions( -DHAVE_CONFIG_H )
 321 include_directories(${CMAKE_BINARY_DIR}/src)
 322 include_directories(${CMAKE_SOURCE_DIR}/include)
 323
 324 include(gmxCheckBuildUserTime)
 325 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 326
 327 include(gmxTestFloatFormat)
 328 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 329                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 330                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 331
 332 include(gmxTestLargeFiles)
 333 gmx_test_large_files(GMX_LARGEFILES)
 334
 335 include(gmxTestSignal)
 336 gmx_test_retsigtype(RETSIGTYPE)
 337
 338 include(gmxTestInline)
 339 gmx_test_inline(INLINE_KEYWORD)
 340
 341 include(gmxTestRestrict)
 342 gmx_test_inline(RESTRICT_KEYWORD)
 343
 344 include(gmxTestPipes)
 345 gmx_test_pipes(HAVE_PIPES)
 346
 347 include(gmxTestInlineASM)
 348 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 349 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 350
 351 # turn on SSE if supported with reasonable defaults.
 352 if (${GMX_ACCELERATION} STREQUAL "auto")
 353     if (GMX_X86_GCC_INLINE_ASM)
 354         set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 355         if (GMX_64_BIT)
 356             set(GMX_X86_64_ASM ON CACHE BOOL
 357                 "Add SSE assembly files for x86_64" FORCE)
 358         else (GMX_64_BIT)
 359             set(GMX_IA32_ASM ON CACHE BOOL
 360                 "Add SSE assembly files for IA32" FORCE)
 361         endif (GMX_64_BIT)
 362     else(GMX_X86_GCC_INLINE_ASM)
 363       set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 364     endif (GMX_X86_GCC_INLINE_ASM)
 365 endif (${GMX_ACCELERATION} STREQUAL "auto")
 366
 367
 368
 369
 370 include(gmxTestXDR)
 371 gmx_test_xdr(GMX_SYSTEM_XDR)
 372 if(NOT GMX_SYSTEM_XDR)
 373     set(GMX_INTERNAL_XDR 1)
 374 endif(NOT GMX_SYSTEM_XDR)
 375
 376 if(GMX_FORTRAN OR GMX_POWER6)
 377     enable_language(Fortran)
 378     include(FortranCInterface)
 379     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 380     if(extra_under_score)
 381         set(extrasuffix "_")
 382     endif(extra_under_score)
 383
 384     if(isupper)
 385         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 386         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 387     else(isupper)
 388         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 389         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 390     endif(isupper)
 391 else(GMX_FORTRAN OR GMX_POWER6)
 392         set(F77_FUNCDEF   "name ## _")
 393         set(F77_FUNCDEF_  "name ## _")
 394 endif(GMX_FORTRAN OR GMX_POWER6)
 395
 396
 397 # Process nonbonded accelerated kernels settings
 398 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 399 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 400 if(${GMX_ACCELERATION} STREQUAL "NONE")
 401   # nothing to do
 402 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 403     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 404       option(GMX_ASM_USEASM-NASM "Use the Nasm assembler (windows)" ON)
 405     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 406       option(GMX_ASM_USEASM-NASM "Use the Nasm assembler (windows)" OFF)
 407     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 408     if (NOT GMX_64_BIT)
 409         # for 32-bit compiles, we might need to turn on sse
 410         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 411         if (XFLAGS_SSE)
 412             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 413         endif (XFLAGS_SSE)
 414         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 415         if (XXFLAGS_SSE)
 416             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 417         endif (XXFLAGS_SSE)
 418     endif (NOT GMX_64_BIT)
 419     if(HAVE_XMMINTRIN_H)
 420         if(GMX_IA32_ASM)
 421           if(GMX_DOUBLE)
 422             set(GMX_IA32_SSE2 1)
 423           else(GMX_DOUBLE)
 424             set(GMX_IA32_SSE 1)
 425           endif(GMX_DOUBLE)
 426         else(GMX_IA32_ASM)
 427           set(GMX_SSE 1)
 428         endif(GMX_IA32_ASM)
 429     endif(HAVE_XMMINTRIN_H)
 430     if(HAVE_EMMINTRIN_H)
 431         if(GMX_X86_64_ASM)
 432           if(GMX_DOUBLE)
 433             set(GMX_X86_64_SSE2 1)
 434           else(GMX_DOUBLE)
 435             set(GMX_X86_64_SSE 1)
 436           endif(GMX_DOUBLE)
 437         else(GMX_X86_64_ASM)
 438           if(NOT GMX_IA32_ASM)
 439             set(GMX_SSE2 1)
 440           endif(NOT GMX_IA32_ASM)
 441         endif(GMX_X86_64_ASM)
 442     endif(HAVE_EMMINTRIN_H)
 443 #    if(HAVE_PMMINTRIN_H)
 444 #        set(GMX_SSE3 1)
 445 #    endif(HAVE_PMMINTRIN_H)
 446 #    if(HAVE_SMMINTRIN_H)
 447 #        set(GMX_SSE4_1 1)
 448 #    endif(HAVE_SMMINTRIN_H)
 449
 450 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 451     set(GMX_FORTRAN 1)
 452 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 453     set(GMX_BLUEGENE 1)
 454 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 455     set(GMX_POWER6 1)
 456 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 457     set(GMX_IA64_ASM 1)
 458     set(DISABLE_WATERWATER_NLIST 1)
 459     set(DISABLE_WATER_NLIST 1)
 460 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 461     check_include_files(altivec.h HAVE_ALTIVEC_H)
 462     if(HAVE_ALTIVEC_H)
 463         set(GMX_PPC_ALTIVEC 1)
 464     endif(HAVE_ALTIVEC_H)
 465 else(${GMX_ACCELERATION} STREQUAL "NONE")
 466     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 467 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 468
 469
 470
 471
 472
 473
 474
 475 # Process QM/MM Settings
 476 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 477 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 478     set(GMX_QMMM_GAUSSIAN 1)
 479 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 480     set(GMX_QMMM_MOPAC 1)
 481 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 482     set(GMX_QMMM_GAMESS 1)
 483 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 484     set(GMX_QMMM_ORCA 1)
 485 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 486     # nothing to do
 487 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 488     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 489 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 490
 491 # Process FFT library settings - if not OpenMM build
 492 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 493 set(PKG_FFT "")
 494 set(PKG_FFT_LIBS "")
 495 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 496 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 497     if(GMX_DOUBLE)
 498         find_package(FFTW3 REQUIRED)
 499         include_directories(${FFTW3_INCLUDE_DIR})
 500         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 501         set(PKG_FFT "fftw3")
 502     else(GMX_DOUBLE)
 503         find_package(FFTW3F REQUIRED)
 504         include_directories(${FFTW3F_INCLUDE_DIR})
 505         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 506         set(PKG_FFT "fftw3f")
 507     endif(GMX_DOUBLE)
 508
 509     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 510         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 511     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 512
 513     set(GMX_FFT_FFTW3 1)
 514
 515     include_directories(${FFTW3_INCLUDE_DIR})
 516     set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 517
 518 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 519 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 520     if(GMX_DOUBLE)
 521         find_package(FFTW2 REQUIRED)
 522     else(GMX_DOUBLE)
 523         find_package(FFTW2F REQUIRED)
 524     endif(GMX_DOUBLE)
 525
 526     if(NOT FFTW2_FOUND)
 527            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 528     endif(NOT FFTW2_FOUND)
 529     include_directories(${FFTW2_INCLUDE_DIR})
 530     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 531     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 532
 533     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 534         set(FFTW2_NAME_DFFTW 1)
 535     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 536         set(FFTW2_NAME_SFFTW 1)
 537     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 538         set(FFTW2_NAME_FFTW 1)
 539     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 540
 541     set(GMX_FFT_FFTW2 1)
 542 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 543 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 544     find_package(MKL REQUIRED)
 545     include_directories(${MKL_INCLUDE_DIR})
 546     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 547     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 548
 549     set(GMX_FFT_MKL 1)
 550     set(HAVE_MKL 1)
 551
 552 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 553 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 554 #    set(GMX_FFT_ACML 1)
 555 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 556     MESSAGE(STATUS "Using internal FFT library - fftpack")
 557     set(GMX_FFT_FFTPACK 1)
 558 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 559     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 560 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 561
 562 # MKL has BLAS/LAPACK routines
 563 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 564   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 565   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 566 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 567   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 568   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 569 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 570
 571 # Math and thread libraries must often come after all others when linking...
 572 if(HAVE_LIBM)
 573     list(APPEND GMX_EXTRA_LIBRARIES m)
 574 endif(HAVE_LIBM)
 575
 576
 577
 578 if(GMX_FAHCORE)
 579   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 580       "Path to swindirect.h")
 581   include_directories(${COREWRAP_INCLUDE_DIR})
 582 endif(GMX_FAHCORE)
 583
 584 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 585 # these are set after everything else
 586 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 587     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 588         FORCE)
 589     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 590         "Flags used by the compiler during all build types" FORCE)
 591     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 592         "Flags used by the compiler during all build types" FORCE)
 593     set(CMAKE_EXE_LINKER_FLAGS
 594         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 595         CACHE STRING "Linker flags" FORCE)
 596 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 597
 598 ########################################################################
 599 # Specify install locations and which subdirectories to process        #
 600 ########################################################################
 601 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 602 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 603 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 604 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 605 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 606
 607 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 608
 609
 610 add_subdirectory(share)
 611 add_subdirectory(include)
 612 add_subdirectory(man)
 613
 614 add_subdirectory(src)
 615
 616 #######################
 617 ## uninstall target
 618 #######################
 619     CONFIGURE_FILE(
 620                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 621                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 622                    IMMEDIATE @ONLY)
 623 ###########################
 624 ADD_CUSTOM_TARGET(uninstall
 625                   "${CMAKE_COMMAND}" -P
 626                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 627 ###########################
 628
 629
 630 ########################################################################
 631 # Tests                                                                #
 632 ########################################################################
 633
 634 enable_testing()
 635 add_test(TestBuildAll make)
 636
 637 add_subdirectory(tests)