docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68
  69
  70 if (NOT ${PYTHON_VERSION_MAJOR} EQUAL 3)
  71     find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  72 else()
  73     MESSAGE(STATUS "Can not build documentation with Python 3")
  74 endif()
  75
  76 # Even if we aren't going to make the full webpage, set up to put all
  77 # the documentation output in the same place, for convenience
  78 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  79 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  80
  81 # Prepare directories for pdf/tex output
  82 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  83 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  84 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  85
  86 # The directory from which man pages will be installed; if it remains
  87 # empty, they will be silently skipped.
  88 set(MAN_PAGE_DIR)
  89 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  90     # When building from the tarball, install the bundled man pages
  91     # (unless overridden).
  92     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 endif()
  94
  95 add_subdirectory(doxygen)
  96
  97 # TODO: Consider whether this could just be replaced by using
  98 # GMX_DEVELOPER_BUILD to control this as well.
  99 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 100 mark_as_advanced(GMX_BUILD_MANUAL)
 101
 102 set(MANUAL_BUILD_IS_POSSIBLE ON)
 103 set(MANUAL_BUILD_NOT_POSSIBLE_REASON)
 104 set(NO_IMAGE_CONVERT_REASON)
 105 if (NOT GMX_BUILD_MANUAL)
 106     # Make sure we only do detection of manual-building dependencies
 107     # when the user opted in for that.
 108     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 109     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "GMX_BUILD_MANUAL is not ON")
 110 elseif (BUILD_IS_INSOURCE)
 111     # UseLATEX.cmake does not work with an in-source build
 112     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 113     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "the build is in-source")
 114 else()
 115     include(manual/UseLATEX.cmake)
 116     if(${PYTHON_VERSION_MAJOR} EQUAL 3)
 117         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 118         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "We can not build the documentation when using python3")
 119     elseif(NOT SPHINX_FOUND)
 120         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 121         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx has not been found and is needed to create the LaTex input files")
 122     elseif(NOT PDFLATEX_COMPILER)
 123         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 124         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "pdflatex is not available")
 125     elseif(NOT IMAGE_CONVERT_POSSIBLE)
 126         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 127         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "a working form of ImageMagick convert is not available")
 128         set(NO_IMAGE_CONVERT_REASON "Can not convert files for online or pdf manual")
 129         # TODO Later, identify other dependencies like bibtex,
 130         # make_index, date, some graphics conversion program,
 131         # etc. Perhaps patch UseLATEX.cmake and contribute upstream.
 132     endif()
 133
 134 endif()
 135
 136 if (SPHINX_FOUND)
 137     # We need to have all the Sphinx input files in a single directory, and
 138     # since some of them are generated, we copy everything into the build tree,
 139     # to this directory.
 140     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
 141     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 142     # As the manual build now depends also on Sphinx, the inclusion path needs
 143     # to be set after we know the basic information for Sphinx.
 144     add_subdirectory(manual)
 145     if (SOURCE_MD5SUM STREQUAL "unknown")
 146         # But for testing the webpage build (e.g. from the repo) we
 147         # need a default value.
 148         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 149     else()
 150         # The real build of the webpage happens from the tarball, and
 151         # this should be set to the matching MD5 sum.
 152         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 153     endif()
 154     # The reference manual still contains the individual sections from the
 155     # LaTeX document, with the files below grouped and annotated by chapter.
 156     set(REFERENCEMANUAL_SPHINX_FILES_GENERAL
 157         # Main index file, preface and introduction.
 158         reference-manual/index.rst
 159         reference-manual/preface.rst
 160         reference-manual/introduction.rst
 161         # Definitions and Units chapter
 162         reference-manual/definitions.rst
 163         # Topologies chapter
 164         reference-manual/topologies.rst
 165         reference-manual/topologies/particle-type.rst
 166         reference-manual/topologies/parameter-files.rst
 167         reference-manual/topologies/molecule-definition.rst
 168         reference-manual/topologies/constraint-algorithm-section.rst
 169         reference-manual/topologies/pdb2gmx-input-files.rst
 170         reference-manual/topologies/topology-file-formats.rst
 171         reference-manual/topologies/force-field-organization.rst
 172         # File formats chapter
 173         reference-manual/file-formats.rst
 174         # Run parameters and programs chapter
 175         reference-manual/run-parameters.rst
 176         # Implementation details chapter
 177         reference-manual/details.rst
 178         # Averages and fluctations chapter
 179         reference-manual/averages.rst
 180         # References
 181         reference-manual/references.rst
 182         # PNG formated plot files that don't need to be converted into PNG
 183         # for the web page.
 184         reference-manual/plots/peregrine.png
 185         reference-manual/plots/adress.png
 186         reference-manual/plots/plotje.png
 187         reference-manual/plots/xvgr.png
 188         )
 189     set(REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES
 190         # Algorithms chapter
 191         reference-manual/algorithms.rst
 192         reference-manual/algorithms/periodic-boundary-conditions.rst
 193         reference-manual/algorithms/group-concept.rst
 194         reference-manual/algorithms/molecular-dynamics.rst
 195         reference-manual/algorithms/shell-molecular-dynamics.rst
 196         reference-manual/algorithms/constraint-algorithms.rst
 197         reference-manual/algorithms/simulated-annealing.rst
 198         reference-manual/algorithms/stochastic-dynamics.rst
 199         reference-manual/algorithms/brownian-dynamics.rst
 200         reference-manual/algorithms/energy-minimization.rst
 201         reference-manual/algorithms/normal-mode-analysis.rst
 202         reference-manual/algorithms/free-energy-calculations.rst
 203         reference-manual/algorithms/replica-exchange.rst
 204         reference-manual/algorithms/essential-dynamics.rst
 205         reference-manual/algorithms/expanded-ensemble.rst
 206         reference-manual/algorithms/parallelization-domain-decomp.rst
 207         # Interaction functions and force fields chapter
 208         reference-manual/functions.rst
 209         reference-manual/functions/bonded-interactions.rst
 210         reference-manual/functions/force-field.rst
 211         reference-manual/functions/free-energy-interactions.rst
 212         reference-manual/functions/interaction-methods.rst
 213         reference-manual/functions/long-range-electrostatics.rst
 214         reference-manual/functions/long-range-vdw.rst
 215         reference-manual/functions/nonbonded-interactions.rst
 216         reference-manual/functions/polarization.rst
 217         reference-manual/functions/restraints.rst
 218         # Special topics chapter
 219         reference-manual/special.rst
 220         reference-manual/special/free-energy-implementation.rst
 221         reference-manual/special/pulling.rst
 222         reference-manual/special/awh.rst
 223         reference-manual/special/enforced-rotation.rst
 224         reference-manual/special/electric-fields.rst
 225         reference-manual/special/comp-electrophys.rst
 226         reference-manual/special/free-energy-pmf.rst
 227         reference-manual/special/remove-fast-dgf.rst
 228         reference-manual/special/viscosity-calculation.rst
 229         reference-manual/special/tabulated-interaction-functions.rst
 230         reference-manual/special/qmmm.rst
 231         reference-manual/special/vmd-imd.rst
 232         reference-manual/special/membrane-embedding.rst
 233         reference-manual/special/mimic-qmmm.rst
 234         # Analysis chapter
 235         reference-manual/analysis.rst
 236         reference-manual/analysis/using-groups.rst
 237         reference-manual/analysis/looking-at-trajectory.rst
 238         reference-manual/analysis/general-properties.rst
 239         reference-manual/analysis/radial-distribution-function.rst
 240         reference-manual/analysis/correlation-function.rst
 241         reference-manual/analysis/curve-fitting.rst
 242         reference-manual/analysis/mean-square-displacement.rst
 243         reference-manual/analysis/bond-angle-dihedral.rst
 244         reference-manual/analysis/radius-of-gyration.rst
 245         reference-manual/analysis/rmsd.rst
 246         reference-manual/analysis/covariance-analysis.rst
 247         reference-manual/analysis/dihedral-pca.rst
 248         reference-manual/analysis/protein-related.rst
 249         reference-manual/analysis/interface-related.rst)
 250     # The image files have also been ordered by the respective
 251     # chapter they are included in in the reference manual
 252     set(REFERENCEMANUAL_IMAGE_FILES
 253         # General folder
 254         reference-manual/plots/decomp.pdf
 255         reference-manual/plots/dih.pdf
 256         reference-manual/plots/drift-all.pdf
 257         reference-manual/plots/f-angle.pdf
 258         reference-manual/plots/f-bond.pdf
 259         reference-manual/plots/fp-highres.pdf
 260         reference-manual/plots/int-mat.pdf
 261         reference-manual/plots/mdpar.pdf
 262         reference-manual/plots/parsort.pdf
 263         reference-manual/plots/ring.pdf
 264         reference-manual/plots/shiftf.pdf
 265         # Algorithms chapter
 266         reference-manual/algorithms/plots/dd-cells.pdf
 267         reference-manual/algorithms/plots/dd-tric.pdf
 268         reference-manual/algorithms/plots/flowchart.pdf
 269         reference-manual/algorithms/plots/free1.pdf
 270         reference-manual/algorithms/plots/free2.pdf
 271         reference-manual/algorithms/plots/leapfrog.pdf
 272         reference-manual/algorithms/plots/lincs.pdf
 273         reference-manual/algorithms/plots/maxwell.pdf
 274         reference-manual/algorithms/plots/mpmd-pme.pdf
 275         reference-manual/algorithms/plots/nstric.pdf
 276         reference-manual/algorithms/plots/par-lincs2.pdf
 277         reference-manual/algorithms/plots/pbctric.pdf
 278         reference-manual/algorithms/plots/rhododec.pdf
 279         reference-manual/algorithms/plots/truncoct.pdf
 280         reference-manual/algorithms/plots/verlet-drift.pdf
 281         # Interaction functions chapter
 282         reference-manual/functions/plots/angle.pdf
 283         reference-manual/functions/plots/bstretch.pdf
 284         reference-manual/functions/plots/chain.pdf
 285         reference-manual/functions/plots/dummies.pdf
 286         reference-manual/functions/plots/f-bham.pdf
 287         reference-manual/functions/plots/fbposres.pdf
 288         reference-manual/functions/plots/f-dih.pdf
 289         reference-manual/functions/plots/f-dr.pdf
 290         reference-manual/functions/plots/fig-02.pdf
 291         reference-manual/functions/plots/fig-04.pdf
 292         reference-manual/functions/plots/f-imps.pdf
 293         reference-manual/functions/plots/f-lj.pdf
 294         reference-manual/functions/plots/f-morse.pdf
 295         reference-manual/functions/plots/f-pr.pdf
 296         reference-manual/functions/plots/f-rbs.pdf
 297         reference-manual/functions/plots/ring-imp.pdf
 298         reference-manual/functions/plots/softcore.pdf
 299         reference-manual/functions/plots/subst-im.pdf
 300         reference-manual/functions/plots/tetra-im.pdf
 301         reference-manual/functions/plots/vcrf.pdf
 302         reference-manual/functions/plots/vsite-4fdn.pdf
 303         # Special topics chapter
 304         reference-manual/special/plots/awh-invN.pdf
 305         reference-manual/special/plots/awh-pmfs.pdf
 306         reference-manual/special/plots/awh-sampleweights.pdf
 307         reference-manual/special/plots/awh-traj.pdf
 308         reference-manual/special/plots/compelsetup.pdf
 309         reference-manual/special/plots/dumaro.pdf
 310         reference-manual/special/plots/dumtypes.pdf
 311         reference-manual/special/plots/equipotential.pdf
 312         reference-manual/special/plots/field.pdf
 313         reference-manual/special/plots/gaussians.pdf
 314         reference-manual/special/plots/pulldirrel.pdf
 315         reference-manual/special/plots/pull.pdf
 316         reference-manual/special/plots/pullref.pdf
 317         reference-manual/special/plots/rotation.pdf
 318         # Analysis chapter
 319         reference-manual/analysis/plots/dih-def.pdf
 320         reference-manual/analysis/plots/distm.pdf
 321         reference-manual/analysis/plots/dssp.pdf
 322         reference-manual/analysis/plots/hbond-insert.pdf
 323         reference-manual/analysis/plots/hbond.pdf
 324         reference-manual/analysis/plots/hpr-wheel.pdf
 325         reference-manual/analysis/plots/msdwater.pdf
 326         reference-manual/analysis/plots/ngmxdump.pdf
 327         reference-manual/analysis/plots/phipsi.pdf
 328         reference-manual/analysis/plots/rama.pdf
 329         reference-manual/analysis/plots/rdfO-O.pdf
 330         reference-manual/analysis/plots/rdf.pdf
 331         reference-manual/analysis/plots/sgangle.pdf
 332         )
 333     set(SPHINX_SOURCE_FILES
 334         index.rst
 335         download.rst
 336         conf.py
 337         links.dat
 338         dev-manual/build-system.rst
 339         dev-manual/change-management.rst
 340         dev-manual/commitstyle.rst
 341         dev-manual/documentation-generation.rst
 342         dev-manual/contribute.rst
 343         dev-manual/doxygen.rst
 344         dev-manual/error-handling.rst
 345         dev-manual/formatting.rst
 346         dev-manual/gmxtree.rst
 347         dev-manual/includestyle.rst
 348         dev-manual/index.rst
 349         dev-manual/jenkins.rst
 350         dev-manual/known-issues.rst
 351         dev-manual/language-features.rst
 352         dev-manual/naming.rst
 353         dev-manual/overview.rst
 354         dev-manual/physical_validation.rst
 355         dev-manual/redmine-states.png
 356         dev-manual/relocatable-binaries.rst
 357         dev-manual/reportstyle.rst
 358         dev-manual/style.rst
 359         dev-manual/testutils.rst
 360         dev-manual/tools.rst
 361         dev-manual/uncrustify.rst
 362         fragments/doxygen-links.rst
 363         how-to/index.rst
 364         how-to/beginners.rst
 365         how-to/topology.rst
 366         how-to/special.rst
 367         how-to/visualize.rst
 368         install-guide/index.rst
 369         release-notes/index.rst
 370         release-notes/highlights.rst
 371         release-notes/features.rst
 372         release-notes/performance.rst
 373         release-notes/tools.rst
 374         release-notes/bugs-fixed.rst
 375         release-notes/removed-functionality.rst
 376         release-notes/deprecated-functionality.rst
 377         release-notes/portability.rst
 378         release-notes/miscellaneous.rst
 379         release-notes/2019/2019.1.rst
 380         release-notes/2019/major/highlights.rst
 381         release-notes/2019/major/features.rst
 382         release-notes/2019/major/performance.rst
 383         release-notes/2019/major/tools.rst
 384         release-notes/2019/major/bugs-fixed.rst
 385         release-notes/2019/major/removed-functionality.rst
 386         release-notes/2019/major/deprecated-functionality.rst
 387         release-notes/2019/major/portability.rst
 388         release-notes/2019/major/miscellaneous.rst
 389         release-notes/2018/2018.6.rst
 390         release-notes/2018/2018.5.rst
 391         release-notes/2018/2018.4.rst
 392         release-notes/2018/2018.3.rst
 393         release-notes/2018/2018.2.rst
 394         release-notes/2018/2018.1.rst
 395         release-notes/2018/major/highlights.rst
 396         release-notes/2018/major/features.rst
 397         release-notes/2018/major/performance.rst
 398         release-notes/2018/major/tools.rst
 399         release-notes/2018/major/bugs-fixed.rst
 400         release-notes/2018/major/removed-features.rst
 401         release-notes/2018/major/portability.rst
 402         release-notes/2018/major/miscellaneous.rst
 403         release-notes/2016/2016.5.rst
 404         release-notes/2016/2016.4.rst
 405         release-notes/2016/2016.3.rst
 406         release-notes/2016/2016.2.rst
 407         release-notes/2016/2016.1.rst
 408         release-notes/2016/major/highlights.rst
 409         release-notes/2016/major/new-features.rst
 410         release-notes/2016/major/performance.rst
 411         release-notes/2016/major/tools.rst
 412         release-notes/2016/major/bugs-fixed.rst
 413         release-notes/2016/major/removed-features.rst
 414         release-notes/2016/major/miscellaneous.rst
 415         release-notes/older/index.rst
 416         # the entry for user-guide/index.rst should not appear here,
 417         # as it will be included conditionally further down depending on
 418         # if the documentation will be build with the full reference
 419         # manual or without.
 420         user-guide/cmdline.rst
 421         user-guide/cutoff-schemes.rst
 422         user-guide/deprecation-policy.rst
 423         user-guide/environment-variables.rst
 424         user-guide/faq.rst
 425         user-guide/floating-point.rst
 426         user-guide/flow.rst
 427         user-guide/force-fields.rst
 428         user-guide/getting-started.rst
 429         user-guide/index.rst
 430         user-guide/managing-simulations.rst
 431         user-guide/mdp-options.rst
 432         user-guide/mdrun-features.rst
 433         user-guide/mdrun-performance.rst
 434         user-guide/run-time-errors.rst
 435         user-guide/security.rst
 436         user-guide/system-preparation.rst
 437         user-guide/terminology.rst
 438         )
 439
 440     include(SphinxMacros.cmake)
 441     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 442
 443     # set temporary variables for doi inclusion
 444     # into the manual, plain string + some wrapping
 445     # for release builds, and dummy string for non-release
 446     # builds
 447     if("${GMX_MANUAL_DOI}" STREQUAL "")
 448       # empty string means no doi, set dummy text
 449       set(GMX_MANUAL_DOI_STRING "This is not a release build of GROMACS, so please reference")
 450       set(GMX_MANUAL_DOI_STRING "${GMX_MANUAL_DOI_STRING} one of the GROMACS papers and the base release of the manual.")
 451     else()
 452       # release version, set plain old boring string
 453       set(GMX_MANUAL_DOI_STRING "Please reference this documentation as https://doi.org/${GMX_MANUAL_DOI}.")
 454     endif()
 455     # same for source doi, but modify the text
 456     if("${GMX_SOURCE_DOI}" STREQUAL "")
 457       # empty string means no release build
 458       set(GMX_SOURCE_DOI_STRING "This is not a release build of GROMACS. Please reference one of the")
 459       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} GROMACS papers, as well as the base release that this version is built from.")
 460       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} Also, please state what modifcations have been performed or where the version")
 461       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} was sourced from.")
 462     else()
 463       # release version, give them a doi url string
 464       set(GMX_SOURCE_DOI_STRING "To cite the source code for this release, please cite")
 465       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} https://doi.org/${GMX_SOURCE_DOI}.")
 466     endif()
 467
 468     if(IMAGE_CONVERT_POSSIBLE)
 469         set(IMAGE_CONVERT_STRING "possible")
 470     else()
 471         set(IMAGE_CONVERT_STRING "impossible")
 472     endif()
 473
 474     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 475     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 476         EXTRA_VARS
 477             SPHINX_EXTENSION_PATH RELENG_PATH
 478             IMAGE_CONVERT_STRING
 479             EXPECTED_DOXYGEN_VERSION
 480             EXPECTED_SPHINX_VERSION
 481             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 482             REQUIRED_OPENCL_MIN_VERSION
 483             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 484             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 485             GMX_TNG_MINIMUM_REQUIRED_VERSION
 486             GMX_LMFIT_REQUIRED_VERSION
 487             GMX_MANUAL_DOI_STRING
 488             GMX_SOURCE_DOI_STRING
 489         COMMENT "Configuring Sphinx configuration file")
 490     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 491     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 492     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 493         include(${RELENG_PATH}/docs/FileList.cmake)
 494         gmx_add_sphinx_source_files(
 495             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 496             FILES ${RELENG_SPHINX_FILES})
 497     else()
 498         gmx_add_sphinx_source_files(FILES
 499             dev-manual/releng/index.rst
 500             dev-manual/releng/jenkins-howto.rst
 501             dev-manual/releng/jenkins-ui.rst
 502             )
 503     endif()
 504     gmx_add_sphinx_source_files(
 505         FILES
 506         ${REFERENCEMANUAL_SPHINX_FILES_GENERAL})
 507     if (IMAGE_CONVERT_POSSIBLE)
 508         gmx_add_sphinx_source_files(
 509             FILES
 510             ${REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES}
 511             ${REFERENCEMANUAL_IMAGE_FILES})
 512         gmx_add_sphinx_image_conversion_files(
 513             FILES
 514             ${REFERENCEMANUAL_IMAGE_FILES})
 515     endif()
 516     gmx_add_sphinx_input_target(sphinx-input-rst)
 517     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 518     add_custom_target(sphinx-input)
 519     add_dependencies(sphinx-input sphinx-input-rst sphinx-image-conversion)
 520     # Remove other rst files from the build tree, since they confuse Sphinx.
 521     # Skip generated files in onlinehelp/, and fragments.
 522     # The latter do not cause issues with obsolete files, as they
 523     # are not considered as Sphinx input files, but will only be
 524     # included using an explicit .. include::.
 525     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 526
 527     # TODO: Make this remove obsolete .rst files.
 528     # TODO: This does not work in cross-compilation scenarios; disable up to
 529     # the necessary level.
 530     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 531         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 532         COMMAND gmx -quiet help -export rst
 533         DEPENDS gmx
 534         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 535         COMMENT "Generating reStructuredText help")
 536     # This dependency ensures that the directories exist before the
 537     # executable tries to write things there.
 538     add_dependencies(sphinx-programs sphinx-input)
 539
 540     # Make the INSTALL file for CPack for the tarball. This gets put
 541     # into the tarball via the CPack rules below, which requires that
 542     # the INSTALL file is in a separate directory by itself.
 543     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 544     add_custom_target(install-guide
 545         COMMAND
 546             ${SPHINX_EXECUTABLE}
 547             -q -b text
 548             -w sphinx-install.log
 549             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 550             -c ${SPHINX_INPUT_DIR}
 551             "${SPHINX_INPUT_DIR}/install-guide"
 552             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 553         COMMAND
 554             ${CMAKE_COMMAND} -E rename
 555             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 556             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 557         WORKING_DIRECTORY
 558             ${CMAKE_CURRENT_BINARY_DIR}
 559         COMMENT "Building INSTALL with Sphinx"
 560         VERBATIM
 561         )
 562     add_dependencies(install-guide sphinx-input)
 563     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 564
 565     # Sphinx cache with pickled ReST documents
 566     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 567     add_custom_target(webpage-sphinx
 568         DEPENDS sphinx-programs
 569         DEPENDS sphinx-input
 570         DEPENDS sphinx-image-conversion
 571         DEPENDS manual
 572         COMMAND
 573             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 574         COMMAND
 575             ${SPHINX_EXECUTABLE}
 576             -q -b html
 577             -w sphinx-html.log
 578             -d "${SPHINX_CACHE_DIR}"
 579             "${SPHINX_INPUT_DIR}"
 580             "${HTML_OUTPUT_DIR}"
 581         WORKING_DIRECTORY
 582             ${CMAKE_CURRENT_BINARY_DIR}
 583         COMMENT "Building HTML documentation with Sphinx"
 584         VERBATIM
 585         )
 586
 587     add_custom_target(man
 588         COMMAND
 589             ${SPHINX_EXECUTABLE}
 590             -q -b man
 591             -w sphinx-man.log
 592             -d ${SPHINX_CACHE_DIR}
 593             -t do_man
 594             ${SPHINX_INPUT_DIR}
 595             ${CMAKE_CURRENT_BINARY_DIR}/man
 596         COMMENT "Building man pages with Sphinx"
 597         VERBATIM)
 598     add_dependencies(man sphinx-input sphinx-programs)
 599     if (GMX_BUILD_HELP)
 600         # If requested, install the man pages built by the 'man' target
 601         # created above.  Nothing will be installed if the user did not
 602         # manually build the target.
 603         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 604     endif()
 605
 606 else()
 607     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 608     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is not available")
 609
 610     add_custom_target(webpage-sphinx
 611         COMMAND ${CMAKE_COMMAND} -E echo
 612             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 613         VERBATIM)
 614     add_custom_target(install-guide
 615         COMMAND ${CMAKE_COMMAND} -E echo
 616             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 617         VERBATIM)
 618     add_custom_target(man
 619         COMMAND ${CMAKE_COMMAND} -E echo
 620             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 621         VERBATIM)
 622     add_custom_target(sphinx-create-texman
 623         COMMAND ${CMAKE_COMMAND} -E echo
 624             "Cannot prepare LaTeX input files because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 625         VERBATIM)
 626 endif()
 627
 628 if (MAN_PAGE_DIR)
 629     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 630     # Trailing slash on directory is significant for
 631     # install(DIRECTORY). See CMake docs.
 632     install(DIRECTORY ${MAN_PAGE_DIR}/
 633         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 634         COMPONENT man OPTIONAL
 635         FILES_MATCHING PATTERN "*.1")
 636 endif()
 637 gmx_cpack_add_generated_source_directory(man)
 638
 639 # Determine whether we can build all the HTML pages and content linked from
 640 # there.  If not, construct an informative message if the user tries to
 641 # build the target; most people never need to know, unless they've asked for
 642 # the webpage build.
 643 set(HTML_BUILD_IS_POSSIBLE ON)
 644 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 645 set(HTML_BUILD_WARNINGS)
 646
 647 # Next, turn it off if any of the preconditions are unsatisified
 648 if (NOT PYTHON_EXECUTABLE)
 649     set(HTML_BUILD_IS_POSSIBLE OFF)
 650     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 651 elseif (NOT SPHINX_FOUND)
 652     # Hardly anything gets built if Sphinx is not available, so don't bother.
 653     set(HTML_BUILD_IS_POSSIBLE OFF)
 654     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 655 endif()
 656 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 657     list(APPEND HTML_BUILD_WARNINGS
 658          "Reference PDF manual was not built, so links to it do not work")
 659 endif()
 660 if (NOT DOXYGEN_EXECUTABLE)
 661     list(APPEND HTML_BUILD_WARNINGS
 662         "Doxygen was not available, so links to Doxygen do not work")
 663 endif()
 664 if (NOT DOXYGEN_DOT_EXECUTABLE)
 665     list(APPEND HTML_BUILD_WARNINGS
 666         "dot/graphviz was not found, so some graphs are missing")
 667 endif()
 668
 669 if (HTML_BUILD_IS_POSSIBLE)
 670     set(_webpage_target_properties)
 671     if (HTML_BUILD_WARNINGS)
 672         list(APPEND _webpage_target_properties
 673              COMMAND ${CMAKE_COMMAND} -E echo
 674                  "webpage was built, but with the following limitations:")
 675         foreach(_warning ${HTML_BUILD_WARNINGS})
 676         list(APPEND _webpage_target_properties
 677              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 678         endforeach()
 679     endif()
 680
 681     if (MANUAL_BUILD_IS_POSSIBLE)
 682         # Make the PDF reference guide
 683         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 684         # TODO Make this depend on the output of the manual build, so that the
 685         # file actually gets copied multiple times.
 686         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 687         add_custom_command(
 688             OUTPUT ${_manual_target_location}
 689             COMMAND ${CMAKE_COMMAND}
 690                 -E remove -f ${_manual_target_location}
 691             COMMAND ${CMAKE_COMMAND}
 692                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 693             DEPENDS manual
 694             VERBATIM)
 695         list(APPEND _webpage_target_properties
 696              DEPENDS ${_manual_target_location})
 697     endif()
 698
 699     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 700     # makes all the Doxygen output directly in
 701     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 702     # to).
 703
 704     # Add a top-level target that builds everything related to the webpage,
 705     # for Jenkins (and possibly others) to use
 706     add_custom_target(webpage ${_webpage_target_properties}
 707         COMMENT "Building webpage"
 708         VERBATIM)
 709     add_dependencies(webpage webpage-sphinx doxygen-all)
 710 else()
 711     add_custom_target(webpage
 712         COMMAND ${CMAKE_COMMAND} -E echo
 713             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 714         COMMENT "Webpage build not possible"
 715         VERBATIM)
 716 endif()