CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39
  40 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  41 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  42
  43 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  44 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  45 endif()
  46
  47 if(NOT CMAKE_BUILD_TYPE)
  48     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  49 endif(NOT CMAKE_BUILD_TYPE)
  50
  51 enable_language(C)
  52
  53 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  54 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  55
  56 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  57 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  58 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  59 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  60     set(CPACK_SET_DESTDIR "ON")
  61 endif()
  62 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  63 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  64 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  65 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  66 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  67 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  68 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  69
  70 #must come after all cpack settings!
  71 include(CPack)
  72
  73 ########################################################################
  74 # Check and warn if cache generated on a different host is being reused
  75 ########################################################################
  76 if(CMAKE_HOST_UNIX)
  77     execute_process(COMMAND hostname
  78                     OUTPUT_VARIABLE TMP_HOSTNAME
  79                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  80     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  81         message(WARNING "
  82             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  83             is being reused! This could lead to inconsitencies; therefore, it is
  84             recommended to regenerate the cache!")
  85     endif()
  86     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  87             "Hostname of the machine where the cache was generated.")
  88 endif()
  89
  90 ########################################################################
  91 # Fix stupid flags on Windows
  92 ########################################################################
  93 SET(SHARED_LIBS_DEFAULT ON)
  94 IF( WIN32 AND NOT CYGWIN)
  95   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  96   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  97   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  98
  99   IF (GMX_PREFER_STATIC_LIBS)
 100     #Only setting Debug and Release flags. Others configurations current not used.
 101     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 102     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 103     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 104     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 105     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 106     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 107     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 108     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 109   ENDIF()
 110
 111   #Workaround for cmake bug 13174. Replace deprecated options.
 112   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 113     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 114     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 115   ENDIF()
 116   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 117     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 118     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 119     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 120
 121     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 122     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 123   ENDIF()
 124 ENDIF()
 125
 126
 127 ########################################################################
 128 # User input options                                                   #
 129 ########################################################################
 130 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 131 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 132 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 133 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 134 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 135 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 136 mark_as_advanced(GMX_POWERPC_INVSQRT)
 137 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 138 mark_as_advanced(GMX_FAHCORE)
 139 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 140
 141 include(gmxDetectAcceleration)
 142 if(NOT DEFINED GMX_ACCELERATION)
 143     if(CMAKE_CROSSCOMPILING)
 144         set(GMX_SUGGESTED_ACCELERATION "None")
 145     else(CMAKE_CROSSCOMPILING)
 146         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 147     endif(CMAKE_CROSSCOMPILING)
 148 endif(NOT DEFINED GMX_ACCELERATION)
 149
 150 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 151     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 152
 153 set(GMX_FFT_LIBRARY "fftw3"
 154     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 155 option(GMX_DISABLE_FFTW_MEASURE
 156        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 157 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 158 set(GMX_QMMM_PROGRAM "none"
 159     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 160 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 161 mark_as_advanced(GMX_BROKEN_CALLOC)
 162 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 163 mark_as_advanced(GMX_MPI_IN_PLACE)
 164 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 165 mark_as_advanced(GMX_LOAD_PLUGINS)
 166
 167 option(GMX_GPU  "Enable GPU acceleration" ON)
 168 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 169
 170 option(USE_VERSION_H "Generate development version string/information" ON)
 171 mark_as_advanced(USE_VERSION_H)
 172
 173 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 174
 175 if(UNIX AND NOT APPLE)
 176     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 177     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 178 endif()
 179
 180 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 181 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 182
 183 ######################################################################
 184 # compiler tests
 185 # these need ot be done early (before further tests).
 186 #####################################################################
 187
 188 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 189 # branch (proposed for v2.8.9) to be able to detect invalid options
 190 # with the Intel Compilers.
 191 # Remove these files from the source tree when a CMake version that
 192 # includes the features in question becomes required.
 193 include(CheckCCompilerFlag)
 194 include(CheckCXXCompilerFlag)
 195
 196 # OpenMP check must come before other CFLAGS!
 197 if(GMX_OPENMP)
 198     find_package(OpenMP)
 199     if(OPENMP_FOUND)
 200         #- only set linker flag, if user didn't set them manual
 201         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 202         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 203         if(NOT (WIN32 AND NOT CYGWIN))
 204             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 205                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 206                 set(OpenMP_SHARED_LINKER_FLAGS "")
 207             else()
 208                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 209                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 210                 endif()
 211                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 212                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 213                 endif()
 214             endif()
 215         endif()
 216     else(OPENMP_FOUND)
 217         message(WARNING
 218                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 219                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 220                 "if you can - for now we are proceeding by turning off OpenMP.")
 221         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 222     endif(OPENMP_FOUND)
 223 endif()
 224
 225
 226 include(gmxCFlags)
 227 gmx_c_flags()
 228
 229 include(gmxGetCompilerVersion)
 230 get_compiler_version()
 231
 232 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 233 # Detect here whether applying a workaround is needed and will apply it later
 234 # on the affected files.
 235 include(gmxGCC44O3BugWorkaround)
 236 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 237
 238 ########################################################################
 239 # Set up binary and library suffixing
 240 ########################################################################
 241 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 242 set(GMX_LIBS_SUFFIX ""
 243   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 244 if (GMX_DEFAULT_SUFFIX)
 245   set(GMX_BINARY_SUFFIX "")
 246   set(GMX_LIBS_SUFFIX "")
 247   if (GMX_MPI)
 248     set(GMX_BINARY_SUFFIX "_mpi")
 249     set(GMX_LIBS_SUFFIX "_mpi")
 250   endif(GMX_MPI)
 251   if (GMX_DOUBLE)
 252     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 253     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 254   endif(GMX_DOUBLE)
 255   if (GMX_OPENMM)
 256     set (GMX_BINARY_SUFFIX "-openmm")
 257     set (GMX_LIBS_SUFFIX "_openmm")
 258   endif(GMX_OPENMM)
 259   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 260   if (NOT SUFFIX_QUIETLY)
 261     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 262     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 263   endif (NOT SUFFIX_QUIETLY)
 264 else(GMX_DEFAULT_SUFFIX)
 265   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 266   if (NOT SUFFIX_QUIETLY)
 267     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 268     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 269   endif (NOT SUFFIX_QUIETLY)
 270 endif(GMX_DEFAULT_SUFFIX)
 271 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 272
 273 set(PKG_CFLAGS "")
 274 if(GMX_DOUBLE)
 275     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 276 endif(GMX_DOUBLE)
 277 if(GMX_SOFTWARE_INVSQRT)
 278   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 279 endif(GMX_SOFTWARE_INVSQRT)
 280 if(GMX_POWERPC_INVSQRT)
 281   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 282 endif(GMX_POWERPC_INVSQRT)
 283
 284 ########################################################################
 285 #Process MPI settings
 286 ########################################################################
 287 include(gmxManageMPI)
 288
 289 #######################################################################
 290 # Check for options incompatible with OpenMM build                    #
 291 #######################################################################
 292 if(GMX_OPENMM)
 293     # we'll use the built-in fft to avoid unnecessary dependencies
 294     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 295     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 296         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 297         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 298                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 299     endif()
 300     if(GMX_MPI)
 301         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 302     endif(GMX_MPI)
 303     if(GMX_THREAD_MPI)
 304         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 305         set(GMX_THREAD_MPI OFF CACHE BOOL
 306                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 307     endif(GMX_THREAD_MPI)
 308     if(GMX_OPENMP)
 309         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 310         set(GMX_OPENMP OFF CACHE BOOL
 311             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 312     endif()
 313     if(GMX_SOFTWARE_INVSQRT)
 314         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 315                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 316     endif(GMX_SOFTWARE_INVSQRT)
 317     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 318     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 319         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 320         set(GMX_ACCELERATION "none" CACHE STRING
 321                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 322     endif()
 323     if(GMX_FAHCORE)
 324         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 325     endif(GMX_FAHCORE)
 326     if(GMX_DOUBLE)
 327         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 328     endif()
 329     # mark as advanced the unused variables
 330     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 331         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 332 else(GMX_OPENMM)
 333      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 334         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 335 endif(GMX_OPENMM)
 336
 337
 338 ########################################################################
 339 # Basic system tests (standard libraries, headers, functions, types)   #
 340 ########################################################################
 341 include(CheckIncludeFiles)
 342 check_include_files(string.h     HAVE_STRING_H)
 343 check_include_files(math.h       HAVE_MATH_H)
 344 check_include_files(limits.h     HAVE_LIMITS_H)
 345 check_include_files(memory.h     HAVE_MEMORY_H)
 346 check_include_files(unistd.h     HAVE_UNISTD_H)
 347 check_include_files(direct.h     HAVE_DIRECT_H)
 348 check_include_files(pwd.h        HAVE_PWD_H)
 349 check_include_files(stdint.h     HAVE_STDINT_H)
 350 check_include_files(stdlib.h     HAVE_STDLIB_H)
 351 check_include_files(pthread.h    HAVE_PTHREAD_H)
 352 check_include_files(dirent.h     HAVE_DIRENT_H)
 353 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 354 check_include_files(regex.h      HAVE_REGEX_H)
 355 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 356 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 357 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 358 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 359 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 360 check_include_files(io.h                 HAVE_IO_H)
 361 check_include_files(sched.h      HAVE_SCHED_H)
 362
 363 include(CheckFunctionExists)
 364 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 365 check_function_exists(strdup            HAVE_STRDUP)
 366 check_function_exists(vprintf           HAVE_VPRINTF)
 367 check_function_exists(memcmp            HAVE_MEMCMP)
 368 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 369 check_function_exists(memalign          HAVE_MEMALIGN)
 370 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 371 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 372 check_function_exists(isnan             HAVE_ISNAN)
 373 check_function_exists(_isnan            HAVE__ISNAN)
 374 check_function_exists(fsync             HAVE_FSYNC)
 375 check_function_exists(_fileno           HAVE__FILENO)
 376 check_function_exists(fileno            HAVE_FILENO)
 377 check_function_exists(_commit           HAVE__COMMIT)
 378 check_function_exists(lstat             HAVE_LSTAT)
 379 check_function_exists(sigaction         HAVE_SIGACTION)
 380 check_function_exists(sysconf           HAVE_SYSCONF)
 381 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 382
 383 include(CheckLibraryExists)
 384 check_library_exists(m sqrt "" HAVE_LIBM)
 385 check_library_exists(m cbrt "" HAVE_CBRT)
 386
 387
 388 include(CheckTypeSize)
 389
 390 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 391 check_type_size("int"           SIZEOF_INT)
 392 check_type_size("long int"      SIZEOF_LONG_INT)
 393 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 394 check_type_size("off_t"         SIZEOF_OFF_T)
 395 check_type_size("void *"        SIZEOF_VOIDP)
 396
 397 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 398     set(GMX_64_BIT TRUE)
 399 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 400     set(GMX_64_BIT FALSE)
 401 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 402
 403 # Check for some basic types that we *need*, so set these to int if they are not present
 404 check_type_size(uid_t uid_t)
 405 if(NOT uid_t)
 406   set(uid_t int)
 407 else(NOT uid_t)
 408   set(uid_t 0)
 409 endif(NOT uid_t)
 410
 411 check_type_size(gid_t gid_t)
 412 if(NOT gid_t)
 413   set(gid_t 1)
 414 else(NOT gid_t)
 415   set(gid_t 0)
 416 endif(NOT gid_t)
 417
 418 check_type_size(size_t size_t)
 419 if(NOT size_t)
 420   set(size_t int)
 421 else(NOT size_t)
 422   set(size_t 0)
 423 endif(NOT size_t)
 424
 425 check_type_size(off_t off_t)
 426 if(NOT off_t)
 427   set(off_t int)
 428 else(NOT off_t)
 429   set(off_t 0)
 430 endif(NOT off_t)
 431
 432 include(TestBigEndian)
 433 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 434
 435
 436
 437
 438 ########################################################################
 439 # Find external packages                                               #
 440 ########################################################################
 441 if(UNIX AND NOT APPLE)
 442     if(GMX_PREFER_STATIC_LIBS)
 443         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 444         if(SHARED_LIBS_DEFAULT)
 445             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 446                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 447             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 448                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 449                 set(SHARED_LIBS_DEFAULT OFF)
 450             endif()
 451         endif()
 452     endif()
 453 endif()
 454 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 455
 456 option(GMX_XML "Use libxml2 to parse xml files" ON)
 457 if (GMX_XML)
 458   find_package(LibXml2)
 459   set(PKG_XML "")
 460   if(LIBXML2_FOUND)
 461     include_directories(${LIBXML2_INCLUDE_DIR})
 462     set(PKG_XML libxml-2.0)
 463     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 464     set(HAVE_LIBXML2 1)
 465   endif(LIBXML2_FOUND)
 466 endif(GMX_XML)
 467
 468 option(GMX_GSL "Add support for gsl" OFF)
 469 if (GMX_GSL)
 470   find_package(gsl)
 471   set(PKG_GSL "")
 472   if(GSL_FOUND)
 473     include_directories(${GSL_INCLUDE_DIR})
 474     set(PKG_GSL gsl)
 475     set(HAVE_LIBGSL 1)
 476   endif(GSL_FOUND)
 477 endif (GMX_GSL)
 478
 479 option(GMX_X11 "Use X window system" OFF)
 480 if (GMX_X11)
 481         find_package(X11)
 482         # X11 includes/libraries are only set in the ngmx subdirectory!
 483         if(X11_FOUND)
 484         set(HAVE_X11 1)
 485         endif(X11_FOUND)
 486 endif(GMX_X11)
 487
 488 if(GMX_THREAD_MPI)
 489     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 490     include(ThreadMPI)
 491     set(THREAD_MPI_LIB thread_mpi)
 492     set(GMX_MPI 1)
 493     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 494 endif(GMX_THREAD_MPI)
 495
 496 if(GMX_OPENMM)
 497     set(CUDA_BUILD_EMULATION OFF)
 498     find_package(CUDA 3.1 REQUIRED)
 499     add_definitions(-DGMX_OPENMM)
 500     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 501         set(CUDA_VERBOSE_BUILD ON)
 502     endif()
 503     find_package(OpenMM)
 504 endif(GMX_OPENMM)
 505
 506
 507 if(GMX_GPU)
 508     if(GMX_DOUBLE)
 509         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 510         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 511     endif()
 512
 513     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 514     if(MSVC)
 515         find_package(CUDA 4.1)
 516     else()
 517         find_package(CUDA 3.2)
 518     endif()
 519
 520     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 521         message(FATAL_ERROR "
 522     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 523     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 524     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 525
 526     CPU or GPU acceleration can be selected at runtime, but if you are
 527     sure you can not make use of GPU acceleration, disable it by setting
 528     the CMake variable GMX_GPU=OFF.")
 529     endif()
 530
 531     if(NOT GMX_OPENMP)
 532         message(WARNING "
 533     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 534     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 535     Note that with MPI multiple processes can be forced to use a single GPU, but this
 536     typically inefficient.")
 537     endif()
 538
 539     include(gmxManageNvccConfig)
 540
 541     # Check whether we can use atomic operations needed for polling wait for GPU
 542     # (to avoid the cudaStreamSynchronize + ECC bug).
 543     # With thread-MPI testing atomics has already been carried out, but without
 544     # thread-MPI we need to invoke the atomics test independently.
 545     if (NOT GMX_THREAD_MPI)
 546         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 547             "Test only the atomic operations of thread-MPI.")
 548         include(ThreadMPI)
 549     endif()
 550
 551     # we need this linker flag in case if we have ld >= 2.22 (typically with gcc 4.5+),
 552     # but it's too cumbersome to check the ld version and the flag should not hurt
 553     if(CMAKE_COMPILER_IS_GNUCC)
 554         set(GROMACS_LINKER_FLAGS "-Wl,--add-needed ${GROMACS_LINKER_FLAGS}")
 555     endif()
 556
 557     # annoyingly enough, FindCUDA leaves a few variables behind as non-advanced
 558     mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 559 endif()
 560
 561 if(APPLE)
 562    find_library(ACCELERATE_FRAMEWORK Accelerate)
 563    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 564 endif(APPLE)
 565
 566 if(CYGWIN)
 567     set(GMX_CYGWIN 1)
 568 endif(CYGWIN)
 569
 570 if(WIN32 AND NOT CYGWIN)
 571     set(GMX_NATIVE_WINDOWS 1)
 572 endif()
 573
 574 # only bother with finding git and using version.h if the source is a git repo
 575 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 576     if(USE_VERSION_H)
 577         # We need at least git v1.5.3 be able to parse git's date output. If not
 578         # found or the version is too small, we can't generate version information.
 579         find_package(Git)
 580
 581         # Find out the git version
 582         if(GIT_FOUND AND NOT GIT_VERSION)
 583           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 584             OUTPUT_VARIABLE _exec_out
 585             OUTPUT_STRIP_TRAILING_WHITESPACE)
 586           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 587           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 588           mark_as_advanced(GIT_VERSION)
 589         endif()
 590
 591         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 592           message("No compatible git version found, won't be able to generate proper development version information.")
 593           set(USE_VERSION_H OFF)
 594         endif()
 595     endif()
 596 else()
 597     set(USE_VERSION_H OFF)
 598 endif()
 599
 600 ########################################################################
 601 # Generate development version info for cache
 602 ########################################################################
 603 # set(GEN_VERSION_INFO_INTERNAL "ON")
 604 # include(gmxGenerateVersionString)
 605
 606 ########################################################################
 607 # Our own GROMACS tests
 608 ########################################################################
 609
 610 add_definitions( -DHAVE_CONFIG_H )
 611 include_directories(${CMAKE_BINARY_DIR}/src)
 612 include_directories(${CMAKE_BINARY_DIR}/include)
 613 include_directories(${CMAKE_SOURCE_DIR}/include)
 614
 615 include(gmxTestInlineASM)
 616 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 617
 618 include(gmxSetBuildInformation)
 619 gmx_set_build_information()
 620 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 621     # The timestep counter headers do not include config.h
 622     add_definitions(-DHAVE_RDTSCP)
 623 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 624
 625 include(gmxTestFloatFormat)
 626 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 627                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 628                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 629
 630 include(gmxTestLargeFiles)
 631 gmx_test_large_files(GMX_LARGEFILES)
 632 check_function_exists(fseeko     HAVE_FSEEKO)
 633
 634 include(gmxTestSignal)
 635 gmx_test_sigusr1(HAVE_SIGUSR1)
 636
 637 include(gmxTestInline)
 638 gmx_test_inline(INLINE_KEYWORD)
 639
 640 include(gmxTestRestrict)
 641 gmx_test_inline(RESTRICT_KEYWORD)
 642
 643 include(gmxTestPipes)
 644 gmx_test_pipes(HAVE_PIPES)
 645
 646 include(gmxTestIsfinite)
 647 gmx_test_isfinite(HAVE_ISFINITE)
 648 gmx_test__isfinite(HAVE__ISFINITE)
 649 gmx_test__finite(HAVE__FINITE)
 650
 651 include(gmxTestXDR)
 652 gmx_test_xdr(GMX_SYSTEM_XDR)
 653 if(NOT GMX_SYSTEM_XDR)
 654     set(GMX_INTERNAL_XDR 1)
 655     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 656 endif(NOT GMX_SYSTEM_XDR)
 657
 658 # Process nonbonded accelerated kernels settings
 659 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 660 if(${GMX_ACCELERATION} STREQUAL "NONE")
 661     # nothing to do
 662 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 663
 664     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 665     if(NOT GNU_SSE2_CFLAG)
 666         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 667     endif(NOT GNU_SSE2_CFLAG)
 668
 669     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 670     if(NOT GNU_SSE2_CXXFLAG)
 671         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 672     endif(NOT GNU_SSE2_CXXFLAG)
 673
 674     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 675
 676     # Only test the include after we have tried to add the correct flag for SSE2 support
 677     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 678
 679     if(NOT HAVE_EMMINTRIN_H)
 680         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 681     endif(NOT HAVE_EMMINTRIN_H)
 682
 683     # The user should not be able to set this orthogonally to the acceleration
 684     set(GMX_X86_SSE2 1)
 685     if (NOT ACCELERATION_QUIETLY)
 686       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 687     endif()
 688
 689 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 690
 691     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 692     if (NOT GNU_SSE4_CFLAG)
 693         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 694     endif(NOT GNU_SSE4_CFLAG)
 695     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 696         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 697         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 698         # intrinsics when SSE2 support is enabled, so we try that instead.
 699         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 700     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 701
 702     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 703     if (NOT GNU_SSE4_CXXFLAG)
 704        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 705     endif(NOT GNU_SSE4_CXXFLAG)
 706     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 707         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 708         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 709         # intrinsics when SSE2 support is enabled, so we try that instead.
 710         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 711     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 712
 713     # This must come after we have added the -msse4.1 flag on some platforms.
 714     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 715
 716     if(NOT HAVE_SMMINTRIN_H)
 717         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 718     endif(NOT HAVE_SMMINTRIN_H)
 719
 720     # The user should not be able to set this orthogonally to the acceleration
 721     set(GMX_X86_SSE4_1 1)
 722     set(GMX_X86_SSE2   1)
 723     if (NOT ACCELERATION_QUIETLY)
 724       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 725     endif()
 726
 727 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 728
 729     # Set the AVX compiler flag for both these choices!
 730
 731     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 732     if (NOT GNU_AVX_CFLAG)
 733         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 734     endif (NOT GNU_AVX_CFLAG)
 735     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 736         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 737     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 738
 739     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 740     if (NOT GNU_AVX_CXXFLAG)
 741        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 742     endif (NOT GNU_AVX_CXXFLAG)
 743     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 744        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 745     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 746
 747     # Only test the header after we have tried to add the flag for AVX support
 748     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 749
 750     if(NOT HAVE_IMMINTRIN_H)
 751         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 752     endif(NOT HAVE_IMMINTRIN_H)
 753
 754     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 755     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 756
 757     # The user should not be able to set this orthogonally to the acceleration
 758     set(GMX_X86_SSE4_1 1)
 759     set(GMX_X86_SSE2   1)
 760
 761     # But just enable one of the choices internally...
 762     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 763         set(GMX_X86_AVX_128_FMA 1)
 764         if (NOT ACCELERATION_QUIETLY)
 765           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 766         endif()
 767     else()
 768         # If we are not doing AVX_128, it must be AVX_256...
 769         set(GMX_X86_AVX_256 1)
 770         if (NOT ACCELERATION_QUIETLY)
 771           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 772         endif()
 773     endif()
 774
 775 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 776
 777 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 778 #    We need to fake it a bit here to avoid jenkins build errors!
 779 #    add_definitions(-DGMX_FORTRAN)
 780
 781 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 782 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 783     if (NOT ACCELERATION_QUIETLY)
 784       message(STATUS "Configuring for BlueGene")
 785     endif()
 786     set(GMX_BLUEGENE 1)
 787     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 788         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 789         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 790     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 791     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 792     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 793     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 794     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 795     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 796 # Access to /etc/passwd is not available on the back end of BlueGene,
 797 # despite being detected by CMake. This can cause linker warnings
 798 # about harmless things in src/gmxlib/string2.h.
 799     set(HAVE_PWD_H OFF)
 800 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 801     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 802     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 803 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 804     set(GMX_POWER6 1)
 805     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 806     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 807 else(${GMX_ACCELERATION} STREQUAL "NONE")
 808     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 809 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 810 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 811
 812 if(GMX_FORTRAN OR GMX_POWER6)
 813     if (GMX_THREAD_MPI)
 814         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 815     endif(GMX_THREAD_MPI)
 816     enable_language(Fortran)
 817     include(FortranCInterface)
 818     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 819     if(extra_under_score)
 820         set(extrasuffix "_")
 821     endif(extra_under_score)
 822     if(prefix)
 823       set(prefix "${prefix} ##")
 824     endif(prefix)
 825     if(suffix)
 826       set(suffix "## ${suffix}")
 827       if(extrasuffix)
 828         set(extrasuffix "${suffix}${extrasuffix}")
 829       endif(extrasuffix)
 830     else(suffix)
 831       if(extrasuffix)
 832         # Don't know if this is needed, but it can't hurt
 833         set(extrasuffix "## ${extrasuffix}")
 834       endif(extrasuffix)
 835     endif(suffix)
 836
 837     if(isupper)
 838         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 839         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 840     else(isupper)
 841         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 842         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 843     endif(isupper)
 844 else(GMX_FORTRAN OR GMX_POWER6)
 845         set(F77_FUNCDEF   "name ## _")
 846         set(F77_FUNCDEF_  "name ## _")
 847 endif(GMX_FORTRAN OR GMX_POWER6)
 848
 849 # Process QM/MM Settings
 850 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 851 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 852     set(GMX_QMMM_GAUSSIAN 1)
 853 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 854     set(GMX_QMMM_MOPAC 1)
 855 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 856     set(GMX_QMMM_GAMESS 1)
 857 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 858     set(GMX_QMMM_ORCA 1)
 859 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 860     # nothing to do
 861 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 862     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 863 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 864
 865 # Process FFT library settings - if not OpenMM build
 866 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 867 set(PKG_FFT "")
 868 set(PKG_FFT_LIBS "")
 869 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 870     if(GMX_DOUBLE)
 871         find_package(FFTW 3 COMPONENTS fftw)
 872     else(GMX_DOUBLE)
 873         find_package(FFTW 3 COMPONENTS fftwf)
 874     endif(GMX_DOUBLE)
 875     if(NOT FFTW_FOUND)
 876       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 877     endif(NOT FFTW_FOUND)
 878     include_directories(${FFTW_INCLUDE_DIRS})
 879     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 880     set(PKG_FFT "${FFTW_PKG}")
 881
 882     set(GMX_FFT_FFTW3 1)
 883
 884     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 885       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 886     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 887
 888 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 889 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 890     find_package(MKL REQUIRED)
 891     include_directories(${MKL_INCLUDE_DIR})
 892     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 893     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 894
 895     set(GMX_FFT_MKL 1)
 896     set(HAVE_MKL 1)
 897
 898 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 899 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 900 #    set(GMX_FFT_ACML 1)
 901 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 902     MESSAGE(STATUS "Using internal FFT library - fftpack")
 903     set(GMX_FFT_FFTPACK 1)
 904 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 905     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 906 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 907
 908 # enable threaded fftw3 if we've found it
 909 if(FFTW3_THREADS OR FFTW3F_THREADS)
 910     add_definitions(-DFFT5D_FFTW_THREADS)
 911 endif()
 912
 913 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 914 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 915 # MKL has BLAS/LAPACK routines
 916 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 917   if(GMX_EXTERNAL_BLAS)
 918     if (GMX_BLAS_USER)
 919         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 920     else(GMX_BLAS_USER)
 921         set(BLAS_FIND_QUIETLY ON)
 922         find_package(BLAS)
 923         if (BLAS_FOUND)
 924           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 925         else()
 926           MESSAGE(STATUS "Using internal BLAS library")
 927           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 928         endif()
 929     endif(GMX_BLAS_USER)
 930   endif(GMX_EXTERNAL_BLAS)
 931   if(GMX_EXTERNAL_LAPACK)
 932     if (GMX_LAPACK_USER)
 933         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 934     else(GMX_LAPACK_USER)
 935         set(LAPACK_FIND_QUIETLY ON)
 936         find_package(LAPACK)
 937         if (LAPACK_FOUND)
 938           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 939         else()
 940           MESSAGE(STATUS "Using internal LAPACK library")
 941           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 942         endif()
 943     endif(GMX_LAPACK_USER)
 944   endif(GMX_EXTERNAL_LAPACK)
 945 endif()
 946 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 947 mark_as_advanced(GMX_EXTERNAL_BLAS)
 948
 949 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 950
 951 if(GMX_LOAD_PLUGINS)
 952   if(CYGWIN OR NOT WIN32)
 953     # Native Windows does not have, nor need dlopen
 954     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 955     include(gmxTestdlopen)
 956     gmx_test_dlopen(HAVE_DLOPEN)
 957   endif()
 958
 959   # so, should we use plug-ins?
 960   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 961     if(NOT VMD_QUIETLY)
 962       MESSAGE(STATUS
 963           "Found the ability to use plug-ins when building shared libaries, "
 964           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 965           "formats).")
 966     endif()
 967     if(NOT GMX_VMD_PLUGIN_PATH)
 968       find_package(VMD)
 969     endif()
 970     set(GMX_USE_PLUGINS ON)
 971     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 972     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 973   else()
 974     set(PKG_DL_LIBS)
 975   endif()
 976 endif(GMX_LOAD_PLUGINS)
 977 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 978
 979 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 980     if(NOT CMAKE_CROSSCOMPILING)
 981         option(GMX_BUILD_MANPAGES "Build man pages" ON)
 982     else()
 983         message(STATUS "Building the man pages is not available when "
 984             "cross-compiling the developer version from git")
 985     endif()
 986 else()
 987     #make sure source package contains all man pages
 988     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
 989         message(FATAL_ERROR "Man pages are missing from source package.")
 990     endif()
 991 endif()
 992 mark_as_advanced(GMX_BUILD_MANPAGES)
 993
 994 # Math and thread libraries must often come after all others when linking...
 995 if(HAVE_LIBM)
 996     list(APPEND GMX_EXTRA_LIBRARIES m)
 997 endif(HAVE_LIBM)
 998
 999 if(GMX_FAHCORE)
1000   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1001       "Path to swindirect.h")
1002   include_directories(${COREWRAP_INCLUDE_DIR})
1003 endif(GMX_FAHCORE)
1004
1005 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1006 # these are set after everything else
1007 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1008     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1009         FORCE)
1010     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1011         "Flags used by the compiler during all build types" FORCE)
1012     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1013         "Flags used by the compiler during all build types" FORCE)
1014     set(CMAKE_EXE_LINKER_FLAGS
1015         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1016         CACHE STRING "Linker flags for creating executables" FORCE)
1017     set(CMAKE_SHARED_LINKER_FLAGS
1018         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1019         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1020 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1021
1022 ######################################
1023 # Output compiler and CFLAGS used
1024 ######################################
1025 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1026 #try executing just the compiler command if that failed...
1027 if(TMP_RESULT)
1028     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1029 endif()
1030 string(LENGTH "${CC_VERSION}" len)
1031 if(len)
1032     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
1033 endif()
1034
1035 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1036 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1037 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1038     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1039 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1040     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1041 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1042     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1043 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1044     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1045 endif()
1046
1047
1048 ########################################################################
1049 # Specify install locations and which subdirectories to process        #
1050 ########################################################################
1051 if (GMX_USE_RELATIVE_INSTALL_PATH)
1052     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1053     mark_as_advanced(GMX_INSTALL_PREFIX)
1054 else()
1055     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1056 endif()
1057
1058 if ( NOT DEFINED GMXLIB )
1059     set(GMXLIB lib)
1060 endif()
1061 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1062 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1063 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1064 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1065 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1066
1067 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1068
1069 ##################################################################
1070 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1071 ##################################################################
1072 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1073     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1074     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1075     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1076     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1077 endif()
1078
1079 add_subdirectory(share)
1080 add_subdirectory(include)
1081 add_subdirectory(src)
1082 add_subdirectory(scripts)
1083
1084 #######################
1085 ## uninstall target
1086 #######################
1087     CONFIGURE_FILE(
1088                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1089                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1090                    IMMEDIATE @ONLY)
1091 ###########################
1092 ADD_CUSTOM_TARGET(uninstall
1093                   "${CMAKE_COMMAND}" -P
1094                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1095 ###########################
1096
1097
1098 ########################################################################
1099 # Tests                                                                #
1100 ########################################################################
1101
1102 include(CTest)
1103 mark_as_advanced(BUILD_TESTING)
1104 IF(BUILD_TESTING)
1105         enable_testing()
1106         add_subdirectory(tests)
1107 ENDIF()
1108