CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 include(gmxManageCcache)
  44
  45 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  46 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  47 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  48
  49 # Set up common version variables, as well as general information about
  50 # the build tree (whether the build is from a source package or from a git
  51 # repository).  Also declares a few functions that will be used for generating
  52 # version info files later.
  53 include(gmxBuildTreeInfo)
  54 include(gmxVersionInfo)
  55
  56 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  57     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  58 endif()
  59 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  60     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  61 endif()
  62
  63 include(gmxBuildTypeReference)
  64 include(gmxBuildTypeProfile)
  65 include(gmxBuildTypeTSAN)
  66 include(gmxBuildTypeASAN)
  67 include(gmxBuildTypeMSAN)
  68 include(gmxBuildTypeReleaseWithAssert)
  69
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  72     # Set the possible values of build type for cmake-gui
  73     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  74         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  75 endif()
  76 if(CMAKE_CONFIGURATION_TYPES)
  77     # Add appropriate GROMACS-specific build types for the Visual
  78     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  79     # are already present by default).
  80     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  81     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  82     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  83         "List of configuration types"
  84         FORCE)
  85 endif()
  86 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  87
  88 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  89
  90 include(gmxCTestUtilities)
  91 gmx_ctest_init()
  92
  93 include(gmxCPackUtilities)
  94 gmx_cpack_init()
  95
  96 # Variables that accumulate stuff influencing the installed headers
  97 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  98 set(INSTALLED_HEADER_DEFINITIONS "")
  99
 100 ########################################################################
 101 # Global non-cache variables for implementing the build system
 102 ########################################################################
 103
 104 # These variables collect libraries that GROMACS requires for
 105 # linking. They should be appended to with list(APPEND ${name}
 106 # new-library) calls. They are:
 107 #  - Libraries that are required for libgromacs (only)
 108 set(GMX_EXTRA_LIBRARIES "")
 109 #  - Libraries that are required for all code in the repository
 110 set(GMX_COMMON_LIBRARIES "")
 111 #  - Libraries that all code linked against libgromacs needs
 112 #    (i.e., something that is exposed in installed headers).
 113 set(GMX_PUBLIC_LIBRARIES "")
 114
 115 ########################################################################
 116 # Check and warn if cache generated on a different host is being reused
 117 ########################################################################
 118 if(CMAKE_HOST_UNIX)
 119     execute_process(COMMAND hostname
 120                     OUTPUT_VARIABLE TMP_HOSTNAME
 121                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 122     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 123         message(WARNING "
 124             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 125             is being reused! This could lead to inconsistencies; therefore, it is
 126             recommended to regenerate the cache!")
 127     endif()
 128     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 129             "Hostname of the machine where the cache was generated.")
 130 endif()
 131
 132 ########################################################################
 133 # Detect architecture before setting options so we can alter defaults
 134 ########################################################################
 135 # Detect the architecture the compiler is targetting, detect
 136 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 137 # to use if none is specified, and populate the cache option for CPU
 138 # SIMD.
 139 include(gmxDetectTargetArchitecture)
 140 gmx_detect_target_architecture()
 141
 142 # Permit the user to specify a particular standard library, e.g. compiling
 143 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 144 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 145 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 146 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 147 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 148
 149 ########################################################################
 150 # Detect CXX11 support and flags
 151 ########################################################################
 152 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 153 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 154 # invalid options with the Intel Compilers, and we have added a line
 155 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 156 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 157 # a semicolon. Since this is also used as a separator in lists inside CMake,
 158 # that string ends up being split into two separate patterns, and the last
 159 # part is just a single word that also matches other messages. We solved this
 160 # by replacing the semicolon with a period that matches any character.
 161 #
 162 # These files should be removed from the source tree when a CMake version that
 163 # includes the features in question becomes required for building GROMACS.
 164 include(CheckCCompilerFlag)
 165 include(CheckCXXCompilerFlag)
 166
 167 # This must come early, since some of our configuration flag tests
 168 # depend on being able to compile C++11 source files.
 169 include(gmxTestCXX11)
 170 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 171
 172 # Make sure all C++ code will be compiled in C++11 mode, with the
 173 # expected standard library.
 174 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 175
 176 ########################################################################
 177 # User input options                                                   #
 178 ########################################################################
 179 include(gmxOptionUtilities)
 180
 181 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 182
 183 # Fujitsu only has SIMD in double precision, so this will be faster
 184 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 185 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 186 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 187 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 188
 189 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 190 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 191 gmx_dependent_option(
 192     GMX_MPI_IN_PLACE
 193     "Enable MPI_IN_PLACE for MPIs that have it defined"
 194     ON
 195     GMX_MPI)
 196 mark_as_advanced(GMX_MPI_IN_PLACE)
 197
 198 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 199
 200 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 201 mark_as_advanced(GMX_FAHCORE)
 202
 203 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 204 mark_as_advanced(GMX_COOL_QUOTES)
 205 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 206
 207 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 208
 209 # Decide on GPU settings based on user-settings and GPU/CUDA
 210 # detection. VS2017 requires CUDA 9.0, for the other arch/compilers
 211 # rest we require CUDA 7.0 or later (including for clang-CUDA).
 212 if(MSVC)
 213     set(REQUIRED_CUDA_VERSION 9.0)
 214 else()
 215     set(REQUIRED_CUDA_VERSION 7.0)
 216 endif()
 217 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 218
 219 # OpenCL required version: 1.2 or newer
 220 set(REQUIRED_OPENCL_MIN_VERSION 1.2)
 221
 222 if(NOT GMX_USE_OPENCL)
 223     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 224     include(gmxManageGPU)
 225     set(GMX_USE_CUDA ${GMX_GPU})
 226     if(GMX_GPU)
 227         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 228     else()
 229         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 230     endif()
 231 else()
 232     #Now the OpenCL path (for both AMD and NVIDIA)
 233     if(GMX_GPU)
 234         include(gmxManageOpenCL)
 235         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 236     else()
 237         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 238     endif()
 239 endif()
 240
 241 gmx_option_multichoice(
 242     GMX_SIMD
 243     "SIMD instruction set for CPU kernels and compiler optimization"
 244     "AUTO"
 245     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 246
 247 if(GMX_TARGET_MIC)
 248     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 249 else()
 250     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 251 endif()
 252
 253 gmx_option_multichoice(
 254     GMX_FFT_LIBRARY
 255     "FFT library"
 256     "${GMX_FFT_LIBRARY_DEFAULT}"
 257     fftw3 mkl "fftpack[built-in]")
 258 gmx_dependent_option(
 259     GMX_BUILD_OWN_FFTW
 260     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 261     OFF
 262     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 263 gmx_dependent_option(
 264     GMX_DISABLE_FFTW_MEASURE
 265     "Do not optimize FFTW setups (not needed with SSE)"
 266     OFF
 267     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 268 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 269 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 270
 271 gmx_option_multichoice(
 272     GMX_QMMM_PROGRAM
 273     "QM package for QM/MM"
 274     None
 275     none gaussian mopac gamess orca)
 276
 277 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 278 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 279
 280 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 281
 282 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 283 mark_as_advanced(GMX_BROKEN_CALLOC)
 284
 285 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 286
 287 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 288
 289 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 290
 291 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 292 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 293
 294 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 295 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 296
 297 option(GMX_BUILD_FOR_COVERAGE
 298        "Tune build for better code coverage metrics (e.g., disable asserts)"
 299        OFF)
 300 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 301
 302 option(GMX_DEVELOPER_BUILD
 303     "Enable Developer convenience features: always build unit-tests"
 304     OFF)
 305 mark_as_advanced(GMX_DEVELOPER_BUILD)
 306
 307 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 308 option(GMX_COMPILER_WARNINGS
 309     "Enable a default set of compiler warnings"
 310     ${GMX_COMPILER_WARNINGS_DEFAULT})
 311 mark_as_advanced(GMX_COMPILER_WARNINGS)
 312 # Always turn on compiler warnings with a developer build.
 313 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 314
 315 option(GMX_BUILD_SHARED_EXE
 316     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 317     ON)
 318 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 319
 320 option(GMX_PHYSICAL_VALIDATION
 321        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 322        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 323        OFF)
 324 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 325
 326 ######################################################################
 327 # Detect OpenMP support
 328 ######################################################################
 329 # The OpenMP detection _must_ come before tests for other CFLAGS.
 330 include(gmxManageOpenMP)
 331
 332
 333
 334 ######################################################################
 335 # Compiler tests
 336 # These need to be done early (before further tests).
 337 #####################################################################
 338
 339 include(gmxCFlags)
 340 gmx_c_flags()
 341
 342 # This variable should be used for additional compiler flags which are not
 343 # generated in gmxCFlags nor are SIMD or MPI related.
 344 #
 345 # TODO These variables should be consolidated into
 346 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 347 # things that work in C compilation (e.g. merging from old branches)
 348 # also work for C++ compilation.
 349 set(EXTRA_C_FLAGS "")
 350 set(EXTRA_CXX_FLAGS "")
 351
 352 # Run through a number of tests for buggy compilers and other issues
 353 include(gmxTestCompilerProblems)
 354 gmx_test_compiler_problems()
 355
 356 # Implement double-precision option. This is complicated because we
 357 # need installed headers to use the precision mode of the build that
 358 # produced the library, but cannot use config.h in that case. We also
 359 # want such variables to always have a definition, because #if is more
 360 # robust than #ifdef. So, we put this value on the compiler command
 361 # line in all cases.
 362 #
 363 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 364 # because no installed header needs it
 365 if(GMX_DOUBLE)
 366     set(GMX_DOUBLE_VALUE 1)
 367 else()
 368     set(GMX_DOUBLE_VALUE 0)
 369 endif()
 370 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 371 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 372
 373 if(WIN32)
 374     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 375     add_definitions(-DGMX_HAVE_WINSOCK)
 376 endif()
 377
 378
 379
 380 ########################################################################
 381 # Basic system tests (standard libraries, headers, functions, types)   #
 382 ########################################################################
 383 include(CheckIncludeFiles)
 384 include(CheckIncludeFileCXX)
 385 check_include_files(unistd.h     HAVE_UNISTD_H)
 386 check_include_files(pwd.h        HAVE_PWD_H)
 387 check_include_files(dirent.h     HAVE_DIRENT_H)
 388 check_include_files(time.h       HAVE_TIME_H)
 389 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 390 check_include_files(io.h         HAVE_IO_H)
 391 check_include_files(sched.h      HAVE_SCHED_H)
 392
 393 check_include_files(regex.h      HAVE_POSIX_REGEX)
 394 # TODO: It could be nice to inform the user if no regex support is found,
 395 # as selections won't be fully functional.
 396
 397 include(CheckCXXSymbolExists)
 398 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 399 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 400 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 401 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 402 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 403 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 404 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 405 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 406
 407 # We cannot check for the __builtins as symbols, but check if code compiles
 408 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 409 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 410 if(MSVC)
 411     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 412     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 413 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 414     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 415     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 416 endif()
 417
 418 include(CheckLibraryExists)
 419 find_library(HAVE_LIBM m)
 420 mark_as_advanced(HAVE_LIBM)
 421 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 422 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 423 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 424
 425 include(TestSchedAffinity)
 426 test_sched_affinity(HAVE_SCHED_AFFINITY)
 427
 428 # Aligned memory allocation. We need to check for both mm_malloc(),
 429 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 430 include(gmxTestMMMalloc)
 431 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 432 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 433 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 434 if(MSVC)
 435     # No need to waste time on this test on platforms where it will never be true
 436     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 437 endif()
 438
 439 include(TestBigEndian)
 440 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 441
 442 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 443
 444 # Management of GROMACS options for specific toolchains should go
 445 # here. Because the initial settings for some of the main options have
 446 # already happened, but things like library detection and MPI compiler
 447 # feature detection have not, the docstrings for any over-rides of
 448 # GROMACS defaults or user settings will make sense. Also, any
 449 # toolchain-related reasons for choosing whether to detect various
 450 # things can be sorted out now, before the detection takes place.
 451 if(GMX_TARGET_FUJITSU_SPARC64)
 452     include(gmxManageFujitsuSparc64)
 453 endif()
 454
 455 ########################################################################
 456 #Process MPI settings
 457 ########################################################################
 458 include(gmxManageMPI)
 459
 460 ########################################################################
 461 #Process MiMiC settings
 462 ########################################################################
 463 include(gmxManageMimic)
 464
 465 ########################################################################
 466 #Process shared/static library settings
 467 ########################################################################
 468 include(gmxManageSharedLibraries)
 469
 470
 471 ########################################################################
 472 # Find external packages                                               #
 473 ########################################################################
 474
 475 # Unconditionally find the package, as it is also required for unit
 476 # tests. This exports LIBXML2_FOUND, which we should not use because
 477 # it does not tell us that linking will succeed. Instead, we test that
 478 # next.
 479 #if(DEFINED LIBXML2_LIBRARIES)
 480 #  set(LibXml2_FIND_QUIETLY TRUE)
 481 #endif()
 482 #find_package(LibXml2)
 483 #include(gmxTestLibXml2)
 484 #gmx_test_libxml2(HAVE_LIBXML2)
 485 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 486 #set(PKG_XML "")
 487 #mark_as_advanced(GMX_XML)
 488 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 489 #if(GMX_XML AND NOT HAVE_LIBXML2)
 490 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 491 #endif()
 492 #if(GMX_XML)
 493 #    include_directories(${LIBXML2_INCLUDE_DIR})
 494 #    set(PKG_XML libxml-2.0)
 495 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 496 #endif()
 497
 498 gmx_option_trivalue(
 499     GMX_HWLOC
 500     "Use hwloc portable hardware locality library"
 501     "AUTO")
 502
 503 if (GMX_HWLOC)
 504     # Find quietly the second time.
 505     if(DEFINED HWLOC_LIBRARIES)
 506         set(Hwloc_FIND_QUIETLY TRUE)
 507     endif()
 508     find_package(Hwloc 1.5)
 509
 510     if (HWLOC_FOUND)
 511         if (HWLOC_LIBRARIES MATCHES ".a$")
 512             set(_STATIC_HWLOC TRUE)
 513         endif()
 514
 515         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 516         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 517             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 518             set(GMX_USE_HWLOC OFF)
 519         else()
 520             set(GMX_USE_HWLOC ON)
 521         endif()
 522
 523         if (GMX_USE_HWLOC)
 524             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 525             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 526         endif()
 527     elseif(GMX_HWLOC_FORCE)
 528         message(FATAL_ERROR "Hwloc package support required, but not found.")
 529     endif()
 530 endif()
 531
 532 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 533 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 534 if(GMX_EXTERNAL_TINYXML2)
 535     # Find an external TinyXML-2 library.
 536     find_package(TinyXML-2 3.0.0)
 537     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 538     if(NOT HAVE_TINYXML2)
 539         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 540     endif()
 541 endif()
 542
 543 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 544 mark_as_advanced(GMX_EXTRAE)
 545
 546 if (GMX_EXTRAE)
 547   find_package(EXTRAE)
 548   if(EXTRAE_FOUND)
 549     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 550     set(HAVE_EXTRAE 1)
 551   else()
 552     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 553   endif()
 554 endif()
 555
 556 option(GMX_X11 "Use X window system" OFF)
 557 if (GMX_X11)
 558     find_package(X11)
 559     # X11 includes/libraries are only set in the ngmx subdirectory!
 560     if(NOT X11_FOUND)
 561         message(FATAL_ERROR
 562                 "X11 include files and/or libraries were not found. "
 563                 "Set GMX_X11=OFF to compile without X11 support. "
 564                 "gmx view will not be available.")
 565     endif()
 566     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 567 endif()
 568
 569 include(ThreadMPI)
 570 # Enable core threading facilities
 571 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 572 if(GMX_THREAD_MPI)
 573     # enable MPI functions
 574     tmpi_enable()
 575     set(MPI_IN_PLACE_EXISTS 1)
 576 endif()
 577 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 578 if (TMPI_ATOMICS_DISABLED)
 579    add_definitions(-DTMPI_ATOMICS_DISABLED)
 580 endif()
 581
 582 include(gmxManageTNG)
 583
 584 include(gmxManageLmfit)
 585
 586 if(GMX_GPU)
 587     # now that we have detected the dependencies, do the second configure pass
 588     gmx_gpu_setup()
 589     if (GMX_CLANG_CUDA)
 590         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 591         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 592     endif()
 593 endif()
 594
 595 if(CYGWIN)
 596     set(GMX_CYGWIN 1)
 597 endif()
 598
 599 if(WIN32)
 600     set(GMX_NATIVE_WINDOWS 1)
 601     # This makes windows.h not declare min/max as macros that would break
 602     # C++ code using std::min/std::max.
 603     add_definitions(-DNOMINMAX)
 604 endif()
 605
 606 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 607     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 608         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 609     endif()
 610     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 611         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 612     endif()
 613 endif()
 614
 615 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 616 mark_as_advanced(GMX_BUILD_UNITTESTS)
 617 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 618
 619 ########################################################################
 620 # Our own GROMACS tests
 621 ########################################################################
 622
 623 add_definitions( -DHAVE_CONFIG_H )
 624 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 625 # TODO required at high level because both libgromacs and progs/mdrun
 626 # require it, both for thread-MPI and its atomics and mutexes.
 627 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 628 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 629 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 630
 631 include(gmxTestInlineASM)
 632 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 633
 634 include(gmxSetBuildInformation)
 635 gmx_set_build_information()
 636
 637 gmx_option_multichoice(
 638     GMX_USE_RDTSCP
 639     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 640     "AUTO"
 641     OFF ON AUTO DETECT)
 642 mark_as_advanced(GMX_USE_RDTSCP)
 643
 644 macro(gmx_check_rdtscp)
 645     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 646         set(HAVE_RDTSCP 1)
 647         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 648     else()
 649         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 650     endif()
 651 endmacro()
 652
 653 set(HAVE_RDTSCP 0)
 654 if (GMX_USE_RDTSCP STREQUAL "ON")
 655     set(HAVE_RDTSCP 1)
 656 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 657     gmx_check_rdtscp()
 658 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 659     # If the user specified automated SIMD selection, that the choice
 660     # is made based on detection on the build host. If so, then RDTSCP
 661     # should be chosen the same way.
 662     #
 663     # If the user specified an AVX SIMD level (e.g. when
 664     # cross-compiling GROMACS) then they will get our best guess, ie
 665     # that in practice AVX mostly correlates with rdtscp (and anyway
 666     # is only relevant in rather old x86 hardware).
 667     if (GMX_SIMD STREQUAL "AUTO")
 668         gmx_check_rdtscp()
 669     elseif (GMX_SIMD MATCHES "AVX")
 670         set(HAVE_RDTSCP 1)
 671     endif()
 672 endif()
 673 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 674 if (HAVE_RDTSCP_CHANGED)
 675     if (HAVE_RDTSCP)
 676         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 677     else()
 678         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 679     endif()
 680 endif()
 681
 682 include(gmxTestLargeFiles)
 683 gmx_test_large_files(GMX_LARGEFILES)
 684
 685 include(gmxTestSignal)
 686 gmx_test_sigusr1(HAVE_SIGUSR1)
 687
 688 include(gmxTestPipes)
 689 gmx_test_pipes(HAVE_PIPES)
 690
 691 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 692
 693 include(gmxTestXDR)
 694 gmx_test_xdr(GMX_SYSTEM_XDR)
 695 # Darwin has system XDR, but it uses a three-argument flavour of
 696 # xdrproc_t that it guarantees will still work if you pass the normal
 697 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 698 # to do that, so it's simpler to just use our own XDR library.
 699 #
 700 # TODO It would be better to craft a cmake test which fails if such
 701 # XDR operations cause warnings, and succeeds otherwise, because it is
 702 # generally preferable to use system libraries where possible.
 703 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 704     set(GMX_INTERNAL_XDR 1)
 705 endif()
 706
 707
 708 ##################################################
 709 # Process SIMD instruction settings
 710 ##################################################
 711 # This checks what flags to add in order to
 712 # support the SIMD instructions we need, it sets
 713 # correct defines for the SIMD instructions supported,
 714 # and adds advanced options to control accuracy
 715 # for SIMD math operations.
 716 include(gmxManageSimd)
 717 gmx_manage_simd()
 718
 719 include(gmxManageCycleCounters)
 720 gmx_manage_cycle_counters()
 721
 722 # Process QM/MM Settings
 723 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 724     set(GMX_QMMM_GAUSSIAN 1)
 725 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 726     set(GMX_QMMM_MOPAC 1)
 727 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 728     set(GMX_QMMM_GAMESS 1)
 729 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 730     set(GMX_QMMM_ORCA 1)
 731 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 732     # nothing to do
 733 else()
 734     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 735 endif()
 736
 737
 738 ##################################################
 739 # Process FFT library settings
 740 ##################################################
 741 include(gmxManageFFTLibraries)
 742
 743
 744 include(gmxManageLinearAlgebraLibraries)
 745
 746 include(gmxManagePluginSupport)
 747
 748 if (GMX_USE_PLUGINS)
 749     if(NOT GMX_VMD_PLUGIN_PATH)
 750         find_package(VMD)
 751     endif()
 752 endif()
 753
 754 # Link real-time library for POSIX timers. The check for clock_gettime
 755 # confirms the linkability of rt.
 756 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 757     list(APPEND GMX_EXTRA_LIBRARIES rt)
 758 endif()
 759
 760 # Math and thread libraries must often come after all others when linking...
 761 if (HAVE_LIBM)
 762     list(APPEND GMX_PUBLIC_LIBRARIES m)
 763 endif()
 764
 765 option(GMX_NACL "Configure for Native Client builds" OFF)
 766 if (GMX_NACL)
 767   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 768   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 769   # TODO: Is this still necessary with the check for its presence?
 770   set(GMX_USE_NICE 0)
 771   set(GMX_NO_RENAME 1)
 772 endif()
 773 mark_as_advanced(GMX_NACL)
 774
 775 if(GMX_FAHCORE)
 776   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 777       "Path to swindirect.h")
 778   include_directories(${COREWRAP_INCLUDE_DIR})
 779 endif()
 780
 781 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 782 # produce warnings if that fails.
 783 set(build_help_default AUTO)
 784 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 785     set(build_help_default OFF)
 786 endif()
 787 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 788 mark_as_advanced(GMX_BUILD_HELP)
 789 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 790     message(FATAL_ERROR
 791         "Rebuilding shell completions or man pages is not supported for "
 792         "in-source builds from a source distribution. "
 793         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 794 endif()
 795
 796 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 797 # these are set after everything else
 798 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 799     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 800     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 801     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 802     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 803 else()
 804     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 805     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 806     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 807     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 808     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 809     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 810     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 811     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 812     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 813 endif()
 814
 815 if(NOT GMX_OPENMP)
 816     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 817     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 818     unset(OpenMP_C_FLAGS CACHE)
 819     unset(OpenMP_CXX_FLAGS CACHE)
 820 else()
 821     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 822     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 823 endif()
 824
 825
 826 ########################################################################
 827 # Specify install locations
 828 ########################################################################
 829 # Use GNUInstallDirs to set paths on multiarch systems.
 830 include(GNUInstallDirs)
 831
 832 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 833 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 834
 835 # Internal convenience so we do not have to join two path segments in the code
 836 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 837
 838 # If the nesting level wrt. the installation root is changed,
 839 # gromacs-config.cmake.cmakein needs to be adapted.
 840 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 841
 842 # TODO: Make GMXRC adapt if this is changed
 843 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 844 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 845
 846 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 847
 848 # Binary and library suffix options
 849 include(gmxManageSuffixes)
 850
 851 ################################################################
 852 # Shared library load path settings
 853 ################################################################
 854 if(NOT GMX_BUILD_SHARED_EXE)
 855     # No rpath
 856     set(CMAKE_SKIP_RPATH TRUE)
 857     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 858     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 859 else()
 860     # The build folder always has bin/ and lib/; if we are also going to
 861     # install to lib/, then the installation RPATH works also in the build
 862     # tree.  This makes installation slightly faster (no need to rewrite the
 863     # RPATHs), and makes the binaries in the build tree relocatable.
 864     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 865         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 866         if(POLICY CMP0068)
 867             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 868             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 869         endif()
 870     endif()
 871     # Set the RPATH as relative to the executable location to make the
 872     # binaries relocatable.
 873     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 874         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 875         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 876     else()
 877         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 878     endif()
 879     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 880     set(CMAKE_MACOSX_RPATH 1)
 881 endif()
 882
 883 #COPYING file: Only necessary for binary distributions.
 884 #Simpler to always install.
 885 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 886
 887 if (GMX_BUILD_FOR_COVERAGE)
 888     # Code heavy with asserts makes conditional coverage close to useless metric,
 889     # as by design most of the false branches are impossible to trigger in
 890     # correctly functioning code.  And the benefit of testing those that could
 891     # be triggered by using an API against its specification isn't usually
 892     # worth the effort.
 893     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 894 endif()
 895
 896 if (BUILD_TESTING)
 897     include(tests/CheckTarget.cmake)
 898 endif()
 899
 900 if (NOT GMX_BUILD_MDRUN_ONLY)
 901     find_package(ImageMagick QUIET COMPONENTS convert)
 902     include(gmxTestImageMagick)
 903     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 904     add_subdirectory(docs)
 905     add_subdirectory(share)
 906     add_subdirectory(scripts)
 907 endif()
 908 add_subdirectory(src)
 909
 910 if (BUILD_TESTING)
 911     add_subdirectory(tests)
 912 endif()
 913
 914 gmx_cpack_write_config()
 915
 916 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 917 # Don't bother the user after the first configure pass.
 918 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 919     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 920 endif()
 921 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 922
 923 #######################
 924 ## uninstall target
 925 #######################
 926 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 927                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 928                   IMMEDIATE @ONLY)
 929 ###########################
 930 ADD_CUSTOM_TARGET(uninstall
 931                   "${CMAKE_COMMAND}" -P
 932                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 933 ###########################
 934 set_directory_properties(PROPERTIES
 935             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")