CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Global non-cache variables for implementing the build system
 100 ########################################################################
 101
 102 # These variables collect libraries that GROMACS requires for
 103 # linking. They should be appended to with list(APPEND ${name}
 104 # new-library) calls. They are:
 105 #  - Libraries that are required for libgromacs (only)
 106 set(GMX_EXTRA_LIBRARIES "")
 107 #  - Libraries that are required for all code in the repository
 108 set(GMX_COMMON_LIBRARIES "")
 109 #  - Libraries that all code linked against libgromacs needs
 110 #    (i.e., something that is exposed in installed headers).
 111 set(GMX_PUBLIC_LIBRARIES "")
 112
 113 ########################################################################
 114 # Check and warn if cache generated on a different host is being reused
 115 ########################################################################
 116 if(CMAKE_HOST_UNIX)
 117     execute_process(COMMAND hostname
 118                     OUTPUT_VARIABLE TMP_HOSTNAME
 119                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 121         message(WARNING "
 122             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 123             is being reused! This could lead to inconsistencies; therefore, it is
 124             recommended to regenerate the cache!")
 125     endif()
 126     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 127             "Hostname of the machine where the cache was generated.")
 128 endif()
 129
 130 ########################################################################
 131 # Detect architecture before setting options so we can alter defaults
 132 ########################################################################
 133 # Detect the architecture the compiler is targetting, detect
 134 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 135 # to use if none is specified, and populate the cache option for CPU
 136 # SIMD.
 137 include(gmxDetectTargetArchitecture)
 138 gmx_detect_target_architecture()
 139
 140 # Permit the user to specify a particular standard library, e.g. compiling
 141 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 142 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 143 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 144 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 145 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 146
 147 ########################################################################
 148 # Detect CXX11 support and flags
 149 ########################################################################
 150 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 151 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 152 # invalid options with the Intel Compilers, and we have added a line
 153 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 154 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 155 # a semicolon. Since this is also used as a separator in lists inside CMake,
 156 # that string ends up being split into two separate patterns, and the last
 157 # part is just a single word that also matches other messages. We solved this
 158 # by replacing the semicolon with a period that matches any character.
 159 #
 160 # These files should be removed from the source tree when a CMake version that
 161 # includes the features in question becomes required for building GROMACS.
 162 include(CheckCCompilerFlag)
 163 include(CheckCXXCompilerFlag)
 164
 165 # This must come early, since some of our configuration flag tests
 166 # depend on being able to compile C++11 source files.
 167 include(gmxTestCXX11)
 168 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 169
 170 # Make sure all C++ code will be compiled in C++11 mode, with the
 171 # expected standard library.
 172 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 173
 174 ########################################################################
 175 # User input options                                                   #
 176 ########################################################################
 177 include(gmxOptionUtilities)
 178
 179 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 180
 181 # Fujitsu only has SIMD in double precision, so this will be faster
 182 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 183 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 184 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 185 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 186
 187 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 188 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 189 gmx_dependent_option(
 190     GMX_MPI_IN_PLACE
 191     "Enable MPI_IN_PLACE for MPIs that have it defined"
 192     ON
 193     GMX_MPI)
 194 mark_as_advanced(GMX_MPI_IN_PLACE)
 195 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 196 mark_as_advanced(GMX_FAHCORE)
 197
 198 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 199 mark_as_advanced(GMX_COOL_QUOTES)
 200 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 201
 202 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 203
 204 # Decide on GPU settings based on user-settings and GPU/CUDA
 205 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 206 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 207 # requires CUDA 8.0
 208 if(MSVC)
 209     set(REQUIRED_CUDA_VERSION 8.0)
 210 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 211     set(REQUIRED_CUDA_VERSION 7.0)
 212 else()
 213     set(REQUIRED_CUDA_VERSION 6.5)
 214 endif()
 215 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 216
 217 # OpenCL required version: 1.1 or newer
 218 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 219
 220 if(NOT GMX_USE_OPENCL)
 221     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 222     include(gmxManageGPU)
 223     set(GMX_USE_CUDA ${GMX_GPU})
 224     if(GMX_GPU)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 226     else()
 227         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 228     endif()
 229 else()
 230     #Now the OpenCL path (for both AMD and NVIDIA)
 231     if(GMX_GPU)
 232         include(gmxManageOpenCL)
 233         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 234     else()
 235         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 236     endif()
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_SIMD
 241     "SIMD instruction set for CPU kernels and compiler optimization"
 242     "AUTO"
 243     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 244
 245 if(GMX_TARGET_MIC)
 246     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 247 else()
 248     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 249 endif()
 250
 251 gmx_option_multichoice(
 252     GMX_FFT_LIBRARY
 253     "FFT library"
 254     "${GMX_FFT_LIBRARY_DEFAULT}"
 255     fftw3 mkl "fftpack[built-in]")
 256 gmx_dependent_option(
 257     GMX_BUILD_OWN_FFTW
 258     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 gmx_dependent_option(
 262     GMX_DISABLE_FFTW_MEASURE
 263     "Do not optimize FFTW setups (not needed with SSE)"
 264     OFF
 265     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 266 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 267 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 268
 269 gmx_option_multichoice(
 270     GMX_QMMM_PROGRAM
 271     "QM package for QM/MM"
 272     None
 273     none gaussian mopac gamess orca)
 274
 275 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 276 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 277
 278 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 279
 280 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 281 mark_as_advanced(GMX_BROKEN_CALLOC)
 282
 283 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 284
 285 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 286
 287 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 288
 289 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 290 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 291
 292 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 293 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 294
 295 option(GMX_BUILD_FOR_COVERAGE
 296        "Tune build for better code coverage metrics (e.g., disable asserts)"
 297        OFF)
 298 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 299
 300 option(GMX_DEVELOPER_BUILD
 301     "Enable Developer convenience features: always build unit-tests"
 302     OFF)
 303 mark_as_advanced(GMX_DEVELOPER_BUILD)
 304
 305 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 306 option(GMX_COMPILER_WARNINGS
 307     "Enable a default set of compiler warnings"
 308     ${GMX_COMPILER_WARNINGS_DEFAULT})
 309 mark_as_advanced(GMX_COMPILER_WARNINGS)
 310 # Always turn on compiler warnings with a developer build.
 311 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 312
 313 option(GMX_BUILD_SHARED_EXE
 314     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 315     ON)
 316 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 317
 318 ######################################################################
 319 # Detect OpenMP support
 320 ######################################################################
 321 # The OpenMP detection _must_ come before tests for other CFLAGS.
 322 include(gmxManageOpenMP)
 323
 324
 325
 326 ######################################################################
 327 # Compiler tests
 328 # These need to be done early (before further tests).
 329 #####################################################################
 330
 331 include(gmxCFlags)
 332 gmx_c_flags()
 333
 334 # This variable should be used for additional compiler flags which are not
 335 # generated in gmxCFlags nor are SIMD or MPI related.
 336 #
 337 # TODO These variables should be consolidated into
 338 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 339 # things that work in C compilation (e.g. merging from old branches)
 340 # also work for C++ compilation.
 341 set(EXTRA_C_FLAGS "")
 342 set(EXTRA_CXX_FLAGS "")
 343
 344 # Run through a number of tests for buggy compilers and other issues
 345 include(gmxTestCompilerProblems)
 346 gmx_test_compiler_problems()
 347
 348 # Implement double-precision option. This is complicated because we
 349 # need installed headers to use the precision mode of the build that
 350 # produced the library, but cannot use config.h in that case. We also
 351 # want such variables to always have a definition, because #if is more
 352 # robust than #ifdef. So, we put this value on the compiler command
 353 # line in all cases.
 354 #
 355 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 356 # because no installed header needs it
 357 if(GMX_DOUBLE)
 358     set(GMX_DOUBLE_VALUE 1)
 359 else()
 360     set(GMX_DOUBLE_VALUE 0)
 361 endif()
 362 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 363 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 364
 365 if(WIN32)
 366     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 367     add_definitions(-DGMX_HAVE_WINSOCK)
 368 endif()
 369
 370
 371
 372 ########################################################################
 373 # Basic system tests (standard libraries, headers, functions, types)   #
 374 ########################################################################
 375 include(CheckIncludeFiles)
 376 include(CheckIncludeFileCXX)
 377 check_include_files(unistd.h     HAVE_UNISTD_H)
 378 check_include_files(pwd.h        HAVE_PWD_H)
 379 check_include_files(dirent.h     HAVE_DIRENT_H)
 380 check_include_files(time.h       HAVE_TIME_H)
 381 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 382 check_include_files(io.h         HAVE_IO_H)
 383 check_include_files(sched.h      HAVE_SCHED_H)
 384
 385 check_include_files(regex.h      HAVE_POSIX_REGEX)
 386 # TODO: It could be nice to inform the user if no regex support is found,
 387 # as selections won't be fully functional.
 388
 389 include(CheckCXXSymbolExists)
 390 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 391 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 392 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 393 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 394 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 395 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 396 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 397 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 398
 399 # We cannot check for the __builtins as symbols, but check if code compiles
 400 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 401 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 402 if(MSVC)
 403     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 404     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 405 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 406     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 407     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 408 endif()
 409
 410 include(CheckLibraryExists)
 411 find_library(HAVE_LIBM m)
 412 mark_as_advanced(HAVE_LIBM)
 413 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 414 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 415
 416 include(TestSchedAffinity)
 417 test_sched_affinity(HAVE_SCHED_AFFINITY)
 418
 419 # Aligned memory allocation. We need to check for both mm_malloc(),
 420 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 421 include(gmxTestMMMalloc)
 422 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 423 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 424 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 425 if(MSVC)
 426     # No need to waste time on this test on platforms where it will never be true
 427     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 428 endif()
 429
 430 include(TestBigEndian)
 431 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 432
 433 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 434
 435 # Management of GROMACS options for specific toolchains should go
 436 # here. Because the initial settings for some of the main options have
 437 # already happened, but things like library detection and MPI compiler
 438 # feature detection have not, the docstrings for any over-rides of
 439 # GROMACS defaults or user settings will make sense. Also, any
 440 # toolchain-related reasons for choosing whether to detect various
 441 # things can be sorted out now, before the detection takes place.
 442 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 443     include(gmxManageBlueGene)
 444 endif()
 445
 446 if(GMX_TARGET_FUJITSU_SPARC64)
 447     include(gmxManageFujitsuSparc64)
 448 endif()
 449
 450 ########################################################################
 451 #Process MPI settings
 452 ########################################################################
 453 include(gmxManageMPI)
 454
 455
 456 ########################################################################
 457 #Process shared/static library settings
 458 ########################################################################
 459 include(gmxManageSharedLibraries)
 460
 461
 462 ########################################################################
 463 # Find external packages                                               #
 464 ########################################################################
 465
 466 # Unconditionally find the package, as it is also required for unit
 467 # tests. This exports LIBXML2_FOUND, which we should not use because
 468 # it does not tell us that linking will succeed. Instead, we test that
 469 # next.
 470 #if(DEFINED LIBXML2_LIBRARIES)
 471 #  set(LibXml2_FIND_QUIETLY TRUE)
 472 #endif()
 473 #find_package(LibXml2)
 474 #include(gmxTestLibXml2)
 475 #gmx_test_libxml2(HAVE_LIBXML2)
 476 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 477 #set(PKG_XML "")
 478 #mark_as_advanced(GMX_XML)
 479 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 480 #if(GMX_XML AND NOT HAVE_LIBXML2)
 481 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 482 #endif()
 483 #if(GMX_XML)
 484 #    include_directories(${LIBXML2_INCLUDE_DIR})
 485 #    set(PKG_XML libxml-2.0)
 486 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 487 #endif()
 488
 489 if(DEFINED HWLOC_LIBRARIES)
 490   set(Hwloc_FIND_QUIETLY TRUE)
 491 endif()
 492 find_package(Hwloc 1.5)
 493 if (HWLOC_FOUND)
 494     if (HWLOC_LIBRARIES MATCHES ".a$")
 495         set(_STATIC_HWLOC TRUE)
 496     endif()
 497
 498     gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 499     if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 500         message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 501         set(GMX_HWLOC_DEFAULT OFF)
 502     else()
 503         set(GMX_HWLOC_DEFAULT ON)
 504     endif()
 505 else()
 506     set(GMX_HWLOC_DEFAULT OFF)
 507 endif()
 508 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 509 if(GMX_HWLOC)
 510     if(HWLOC_FOUND)
 511         include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 512         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 513     else()
 514         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 515     endif()
 516 endif()
 517
 518 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 519 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 520 if(GMX_EXTERNAL_TINYXML2)
 521     # Find an external TinyXML-2 library.
 522     find_package(TinyXML-2 3.0.0)
 523     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 524     if(NOT HAVE_TINYXML2)
 525         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 526     endif()
 527 endif()
 528
 529 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 530 mark_as_advanced(GMX_EXTRAE)
 531
 532 if (GMX_EXTRAE)
 533   find_package(EXTRAE)
 534   if(EXTRAE_FOUND)
 535     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 536     set(HAVE_EXTRAE 1)
 537   else()
 538     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 539   endif()
 540 endif()
 541
 542 option(GMX_X11 "Use X window system" OFF)
 543 if (GMX_X11)
 544     find_package(X11)
 545     # X11 includes/libraries are only set in the ngmx subdirectory!
 546     if(NOT X11_FOUND)
 547         message(FATAL_ERROR
 548                 "X11 include files and/or libraries were not found. "
 549                 "Set GMX_X11=OFF to compile without X11 support. "
 550                 "gmx view will not be available.")
 551     endif()
 552     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 553 endif()
 554
 555 include(ThreadMPI)
 556 # Enable core threading facilities
 557 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 558 # Enable tMPI C++ support
 559 tmpi_enable_cxx()
 560 if(GMX_THREAD_MPI)
 561     # enable MPI functions
 562     tmpi_enable()
 563     set(MPI_IN_PLACE_EXISTS 1)
 564 endif()
 565 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 566 if (TMPI_ATOMICS_DISABLED)
 567    add_definitions(-DTMPI_ATOMICS_DISABLED)
 568 endif()
 569
 570 include(gmxManageTNG)
 571
 572 include(gmxManageLmfit)
 573
 574 if(GMX_GPU)
 575     # now that we have detected the dependencies, do the second configure pass
 576     gmx_gpu_setup()
 577 endif()
 578
 579 if(CYGWIN)
 580     set(GMX_CYGWIN 1)
 581 endif()
 582
 583 if(WIN32)
 584     set(GMX_NATIVE_WINDOWS 1)
 585     # This makes windows.h not declare min/max as macros that would break
 586     # C++ code using std::min/std::max.
 587     add_definitions(-DNOMINMAX)
 588 endif()
 589
 590 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 591     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 592         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 593     endif()
 594     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 595         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 596     endif()
 597 endif()
 598
 599 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 600 mark_as_advanced(GMX_BUILD_UNITTESTS)
 601 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 602
 603 ########################################################################
 604 # Our own GROMACS tests
 605 ########################################################################
 606
 607 add_definitions( -DHAVE_CONFIG_H )
 608 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 609 # TODO required at high level because both libgromacs and progs/mdrun
 610 # require it, both for thread-MPI and its atomics and mutexes.
 611 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 612 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 613 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 614
 615 include(gmxTestInlineASM)
 616 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 617
 618 include(gmxSetBuildInformation)
 619 gmx_set_build_information()
 620
 621 gmx_option_multichoice(
 622     GMX_USE_RDTSCP
 623     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 624     "AUTO"
 625     OFF ON AUTO DETECT)
 626 mark_as_advanced(GMX_USE_RDTSCP)
 627
 628 macro(gmx_check_rdtscp)
 629     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 630         set(HAVE_RDTSCP 1)
 631         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 632     else()
 633         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 634     endif()
 635 endmacro()
 636
 637 set(HAVE_RDTSCP 0)
 638 if (GMX_USE_RDTSCP STREQUAL "ON")
 639     set(HAVE_RDTSCP 1)
 640 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 641     gmx_check_rdtscp()
 642 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 643     # If the user specified automated SIMD selection, that the choice
 644     # is made based on detection on the build host. If so, then RDTSCP
 645     # should be chosen the same way.
 646     #
 647     # If the user specified an AVX SIMD level (e.g. when
 648     # cross-compiling GROMACS) then they will get our best guess, ie
 649     # that in practice AVX mostly correlates with rdtscp (and anyway
 650     # is only relevant in rather old x86 hardware).
 651     if (GMX_SIMD STREQUAL "AUTO")
 652         gmx_check_rdtscp()
 653     elseif (GMX_SIMD MATCHES "AVX")
 654         set(HAVE_RDTSCP 1)
 655     endif()
 656 endif()
 657 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 658 if (HAVE_RDTSCP_CHANGED)
 659     if (HAVE_RDTSCP)
 660         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 661     else()
 662         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 663     endif()
 664 endif()
 665
 666 include(gmxTestLargeFiles)
 667 gmx_test_large_files(GMX_LARGEFILES)
 668
 669 include(gmxTestSignal)
 670 gmx_test_sigusr1(HAVE_SIGUSR1)
 671
 672 include(gmxTestPipes)
 673 gmx_test_pipes(HAVE_PIPES)
 674
 675 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 676
 677 include(gmxTestXDR)
 678 gmx_test_xdr(GMX_SYSTEM_XDR)
 679 if(NOT GMX_SYSTEM_XDR)
 680     set(GMX_INTERNAL_XDR 1)
 681 endif()
 682
 683
 684 ##################################################
 685 # Process SIMD instruction settings
 686 ##################################################
 687 # This checks what flags to add in order to
 688 # support the SIMD instructions we need, it sets
 689 # correct defines for the SIMD instructions supported,
 690 # and adds advanced options to control accuracy
 691 # for SIMD math operations.
 692 include(gmxManageSimd)
 693 gmx_manage_simd()
 694
 695 include(gmxManageCycleCounters)
 696 gmx_manage_cycle_counters()
 697
 698 # Process QM/MM Settings
 699 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 700     set(GMX_QMMM_GAUSSIAN 1)
 701 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 702     set(GMX_QMMM_MOPAC 1)
 703 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 704     set(GMX_QMMM_GAMESS 1)
 705 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 706     set(GMX_QMMM_ORCA 1)
 707 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 708     # nothing to do
 709 else()
 710     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 711 endif()
 712
 713
 714 ##################################################
 715 # Process FFT library settings
 716 ##################################################
 717 include(gmxManageFFTLibraries)
 718
 719
 720 include(gmxManageLinearAlgebraLibraries)
 721
 722 include(gmxManagePluginSupport)
 723
 724 if (GMX_USE_PLUGINS)
 725     if(NOT GMX_VMD_PLUGIN_PATH)
 726         find_package(VMD)
 727     endif()
 728 endif()
 729
 730 # Link real-time library for POSIX timers. The check for clock_gettime
 731 # confirms the linkability of rt.
 732 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 733     list(APPEND GMX_EXTRA_LIBRARIES rt)
 734 endif()
 735
 736 # Math and thread libraries must often come after all others when linking...
 737 if (HAVE_LIBM)
 738     list(APPEND GMX_PUBLIC_LIBRARIES m)
 739 endif()
 740
 741 option(GMX_NACL "Configure for Native Client builds" OFF)
 742 if (GMX_NACL)
 743   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 744   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 745   # TODO: Is this still necessary with the check for its presence?
 746   set(GMX_USE_NICE 0)
 747   set(GMX_NO_RENAME 1)
 748 endif()
 749 mark_as_advanced(GMX_NACL)
 750
 751 if(GMX_FAHCORE)
 752   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 753       "Path to swindirect.h")
 754   include_directories(${COREWRAP_INCLUDE_DIR})
 755 endif()
 756
 757 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 758 # produce warnings if that fails.
 759 set(build_help_default AUTO)
 760 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 761     set(build_help_default OFF)
 762 endif()
 763 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 764 mark_as_advanced(GMX_BUILD_HELP)
 765 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 766     message(FATAL_ERROR
 767         "Rebuilding shell completions or man pages is not supported for "
 768         "in-source builds from a source distribution. "
 769         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 770 endif()
 771
 772 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 773 # these are set after everything else
 774 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 775     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 776     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 777     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 778     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 779 else()
 780     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 781     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 782     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 783     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 784     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 785     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 786     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 787     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 788     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 789 endif()
 790
 791 if(NOT GMX_OPENMP)
 792     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 793     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 794     unset(OpenMP_C_FLAGS CACHE)
 795     unset(OpenMP_CXX_FLAGS CACHE)
 796 else()
 797     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 798     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 799 endif()
 800
 801 ########################################################################
 802 # Specify install locations
 803 ########################################################################
 804 # Use GNUInstallDirs to set paths on multiarch systems.
 805 include(GNUInstallDirs)
 806
 807 # Customization for the installation tree paths.
 808 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 809     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 810 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 811     "Data installation directory under share/ (default: gromacs)")
 812 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 813
 814 # These variables are used internally to provide a central location for
 815 # customizing the install locations.
 816 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 817 set(BIN_INSTALL_DIR       bin)
 818 # This variable also gets written into config.h for use in finding the data
 819 # directories.
 820 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 821 set(MAN_INSTALL_DIR       share/man)
 822 # If the nesting level wrt. the installation root is changed,
 823 # gromacs-config.cmake.cmakein needs to be adapted.
 824 set(CMAKE_INSTALL_DIR     share/cmake)
 825 # TODO: Make GMXRC adapt if this is changed
 826 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 827 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 828 set(INCL_INSTALL_DIR      include)
 829
 830 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 831
 832 # Binary and library suffix options
 833 include(gmxManageSuffixes)
 834
 835 ################################################################
 836 # Shared library load path settings
 837 ################################################################
 838 if(NOT GMX_BUILD_SHARED_EXE)
 839     # No rpath
 840     set(CMAKE_SKIP_RPATH TRUE)
 841     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 842     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 843 else()
 844     # The build folder always has bin/ and lib/; if we are also going to
 845     # install to lib/, then the installation RPATH works also in the build
 846     # tree.  This makes installation slightly faster (no need to rewrite the
 847     # RPATHs), and makes the binaries in the build tree relocatable.
 848     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 849         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 850     endif()
 851     # Set the RPATH as relative to the executable location to make the
 852     # binaries relocatable.
 853     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 854         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 855     else()
 856         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 857     endif()
 858     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 859     set(CMAKE_MACOSX_RPATH 1)
 860 endif()
 861
 862 #COPYING file: Only necessary for binary distributions.
 863 #Simpler to always install.
 864 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 865
 866 if (GMX_BUILD_FOR_COVERAGE)
 867     # Code heavy with asserts makes conditional coverage close to useless metric,
 868     # as by design most of the false branches are impossible to trigger in
 869     # correctly functioning code.  And the benefit of testing those that could
 870     # be triggered by using an API against its specification isn't usually
 871     # worth the effort.
 872     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 873 endif()
 874
 875 if (BUILD_TESTING)
 876     include(tests/CheckTarget.cmake)
 877 endif()
 878
 879 if (NOT GMX_BUILD_MDRUN_ONLY)
 880     add_subdirectory(docs)
 881     add_subdirectory(share)
 882     add_subdirectory(scripts)
 883 endif()
 884 add_subdirectory(src)
 885
 886 if (BUILD_TESTING)
 887     add_subdirectory(tests)
 888 endif()
 889
 890 gmx_cpack_write_config()
 891
 892 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 893 # Don't bother the user after the first configure pass.
 894 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 895     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 896 endif()
 897 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 898
 899 #######################
 900 ## uninstall target
 901 #######################
 902 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 903                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 904                   IMMEDIATE @ONLY)
 905 ###########################
 906 ADD_CUSTOM_TARGET(uninstall
 907                   "${CMAKE_COMMAND}" -P
 908                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 909 ###########################
 910 set_directory_properties(PROPERTIES
 911             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")