cmake/gmxManageSuffixes.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 function(gmx_create_suffix_options)
  36     set(_defaults "_d for double, _mpi for MPI, _mpi_d for both")
  37     option(
  38         GMX_DEFAULT_SUFFIX
  39         "Use default suffixes for GROMACS binaries and libs (${_defaults}; rerun cmake after changing to see relevant options)"
  40         ON)
  41     gmx_dependent_cache_variable(
  42         GMX_BINARY_SUFFIX
  43         "Suffix for GROMACS binaries (default: ${_defaults})."
  44         STRING ""
  45         "NOT GMX_DEFAULT_SUFFIX")
  46     gmx_dependent_cache_variable(
  47         GMX_LIBS_SUFFIX
  48         "Suffix for GROMACS libraries (default: ${_defaults})."
  49         STRING ""
  50         "NOT GMX_DEFAULT_SUFFIX")
  51 endfunction()
  52
  53 gmx_create_suffix_options()
  54 if (GMX_DEFAULT_SUFFIX)
  55     gmx_check_if_changed(SUFFIXES_CHANGED GMX_DEFAULT_SUFFIX)
  56     set(GMX_BINARY_SUFFIX "")
  57     set(GMX_LIBS_SUFFIX "")
  58     if (GMX_LIB_MPI)
  59         set(GMX_BINARY_SUFFIX "_mpi")
  60         set(GMX_LIBS_SUFFIX "_mpi")
  61     endif()
  62     if (GMX_DOUBLE)
  63         set(GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
  64         set(GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
  65     endif()
  66     if (SUFFIXES_CHANGED)
  67         message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
  68         message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
  69     endif()
  70 else()
  71     if ("${GMX_LIBS_SUFFIX}" MATCHES "^_mdrun")
  72         message(FATAL_ERROR "Library suffix (GMX_LIBS_SUFFIX) cannot start with '_mdrun', as that is reserved for internal use")
  73     endif()
  74     gmx_check_if_changed(SUFFIXES_CHANGED
  75                          GMX_DEFAULT_SUFFIX GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
  76     if (SUFFIXES_CHANGED)
  77         message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
  78         message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
  79     endif()
  80 endif()
  81 unset(SUFFIXES_CHANGED)
  82
  83 if (GMX_BUILD_MDRUN_ONLY)
  84     set(GMX_LIBS_SUFFIX "_mdrun${GMX_LIBS_SUFFIX}")
  85 endif()