cmake/gmxManageOpenMP.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Manage the OpenMP setup. This wrapper file checks for some known-bad compiler
  36 # versions before trying to detect OpenMP with the standard find-package-module,
  37 # and then does some additional tests for flags afterwards.
  38
  39 if(GMX_OPENMP)
  40     if(CMAKE_C_COMPILER_ID MATCHES "Cray" AND CMAKE_VERSION VERSION_LESS 3)
  41         message(STATUS "OpenMP multithreading is not detected correctly for the Cray compiler with CMake before version 3.0 (see http://public.kitware.com/Bug/view.php?id=14567)")
  42         set(GMX_OPENMP OFF CACHE BOOL
  43             "OpenMP multithreading is not detected correctly for the Cray compiler with CMake before version 3.0 (see http://public.kitware.com/Bug/view.php?id=14567)" FORCE)
  44     else()
  45         # We should do OpenMP detection if we get here
  46         # OpenMP check must come before other CFLAGS!
  47         find_package(OpenMP)
  48         if(OPENMP_FOUND)
  49             # CMake on Windows doesn't support linker flags passed to target_link_libraries
  50             # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
  51             if(NOT (WIN32 AND NOT MINGW))
  52                 if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP AND NOT APPLE)
  53                     set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
  54                     set(OpenMP_SHARED_LINKER_FLAGS "")
  55                 else()
  56                     # Only set a linker flag if the user didn't set them manually
  57                     if(NOT DEFINED OpenMP_LINKER_FLAGS)
  58                         set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
  59                     endif()
  60                     if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
  61                         set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
  62                     endif()
  63                 endif()
  64             endif()
  65             if(MINGW)
  66                 #GCC Bug 48659
  67                 set(OpenMP_C_FLAGS "${OpenMP_C_FLAGS} -mstackrealign")
  68             endif()
  69         else()
  70             message(WARNING
  71                     "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
  72             set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
  73         endif()
  74     endif()
  75 endif()
  76 gmx_dependent_cache_variable(GMX_OPENMP_MAX_THREADS
  77     "Maximum number of OpenMP Threads supported. Has to be 32 or a multiple of 64."
  78     STRING 32 GMX_OPENMP)
  79 mark_as_advanced(GMX_OPENMP_MAX_THREADS)
  80 math(EXPR MAX_THREAD_MOD "${GMX_OPENMP_MAX_THREADS} % 64")
  81 if (NOT GMX_OPENMP_MAX_THREADS EQUAL 32 AND NOT ${MAX_THREAD_MOD} EQUAL 0)
  82     message(FATAL_ERROR "Only 32 or multiples of 64 supported for GMX_OPENMP_MAX_THREADS.")
  83 endif()