src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  38 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  39
  40 function (_gmx_add_files_to_property PROPERTY)
  41     foreach (_file ${ARGN})
  42         if (IS_ABSOLUTE "${_file}")
  43             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  44         else()
  45             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  46                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  47         endif()
  48     endforeach()
  49 endfunction ()
  50
  51 function (gmx_add_libgromacs_sources)
  52     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  53 endfunction ()
  54
  55 function (gmx_install_headers)
  56     if (NOT GMX_BUILD_MDRUN_ONLY)
  57         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  58         install(FILES       ${ARGN}
  59                 DESTINATION "${INCL_INSTALL_DIR}/${_dest}"
  60                 COMPONENT   development)
  61     endif()
  62     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  63 endfunction ()
  64
  65 function (gmx_write_installed_header_list)
  66     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  67     string(REPLACE ";" "\n" _list "${_list}")
  68     # TODO: Make this only update the file timestamp if the contents actually change.
  69     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  70 endfunction()
  71
  72 add_subdirectory(gmxlib)
  73 add_subdirectory(mdlib)
  74 add_subdirectory(applied-forces)
  75 add_subdirectory(listed-forces)
  76 add_subdirectory(commandline)
  77 add_subdirectory(domdec)
  78 add_subdirectory(ewald)
  79 add_subdirectory(fft)
  80 add_subdirectory(gpu_utils)
  81 add_subdirectory(hardware)
  82 add_subdirectory(linearalgebra)
  83 add_subdirectory(math)
  84 add_subdirectory(mdrunutility)
  85 add_subdirectory(mdtypes)
  86 add_subdirectory(onlinehelp)
  87 add_subdirectory(options)
  88 add_subdirectory(pbcutil)
  89 add_subdirectory(random)
  90 add_subdirectory(tables)
  91 add_subdirectory(timing)
  92 add_subdirectory(topology)
  93 add_subdirectory(trajectory)
  94 add_subdirectory(utility)
  95 add_subdirectory(fileio)
  96 add_subdirectory(swap)
  97 add_subdirectory(essentialdynamics)
  98 add_subdirectory(pulling)
  99 add_subdirectory(simd)
 100 add_subdirectory(imd)
 101 if (NOT GMX_BUILD_MDRUN_ONLY)
 102     add_subdirectory(gmxana)
 103     add_subdirectory(gmxpreprocess)
 104     add_subdirectory(correlationfunctions)
 105     add_subdirectory(statistics)
 106     add_subdirectory(analysisdata)
 107     add_subdirectory(selection)
 108     add_subdirectory(trajectoryanalysis)
 109     add_subdirectory(energyanalysis)
 110     add_subdirectory(tools)
 111 endif()
 112
 113 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 114 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 115
 116 # This would be the standard way to include thread_mpi, but
 117 # we want libgromacs to link the functions directly
 118 #if(GMX_THREAD_MPI)
 119 #    add_subdirectory(thread_mpi)
 120 #endif()
 121 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 122
 123 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 124 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 125
 126 get_lmfit_properties(LMFIT_SOURCES LMFIT_LIBRARIES_TO_LINK LMFIT_INCLUDE_DIRECTORY LMFIT_INCLUDE_DIR_ORDER)
 127 include_directories(${LMFIT_INCLUDE_DIR_ORDER} SYSTEM "${LMFIT_INCLUDE_DIRECTORY}")
 128 list(APPEND LIBGROMACS_SOURCES ${LMFIT_SOURCES})
 129
 130 configure_file(version.h.cmakein version.h)
 131 gmx_install_headers(
 132     analysisdata.h
 133     commandline.h
 134     options.h
 135     random.h
 136     selection.h
 137     trajectoryanalysis.h
 138     utility.h
 139     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 140     )
 141
 142 # This code is here instead of utility/CMakeLists.txt, because CMake
 143 # custom commands and source file properties can only be set in the directory
 144 # that contains the target that uses them.
 145 # TODO: Generate a header instead that can be included from baseversion.c.
 146 # That probably simplifies things somewhat.
 147 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 148 gmx_configure_version_file(
 149     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 150     REMOTE_HASH)
 151 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 152
 153 if (GMX_USE_CUDA)
 154     # Work around FindCUDA that prevents using target_link_libraries()
 155     # with keywords otherwise...
 156     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 157     cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 158 else()
 159     add_library(libgromacs ${LIBGROMACS_SOURCES})
 160 endif()
 161
 162 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 163 # is a generated source file. These are awkward to suppress inline, so
 164 # we do it in the compilation command (after testing that the compiler
 165 # supports the suppressions).
 166 include(CheckCXXCompilerFlag)
 167 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 168 if (HAS_NO_UNUSED_PARAMETER)
 169     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 170 endif()
 171 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 172
 173 gmx_setup_tng_for_libgromacs()
 174
 175 target_link_libraries(libgromacs
 176                       PRIVATE
 177                       ${EXTRAE_LIBRARIES}
 178                       ${GMX_EXTRA_LIBRARIES}
 179                       ${GMX_COMMON_LIBRARIES}
 180                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 181                       ${LMFIT_LIBRARIES_TO_LINK}
 182                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS} ${OPENCL_LIBRARIES}
 183                       ${GMX_STDLIB_LIBRARIES}
 184                       PUBLIC
 185                       ${GMX_PUBLIC_LIBRARIES}
 186                       )
 187 set_target_properties(libgromacs PROPERTIES
 188                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 189                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 190                       VERSION ${LIBRARY_VERSION}
 191                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 192
 193 gmx_write_installed_header_list()
 194
 195 # Only install the library in mdrun-only mode if it is actually necessary
 196 # for the binary
 197 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 198     install(TARGETS libgromacs
 199             EXPORT libgromacs
 200             LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 201             RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 202             ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 203             COMPONENT libraries)
 204 endif()
 205
 206 if (NOT GMX_BUILD_MDRUN_ONLY)
 207     include(InstallLibInfo.cmake)
 208 endif()
 209
 210 # Technically, the user could want to do this for an OpenCL build
 211 # using the CUDA runtime, but currently there's no reason to want to
 212 # do that.
 213 if (INSTALL_CUDART_LIB) #can be set manual by user
 214     if (GMX_USE_CUDA)
 215         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 216             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 217             if(IS_CUDART) #libcuda should not be installed
 218                 #install also name-links (linker uses those)
 219                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 220                 install(FILES ${CUDA_LIBS} DESTINATION
 221                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 222             endif()
 223         endforeach()
 224     else()
 225         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 226     endif()
 227 endif()
 228
 229 if(GMX_USE_OPENCL)
 230     set(OPENCL_KERNELS ${MDLIB_OPENCL_KERNELS})
 231
 232     install(FILES ${OPENCL_KERNELS} DESTINATION
 233         ${OCL_INSTALL_DIR} COMPONENT libraries)
 234 endif()