CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 # PROJECT_VERSION should have the following structure:
  15 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  16 #
  17 # The "-dev" suffix is important to keep because it makes possible to distinguish
  18 # between a build from official release and a build from git release branch on a
  19 # machine with no git.
  20 #
  21 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  22 set(PROJECT_VERSION "4.6-dev")
  23 set(CUSTOM_VERSION_STRING ""
  24     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  25 mark_as_advanced(CUSTOM_VERSION_STRING)
  26 if (CUSTOM_VERSION_STRING)
  27     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  28 endif (CUSTOM_VERSION_STRING)
  29 set(SOVERSION 6)
  30 # It is a bit irritating, but this has to be set separately for now!
  31 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  32 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  33 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  34
  35
  36 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  38
  39 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  40 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  41 endif()
  42
  43 if(NOT CMAKE_BUILD_TYPE)
  44     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  45 endif(NOT CMAKE_BUILD_TYPE)
  46
  47 enable_language(C)
  48
  49 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  50 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  51 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  52 set(CPACK_SET_DESTDIR "ON")
  53 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  54 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  55 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  56 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  57 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  58
  59 #must come after all cpack settings!
  60 include(CPack)
  61
  62 ########################################################################
  63 # Check and warn if cache generated on a different host is being reused
  64 ########################################################################
  65 if(CMAKE_HOST_UNIX)
  66     execute_process(COMMAND hostname
  67                     OUTPUT_VARIABLE TMP_HOSTNAME
  68                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  69     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  70         message(WARNING "
  71             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  72             is being reused! This could lead to inconsitencies; therefore, it is
  73             recommended to regenerate the cache!")
  74     endif()
  75     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  76             "Hostname of the machine where the cache was generated.")
  77 endif()
  78
  79 ########################################################################
  80 # Fix stupid flags on Windows
  81 ########################################################################
  82 SET(SHARED_LIBS_DEFAULT ON)
  83 IF( WIN32 AND NOT CYGWIN)
  84   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  85   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  86   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  87
  88   IF (GMX_PREFER_STATIC_LIBS)
  89     #Only setting Debug and Release flags. Others configurations current not used.
  90     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  91     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  92     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  93     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  94     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  95     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
  96     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
  97     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
  98   ENDIF()
  99
 100   #Workaround for cmake bug 13174. Replace deprecated options.
 101   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 102     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 103     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 104   ENDIF()
 105   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 106     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 107     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 108     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 109
 110     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 111     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 112   ENDIF()
 113 ENDIF()
 114
 115 ########################################################################
 116 # User input options                                                   #
 117 ########################################################################
 118 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 119 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 120 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 121 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 122 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 123 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 124 mark_as_advanced(GMX_POWERPC_INVSQRT)
 125 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 126 mark_as_advanced(GMX_FAHCORE)
 127 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 128
 129 include(gmxDetectAcceleration)
 130 if(NOT DEFINED GMX_ACCELERATION)
 131     if(CMAKE_CROSSCOMPILING)
 132         set(GMX_SUGGESTED_ACCELERATION "None")
 133     else(CMAKE_CROSSCOMPILING)
 134         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 135     endif(CMAKE_CROSSCOMPILING)
 136 endif(NOT DEFINED GMX_ACCELERATION)
 137
 138 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 139     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 140
 141 set(GMX_FFT_LIBRARY "fftw3"
 142     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 143 option(GMX_DISABLE_FFTW_MEASURE
 144        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 145 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 146 set(GMX_QMMM_PROGRAM "none"
 147     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 148 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 149 mark_as_advanced(GMX_BROKEN_CALLOC)
 150 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 151 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 152 mark_as_advanced(GMX_MPI_IN_PLACE)
 153 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 154 mark_as_advanced(GMX_LOAD_PLUGINS)
 155
 156 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 157
 158 option(USE_VERSION_H "Generate development version string/information" ON)
 159 mark_as_advanced(USE_VERSION_H)
 160
 161 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 162
 163 if(UNIX AND NOT APPLE)
 164     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 165     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 166 endif()
 167
 168
 169 ######################################################################
 170 # compiler tests
 171 # these need ot be done early (before further tests).
 172 #####################################################################
 173
 174 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 175 # branch (proposed for v2.8.9) to be able to detect invalid options
 176 # with the Intel Compilers.
 177 # Remove these files from the source tree when a CMake version that
 178 # includes the features in question becomes required.
 179 include(CheckCCompilerFlag)
 180 include(CheckCXXCompilerFlag)
 181
 182 # OpenMP check must come before other CFLAGS!
 183 if(GMX_OPENMP)
 184     find_package(OpenMP)
 185     if(OPENMP_FOUND)
 186         set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 187         set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 188         add_definitions(-DGMX_OPENMP)
 189     else(OPENMP_FOUND)
 190         message(WARNING
 191                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 192                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 193                 "if you can - for now we are proceeding by turning off OpenMP.")
 194         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 195     endif(OPENMP_FOUND)
 196 endif()
 197
 198
 199 include(gmxCFlags)
 200 gmx_c_flags()
 201
 202 ########################################################################
 203 # Set up binary and library suffixing
 204 ########################################################################
 205 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 206 set(GMX_LIBS_SUFFIX ""
 207   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 208 if (GMX_DEFAULT_SUFFIX)
 209   set(GMX_BINARY_SUFFIX "")
 210   set(GMX_LIBS_SUFFIX "")
 211   if (GMX_MPI)
 212     set(GMX_BINARY_SUFFIX "_mpi")
 213     set(GMX_LIBS_SUFFIX "_mpi")
 214   endif(GMX_MPI)
 215   if (GMX_DOUBLE)
 216     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 217     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 218   endif(GMX_DOUBLE)
 219   if (GMX_OPENMM)
 220     set (GMX_BINARY_SUFFIX "-openmm")
 221     set (GMX_LIBS_SUFFIX "_openmm")
 222   endif(GMX_OPENMM)
 223   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 224   if (NOT SUFFIX_QUIETLY)
 225     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 226     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 227   endif (NOT SUFFIX_QUIETLY)
 228 else(GMX_DEFAULT_SUFFIX)
 229   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 230   if (NOT SUFFIX_QUIETLY)
 231     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 232     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 233   endif (NOT SUFFIX_QUIETLY)
 234 endif(GMX_DEFAULT_SUFFIX)
 235 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 236
 237 set(PKG_CFLAGS "")
 238 if(GMX_DOUBLE)
 239     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 240 endif(GMX_DOUBLE)
 241 if(GMX_SOFTWARE_INVSQRT)
 242   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 243 endif(GMX_SOFTWARE_INVSQRT)
 244 if(GMX_POWERPC_INVSQRT)
 245   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 246 endif(GMX_POWERPC_INVSQRT)
 247
 248 ########################################################################
 249 #Process MPI settings
 250 ########################################################################
 251 include(gmxManageMPI)
 252
 253 #######################################################################
 254 # Check for options incompatible with OpenMM build                    #
 255 #######################################################################
 256 if(GMX_OPENMM)
 257     # we'll use the built-in fft to avoid unnecessary dependencies
 258     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 259     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 260         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 261         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 262                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 263     endif()
 264     if(GMX_MPI)
 265         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 266     endif(GMX_MPI)
 267     if(GMX_THREAD_MPI)
 268         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 269         set(GMX_THREAD_MPI OFF CACHE BOOL
 270                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 271     endif(GMX_THREAD_MPI)
 272     if(GMX_OPENMP)
 273         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 274         set(GMX_OPENMP OFF CACHE BOOL
 275             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 276     endif()
 277     if(GMX_SOFTWARE_INVSQRT)
 278         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 279                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 280     endif(GMX_SOFTWARE_INVSQRT)
 281     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 282     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 283         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 284         set(GMX_ACCELERATION "none" CACHE STRING
 285                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 286     endif()
 287     if(GMX_FAHCORE)
 288         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 289     endif(GMX_FAHCORE)
 290     if(GMX_DOUBLE)
 291         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 292     endif()
 293     # mark as advanced the unused variables
 294     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 295         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 296 else(GMX_OPENMM)
 297      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 298         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 299 endif(GMX_OPENMM)
 300
 301
 302
 303
 304 ########################################################################
 305 # Basic system tests (standard libraries, headers, functions, types)   #
 306 ########################################################################
 307 include(CheckIncludeFiles)
 308 check_include_files(string.h     HAVE_STRING_H)
 309 check_include_files(math.h       HAVE_MATH_H)
 310 check_include_files(limits.h     HAVE_LIMITS_H)
 311 check_include_files(memory.h     HAVE_MEMORY_H)
 312 check_include_files(unistd.h     HAVE_UNISTD_H)
 313 check_include_files(direct.h     HAVE_DIRECT_H)
 314 check_include_files(pwd.h        HAVE_PWD_H)
 315 check_include_files(stdint.h     HAVE_STDINT_H)
 316 check_include_files(stdlib.h     HAVE_STDLIB_H)
 317 check_include_files(pthread.h    HAVE_PTHREAD_H)
 318 check_include_files(dirent.h     HAVE_DIRENT_H)
 319 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 320 check_include_files(regex.h      HAVE_REGEX_H)
 321 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 322 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 323 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 324 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 325 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 326 check_include_files(io.h                 HAVE_IO_H)
 327
 328
 329 include(CheckFunctionExists)
 330 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 331 check_function_exists(strdup            HAVE_STRDUP)
 332 check_function_exists(vprintf           HAVE_VPRINTF)
 333 check_function_exists(memcmp            HAVE_MEMCMP)
 334 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 335 check_function_exists(memalign          HAVE_MEMALIGN)
 336 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 337 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 338 check_function_exists(isnan             HAVE_ISNAN)
 339 check_function_exists(_isnan            HAVE__ISNAN)
 340 check_function_exists(fsync             HAVE_FSYNC)
 341 check_function_exists(_fileno           HAVE__FILENO)
 342 check_function_exists(fileno            HAVE_FILENO)
 343 check_function_exists(_commit           HAVE__COMMIT)
 344 check_function_exists(lstat             HAVE_LSTAT)
 345 check_function_exists(sigaction         HAVE_SIGACTION)
 346
 347 include(CheckLibraryExists)
 348 check_library_exists(m sqrt "" HAVE_LIBM)
 349 check_library_exists(m cbrt "" HAVE_CBRT)
 350
 351
 352 include(CheckTypeSize)
 353
 354 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 355 check_type_size("int"           SIZEOF_INT)
 356 check_type_size("long int"      SIZEOF_LONG_INT)
 357 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 358 check_type_size("off_t"         SIZEOF_OFF_T)
 359 check_type_size("void *"        SIZEOF_VOIDP)
 360
 361 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 362     set(GMX_64_BIT TRUE)
 363 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 364     set(GMX_64_BIT FALSE)
 365 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 366
 367 # Check for some basic types that we *need*, so set these to int if they are not present
 368 check_type_size(uid_t uid_t)
 369 if(NOT uid_t)
 370   set(uid_t int)
 371 else(NOT uid_t)
 372   set(uid_t 0)
 373 endif(NOT uid_t)
 374
 375 check_type_size(gid_t gid_t)
 376 if(NOT gid_t)
 377   set(gid_t 1)
 378 else(NOT gid_t)
 379   set(gid_t 0)
 380 endif(NOT gid_t)
 381
 382 check_type_size(size_t size_t)
 383 if(NOT size_t)
 384   set(size_t int)
 385 else(NOT size_t)
 386   set(size_t 0)
 387 endif(NOT size_t)
 388
 389 check_type_size(off_t off_t)
 390 if(NOT off_t)
 391   set(off_t int)
 392 else(NOT off_t)
 393   set(off_t 0)
 394 endif(NOT off_t)
 395
 396 include(TestBigEndian)
 397 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 398
 399
 400
 401
 402 ########################################################################
 403 # Find external packages                                               #
 404 ########################################################################
 405 if(UNIX AND NOT APPLE)
 406     if(GMX_PREFER_STATIC_LIBS)
 407         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 408         if(BUILD_SHARED_LIBS)
 409             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 410             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 411         endif()
 412     endif()
 413 endif()
 414
 415 option(GMX_XML "Use libxml2 to parse xml files" ON)
 416 if (GMX_XML)
 417   find_package(LibXml2)
 418   set(PKG_XML "")
 419   if(LIBXML2_FOUND)
 420     include_directories(${LIBXML2_INCLUDE_DIR})
 421     set(PKG_XML libxml-2.0)
 422     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 423     set(HAVE_LIBXML2 1)
 424   endif(LIBXML2_FOUND)
 425 endif(GMX_XML)
 426
 427 option(GMX_GSL "Add support for gsl" OFF)
 428 if (GMX_GSL)
 429   find_package(gsl)
 430   set(PKG_GSL "")
 431   if(GSL_FOUND)
 432     include_directories(${GSL_INCLUDE_DIR})
 433     set(PKG_GSL gsl)
 434     set(HAVE_LIBGSL 1)
 435   endif(GSL_FOUND)
 436 endif (GMX_GSL)
 437
 438 option(GMX_X11 "Use X window system" OFF)
 439 if (GMX_X11)
 440         find_package(X11)
 441         # X11 includes/libraries are only set in the ngmx subdirectory!
 442         if(X11_FOUND)
 443         set(HAVE_X11 1)
 444         endif(X11_FOUND)
 445 endif(GMX_X11)
 446
 447 if(GMX_THREAD_MPI)
 448     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 449     include(ThreadMPI)
 450     set(THREAD_MPI_LIB thread_mpi)
 451     set(GMX_MPI 1)
 452     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 453 endif(GMX_THREAD_MPI)
 454
 455 if(GMX_OPENMM)
 456     set(CUDA_BUILD_EMULATION OFF)
 457     find_package(CUDA 3.1 REQUIRED)
 458     add_definitions(-DGMX_OPENMM)
 459     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 460         set(CUDA_VERBOSE_BUILD ON)
 461     endif()
 462     find_package(OpenMM)
 463 endif(GMX_OPENMM)
 464
 465
 466 if(APPLE)
 467    find_library(ACCELERATE_FRAMEWORK Accelerate)
 468    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 469 endif(APPLE)
 470
 471 if(CYGWIN)
 472     set(GMX_CYGWIN 1)
 473 endif(CYGWIN)
 474
 475 if(WIN32 AND NOT CYGWIN)
 476     set(GMX_NATIVE_WINDOWS 1)
 477 endif()
 478
 479 # only bother with finding git and using version.h if the source is a git repo
 480 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 481     if(USE_VERSION_H)
 482         # We need at least git v1.5.3 be able to parse git's date output. If not
 483         # found or the version is too small, we can't generate version information.
 484         find_package(Git)
 485
 486         # Find out the git version
 487         if(GIT_FOUND AND NOT GIT_VERSION)
 488           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 489             OUTPUT_VARIABLE _exec_out
 490             OUTPUT_STRIP_TRAILING_WHITESPACE)
 491           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 492           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 493           mark_as_advanced(GIT_VERSION)
 494         endif()
 495
 496         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 497           message("No compatible git version found, won't be able to generate proper development version information.")
 498           set(USE_VERSION_H OFF)
 499         endif()
 500     endif()
 501 else()
 502     set(USE_VERSION_H OFF)
 503 endif()
 504
 505 ########################################################################
 506 # Generate development version info for cache
 507 ########################################################################
 508 # set(GEN_VERSION_INFO_INTERNAL "ON")
 509 # include(gmxGenerateVersionString)
 510
 511 ########################################################################
 512 # Our own GROMACS tests
 513 ########################################################################
 514
 515 add_definitions( -DHAVE_CONFIG_H )
 516 include_directories(${CMAKE_BINARY_DIR}/src)
 517 include_directories(${CMAKE_BINARY_DIR}/include)
 518 include_directories(${CMAKE_SOURCE_DIR}/include)
 519
 520 include(gmxTestInlineASM)
 521 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 522
 523 include(gmxSetBuildInformation)
 524 gmx_set_build_information()
 525 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 526     # The timestep counter headers do not include config.h
 527     add_definitions(-DHAVE_RDTSCP)
 528 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 529
 530 include(gmxTestFloatFormat)
 531 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 532                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 533                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 534
 535 include(gmxTestLargeFiles)
 536 gmx_test_large_files(GMX_LARGEFILES)
 537 check_function_exists(fseeko     HAVE_FSEEKO)
 538
 539 include(gmxTestSignal)
 540 gmx_test_sigusr1(HAVE_SIGUSR1)
 541
 542 include(gmxTestInline)
 543 gmx_test_inline(INLINE_KEYWORD)
 544
 545 include(gmxTestRestrict)
 546 gmx_test_inline(RESTRICT_KEYWORD)
 547
 548 include(gmxTestPipes)
 549 gmx_test_pipes(HAVE_PIPES)
 550
 551 include(gmxTestIsfinite)
 552 gmx_test_isfinite(HAVE_ISFINITE)
 553 gmx_test__isfinite(HAVE__ISFINITE)
 554 gmx_test__finite(HAVE__FINITE)
 555
 556 include(gmxTestXDR)
 557 gmx_test_xdr(GMX_SYSTEM_XDR)
 558 if(NOT GMX_SYSTEM_XDR)
 559     set(GMX_INTERNAL_XDR 1)
 560     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 561 endif(NOT GMX_SYSTEM_XDR)
 562
 563 # Process nonbonded accelerated kernels settings
 564 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 565 if(${GMX_ACCELERATION} STREQUAL "NONE")
 566     # nothing to do
 567 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 568
 569     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 570     if(NOT GNU_SSE2_CFLAG)
 571         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 572     endif(NOT GNU_SSE2_CFLAG)
 573
 574     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 575     if(NOT GNU_SSE2_CXXFLAG)
 576         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 577     endif(NOT GNU_SSE2_CXXFLAG)
 578
 579     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 580
 581     # Only test the include after we have tried to add the correct flag for SSE2 support
 582     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 583
 584     if(NOT HAVE_EMMINTRIN_H)
 585         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 586     endif(NOT HAVE_EMMINTRIN_H)
 587
 588     # The user should not be able to set this orthogonally to the acceleration
 589     set(GMX_X86_SSE2 1)
 590
 591     message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 592
 593 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 594
 595     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 596     if (NOT GNU_SSE4_CFLAG)
 597         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 598     endif(NOT GNU_SSE4_CFLAG)
 599     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 600         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 601         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 602         # intrinsics when SSE2 support is enabled, so we try that instead.
 603         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 604     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 605
 606     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 607     if (NOT GNU_SSE4_CXXFLAG)
 608        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 609     endif(NOT GNU_SSE4_CXXFLAG)
 610     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 611         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 612         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 613         # intrinsics when SSE2 support is enabled, so we try that instead.
 614         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 615     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 616
 617     # This must come after we have added the -msse4.1 flag on some platforms.
 618     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 619
 620     if(NOT HAVE_SMMINTRIN_H)
 621         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 622     endif(NOT HAVE_SMMINTRIN_H)
 623
 624     # The user should not be able to set this orthogonally to the acceleration
 625     set(GMX_X86_SSE4_1 1)
 626     set(GMX_X86_SSE2   1)
 627
 628     message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 629
 630 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 631
 632     # Set the AVX compiler flag for both these choices!
 633
 634     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 635     if (NOT GNU_AVX_CFLAG)
 636         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 637     endif (NOT GNU_AVX_CFLAG)
 638     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 639         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 640     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 641
 642     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 643     if (NOT GNU_AVX_CXXFLAG)
 644        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 645     endif (NOT GNU_AVX_CXXFLAG)
 646     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 647        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 648     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 649
 650     # Only test the header after we have tried to add the flag for AVX support
 651     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 652
 653     if(NOT HAVE_IMMINTRIN_H)
 654         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 655     endif(NOT HAVE_IMMINTRIN_H)
 656
 657     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 658     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 659
 660     # The user should not be able to set this orthogonally to the acceleration
 661     set(GMX_X86_SSE4_1 1)
 662     set(GMX_X86_SSE2   1)
 663
 664     # But just enable one of the choices internally...
 665     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 666         set(GMX_X86_AVX_128_FMA 1)
 667         message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 668     else()
 669         # If we are not doing AVX_128, it must be AVX_256...
 670         set(GMX_X86_AVX_256 1)
 671         message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 672     endif()
 673
 674 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 675
 676 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 677 #    We need to fake it a bit here to avoid jenkins build errors!
 678 #    add_definitions(-DGMX_FORTRAN)
 679
 680 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 681 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 682     message(STATUS "Configuring for BlueGene")
 683     set(GMX_BLUEGENE 1)
 684     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 685         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 686         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 687     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 688     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 689     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 690     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 691     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 692     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 693 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 694     set(GMX_POWER6 1)
 695     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 696     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 697 else(${GMX_ACCELERATION} STREQUAL "NONE")
 698     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 699 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 700
 701 if(GMX_FORTRAN OR GMX_POWER6)
 702     if (GMX_THREAD_MPI)
 703         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 704     endif(GMX_THREAD_MPI)
 705     enable_language(Fortran)
 706     include(FortranCInterface)
 707     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 708     if(extra_under_score)
 709         set(extrasuffix "_")
 710     endif(extra_under_score)
 711     if(prefix)
 712       set(prefix "${prefix} ##")
 713     endif(prefix)
 714     if(suffix)
 715       set(suffix "## ${suffix}")
 716       if(extrasuffix)
 717         set(extrasuffix "${suffix}${extrasuffix}")
 718       endif(extrasuffix)
 719     else(suffix)
 720       if(extrasuffix)
 721         # Don't know if this is needed, but it can't hurt
 722         set(extrasuffix "## ${extrasuffix}")
 723       endif(extrasuffix)
 724     endif(suffix)
 725
 726     if(isupper)
 727         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 728         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 729     else(isupper)
 730         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 731         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 732     endif(isupper)
 733 else(GMX_FORTRAN OR GMX_POWER6)
 734         set(F77_FUNCDEF   "name ## _")
 735         set(F77_FUNCDEF_  "name ## _")
 736 endif(GMX_FORTRAN OR GMX_POWER6)
 737
 738 # Process QM/MM Settings
 739 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 740 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 741     set(GMX_QMMM_GAUSSIAN 1)
 742 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 743     set(GMX_QMMM_MOPAC 1)
 744 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 745     set(GMX_QMMM_GAMESS 1)
 746 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 747     set(GMX_QMMM_ORCA 1)
 748 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 749     # nothing to do
 750 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 751     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 752 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 753
 754 # Process FFT library settings - if not OpenMM build
 755 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 756 set(PKG_FFT "")
 757 set(PKG_FFT_LIBS "")
 758 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 759     if(GMX_DOUBLE)
 760         find_package(FFTW 3 COMPONENTS fftw)
 761     else(GMX_DOUBLE)
 762         find_package(FFTW 3 COMPONENTS fftwf)
 763     endif(GMX_DOUBLE)
 764     if(NOT FFTW_FOUND)
 765       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 766     endif(NOT FFTW_FOUND)
 767     include_directories(${FFTW_INCLUDE_DIRS})
 768     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 769     set(PKG_FFT "${FFTW_PKG}")
 770
 771     set(GMX_FFT_FFTW3 1)
 772
 773     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 774       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 775     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 776
 777 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 778 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 779     find_package(MKL REQUIRED)
 780     include_directories(${MKL_INCLUDE_DIR})
 781     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 782     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 783
 784     set(GMX_FFT_MKL 1)
 785     set(HAVE_MKL 1)
 786
 787 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 788 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 789 #    set(GMX_FFT_ACML 1)
 790 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 791     MESSAGE(STATUS "Using internal FFT library - fftpack")
 792     set(GMX_FFT_FFTPACK 1)
 793 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 794     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 795 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 796
 797 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 798 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 799 # MKL has BLAS/LAPACK routines
 800 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 801   if(GMX_EXTERNAL_BLAS)
 802     if (GMX_BLAS_USER)
 803         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 804     else(GMX_BLAS_USER)
 805         set(BLAS_FIND_QUIETLY ON)
 806         find_package(BLAS)
 807         if (BLAS_FOUND)
 808           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 809         else()
 810           MESSAGE(STATUS "Using internal BLAS library")
 811           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 812         endif()
 813     endif(GMX_BLAS_USER)
 814   endif(GMX_EXTERNAL_BLAS)
 815   if(GMX_EXTERNAL_LAPACK)
 816     if (GMX_LAPACK_USER)
 817         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 818     else(GMX_LAPACK_USER)
 819         set(LAPACK_FIND_QUIETLY ON)
 820         find_package(LAPACK)
 821         if (LAPACK_FOUND)
 822           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 823         else()
 824           MESSAGE(STATUS "Using internal LAPACK library")
 825           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 826         endif()
 827     endif(GMX_LAPACK_USER)
 828   endif(GMX_EXTERNAL_LAPACK)
 829 endif()
 830 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 831 mark_as_advanced(GMX_EXTERNAL_BLAS)
 832
 833 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 834 set(GMX_VMD_PLUGIN_PATH)
 835 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 836
 837 if(GMX_LOAD_PLUGINS)
 838   if(CYGWIN OR NOT WIN32)
 839     # Native Windows does not have, nor need dlopen
 840     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 841     include(gmxTestdlopen)
 842     gmx_test_dlopen(HAVE_DLOPEN)
 843   endif()
 844
 845   find_package(VMD)
 846
 847   # Test for unsuitable versions of VMD
 848
 849   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 850     message(STATUS "Checking for suitable VMD version")
 851     exec_program(${VMD_EXECUTABLE}
 852       ARGS --help
 853       OUTPUT_VARIABLE VMD_HELP
 854       RETURN_VALUE VMD_EXEC_RETURN)
 855
 856     if(VMD_EXEC_RETURN EQUAL 0)
 857       # This is the accepted idiom for subexpression matching, unfortunately
 858       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 859       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 860
 861       if(VMD_VERSION VERSION_LESS "1.8")
 862         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 863         unset(VMD_EXECUTABLE)
 864         set(VMD_FOUND FALSE)
 865       else()
 866         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 867         if(DEFINED ENV{VMDDIR})
 868           # This permits GROMACS to avoid hard-coding a fall-back
 869           # path that it can tell right now would be useless.
 870           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 871         else()
 872           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 873         endif()
 874       endif()
 875
 876       # clean up
 877       unset(VMD_HELP)
 878       unset(VMD_VERSION)
 879       unset(VMD_ARCH)
 880     endif()
 881   endif()
 882
 883   # so, should we use plug-ins?
 884   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 885     if (NOT VMD_QUIETLY)
 886       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 887     endif(NOT VMD_QUIETLY)
 888     set(GMX_USE_PLUGINS ON)
 889     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 890     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 891   else()
 892     set(PKG_DL_LIBS)
 893   endif()
 894 endif(GMX_LOAD_PLUGINS)
 895 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 896
 897 # Math and thread libraries must often come after all others when linking...
 898 if(HAVE_LIBM)
 899     list(APPEND GMX_EXTRA_LIBRARIES m)
 900 endif(HAVE_LIBM)
 901
 902 if(GMX_FAHCORE)
 903   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 904       "Path to swindirect.h")
 905   include_directories(${COREWRAP_INCLUDE_DIR})
 906 endif(GMX_FAHCORE)
 907
 908 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 909 # these are set after everything else
 910 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 911     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 912         FORCE)
 913     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 914         "Flags used by the compiler during all build types" FORCE)
 915     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 916         "Flags used by the compiler during all build types" FORCE)
 917     set(CMAKE_EXE_LINKER_FLAGS
 918         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 919         CACHE STRING "Linker flags" FORCE)
 920 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 921
 922 ######################################
 923 # Output compiler and CFLAGS used
 924 ######################################
 925 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 926 #try executing just the compiler command if that failed...
 927 if(TMP_RESULT)
 928     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 929 endif()
 930 string(LENGTH "${CC_VERSION}" len)
 931 if(len)
 932     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 933 endif()
 934
 935 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 936 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 937 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 938     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 939 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 940     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 941 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 942     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 943 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 944     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 945 endif()
 946
 947
 948 ########################################################################
 949 # Specify install locations and which subdirectories to process        #
 950 ########################################################################
 951 if ( DEFINED GMXLIB )
 952     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 953 else()
 954     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 955 endif()
 956 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 957 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 958 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 959 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 960
 961 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 962
 963 ##################################################################
 964 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 965 ##################################################################
 966 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 967     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 968     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 969     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 970     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 971 endif()
 972
 973 add_subdirectory(share)
 974 add_subdirectory(include)
 975 add_subdirectory(man)
 976 add_subdirectory(src)
 977 add_subdirectory(scripts)
 978
 979 #######################
 980 ## uninstall target
 981 #######################
 982     CONFIGURE_FILE(
 983                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 984                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 985                    IMMEDIATE @ONLY)
 986 ###########################
 987 ADD_CUSTOM_TARGET(uninstall
 988                   "${CMAKE_COMMAND}" -P
 989                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 990 ###########################
 991
 992
 993 ########################################################################
 994 # Tests                                                                #
 995 ########################################################################
 996
 997 include(CTest)
 998 mark_as_advanced(BUILD_TESTING)
 999 IF(BUILD_TESTING)
1000         enable_testing()
1001         add_subdirectory(tests)
1002 ENDIF()
1003