docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.4.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # The directory from which man pages will be installed; if it remains
  76 # empty, they will be silently skipped.
  77 set(MAN_PAGE_DIR)
  78 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  79     # When building from the tarball, install the bundled man pages
  80     # (unless overridden).
  81     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  82 endif()
  83
  84 add_subdirectory(doxygen)
  85 add_subdirectory(manual)
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/commitstyle.rst
 108         dev-manual/documentation-generation.rst
 109         dev-manual/contribute.rst
 110         dev-manual/doxygen.rst
 111         dev-manual/error-handling.rst
 112         dev-manual/formatting.rst
 113         dev-manual/gmxtree.rst
 114         dev-manual/includestyle.rst
 115         dev-manual/jenkins.rst
 116         dev-manual/language-features.rst
 117         dev-manual/naming.rst
 118         dev-manual/overview.rst
 119         dev-manual/redmine-states.png
 120         dev-manual/relocatable-binaries.rst
 121         dev-manual/reportstyle.rst
 122         dev-manual/style.rst
 123         dev-manual/testutils.rst
 124         dev-manual/tools.rst
 125         dev-manual/uncrustify.rst
 126         fragments/doxygen-links.rst
 127         install-guide/index.rst
 128         release-notes/index.rst
 129         release-notes/2018/2018.2.rst
 130         release-notes/2018/2018.1.rst
 131         release-notes/2018/major/highlights.rst
 132         release-notes/2018/major/features.rst
 133         release-notes/2018/major/performance.rst
 134         release-notes/2018/major/tools.rst
 135         release-notes/2018/major/bugs-fixed.rst
 136         release-notes/2018/major/removed-features.rst
 137         release-notes/2018/major/portability.rst
 138         release-notes/2018/major/miscellaneous.rst
 139         release-notes/2016/2016.5.rst
 140         release-notes/2016/2016.4.rst
 141         release-notes/2016/2016.3.rst
 142         release-notes/2016/2016.2.rst
 143         release-notes/2016/2016.1.rst
 144         release-notes/2016/major/highlights.rst
 145         release-notes/2016/major/new-features.rst
 146         release-notes/2016/major/performance.rst
 147         release-notes/2016/major/tools.rst
 148         release-notes/2016/major/bugs-fixed.rst
 149         release-notes/2016/major/removed-features.rst
 150         release-notes/2016/major/miscellaneous.rst
 151         release-notes/older/index.rst
 152         user-guide/index.rst
 153         user-guide/cutoff-schemes.rst
 154         user-guide/getting-started.rst
 155         user-guide/force-fields.rst
 156         user-guide/faq.rst
 157         user-guide/flow.rst
 158         user-guide/floating-point.rst
 159         user-guide/system-preparation.rst
 160         user-guide/managing-simulations.rst
 161         user-guide/mdrun-features.rst
 162         user-guide/mdrun-performance.rst
 163         user-guide/mdp-options.rst
 164         user-guide/run-time-errors.rst
 165         user-guide/file-formats.rst
 166         user-guide/cmdline.rst
 167         user-guide/environment-variables.rst
 168         user-guide/terminology.rst
 169         user-guide/plotje.gif
 170         user-guide/xvgr.gif
 171         conf.py
 172         links.dat
 173         )
 174
 175     include(SphinxMacros.cmake)
 176     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 177
 178     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 179     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 180         EXTRA_VARS
 181             SPHINX_EXTENSION_PATH RELENG_PATH
 182             EXPECTED_DOXYGEN_VERSION
 183             EXPECTED_SPHINX_VERSION
 184             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 185             REQUIRED_OPENCL_MIN_VERSION
 186             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 187             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 188             GMX_TNG_MINIMUM_REQUIRED_VERSION
 189             GMX_LMFIT_MINIMUM_REQUIRED_VERSION
 190         COMMENT "Configuring Sphinx configuration file")
 191     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 192     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 193     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 194         include(${RELENG_PATH}/docs/FileList.cmake)
 195         gmx_add_sphinx_source_files(
 196             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 197             FILES ${RELENG_SPHINX_FILES})
 198     else()
 199         gmx_add_sphinx_source_files(FILES
 200             dev-manual/releng/index.rst
 201             dev-manual/releng/jenkins-howto.rst
 202             dev-manual/releng/jenkins-ui.rst
 203             )
 204     endif()
 205     gmx_add_sphinx_input_target(sphinx-input)
 206     # Remove other rst files from the build tree, since they confuse Sphinx.
 207     # Skip generated files in onlinehelp/, and fragments.
 208     # The latter do not cause issues with obsolete files, as they
 209     # are not considered as Sphinx input files, but will only be
 210     # included using an explicit .. include::.
 211     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 212
 213     # TODO: Make this remove obsolete .rst files.
 214     # TODO: This does not work in cross-compilation scenarios; disable up to
 215     # the necessary level.
 216     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 217         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 218         COMMAND gmx -quiet help -export rst
 219         DEPENDS gmx
 220         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 221         COMMENT "Generating reStructuredText help")
 222     # This dependency ensures that the directories exist before the
 223     # executable tries to write things there.
 224     add_dependencies(sphinx-programs sphinx-input)
 225
 226     # Make the INSTALL file for CPack for the tarball. This gets put
 227     # into the tarball via the CPack rules below, which requires that
 228     # the INSTALL file is in a separate directory by itself.
 229     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 230     add_custom_target(install-guide
 231         COMMAND
 232             ${SPHINX_EXECUTABLE}
 233             -q -b text
 234             -w sphinx-install.log
 235             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 236             -c ${SPHINX_INPUT_DIR}
 237             "${SPHINX_INPUT_DIR}/install-guide"
 238             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 239         COMMAND
 240             ${CMAKE_COMMAND} -E rename
 241             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 242             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 243         WORKING_DIRECTORY
 244             ${CMAKE_CURRENT_BINARY_DIR}
 245         COMMENT "Building INSTALL with Sphinx"
 246         VERBATIM
 247         )
 248     add_dependencies(install-guide sphinx-input)
 249     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 250
 251     # Sphinx cache with pickled ReST documents
 252     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 253
 254     add_custom_target(webpage-sphinx
 255         COMMAND
 256             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 257         COMMAND
 258             ${SPHINX_EXECUTABLE}
 259             -q -b html
 260             -w sphinx-html.log
 261             -d "${SPHINX_CACHE_DIR}"
 262             "${SPHINX_INPUT_DIR}"
 263             "${HTML_OUTPUT_DIR}"
 264         WORKING_DIRECTORY
 265             ${CMAKE_CURRENT_BINARY_DIR}
 266         COMMENT "Building HTML documentation with Sphinx"
 267         VERBATIM
 268         )
 269     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 270
 271     add_custom_target(man
 272         COMMAND
 273             ${SPHINX_EXECUTABLE}
 274             -q -b man
 275             -w sphinx-man.log
 276             -d ${SPHINX_CACHE_DIR}
 277             -t do_man
 278             ${SPHINX_INPUT_DIR}
 279             ${CMAKE_CURRENT_BINARY_DIR}/man
 280         COMMENT "Building man pages with Sphinx"
 281         VERBATIM)
 282     add_dependencies(man sphinx-input sphinx-programs)
 283     if (GMX_BUILD_HELP)
 284         # If requested, install the man pages built by the 'man' target
 285         # created above.  Nothing will be installed if the user did not
 286         # manually build the target.
 287         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 288     endif()
 289 else()
 290     add_custom_target(webpage-sphinx
 291         COMMAND ${CMAKE_COMMAND} -E echo
 292             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 293         VERBATIM)
 294     add_custom_target(install-guide
 295         COMMAND ${CMAKE_COMMAND} -E echo
 296             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 297         VERBATIM)
 298     add_custom_target(man
 299         COMMAND ${CMAKE_COMMAND} -E echo
 300             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 301         VERBATIM)
 302 endif()
 303
 304 if (MAN_PAGE_DIR)
 305     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 306     # Trailing slash on directory is significant for
 307     # install(DIRECTORY). See CMake docs.
 308     install(DIRECTORY ${MAN_PAGE_DIR}/
 309         DESTINATION ${MAN_INSTALL_DIR}/man1
 310         COMPONENT man OPTIONAL
 311         FILES_MATCHING PATTERN "*.1")
 312 endif()
 313 gmx_cpack_add_generated_source_directory(man)
 314
 315 # Determine whether we can build all the HTML pages and content linked from
 316 # there.  If not, construct an informative message if the user tries to
 317 # build the target; most people never need to know, unless they've asked for
 318 # the webpage build.
 319 set(HTML_BUILD_IS_POSSIBLE ON)
 320 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 321 set(HTML_BUILD_WARNINGS)
 322
 323 # Next, turn it off if any of the preconditions are unsatisified
 324 if (NOT PYTHON_EXECUTABLE)
 325     set(HTML_BUILD_IS_POSSIBLE OFF)
 326     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 327 elseif (NOT SPHINX_FOUND)
 328     # Hardly anything gets built if Sphinx is not available, so don't bother.
 329     set(HTML_BUILD_IS_POSSIBLE OFF)
 330     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 331 endif()
 332 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 333     list(APPEND HTML_BUILD_WARNINGS
 334          "Reference PDF manual was not built, so links to it do not work")
 335 endif()
 336 if (NOT DOXYGEN_EXECUTABLE)
 337     list(APPEND HTML_BUILD_WARNINGS
 338         "Doxygen was not available, so links to Doxygen do not work")
 339 endif()
 340 if (NOT DOXYGEN_DOT_EXECUTABLE)
 341     list(APPEND HTML_BUILD_WARNINGS
 342         "dot/graphviz was not found, so some graphs are missing")
 343 endif()
 344
 345 if (HTML_BUILD_IS_POSSIBLE)
 346     set(_webpage_target_properties)
 347     if (HTML_BUILD_WARNINGS)
 348         list(APPEND _webpage_target_properties
 349              COMMAND ${CMAKE_COMMAND} -E echo
 350                  "webpage was built, but with the following limitations:")
 351         foreach(_warning ${HTML_BUILD_WARNINGS})
 352         list(APPEND _webpage_target_properties
 353              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 354         endforeach()
 355     endif()
 356
 357     if (MANUAL_BUILD_IS_POSSIBLE)
 358         # Make the PDF reference guide
 359         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 360         # TODO Make this depend on the output of the manual build, so that the
 361         # file actually gets copied multiple times.
 362         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 363         add_custom_command(
 364             OUTPUT ${_manual_target_location}
 365             COMMAND ${CMAKE_COMMAND}
 366                 -E remove -f ${_manual_target_location}
 367             COMMAND ${CMAKE_COMMAND}
 368                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 369             DEPENDS manual
 370             VERBATIM)
 371         list(APPEND _webpage_target_properties
 372              DEPENDS ${_manual_target_location})
 373     endif()
 374
 375     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 376     # makes all the Doxygen output directly in
 377     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 378     # to).
 379
 380     # Add a top-level target that builds everything related to the webpage,
 381     # for Jenkins (and possibly others) to use
 382     add_custom_target(webpage ${_webpage_target_properties}
 383         COMMENT "Building webpage"
 384         VERBATIM)
 385     add_dependencies(webpage webpage-sphinx doxygen-all)
 386 else()
 387     add_custom_target(webpage
 388         COMMAND ${CMAKE_COMMAND} -E echo
 389             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 390         COMMENT "Webpage build not possible"
 391         VERBATIM)
 392 endif()