CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 set(PROJECT_VERSION "4.0.99_development_20090605"
   5     CACHE STRING "Gromacs version string")
   6
   7 # Cmake modules/macros are in a subdirectory to keep this file cleaner
   8 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
   9
  10 ########################################################################
  11 # User input options                                                   #
  12 ########################################################################
  13 option(GMX_DOUBLE "Use double precision" OFF)
  14 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  15 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" OFF)
  16 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  17 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  18 set(GMX_ACCELERATION "none"
  19     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  20
  21 set(GMX_FFT_LIBRARY "fftw3"
  22     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  23 option(GMX_DISABLE_FFTW_MEASURE
  24        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  25 set(GMX_QMMM_PROGRAM "none"
  26     CACHE STRING "QM package choices: none,gaussian,mopac,gamess")
  27 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  28 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  29
  30 enable_language(C)
  31
  32 ########################################################################
  33 # Fix stupid flags on MSVC
  34 ########################################################################
  35 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  36     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  37     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  38     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  39     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  40 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  41
  42 set(GMX_EXTRA_LIBRARIES)
  43
  44 ########################################################################
  45 #Process MPI settings
  46 ########################################################################
  47 if(GMX_MPI)
  48     if(GMX_THREADS)
  49         message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  50     endif(GMX_THREADS)
  51     find_package(MPI)
  52     if(MPI_FOUND)
  53         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  54         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  55         include_directories(${MPI_INCLUDE_PATH})
  56         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  57         add_definitions( -DMPI ) #for FAHCORE
  58         include(gmxTestMPI_IN_PLACE)
  59         gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  60     else(MPI_FOUND)
  61         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
  62     endif(MPI_FOUND)
  63     include(gmxTestCatamount)
  64     gmx_test_catamount(GMX_CRAY_XT3)
  65     if(GMX_CRAY_XT3)
  66         set(GMX_NO_SYSTEM 1)
  67         set(GMX_NO_NICE 1)
  68     endif(GMX_CRAY_XT3)
  69     set(GMX_LIB_MPI 1)
  70 endif(GMX_MPI)
  71
  72 ########################################################################
  73 # Basic system tests (standard libraries, headers, functions, types)   #
  74 ########################################################################
  75 include(CheckIncludeFiles)
  76 check_include_files(string.h     HAVE_STRING_H)
  77 check_include_files(limits.h     HAVE_LIMITS_H)
  78 check_include_files(memory.h     HAVE_MEMORY_H)
  79 check_include_files(unistd.h     HAVE_UNISTD_H)
  80 check_include_files(pwd.h        HAVE_PWD_H)
  81 check_include_files(stdint.h     HAVE_STDINT_H)
  82 check_include_files(stdlib.h     HAVE_STDLIB_H)
  83 check_include_files(pthread.h    HAVE_PTHREAD_H)
  84 check_include_files(inttypes.h   HAVE_INTTYPES_H)
  85 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
  86 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
  87 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
  88 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
  89 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
  90 # SSE support
  91 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
  92 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
  93 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
  94 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
  95
  96 include(CheckFunctionExists)
  97 check_function_exists(strcasecmp        HAVE_STRCASECMP)
  98 check_function_exists(strdup            HAVE_STRDUP)
  99 check_function_exists(vprintf           HAVE_VPRINTF)
 100 check_function_exists(memcmp            HAVE_MEMCMP)
 101 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 102 check_function_exists(isnan             HAVE_ISNAN)
 103 check_function_exists(_isnan            HAVE__ISNAN)
 104 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 105
 106 include(CheckLibraryExists)
 107 check_library_exists(m sqrt "" HAVE_LIBM)
 108
 109 include(CheckTypeSize)
 110 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 111 check_type_size("int"           SIZEOF_INT)
 112 check_type_size("long int"      SIZEOF_LONG_INT)
 113 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 114 check_type_size("off_t"         SIZEOF_OFF_T)
 115 check_type_size("void *"        SIZEOF_VOIDP)
 116
 117 # Check for some basic types that we *need*, so set these to int if they are not present
 118 check_type_size(uid_t uid_t)
 119 if(NOT uid_t)
 120   set(uid_t int)
 121 else(NOT uid_t)
 122   set(uid_t 0)
 123 endif(NOT uid_t)
 124
 125 check_type_size(gid_t gid_t)
 126 if(NOT gid_t)
 127   set(gid_t 1)
 128 else(NOT gid_t)
 129   set(gid_t 0)
 130 endif(NOT gid_t)
 131
 132 check_type_size(size_t size_t)
 133 if(NOT size_t)
 134   set(size_t int)
 135 else(NOT size_t)
 136   set(size_t 0)
 137 endif(NOT size_t)
 138
 139 check_type_size(off_t off_t)
 140 if(NOT off_t)
 141   set(off_t int)
 142 else(NOT off_t)
 143   set(off_t 0)
 144 endif(NOT off_t)
 145
 146 include(TestBigEndian)
 147 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 148
 149
 150
 151 ########################################################################
 152 # Find external packages                                               #
 153 ########################################################################
 154
 155 find_package(LibXml2)
 156 if(LIBXML2_FOUND)
 157     include_directories(${LIBXML2_INCLUDE_DIR})
 158     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 159     set(HAVE_LIBXML2 1)
 160 endif(LIBXML2_FOUND)
 161
 162 find_package(X11)
 163 # X11 includes/libraries are only set in the ngmx subdirectory!
 164 if(X11_FOUND)
 165     set(HAVE_X11 1)
 166 endif(X11_FOUND)
 167
 168 if(GMX_THREADS)
 169     include(ThreadMPI)
 170     set(THREAD_MPI_LIB thread_mpi)
 171     set(GMX_MPI 1)
 172 endif(GMX_THREADS)
 173
 174
 175 if(APPLE)
 176    find_library(ACCELERATE_FRAMEWORK Accelerate)
 177    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 178 endif(APPLE)
 179
 180 ########################################################################
 181 # Our own GROMACS tests
 182 ########################################################################
 183
 184 include(gmxCFlags)
 185 gmx_c_flags()
 186
 187 add_definitions( -DHAVE_CONFIG_H )
 188 include_directories(${CMAKE_BINARY_DIR}/src)
 189 include_directories(${CMAKE_SOURCE_DIR}/include)
 190
 191 include(gmxCheckBuildUserTime)
 192 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 193
 194 include(gmxTestFloatFormat)
 195 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 196                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 197                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 198
 199 include(gmxTestLargeFiles)
 200 gmx_test_large_files(GMX_LARGEFILES)
 201
 202 include(gmxTestSignal)
 203 gmx_test_retsigtype(RETSIGTYPE)
 204 gmx_test_sigusr1(HAVE_SIGUSR1)
 205
 206 include(gmxTestInline)
 207 gmx_test_inline(INLINE_KEYWORD)
 208
 209 include(gmxTestPipes)
 210 gmx_test_pipes(HAVE_PIPES)
 211
 212 include(gmxTestInlineASM)
 213 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 214 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 215
 216 include(gmxTestXDR)
 217 gmx_test_xdr(GMX_SYSTEM_XDR)
 218 if(NOT GMX_SYSTEM_XDR)
 219     set(GMX_INTERNAL_XDR 1)
 220 endif(NOT GMX_SYSTEM_XDR)
 221
 222 if(GMX_FORTRAN OR GMX_POWER6)
 223     enable_language(Fortran)
 224     include(FortranCInterface)
 225     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 226     if(extra_under_score)
 227         set(extrasuffix "_")
 228     endif(extra_under_score)
 229
 230     if(isupper)
 231         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 232         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 233     else(isupper)
 234         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 235         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 236     endif(isupper)
 237 else(GMX_FORTRAN OR GMX_POWER6)
 238         set(F77_FUNCDEF   "name ## _")
 239         set(F77_FUNCDEF_  "name ## _")
 240 endif(GMX_FORTRAN OR GMX_POWER6)
 241
 242
 243 # Process nonbonded accelerated kernels settings
 244 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 245 if(${GMX_ACCELERATION} STREQUAL "NONE")
 246   # nothing to do
 247 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 248     if(HAVE_XMMINTRIN_H)
 249         set(GMX_SSE 1)
 250     endif(HAVE_XMMINTRIN_H)
 251     if(HAVE_EMMINTRIN_H)
 252         set(GMX_SSE2 1)
 253     endif(HAVE_EMMINTRIN_H)
 254 #    if(HAVE_PMMINTRIN_H)
 255 #        set(GMX_SSE3 1)
 256 #    endif(HAVE_PMMINTRIN_H)
 257 #    if(HAVE_SMMINTRIN_H)
 258 #        set(GMX_SSE4_1 1)
 259 #    endif(HAVE_SMMINTRIN_H)
 260
 261 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 262     set(GMX_FORTRAN 1)
 263 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 264     set(GMX_BLUEGENE 1)
 265 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 266     set(GMX_POWER6 1)
 267 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 268     set(GMX_IA64_ASM 1)
 269     set(DISABLE_WATERWATER_NLIST 1)
 270     set(DISABLE_WATER_NLIST 1)
 271 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 272     check_include_files(altivec.h HAVE_ALTIVEC_H)
 273     if(HAVE_ALTIVEC_H)
 274         set(GMX_PPC_ALTIVEC 1)
 275     endif(HAVE_ALTIVEC_H)
 276 else(${GMX_ACCELERATION} STREQUAL "NONE")
 277     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 278 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 279
 280
 281
 282
 283
 284
 285
 286 # Process QM/MM Settings
 287 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 288 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 289     set(GMX_QMMM_GAUSSIAN 1)
 290 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 291     set(GMX_QMMM_MOPAC 1)
 292 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 293     set(GMX_QMMM_GAMESS 1)
 294 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 295     # nothing to do
 296 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 297     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, None")
 298 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 299
 300 # Process FFT library settings
 301 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 302 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 303 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 304     if(GMX_DOUBLE)
 305         find_package(FFTW3 REQUIRED)
 306     else(GMX_DOUBLE)
 307         find_package(FFTW3F REQUIRED)
 308     endif(GMX_DOUBLE)
 309
 310     if(NOT FFTW3_FOUND)
 311         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 312     endif(NOT FFTW3_FOUND)
 313
 314     set(GMX_FFT_FFTW3 1)
 315     include_directories(${FFTW3_INCLUDE_DIR})
 316     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 317
 318 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 319 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 320     if(GMX_DOUBLE)
 321         find_package(FFTW2 REQUIRED)
 322     else(GMX_DOUBLE)
 323         find_package(FFTW2F REQUIRED)
 324     endif(GMX_DOUBLE)
 325
 326     if(NOT FFTW2_FOUND)
 327            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 328     endif(NOT FFTW2_FOUND)
 329     include_directories(${FFTW2_INCLUDE_DIR})
 330     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 331
 332     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 333         set(FFTW2_NAME_DFFTW 1)
 334     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 335         set(FFTW2_NAME_SFFTW 1)
 336     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 337         set(FFTW2_NAME_FFTW 1)
 338     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 339
 340     set(GMX_FFT_FFTW2 1)
 341 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 342 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 343     find_package(MKL REQUIRED)
 344     include_directories(${MKL_INCLUDE_DIR})
 345     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 346
 347     set(GMX_FFT_MKL 1)
 348     set(HAVE_MKL 1)
 349
 350 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 351 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 352 #    set(GMX_FFT_ACML 1)
 353 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 354     MESSAGE(STATUS "Using internal FFT library - fftpack")
 355     set(GMX_FFT_FFTPACK 1)
 356 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 357     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 358 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 359
 360 # MKL has BLAS/LAPACK routines
 361 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 362   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 363   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 364 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 365   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 366   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 367 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 368
 369 # Math and thread libraries must often come after all others when linking...
 370 if(HAVE_LIBM)
 371     list(APPEND GMX_EXTRA_LIBRARIES m)
 372 endif(HAVE_LIBM)
 373
 374
 375 if(GMX_FAHCORE)
 376   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 377       "Path to swindirect.h")
 378   include_directories(${COREWRAP_INCLUDE_DIR})
 379 endif(GMX_FAHCORE)
 380
 381 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 382 set(CMAKE_C_FLAGS ${GROMACS_C_FLAGS} CACHE STRING "Compiler flags")
 383 set(CMAKE_EXE_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} CACHE STRING "Linker flags")
 384
 385 ########################################################################
 386 # Specify install locations and which subdirectories to process        #
 387 ########################################################################
 388 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 389 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 390 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 391 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 392
 393 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 394
 395
 396 add_subdirectory(share)
 397 add_subdirectory(include)
 398 add_subdirectory(man)
 399
 400 add_subdirectory(src)
 401
 402