CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.6-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  26 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41 enable_language(CXX)
  42
  43 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  44 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  45 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  46 set(CPACK_SET_DESTDIR "ON")
  47 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  48 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  49 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  50 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  51 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  52
  53 #must come after all cpack settings!
  54 include(CPack)
  55
  56 ########################################################################
  57 # Check and warn if cache generated on a different host is being reused
  58 ########################################################################
  59 if(CMAKE_HOST_UNIX)
  60     execute_process(COMMAND hostname
  61                     OUTPUT_VARIABLE TMP_HOSTNAME
  62                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  63     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  64         message(WARNING "
  65             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  66             is being reused! This could lead to inconsitencies; therefore, it is
  67             recommended to regenerate the cache!")
  68     endif()
  69     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  70             "Hostname of the machine where the cache was generated.")
  71 endif()
  72
  73 ########################################################################
  74 # Fix stupid flags on MSVC
  75 ########################################################################
  76 SET(SHARED_LIBS_DEFAULT ON)
  77 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  78     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  79     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  80     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  81     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  82     SET(SHARED_LIBS_DEFAULT OFF)
  83 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  84
  85 set(GMX_EXTRA_LIBRARIES)
  86
  87
  88
  89 ######################################################################
  90 # compiler tests
  91 # these need ot be done early (before further tests).
  92 #####################################################################
  93
  94 include(CheckCCompilerFlag)
  95 include(CheckCXXCompilerFlag)
  96
  97 include(gmxCFlags)
  98 gmx_c_flags()
  99
 100 ########################################################################
 101 # User input options                                                   #
 102 ########################################################################
 103 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 104 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 105 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 106 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 107 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 108 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 109 mark_as_advanced(GMX_POWERPC_INVSQRT)
 110 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 111 mark_as_advanced(GMX_FAHCORE)
 112 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 113 set(GMX_ACCELERATION "auto"
 114     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 115
 116 set(GMX_FFT_LIBRARY "fftw3"
 117     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 118 option(GMX_DISABLE_FFTW_MEASURE
 119        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 120 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 121 set(GMX_QMMM_PROGRAM "none"
 122     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 123 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 124 mark_as_advanced(GMX_BROKEN_CALLOC)
 125 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 126 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 127 mark_as_advanced(GMX_MPI_IN_PLACE)
 128 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 129 mark_as_advanced(GMX_LOAD_PLUGINS)
 130
 131
 132 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 133 mark_as_advanced(GMX_IA32_ASM)
 134 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 135 mark_as_advanced(GMX_X86_64_ASM)
 136
 137 option(USE_VERSION_H "Generate development version string/information" ON)
 138 mark_as_advanced(USE_VERSION_H)
 139
 140 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 141
 142 if(UNIX AND NOT APPLE)
 143     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 144     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 145 endif()
 146
 147 ########################################################################
 148 # Set up binary and library suffixing
 149 ########################################################################
 150 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 151 set(GMX_LIBS_SUFFIX ""
 152   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 153 if (GMX_DEFAULT_SUFFIX)
 154   set(GMX_BINARY_SUFFIX "")
 155   set(GMX_LIBS_SUFFIX "")
 156   if (GMX_MPI)
 157     set(GMX_BINARY_SUFFIX "_mpi")
 158     set(GMX_LIBS_SUFFIX "_mpi")
 159   endif(GMX_MPI)
 160   if (GMX_DOUBLE)
 161     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 162     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 163   endif(GMX_DOUBLE)
 164   if (GMX_OPENMM)
 165     set (GMX_BINARY_SUFFIX "-gpu")
 166     set (GMX_LIBS_SUFFIX "_gpu")
 167   endif(GMX_OPENMM)
 168   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 169   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 170   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 171 else(GMX_DEFAULT_SUFFIX)
 172   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 173   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 174   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 175 endif(GMX_DEFAULT_SUFFIX)
 176
 177 set(PKG_CFLAGS "")
 178 if(GMX_DOUBLE)
 179     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 180 endif(GMX_DOUBLE)
 181 if(GMX_SOFTWARE_INVSQRT)
 182   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 183 endif(GMX_SOFTWARE_INVSQRT)
 184 if(GMX_POWERPC_INVSQRT)
 185   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 186 endif(GMX_POWERPC_INVSQRT)
 187
 188 ########################################################################
 189 #Process MPI settings
 190 ########################################################################
 191 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 192 if(GMX_MPI)
 193     if(GMX_THREADS)
 194         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 195         set(GMX_THREADS OFF CACHE BOOL
 196             "Thread-based parallelization conflicts with MPI." FORCE)
 197     endif(GMX_THREADS)
 198
 199     # Work-around for Cray MPI
 200     TRY_COMPILE(MPI_FOUND ${CMAKE_BINARY_DIR}
 201       "${CMAKE_SOURCE_DIR}/cmake/TestMPI.c"
 202       COMPILE_DEFINITIONS )
 203     if(NOT MPI_FOUND)
 204       # search for normal MPI installations
 205       find_package(MPI)
 206     endif(NOT MPI_FOUND)
 207
 208     if(MPI_FOUND)
 209         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 210         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 211
 212         include_directories(${MPI_INCLUDE_PATH})
 213         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 214         if(GMX_FAHCORE)
 215             add_definitions( -DMPI ) #for FAHCORE
 216         endif(GMX_FAHCORE)
 217         include(gmxTestMPI_IN_PLACE)
 218         if (GMX_MPI_IN_PLACE)
 219             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 220         endif (GMX_MPI_IN_PLACE)
 221
 222         # test for unsuitable versions of OpenMPI
 223         exec_program(${MPIEXEC}
 224           ARGS --version
 225           OUTPUT_VARIABLE MPI_TYPE
 226           RETURN_VALUE MPI_EXEC_RETURN)
 227         if(MPI_EXEC_RETURN EQUAL 0)
 228           if(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 229             string(REGEX MATCH "[0-9]+\\.[0-9]*\\.?[0-9]*" MPI_VERSION ${MPI_TYPE})
 230             if(MPI_VERSION VERSION_LESS "1.4.1")
 231               MESSAGE(WARNING "
 232             There are known problems with OpenMPI version < 1.4.1.
 233             Please consider updating your OpenMPI.")
 234             endif(MPI_VERSION VERSION_LESS "1.4.1")
 235             unset(MPI_VERSION)
 236           else(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 237             # This is not OpenMPI, so give the old generic warning message
 238             MESSAGE(WARNING "
 239             There are known problems with some MPI implementations:
 240                      MVAPICH2 version <= 1.4.1
 241             Please consider updating your MPI if applicable.")
 242           endif(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 243           unset(MPI_TYPE)
 244         endif(MPI_EXEC_RETURN EQUAL 0)
 245     else(MPI_FOUND)
 246         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 247     endif(MPI_FOUND)
 248     include(gmxTestCatamount)
 249     gmx_test_catamount(GMX_CRAY_XT3)
 250     if(GMX_CRAY_XT3)
 251         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 252         set(GMX_NO_SYSTEM 1)
 253         set(GMX_NO_NICE 1)
 254     endif(GMX_CRAY_XT3)
 255     set(GMX_LIB_MPI 1)
 256     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 257 endif(GMX_MPI)
 258
 259
 260 #######################################################################
 261 # Check for options incompatible with OpenMM build                    #
 262 #######################################################################
 263 if(GMX_OPENMM)
 264     cmake_minimum_required(VERSION 2.6.4)
 265     # we'll use the built-in fft to avoid unnecessary dependencies
 266     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 267     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 268         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 269         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 270                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 271     endif()
 272     if(GMX_MPI)
 273         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 274     endif(GMX_MPI)
 275     if(GMX_THREADS)
 276         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 277         set(GMX_THREADS OFF CACHE BOOL
 278                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 279     endif(GMX_THREADS)
 280     if(GMX_SOFTWARE_INVSQRT)
 281         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 282                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 283     endif(GMX_SOFTWARE_INVSQRT)
 284     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 285     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 286         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 287         set(GMX_ACCELERATION "none" CACHE STRING
 288                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 289     endif()
 290     if(GMX_FAHCORE)
 291         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 292     endif(GMX_FAHCORE)
 293     if(GMX_DOUBLE)
 294         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 295     endif()
 296     # mark as advanced the unused variables
 297     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 298         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 299 else(GMX_OPENMM)
 300      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 301         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 302 endif(GMX_OPENMM)
 303
 304
 305 ########################################################################
 306 # Basic system tests (standard libraries, headers, functions, types)   #
 307 ########################################################################
 308 include(CheckIncludeFiles)
 309 check_include_files(string.h     HAVE_STRING_H)
 310 check_include_files(math.h       HAVE_MATH_H)
 311 check_include_files(limits.h     HAVE_LIMITS_H)
 312 check_include_files(memory.h     HAVE_MEMORY_H)
 313 check_include_files(unistd.h     HAVE_UNISTD_H)
 314 check_include_files(direct.h     HAVE_DIRECT_H)
 315 check_include_files(pwd.h        HAVE_PWD_H)
 316 check_include_files(stdint.h     HAVE_STDINT_H)
 317 check_include_files(stdlib.h     HAVE_STDLIB_H)
 318 check_include_files(pthread.h    HAVE_PTHREAD_H)
 319 check_include_files(dirent.h     HAVE_DIRENT_H)
 320 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 321 check_include_files(regex.h      HAVE_REGEX_H)
 322 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 323 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 324 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 325 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 326 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 327 # SSE support
 328 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 329 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 330 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 331 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 332 check_include_files(io.h                 HAVE_IO_H)
 333
 334
 335 include(CheckFunctionExists)
 336 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 337 check_function_exists(strdup            HAVE_STRDUP)
 338 check_function_exists(vprintf           HAVE_VPRINTF)
 339 check_function_exists(memcmp            HAVE_MEMCMP)
 340 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 341 check_function_exists(memalign          HAVE_MEMALIGN)
 342 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 343 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 344 check_function_exists(isnan             HAVE_ISNAN)
 345 check_function_exists(_isnan            HAVE__ISNAN)
 346 check_function_exists(isfinite          HAVE_ISFINITE)
 347 check_function_exists(_isfinite         HAVE__ISFINITE)
 348 check_function_exists(fsync             HAVE_FSYNC)
 349 check_function_exists(_fileno           HAVE__FILENO)
 350 check_function_exists(fileno            HAVE_FILENO)
 351 check_function_exists(_commit           HAVE__COMMIT)
 352
 353 include(CheckLibraryExists)
 354 check_library_exists(m sqrt "" HAVE_LIBM)
 355 check_library_exists(m cbrt "" HAVE_CBRT)
 356
 357
 358 include(CheckTypeSize)
 359
 360 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 361 check_type_size("int"           SIZEOF_INT)
 362 check_type_size("long int"      SIZEOF_LONG_INT)
 363 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 364 check_type_size("off_t"         SIZEOF_OFF_T)
 365 check_type_size("void *"        SIZEOF_VOIDP)
 366
 367 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 368     set(GMX_64_BIT TRUE)
 369 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 370     set(GMX_64_BIT FALSE)
 371 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 372
 373 # Check for some basic types that we *need*, so set these to int if they are not present
 374 check_type_size(uid_t uid_t)
 375 if(NOT uid_t)
 376   set(uid_t int)
 377 else(NOT uid_t)
 378   set(uid_t 0)
 379 endif(NOT uid_t)
 380
 381 check_type_size(gid_t gid_t)
 382 if(NOT gid_t)
 383   set(gid_t 1)
 384 else(NOT gid_t)
 385   set(gid_t 0)
 386 endif(NOT gid_t)
 387
 388 check_type_size(size_t size_t)
 389 if(NOT size_t)
 390   set(size_t int)
 391 else(NOT size_t)
 392   set(size_t 0)
 393 endif(NOT size_t)
 394
 395 check_type_size(off_t off_t)
 396 if(NOT off_t)
 397   set(off_t int)
 398 else(NOT off_t)
 399   set(off_t 0)
 400 endif(NOT off_t)
 401
 402 include(TestBigEndian)
 403 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 404
 405
 406
 407
 408 ########################################################################
 409 # Find external packages                                               #
 410 ########################################################################
 411 if(UNIX AND NOT APPLE)
 412     if(GMX_PREFER_STATIC_LIBS)
 413         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 414         if(BUILD_SHARED_LIBS)
 415             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 416             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 417         endif()
 418     endif()
 419 endif()
 420
 421 option(GMX_XML "Use libxml2 to parse xml files" ON)
 422 if (GMX_XML)
 423   find_package(LibXml2)
 424   set(PKG_XML "")
 425   if(LIBXML2_FOUND)
 426     include_directories(${LIBXML2_INCLUDE_DIR})
 427     set(PKG_XML libxml-2.0)
 428     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 429     set(HAVE_LIBXML2 1)
 430   endif(LIBXML2_FOUND)
 431 endif(GMX_XML)
 432
 433 option(GMX_GSL "Add support for gsl" OFF)
 434 if (GMX_GSL)
 435   find_package(gsl)
 436   set(PKG_GSL "")
 437   if(GSL_FOUND)
 438     include_directories(${GSL_INCLUDE_DIR})
 439     set(PKG_GSL gsl)
 440     set(HAVE_LIBGSL 1)
 441   endif(GSL_FOUND)
 442 endif (GMX_GSL)
 443
 444 option(GMX_X11 "Use X window system" OFF)
 445 if (GMX_X11)
 446         find_package(X11)
 447         # X11 includes/libraries are only set in the ngmx subdirectory!
 448         if(X11_FOUND)
 449         set(HAVE_X11 1)
 450         endif(X11_FOUND)
 451 endif(GMX_X11)
 452
 453 if(GMX_THREADS)
 454     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 455     include(ThreadMPI)
 456     set(THREAD_MPI_LIB thread_mpi)
 457     set(GMX_MPI 1)
 458     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 459     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 460         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 461     endif()
 462 endif(GMX_THREADS)
 463
 464 if(GMX_OPENMM)
 465     set(CUDA_BUILD_EMULATION OFF)
 466     find_package(CUDA 3.1 REQUIRED)
 467     add_definitions(-DGMX_OPENMM)
 468     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 469         set(CUDA_VERBOSE_BUILD ON)
 470     endif()
 471     find_package(OpenMM)
 472 endif(GMX_OPENMM)
 473
 474 if(APPLE)
 475    find_library(ACCELERATE_FRAMEWORK Accelerate)
 476    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 477 endif(APPLE)
 478
 479 if(CYGWIN)
 480     set(GMX_CYGWIN 1)
 481 endif(CYGWIN)
 482
 483 # only bother with finding git and using version.h if the source is a git repo
 484 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 485     if(USE_VERSION_H)
 486         # We need at least git v1.5.1 be able to parse git's date output. If not
 487         # found or the version is too small, we can't generate version information.
 488         find_package(Git)
 489
 490         # Find out the git version
 491         if(GIT_FOUND AND NOT GIT_VERSION)
 492           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 493             OUTPUT_VARIABLE _exec_out
 494             OUTPUT_STRIP_TRAILING_WHITESPACE)
 495           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 496           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 497           mark_as_advanced(GIT_VERSION)
 498         endif()
 499
 500         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 501           message("No compatible git version found, won't be able to generate proper development version information.")
 502           set(USE_VERSION_H OFF)
 503         endif()
 504     endif()
 505 else()
 506     set(USE_VERSION_H OFF)
 507 endif()
 508
 509 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 510 if ( NOT GMX_INTERNAL_BOOST )
 511   find_package( Boost 1.36.0 )
 512 else ( NOT GMX_INTERNAL_BOOST )
 513   set (Boost_FOUND FALSE)
 514 endif( NOT GMX_INTERNAL_BOOST )
 515
 516 if(Boost_FOUND)
 517   include_directories(${Boost_INCLUDE_DIRS})
 518 else()
 519   message("Boost >= 1.36 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 520   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 521   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 522   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 523   # (from share/template/)
 524   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 525   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost")
 526   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 527           DESTINATION ${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost
 528           COMPONENT development)
 529 endif()
 530
 531 option(GMX_USE_GTEST "Build tests that require Google C++ Testing Framework" ON)
 532 option(GMX_USE_GMOCK "Build tests that require Google C++ Mocking Framework" ON)
 533 mark_as_advanced(GMX_USE_GTEST)
 534 mark_as_advanced(GMX_USE_GMOCK)
 535 if (BUILD_TESTING)
 536     add_subdirectory(src/external/gmock-1.6.0)
 537 endif (BUILD_TESTING)
 538 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 539
 540 find_package(Doxygen)
 541
 542 ########################################################################
 543 # Generate development version info for cache
 544 ########################################################################
 545 # set(GEN_VERSION_INFO_INTERNAL "ON")
 546 # include(gmxGenerateVersionString)
 547
 548 ########################################################################
 549 # Our own GROMACS tests
 550 ########################################################################
 551
 552 add_definitions( -DHAVE_CONFIG_H )
 553 include_directories(${CMAKE_SOURCE_DIR}/src)
 554 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 555 include_directories(${CMAKE_BINARY_DIR}/src)
 556 # Required for now to make old code compile
 557 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 558
 559 include(gmxCheckBuildUserTime)
 560 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 561
 562 include(gmxTestFloatFormat)
 563 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 564                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 565                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 566
 567 include(gmxTestLargeFiles)
 568 gmx_test_large_files(GMX_LARGEFILES)
 569 check_function_exists(fseeko     HAVE_FSEEKO)
 570
 571 include(gmxTestSignal)
 572 gmx_test_sigusr1(HAVE_SIGUSR1)
 573
 574 include(gmxTestInline)
 575 gmx_test_inline(INLINE_KEYWORD)
 576
 577 include(gmxTestRestrict)
 578 gmx_test_inline(RESTRICT_KEYWORD)
 579
 580 include(gmxTestPipes)
 581 gmx_test_pipes(HAVE_PIPES)
 582
 583 include(gmxTestInlineASM)
 584 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 585 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 586
 587 # turn on SSE if supported with reasonable defaults.
 588 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 589   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 590
 591     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 592
 593     # Determine the assembler/compiler to use
 594   else()
 595     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 596   endif()
 597 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 598
 599 include(gmxTestXDR)
 600 gmx_test_xdr(GMX_SYSTEM_XDR)
 601 if(NOT GMX_SYSTEM_XDR)
 602     set(GMX_INTERNAL_XDR 1)
 603     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 604 endif(NOT GMX_SYSTEM_XDR)
 605
 606 # Process nonbonded accelerated kernels settings
 607 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 608 if(${GMX_ACCELERATION} STREQUAL "NONE")
 609   # nothing to do
 610 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 611
 612     if (GMX_64_BIT)
 613       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 614     else (GMX_64_BIT)
 615       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 616     endif (GMX_64_BIT)
 617
 618     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 619       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 620     else()
 621       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 622     endif()
 623         mark_as_advanced(GMX_ASM_USEASM-NASM)
 624
 625     if (NOT GMX_64_BIT)
 626         # for 32-bit compiles, we might need to turn on sse
 627         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 628         if (XFLAGS_SSE)
 629             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 630         endif (XFLAGS_SSE)
 631         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 632         if (XXFLAGS_SSE)
 633             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 634         endif (XXFLAGS_SSE)
 635     endif (NOT GMX_64_BIT)
 636
 637     if(GMX_IA32_ASM)
 638       if(GMX_DOUBLE)
 639         set(GMX_IA32_SSE2 1)
 640       else()
 641        set(GMX_IA32_SSE 1)
 642       endif()
 643     elseif(GMX_X86_64_ASM)
 644       if(GMX_DOUBLE)
 645        set(GMX_X86_64_SSE2 1)
 646       else()
 647         set(GMX_X86_64_SSE 1)
 648       endif()
 649     endif()
 650
 651 #    if(HAVE_PMMINTRIN_H)
 652 #        set(GMX_SSE3 1)
 653 #    endif(HAVE_PMMINTRIN_H)
 654 #    if(HAVE_SMMINTRIN_H)
 655 #        set(GMX_SSE4_1 1)
 656 #    endif(HAVE_SMMINTRIN_H)
 657
 658 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 659     set(GMX_FORTRAN 1)
 660     #these are switch on by default sometimes
 661     set(GMX_IA32_ASM 0)
 662     set(GMX_GMX_X86_64_ASM 0)
 663 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 664 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 665     message(STATUS "Configuring for BlueGene")
 666     set(GMX_BLUEGENE 1)
 667     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 668         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 669         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 670     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 671     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 672     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 673     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 674     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 675     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 676 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 677     set(GMX_POWER6 1)
 678     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 679     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 680 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 681     set(GMX_IA64_ASM 1)
 682     set(DISABLE_WATERWATER_NLIST 1)
 683     set(DISABLE_WATER_NLIST 1)
 684 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 685     check_include_files(altivec.h HAVE_ALTIVEC_H)
 686     if(HAVE_ALTIVEC_H)
 687         set(GMX_PPC_ALTIVEC 1)
 688     endif(HAVE_ALTIVEC_H)
 689 else(${GMX_ACCELERATION} STREQUAL "NONE")
 690     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 691 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 692
 693 if(GMX_FORTRAN OR GMX_POWER6)
 694     if (GMX_THREADS)
 695         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 696     endif(GMX_THREADS)
 697     enable_language(Fortran)
 698     include(FortranCInterface)
 699     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 700     if(extra_under_score)
 701         set(extrasuffix "_")
 702     endif(extra_under_score)
 703     if(prefix)
 704       set(prefix "${prefix} ##")
 705     endif(prefix)
 706     if(suffix)
 707       set(suffix "## ${suffix}")
 708       if(extrasuffix)
 709         set(extrasuffix "${suffix}${extrasuffix}")
 710       endif(extrasuffix)
 711     else(suffix)
 712       if(extrasuffix)
 713         # Don't know if this is needed, but it can't hurt
 714         set(extrasuffix "## ${extrasuffix}")
 715       endif(extrasuffix)
 716     endif(suffix)
 717
 718     if(isupper)
 719         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 720         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 721     else(isupper)
 722         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 723         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 724     endif(isupper)
 725 else(GMX_FORTRAN OR GMX_POWER6)
 726         set(F77_FUNCDEF   "name ## _")
 727         set(F77_FUNCDEF_  "name ## _")
 728 endif(GMX_FORTRAN OR GMX_POWER6)
 729
 730 # Process QM/MM Settings
 731 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 732 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 733     set(GMX_QMMM_GAUSSIAN 1)
 734 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 735     set(GMX_QMMM_MOPAC 1)
 736 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 737     set(GMX_QMMM_GAMESS 1)
 738 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 739     set(GMX_QMMM_ORCA 1)
 740 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 741     # nothing to do
 742 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 743     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 744 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 745
 746 # Process FFT library settings - if not OpenMM build
 747 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 748 set(PKG_FFT "")
 749 set(PKG_FFT_LIBS "")
 750 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 751 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 752     if(GMX_DOUBLE)
 753         find_package(FFTW3 REQUIRED)
 754                 include_directories(${FFTW3_INCLUDE_DIR})
 755         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 756         set(PKG_FFT "fftw3")
 757     else(GMX_DOUBLE)
 758         find_package(FFTW3F REQUIRED)
 759         include_directories(${FFTW3F_INCLUDE_DIR})
 760         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 761         set(PKG_FFT "fftw3f")
 762     endif(GMX_DOUBLE)
 763
 764     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 765         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 766     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 767
 768     set(GMX_FFT_FFTW3 1)
 769
 770 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 771 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 772     if(GMX_DOUBLE)
 773         find_package(FFTW2 REQUIRED)
 774     else(GMX_DOUBLE)
 775         find_package(FFTW2F REQUIRED)
 776     endif(GMX_DOUBLE)
 777
 778     if(NOT FFTW2_FOUND)
 779            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 780     endif(NOT FFTW2_FOUND)
 781     include_directories(${FFTW2_INCLUDE_DIR})
 782     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 783     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 784
 785     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 786         set(FFTW2_NAME_DFFTW 1)
 787     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 788         set(FFTW2_NAME_SFFTW 1)
 789     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 790         set(FFTW2_NAME_FFTW 1)
 791     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 792
 793     set(GMX_FFT_FFTW2 1)
 794 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 795 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 796     find_package(MKL REQUIRED)
 797     include_directories(${MKL_INCLUDE_DIR})
 798     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 799     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 800
 801     set(GMX_FFT_MKL 1)
 802     set(HAVE_MKL 1)
 803
 804 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 805 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 806 #    set(GMX_FFT_ACML 1)
 807 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 808     MESSAGE(STATUS "Using internal FFT library - fftpack")
 809     set(GMX_FFT_FFTPACK 1)
 810 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 811     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 812 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 813
 814 # MKL has BLAS/LAPACK routines
 815 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 816   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 817   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 818 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 819   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 820   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 821   if(GMX_EXTERNAL_BLAS)
 822     #FindBLAS needs Fortran
 823     enable_language(Fortran)
 824     if (GMX_BLAS_USER)
 825         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 826     else(GMX_BLAS_USER)
 827         find_package(BLAS REQUIRED)
 828         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 829     endif(GMX_BLAS_USER)
 830   endif(GMX_EXTERNAL_BLAS)
 831   if(GMX_EXTERNAL_LAPACK)
 832     #FindLAPACK needs Fortran
 833     enable_language(Fortran)
 834         if (GMX_LAPACK_USER)
 835         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 836         else(GMX_LAPACK_USER)
 837         find_package(LAPACK REQUIRED)
 838         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 839     endif(GMX_LAPACK_USER)
 840   endif(GMX_EXTERNAL_LAPACK)
 841 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 842 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 843 mark_as_advanced(GMX_EXTERNAL_BLAS)
 844
 845 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 846 set(GMX_VMD_PLUGIN_PATH)
 847 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 848
 849 if(GMX_LOAD_PLUGINS)
 850   include(gmxTestdlopen)
 851   gmx_test_dlopen(HAVE_DLOPEN)
 852
 853   find_package(VMD)
 854
 855   # Test for unsuitable versions of VMD
 856
 857   if(VMD_FOUND)
 858     message(STATUS "Checking for suitable VMD version")
 859     exec_program(${VMD_EXECUTABLE}
 860       ARGS --help
 861       OUTPUT_VARIABLE VMD_HELP
 862       RETURN_VALUE VMD_EXEC_RETURN)
 863
 864     if(VMD_EXEC_RETURN EQUAL 0)
 865       # This is the accepted idiom for subexpression matching, unfortunately
 866       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 867       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 868
 869       if(VMD_VERSION VERSION_LESS "1.8")
 870         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 871         unset(VMD_EXECUTABLE)
 872         set(VMD_FOUND FALSE)
 873       else()
 874         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 875         if(DEFINED ENV{VMDDIR})
 876           # This permits GROMACS to avoid hard-coding a fall-back
 877           # path that it can tell right now would be useless.
 878           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 879         else()
 880           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 881         endif()
 882       endif()
 883
 884       # clean up
 885       unset(VMD_HELP)
 886       unset(VMD_VERSION)
 887       unset(VMD_ARCH)
 888     endif()
 889   endif()
 890
 891   # so, should we use plug-ins?
 892   if(((WIN32 AND NOT CYGWIN) OR HAVE_DLOPEN) AND BUILD_SHARED_LIBS)
 893     MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 894     set(GMX_USE_PLUGINS ON)
 895     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 896     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 897   else()
 898     set(PKG_DL_LIBS)
 899   endif()
 900 endif(GMX_LOAD_PLUGINS)
 901
 902 # Math and thread libraries must often come after all others when linking...
 903 if(HAVE_LIBM)
 904     list(APPEND GMX_EXTRA_LIBRARIES m)
 905 endif(HAVE_LIBM)
 906
 907 if(GMX_FAHCORE)
 908   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 909       "Path to swindirect.h")
 910   include_directories(${COREWRAP_INCLUDE_DIR})
 911 endif(GMX_FAHCORE)
 912
 913 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 914 # these are set after everything else
 915 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 916     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 917         FORCE)
 918     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 919         "Flags used by the compiler during all build types" FORCE)
 920     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 921         "Flags used by the compiler during all build types" FORCE)
 922     set(CMAKE_EXE_LINKER_FLAGS
 923         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 924         CACHE STRING "Linker flags" FORCE)
 925 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 926
 927 ########################################################################
 928 # Specify install locations and which subdirectories to process        #
 929 ########################################################################
 930 if ( DEFINED GMXLIB )
 931     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 932 else()
 933     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 934 endif()
 935 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 936 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 937 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 938 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 939
 940 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 941
 942 ##################################################################
 943 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 944 ##################################################################
 945 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 946     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 947     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 948     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 949     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 950 endif()
 951
 952 add_subdirectory(share)
 953 add_subdirectory(man)
 954 add_subdirectory(src)
 955 add_subdirectory(scripts)
 956
 957 #######################
 958 ## uninstall target
 959 #######################
 960     CONFIGURE_FILE(
 961                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 962                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 963                    IMMEDIATE @ONLY)
 964 ###########################
 965 ADD_CUSTOM_TARGET(uninstall
 966                   "${CMAKE_COMMAND}" -P
 967                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 968 ###########################
 969
 970 ########################################################################
 971 # Doxygen configuration
 972 ########################################################################
 973 if (DOXYGEN_FOUND)
 974     FILE(GLOB NB_KERNEL_DIRS src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
 975     LIST(REMOVE_ITEM NB_KERNEL_DIRS
 976          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
 977     FOREACH(NB_KERNEL_DIR ${NB_KERNEL_DIRS})
 978         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
 979             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${NB_KERNEL_DIR}")
 980     ENDFOREACH(NB_KERNEL_DIR)
 981     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile.cmakein
 982                    ${CMAKE_BINARY_DIR}/Doxyfile)
 983     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-lib.cmakein
 984                    ${CMAKE_BINARY_DIR}/Doxyfile-lib)
 985     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-user.cmakein
 986                    ${CMAKE_BINARY_DIR}/Doxyfile-user)
 987 endif (DOXYGEN_FOUND)
 988
 989
 990 ########################################################################
 991 # Tests                                                                #
 992 ########################################################################
 993
 994 include(CTest)
 995 mark_as_advanced(BUILD_TESTING)
 996 IF(BUILD_TESTING)
 997     enable_testing()
 998     add_subdirectory(tests)
 999 ENDIF()
1000