src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  43 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  44
  45 function (_gmx_add_files_to_property PROPERTY)
  46     foreach (_file ${ARGN})
  47         if (IS_ABSOLUTE "${_file}")
  48             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  49         else()
  50             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  51                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  52         endif()
  53     endforeach()
  54 endfunction ()
  55
  56 function (gmx_add_libgromacs_sources)
  57     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  58 endfunction ()
  59
  60 function (gmx_install_headers)
  61     if (NOT GMX_BUILD_MDRUN_ONLY)
  62         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  63         install(FILES       ${ARGN}
  64                 DESTINATION "${INCL_INSTALL_DIR}/${_dest}"
  65                 COMPONENT   development)
  66     endif()
  67     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  68 endfunction ()
  69
  70 function (gmx_write_installed_header_list)
  71     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  72     string(REPLACE ";" "\n" _list "${_list}")
  73     # TODO: Make this only update the file timestamp if the contents actually change.
  74     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  75 endfunction()
  76
  77 add_subdirectory(gmxlib)
  78 add_subdirectory(mdlib)
  79 add_subdirectory(applied-forces)
  80 add_subdirectory(listed-forces)
  81 add_subdirectory(commandline)
  82 add_subdirectory(domdec)
  83 add_subdirectory(ewald)
  84 add_subdirectory(fft)
  85 add_subdirectory(gpu_utils)
  86 add_subdirectory(hardware)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(mdrun)
  90 add_subdirectory(mdrunutility)
  91 add_subdirectory(mdtypes)
  92 add_subdirectory(onlinehelp)
  93 add_subdirectory(options)
  94 add_subdirectory(pbcutil)
  95 add_subdirectory(random)
  96 add_subdirectory(tables)
  97 add_subdirectory(taskassignment)
  98 add_subdirectory(timing)
  99 add_subdirectory(topology)
 100 add_subdirectory(trajectory)
 101 add_subdirectory(utility)
 102 add_subdirectory(fileio)
 103 add_subdirectory(swap)
 104 add_subdirectory(essentialdynamics)
 105 add_subdirectory(pulling)
 106 add_subdirectory(awh)
 107 add_subdirectory(simd)
 108 add_subdirectory(imd)
 109 if (NOT GMX_BUILD_MDRUN_ONLY)
 110     add_subdirectory(gmxana)
 111     add_subdirectory(gmxpreprocess)
 112     add_subdirectory(correlationfunctions)
 113     add_subdirectory(statistics)
 114     add_subdirectory(analysisdata)
 115     add_subdirectory(selection)
 116     add_subdirectory(trajectoryanalysis)
 117     add_subdirectory(energyanalysis)
 118     add_subdirectory(tools)
 119 endif()
 120
 121 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 122 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 123
 124 # This would be the standard way to include thread_mpi, but
 125 # we want libgromacs to link the functions directly
 126 #if(GMX_THREAD_MPI)
 127 #    add_subdirectory(thread_mpi)
 128 #endif()
 129 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 130
 131 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 132 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 133
 134 get_lmfit_properties(LMFIT_SOURCES LMFIT_LIBRARIES_TO_LINK LMFIT_INCLUDE_DIRECTORY LMFIT_INCLUDE_DIR_ORDER)
 135 include_directories(${LMFIT_INCLUDE_DIR_ORDER} SYSTEM "${LMFIT_INCLUDE_DIRECTORY}")
 136 list(APPEND LIBGROMACS_SOURCES ${LMFIT_SOURCES})
 137
 138 configure_file(version.h.cmakein version.h)
 139 gmx_install_headers(
 140     analysisdata.h
 141     commandline.h
 142     options.h
 143     random.h
 144     selection.h
 145     trajectoryanalysis.h
 146     utility.h
 147     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 148     )
 149
 150 # This code is here instead of utility/CMakeLists.txt, because CMake
 151 # custom commands and source file properties can only be set in the directory
 152 # that contains the target that uses them.
 153 # TODO: Generate a header instead that can be included from baseversion.c.
 154 # That probably simplifies things somewhat.
 155 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 156 gmx_configure_version_file(
 157     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 158     REMOTE_HASH)
 159 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 160
 161 # set up CUDA compilation with clang
 162 if (GMX_CLANG_CUDA)
 163     foreach (_file ${LIBGROMACS_SOURCES})
 164         get_filename_component(_ext ${_file} EXT)
 165         if (${_ext} STREQUAL ".cu")
 166             gmx_compile_cuda_file_with_clang(${_file})
 167         endif()
 168     endforeach()
 169 endif()
 170
 171 if (GMX_USE_CUDA)
 172     # Work around FindCUDA that prevents using target_link_libraries()
 173     # with keywords otherwise...
 174     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 175     if (NOT GMX_CLANG_CUDA)
 176         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 177     else()
 178         add_library(libgromacs ${LIBGROMACS_SOURCES})
 179     endif()
 180     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 181 else()
 182     add_library(libgromacs ${LIBGROMACS_SOURCES})
 183 endif()
 184
 185 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 186 # is a generated source file. These are awkward to suppress inline, so
 187 # we do it in the compilation command (after testing that the compiler
 188 # supports the suppressions).
 189 include(CheckCXXCompilerFlag)
 190 check_cxx_compiler_flag(-Wno-unused HAS_NO_UNUSED)
 191 if (HAS_NO_UNUSED)
 192     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter -Wno-unused-function")
 193 endif()
 194 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 195
 196 if(SIMD_AVX_512_CXX_SUPPORTED)
 197     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file
 198     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 199 endif()
 200
 201 gmx_setup_tng_for_libgromacs()
 202
 203 target_link_libraries(libgromacs
 204                       PRIVATE
 205                       ${EXTRAE_LIBRARIES}
 206                       ${GMX_EXTRA_LIBRARIES}
 207                       ${GMX_COMMON_LIBRARIES}
 208                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 209                       ${LMFIT_LIBRARIES_TO_LINK}
 210                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS} ${OpenCL_LIBRARIES}
 211                       ${GMX_STDLIB_LIBRARIES}
 212                       PUBLIC
 213                       ${GMX_PUBLIC_LIBRARIES}
 214                       )
 215 set_target_properties(libgromacs PROPERTIES
 216                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 217                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 218                       VERSION ${LIBRARY_VERSION}
 219                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 220
 221 gmx_write_installed_header_list()
 222
 223 # Only install the library in mdrun-only mode if it is actually necessary
 224 # for the binary
 225 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 226     install(TARGETS libgromacs
 227             EXPORT libgromacs
 228             LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 229             RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 230             ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 231             COMPONENT libraries)
 232 endif()
 233
 234 if (NOT GMX_BUILD_MDRUN_ONLY)
 235     include(InstallLibInfo.cmake)
 236 endif()
 237
 238 # Technically, the user could want to do this for an OpenCL build
 239 # using the CUDA runtime, but currently there's no reason to want to
 240 # do that.
 241 if (INSTALL_CUDART_LIB) #can be set manual by user
 242     if (GMX_USE_CUDA)
 243         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 244             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 245             if(IS_CUDART) #libcuda should not be installed
 246                 #install also name-links (linker uses those)
 247                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 248                 install(FILES ${CUDA_LIBS} DESTINATION
 249                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 250             endif()
 251         endforeach()
 252     else()
 253         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 254     endif()
 255 endif()
 256
 257 if(GMX_USE_OPENCL)
 258     set(OPENCL_KERNELS ${MDLIB_OPENCL_KERNELS})
 259
 260     install(FILES ${OPENCL_KERNELS} DESTINATION
 261         ${OCL_INSTALL_DIR} COMPONENT libraries)
 262 endif()
 263
 264 if (BUILD_TESTING)
 265     add_subdirectory(compat/tests)
 266 endif()