docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # Prepare directories for pdf/tex output
  76 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  77 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  78 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  79
  80 # The directory from which man pages will be installed; if it remains
  81 # empty, they will be silently skipped.
  82 set(MAN_PAGE_DIR)
  83 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  84     # When building from the tarball, install the bundled man pages
  85     # (unless overridden).
  86     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  87 endif()
  88
  89 add_subdirectory(doxygen)
  90 if (SPHINX_FOUND)
  91     # We need to have all the Sphinx input files in a single directory, and
  92     # since some of them are generated, we copy everything into the build tree,
  93     # to this directory.
  94     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  95     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  96     # As the manual build now depends also on Sphinx, the inclusion path needs
  97     # to be set after we know the basic information for Sphinx.
  98     add_subdirectory(manual)
  99     if (SOURCE_MD5SUM STREQUAL "unknown")
 100         # But for testing the webpage build (e.g. from the repo) we
 101         # need a default value.
 102         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 103     else()
 104         # The real build of the webpage happens from the tarball, and
 105         # this should be set to the matching MD5 sum.
 106         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 107     endif()
 108     # The reference manual still contains the individual sections from the
 109     # LaTeX document, with the files below grouped and annotated by chapter.
 110     set(REFERENCEMANUAL_SPHINX_FILES
 111         # Main index file, preface and introduction.
 112         reference-manual/index.rst
 113         reference-manual/preface.rst
 114         reference-manual/introduction.rst
 115         # Definitions and Units chapter
 116         reference-manual/definitions.rst
 117         # Algorithms chapter
 118         reference-manual/algorithms.rst
 119         reference-manual/algorithms/periodic-boundary-conditions.rst
 120         reference-manual/algorithms/group-concept.rst
 121         reference-manual/algorithms/molecular-dynamics.rst
 122         reference-manual/algorithms/shell-molecular-dynamics.rst
 123         reference-manual/algorithms/constraint-algorithms.rst
 124         reference-manual/algorithms/simulated-annealing.rst
 125         reference-manual/algorithms/stochastic-dynamics.rst
 126         reference-manual/algorithms/brownian-dynamics.rst
 127         reference-manual/algorithms/energy-minimization.rst
 128         reference-manual/algorithms/normal-mode-analysis.rst
 129         reference-manual/algorithms/free-energy-calculations.rst
 130         reference-manual/algorithms/replica-exchange.rst
 131         reference-manual/algorithms/essential-dynamics.rst
 132         reference-manual/algorithms/expanded-ensemble.rst
 133         reference-manual/algorithms/parallelization-domain-decomp.rst
 134         # Interaction functions and force fields chapter
 135         reference-manual/functions.rst
 136         reference-manual/functions/bonded-interactions.rst
 137         reference-manual/functions/force-field.rst
 138         reference-manual/functions/free-energy-interactions.rst
 139         reference-manual/functions/interaction-methods.rst
 140         reference-manual/functions/long-range-electrostatics.rst
 141         reference-manual/functions/long-range-vdw.rst
 142         reference-manual/functions/nonbonded-interactions.rst
 143         reference-manual/functions/polarization.rst
 144         reference-manual/functions/restraints.rst
 145         # Topologies chapter
 146         reference-manual/topologies.rst
 147         reference-manual/topologies/particle-type.rst
 148         reference-manual/topologies/parameter-files.rst
 149         reference-manual/topologies/molecule-definition.rst
 150         reference-manual/topologies/constraint-algorithm-section.rst
 151         reference-manual/topologies/pdb2gmx-input-files.rst
 152         reference-manual/topologies/topology-file-formats.rst
 153         reference-manual/topologies/force-field-organization.rst
 154         # File formats chapter
 155         reference-manual/file-formats.rst
 156         # Special topics chapter
 157         reference-manual/special.rst
 158         reference-manual/special/free-energy-implementation.rst
 159         reference-manual/special/pulling.rst
 160         reference-manual/special/awh.rst
 161         reference-manual/special/enforced-rotation.rst
 162         reference-manual/special/electric-fields.rst
 163         reference-manual/special/comp-electrophys.rst
 164         reference-manual/special/free-energy-pmf.rst
 165         reference-manual/special/remove-fast-dgf.rst
 166         reference-manual/special/viscosity-calculation.rst
 167         reference-manual/special/tabulated-interaction-functions.rst
 168         reference-manual/special/qmmm.rst
 169         reference-manual/special/vmd-imd.rst
 170         reference-manual/special/membrane-embedding.rst
 171         # Run parameters and programs chapter
 172         reference-manual/run-parameters.rst
 173         # Analysis chapter
 174         reference-manual/analysis.rst
 175         reference-manual/analysis/using-groups.rst
 176         reference-manual/analysis/looking-at-trajectory.rst
 177         reference-manual/analysis/general-properties.rst
 178         reference-manual/analysis/radial-distribution-function.rst
 179         reference-manual/analysis/correlation-function.rst
 180         reference-manual/analysis/curve-fitting.rst
 181         reference-manual/analysis/mean-square-displacement.rst
 182         reference-manual/analysis/bond-angle-dihedral.rst
 183         reference-manual/analysis/radius-of-gyration.rst
 184         reference-manual/analysis/rmsd.rst
 185         reference-manual/analysis/covariance-analysis.rst
 186         reference-manual/analysis/dihedral-pca.rst
 187         reference-manual/analysis/protein-related.rst
 188         reference-manual/analysis/interface-related.rst
 189         # Implementation details chapter
 190         reference-manual/details.rst
 191         # Averages and fluctations chapter
 192         reference-manual/averages.rst
 193         # References
 194         reference-manual/references.rst
 195         # PNG formated plot files that don't need to be converted into PNG
 196         # for the web page.
 197         reference-manual/plots/peregrine.png
 198         reference-manual/plots/adress.png
 199         reference-manual/plots/plotje.png
 200         reference-manual/plots/xvgr.png
 201         )
 202     # The image files have also been ordered by the respective
 203     # chapter they are included in in the reference manual
 204     set(REFERENCEMANUAL_IMAGE_FILES
 205         # General folder
 206         reference-manual/plots/decomp.pdf
 207         reference-manual/plots/dih.pdf
 208         reference-manual/plots/drift-all.pdf
 209         reference-manual/plots/f-angle.pdf
 210         reference-manual/plots/f-bond.pdf
 211         reference-manual/plots/fp-highres.pdf
 212         reference-manual/plots/int-mat.pdf
 213         reference-manual/plots/mdpar.pdf
 214         reference-manual/plots/parsort.pdf
 215         reference-manual/plots/ring.pdf
 216         reference-manual/plots/shiftf.pdf
 217         # Algorithms chapter
 218         reference-manual/algorithms/plots/dd-cells.pdf
 219         reference-manual/algorithms/plots/dd-tric.pdf
 220         reference-manual/algorithms/plots/flowchart.pdf
 221         reference-manual/algorithms/plots/free1.pdf
 222         reference-manual/algorithms/plots/free2.pdf
 223         reference-manual/algorithms/plots/leapfrog.pdf
 224         reference-manual/algorithms/plots/lincs.pdf
 225         reference-manual/algorithms/plots/maxwell.pdf
 226         reference-manual/algorithms/plots/mpmd-pme.pdf
 227         reference-manual/algorithms/plots/nstric.pdf
 228         reference-manual/algorithms/plots/par-lincs2.pdf
 229         reference-manual/algorithms/plots/pbctric.pdf
 230         reference-manual/algorithms/plots/rhododec.pdf
 231         reference-manual/algorithms/plots/truncoct.pdf
 232         reference-manual/algorithms/plots/verlet-drift.pdf
 233         # Interaction functions chapter
 234         reference-manual/functions/plots/angle.pdf
 235         reference-manual/functions/plots/bstretch.pdf
 236         reference-manual/functions/plots/chain.pdf
 237         reference-manual/functions/plots/dummies.pdf
 238         reference-manual/functions/plots/f-bham.pdf
 239         reference-manual/functions/plots/fbposres.pdf
 240         reference-manual/functions/plots/f-dih.pdf
 241         reference-manual/functions/plots/f-dr.pdf
 242         reference-manual/functions/plots/fig-02.pdf
 243         reference-manual/functions/plots/fig-04.pdf
 244         reference-manual/functions/plots/f-imps.pdf
 245         reference-manual/functions/plots/f-lj.pdf
 246         reference-manual/functions/plots/f-morse.pdf
 247         reference-manual/functions/plots/f-pr.pdf
 248         reference-manual/functions/plots/f-rbs.pdf
 249         reference-manual/functions/plots/ring-imp.pdf
 250         reference-manual/functions/plots/softcore.pdf
 251         reference-manual/functions/plots/subst-im.pdf
 252         reference-manual/functions/plots/tetra-im.pdf
 253         reference-manual/functions/plots/vcrf.pdf
 254         reference-manual/functions/plots/vsite-4fdn.pdf
 255         # Special topics chapter
 256         reference-manual/special/plots/awh-invN.pdf
 257         reference-manual/special/plots/awh-pmfs.pdf
 258         reference-manual/special/plots/awh-sampleweights.pdf
 259         reference-manual/special/plots/awh-traj.pdf
 260         reference-manual/special/plots/compelsetup.pdf
 261         reference-manual/special/plots/dumaro.pdf
 262         reference-manual/special/plots/dumtypes.pdf
 263         reference-manual/special/plots/equipotential.pdf
 264         reference-manual/special/plots/field.pdf
 265         reference-manual/special/plots/gaussians.pdf
 266         reference-manual/special/plots/pulldirrel.pdf
 267         reference-manual/special/plots/pull.pdf
 268         reference-manual/special/plots/pullref.pdf
 269         reference-manual/special/plots/rotation.pdf
 270         # Analysis chapter
 271         reference-manual/analysis/plots/dih-def.pdf
 272         reference-manual/analysis/plots/distm.pdf
 273         reference-manual/analysis/plots/dssp.pdf
 274         reference-manual/analysis/plots/hbond-insert.pdf
 275         reference-manual/analysis/plots/hbond.pdf
 276         reference-manual/analysis/plots/hpr-wheel.pdf
 277         reference-manual/analysis/plots/msdwater.pdf
 278         reference-manual/analysis/plots/ngmxdump.pdf
 279         reference-manual/analysis/plots/phipsi.pdf
 280         reference-manual/analysis/plots/rama.pdf
 281         reference-manual/analysis/plots/rdfO-O.pdf
 282         reference-manual/analysis/plots/rdf.pdf
 283         reference-manual/analysis/plots/sgangle.pdf
 284         )
 285     set(SPHINX_SOURCE_FILES
 286         index.rst
 287         download.rst
 288         conf.py
 289         links.dat
 290         dev-manual/build-system.rst
 291         dev-manual/change-management.rst
 292         dev-manual/commitstyle.rst
 293         dev-manual/documentation-generation.rst
 294         dev-manual/contribute.rst
 295         dev-manual/doxygen.rst
 296         dev-manual/error-handling.rst
 297         dev-manual/formatting.rst
 298         dev-manual/gmxtree.rst
 299         dev-manual/includestyle.rst
 300         dev-manual/index.rst
 301         dev-manual/jenkins.rst
 302         dev-manual/language-features.rst
 303         dev-manual/naming.rst
 304         dev-manual/overview.rst
 305         dev-manual/physical_validation.rst
 306         dev-manual/redmine-states.png
 307         dev-manual/relocatable-binaries.rst
 308         dev-manual/reportstyle.rst
 309         dev-manual/style.rst
 310         dev-manual/testutils.rst
 311         dev-manual/tools.rst
 312         dev-manual/uncrustify.rst
 313         fragments/doxygen-links.rst
 314         install-guide/index.rst
 315         release-notes/index.rst
 316         release-notes/highlights.rst
 317         release-notes/features.rst
 318         release-notes/performance.rst
 319         release-notes/tools.rst
 320         release-notes/bugs-fixed.rst
 321         release-notes/removed-features.rst
 322         release-notes/portability.rst
 323         release-notes/miscellaneous.rst
 324         release-notes/2018/2018.3.rst
 325         release-notes/2018/2018.2.rst
 326         release-notes/2018/2018.1.rst
 327         release-notes/2018/major/highlights.rst
 328         release-notes/2018/major/features.rst
 329         release-notes/2018/major/performance.rst
 330         release-notes/2018/major/tools.rst
 331         release-notes/2018/major/bugs-fixed.rst
 332         release-notes/2018/major/removed-features.rst
 333         release-notes/2018/major/portability.rst
 334         release-notes/2018/major/miscellaneous.rst
 335         release-notes/2016/2016.5.rst
 336         release-notes/2016/2016.4.rst
 337         release-notes/2016/2016.3.rst
 338         release-notes/2016/2016.2.rst
 339         release-notes/2016/2016.1.rst
 340         release-notes/2016/major/highlights.rst
 341         release-notes/2016/major/new-features.rst
 342         release-notes/2016/major/performance.rst
 343         release-notes/2016/major/tools.rst
 344         release-notes/2016/major/bugs-fixed.rst
 345         release-notes/2016/major/removed-features.rst
 346         release-notes/2016/major/miscellaneous.rst
 347         release-notes/older/index.rst
 348         user-guide/index.rst
 349         user-guide/cmdline.rst
 350         user-guide/cutoff-schemes.rst
 351         user-guide/environment-variables.rst
 352         user-guide/faq.rst
 353         user-guide/floating-point.rst
 354         user-guide/system-preparation.rst
 355         user-guide/force-fields.rst
 356         user-guide/getting-started.rst
 357         user-guide/managing-simulations.rst
 358         user-guide/mdp-options.rst
 359         user-guide/mdrun-features.rst
 360         user-guide/mdrun-performance.rst
 361         user-guide/run-time-errors.rst
 362         user-guide/system-preparation.rst
 363         user-guide/terminology.rst
 364         )
 365
 366     include(SphinxMacros.cmake)
 367     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 368
 369     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 370     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 371         EXTRA_VARS
 372             SPHINX_EXTENSION_PATH RELENG_PATH
 373             EXPECTED_DOXYGEN_VERSION
 374             EXPECTED_SPHINX_VERSION
 375             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 376             REQUIRED_OPENCL_MIN_VERSION
 377             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 378             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 379             GMX_TNG_MINIMUM_REQUIRED_VERSION
 380             GMX_LMFIT_REQUIRED_VERSION
 381         COMMENT "Configuring Sphinx configuration file")
 382     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 383     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 384     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 385         include(${RELENG_PATH}/docs/FileList.cmake)
 386         gmx_add_sphinx_source_files(
 387             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 388             FILES ${RELENG_SPHINX_FILES})
 389     else()
 390         gmx_add_sphinx_source_files(FILES
 391             dev-manual/releng/index.rst
 392             dev-manual/releng/jenkins-howto.rst
 393             dev-manual/releng/jenkins-ui.rst
 394             )
 395     endif()
 396     if (IMAGE_CONVERT_POSSIBLE)
 397         gmx_add_sphinx_source_files(
 398             FILES
 399             ${REFERENCEMANUAL_SPHINX_FILES}
 400             user-guide/index.rst
 401             user-guide/flow.rst)
 402         gmx_add_sphinx_source_files(
 403             FILES
 404             ${REFERENCEMANUAL_IMAGE_FILES})
 405         gmx_add_sphinx_image_conversion_files(
 406             FILES
 407             ${REFERENCEMANUAL_IMAGE_FILES})
 408     else()
 409         gmx_add_sphinx_source_files(
 410             FROM ${CMAKE_CURRENT_SOURCE_DIR}/reference-manual TO user-guide
 411             FILES
 412             file-formats.rst
 413             plots/plotje.png
 414             plots/xvgr.png)
 415         gmx_add_sphinx_source_files(
 416             FROM ${CMAKE_CURRENT_SOURCE_DIR}/reference-manual-minimal TO reference-manual
 417             FILES
 418             index.rst)
 419         gmx_add_sphinx_source_files(
 420             FROM ${CMAKE_CURRENT_SOURCE_DIR}/user-guide-old TO user-guide
 421             FILES
 422             index.rst
 423             flow.rst)
 424     endif()
 425     gmx_add_sphinx_input_target(sphinx-input)
 426     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 427     # Remove other rst files from the build tree, since they confuse Sphinx.
 428     # Skip generated files in onlinehelp/, and fragments.
 429     # The latter do not cause issues with obsolete files, as they
 430     # are not considered as Sphinx input files, but will only be
 431     # included using an explicit .. include::.
 432     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 433
 434     # TODO: Make this remove obsolete .rst files.
 435     # TODO: This does not work in cross-compilation scenarios; disable up to
 436     # the necessary level.
 437     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 438         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 439         COMMAND gmx -quiet help -export rst
 440         DEPENDS gmx
 441         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 442         COMMENT "Generating reStructuredText help")
 443     # This dependency ensures that the directories exist before the
 444     # executable tries to write things there.
 445     add_dependencies(sphinx-programs sphinx-input)
 446
 447     # Make the INSTALL file for CPack for the tarball. This gets put
 448     # into the tarball via the CPack rules below, which requires that
 449     # the INSTALL file is in a separate directory by itself.
 450     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 451     add_custom_target(install-guide
 452         COMMAND
 453             ${SPHINX_EXECUTABLE}
 454             -q -E -b text
 455             -w sphinx-install.log
 456             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 457             -c ${SPHINX_INPUT_DIR}
 458             "${SPHINX_INPUT_DIR}/install-guide"
 459             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 460         COMMAND
 461             ${CMAKE_COMMAND} -E rename
 462             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 463             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 464         WORKING_DIRECTORY
 465             ${CMAKE_CURRENT_BINARY_DIR}
 466         COMMENT "Building INSTALL with Sphinx"
 467         VERBATIM
 468         )
 469     add_dependencies(install-guide sphinx-input)
 470     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 471
 472     # Sphinx cache with pickled ReST documents
 473     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 474     add_custom_target(webpage-sphinx
 475         DEPENDS sphinx-programs
 476         DEPENDS sphinx-input
 477         DEPENDS sphinx-image-conversion
 478         COMMAND
 479             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 480         COMMAND
 481             ${SPHINX_EXECUTABLE}
 482             -q -E -b html
 483             -w sphinx-html.log
 484             -d "${SPHINX_CACHE_DIR}"
 485             "${SPHINX_INPUT_DIR}"
 486             "${HTML_OUTPUT_DIR}"
 487         WORKING_DIRECTORY
 488             ${CMAKE_CURRENT_BINARY_DIR}
 489         COMMENT "Building HTML documentation with Sphinx"
 490         VERBATIM
 491         )
 492
 493     add_custom_target(man
 494         COMMAND
 495             ${SPHINX_EXECUTABLE}
 496             -q -E -b man
 497             -w sphinx-man.log
 498             -d ${SPHINX_CACHE_DIR}
 499             -t do_man
 500             ${SPHINX_INPUT_DIR}
 501             ${CMAKE_CURRENT_BINARY_DIR}/man
 502         COMMENT "Building man pages with Sphinx"
 503         VERBATIM)
 504     add_dependencies(man sphinx-input sphinx-programs)
 505     if (GMX_BUILD_HELP)
 506         # If requested, install the man pages built by the 'man' target
 507         # created above.  Nothing will be installed if the user did not
 508         # manually build the target.
 509         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 510     endif()
 511
 512 else()
 513     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 514     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is not available")
 515
 516     add_custom_target(webpage-sphinx
 517         COMMAND ${CMAKE_COMMAND} -E echo
 518             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 519         VERBATIM)
 520     add_custom_target(install-guide
 521         COMMAND ${CMAKE_COMMAND} -E echo
 522             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 523         VERBATIM)
 524     add_custom_target(man
 525         COMMAND ${CMAKE_COMMAND} -E echo
 526             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 527         VERBATIM)
 528     add_custom_target(sphinx-create-texman
 529         COMMAND ${CMAKE_COMMAND} -E echo
 530             "Cannot prepare LaTeX input files because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 531         VERBATIM)
 532 endif()
 533
 534 if (MAN_PAGE_DIR)
 535     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 536     # Trailing slash on directory is significant for
 537     # install(DIRECTORY). See CMake docs.
 538     install(DIRECTORY ${MAN_PAGE_DIR}/
 539         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 540         COMPONENT man OPTIONAL
 541         FILES_MATCHING PATTERN "*.1")
 542 endif()
 543 gmx_cpack_add_generated_source_directory(man)
 544
 545 # Determine whether we can build all the HTML pages and content linked from
 546 # there.  If not, construct an informative message if the user tries to
 547 # build the target; most people never need to know, unless they've asked for
 548 # the webpage build.
 549 set(HTML_BUILD_IS_POSSIBLE ON)
 550 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 551 set(HTML_BUILD_WARNINGS)
 552
 553 # Next, turn it off if any of the preconditions are unsatisified
 554 if (NOT PYTHON_EXECUTABLE)
 555     set(HTML_BUILD_IS_POSSIBLE OFF)
 556     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 557 elseif (NOT SPHINX_FOUND)
 558     # Hardly anything gets built if Sphinx is not available, so don't bother.
 559     set(HTML_BUILD_IS_POSSIBLE OFF)
 560     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 561 endif()
 562 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 563     list(APPEND HTML_BUILD_WARNINGS
 564          "Reference PDF manual was not built, so links to it do not work")
 565 endif()
 566 if (NOT DOXYGEN_EXECUTABLE)
 567     list(APPEND HTML_BUILD_WARNINGS
 568         "Doxygen was not available, so links to Doxygen do not work")
 569 endif()
 570 if (NOT DOXYGEN_DOT_EXECUTABLE)
 571     list(APPEND HTML_BUILD_WARNINGS
 572         "dot/graphviz was not found, so some graphs are missing")
 573 endif()
 574
 575 if (HTML_BUILD_IS_POSSIBLE)
 576     set(_webpage_target_properties)
 577     if (HTML_BUILD_WARNINGS)
 578         list(APPEND _webpage_target_properties
 579              COMMAND ${CMAKE_COMMAND} -E echo
 580                  "webpage was built, but with the following limitations:")
 581         foreach(_warning ${HTML_BUILD_WARNINGS})
 582         list(APPEND _webpage_target_properties
 583              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 584         endforeach()
 585     endif()
 586
 587     if (MANUAL_BUILD_IS_POSSIBLE)
 588         # Make the PDF reference guide
 589         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 590         # TODO Make this depend on the output of the manual build, so that the
 591         # file actually gets copied multiple times.
 592         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 593         add_custom_command(
 594             OUTPUT ${_manual_target_location}
 595             COMMAND ${CMAKE_COMMAND}
 596                 -E remove -f ${_manual_target_location}
 597             COMMAND ${CMAKE_COMMAND}
 598                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 599             DEPENDS manual
 600             VERBATIM)
 601         list(APPEND _webpage_target_properties
 602              DEPENDS ${_manual_target_location})
 603     endif()
 604
 605     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 606     # makes all the Doxygen output directly in
 607     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 608     # to).
 609
 610     # Add a top-level target that builds everything related to the webpage,
 611     # for Jenkins (and possibly others) to use
 612     add_custom_target(webpage ${_webpage_target_properties}
 613         COMMENT "Building webpage"
 614         VERBATIM)
 615     add_dependencies(webpage webpage-sphinx doxygen-all)
 616 else()
 617     add_custom_target(webpage
 618         COMMAND ${CMAKE_COMMAND} -E echo
 619             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 620         COMMENT "Webpage build not possible"
 621         VERBATIM)
 622 endif()