cmake/gmxDetectSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Check the username performing the build, as well as date and time
  36 #
  37 # gmx_detect_simd(GMX_SUGGESTED_SIMD)
  38 #
  39 # Try to detect CPU information and suggest SIMD instruction set
  40 # that fits the current CPU. This should work on all architectures
  41 # where we are not cross-compiling; depending on the architecture the
  42 # detection will either use special assembly instructions (like cpuid),
  43 # preprocessor defines, or probing /proc/cpuinfo on Linux.
  44 #
  45 # This assumes gmx_detect_target_architecture() has already been run,
  46 # so that things like GMX_TARGET_X86 are already available.
  47 # (otherwise we cannot use inline ASM on x86).
  48 #
  49 # Sets ${GMX_SUGGESTED_SIMD} in the parent scope if
  50 # GMX_SIMD is not set (e.g. by the user, or a previous run
  51 # of CMake).
  52 #
  53
  54 # we rely on inline asm support for GNU!
  55 include(gmxTestInlineASM)
  56
  57 function(gmx_suggest_simd _suggested_simd)
  58
  59     # for x86 we need inline asm to use cpuid
  60     gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
  61
  62     if(GMX_X86_GCC_INLINE_ASM)
  63         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM=1")
  64     else()
  65         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM=0")
  66     endif()
  67
  68     message(STATUS "Detecting best SIMD instructions for this CPU")
  69
  70     # Get CPU SIMD properties information
  71     set(_compile_definitions "${GCC_INLINE_ASM_DEFINE} -I${CMAKE_SOURCE_DIR}/src -DGMX_CPUINFO_STANDALONE")
  72
  73     # We need to execute the binary, so this only works if not cross-compiling.
  74     # However, note that we are NOT limited to x86.
  75     if(NOT CMAKE_CROSSCOMPILING)
  76         try_run(GMX_CPUINFO_RUN_SIMD GMX_CPUINFO_COMPILED
  77                 ${CMAKE_BINARY_DIR}
  78                 ${CMAKE_SOURCE_DIR}/src/gromacs/hardware/cpuinfo.cpp
  79                 COMPILE_DEFINITIONS ${_compile_definitions}
  80                 RUN_OUTPUT_VARIABLE OUTPUT_TMP
  81                 COMPILE_OUTPUT_VARIABLE GMX_CPUINFO_COMPILE_OUTPUT
  82                 ARGS "-features")
  83
  84         if(NOT GMX_CPUINFO_COMPILED)
  85             message(WARNING "Cannot compile cpuinfo code, which means no SIMD instructions.")
  86             message(STATUS "Compile output: ${GMX_CPUINFO_COMPILE_OUTPUT}")
  87             set(OUTPUT_TMP "None")
  88         elseif(NOT GMX_CPUINFO_RUN_SIMD EQUAL 0)
  89             message(WARNING "Cannot run cpuinfo code, which means no SIMD instructions.")
  90             message(STATUS "Run output: ${OUTPUT_TMP}")
  91             set(OUTPUT_TMP "None")
  92         endif(NOT GMX_CPUINFO_COMPILED)
  93
  94         if(GMX_TARGET_X86)
  95             if(OUTPUT_TMP MATCHES " avx512er ")
  96                 set(OUTPUT_SIMD "AVX_512_KNL")
  97             elseif(OUTPUT_TMP MATCHES " avx512f ")
  98                 set(OUTPUT_SIMD "AVX_512")
  99             elseif(OUTPUT_TMP MATCHES " avx2 ")
 100                 set(OUTPUT_SIMD "AVX2_256")
 101             elseif(OUTPUT_TMP MATCHES " avx ")
 102                 if(OUTPUT_TMP MATCHES " fma4 ")
 103                     # AMD that works better with avx-128-fma
 104                 set(OUTPUT_SIMD "AVX_128_FMA")
 105                 else()
 106                     # Intel
 107                 set(OUTPUT_SIMD "AVX_256")
 108                 endif()
 109             elseif(OUTPUT_TMP MATCHES " sse4.1 ")
 110                 set(OUTPUT_SIMD "SSE4.1")
 111             elseif(OUTPUT_TMP MATCHES " sse2 ")
 112                 set(OUTPUT_SIMD "SSE2")
 113             endif()
 114         else()
 115             if(OUTPUT_TMP MATCHES " vsx ")
 116                 set(OUTPUT_SIMD "IBM_VSX")
 117             elseif(OUTPUT_TMP MATCHES " vmx ")
 118                 set(OUTPUT_SIMD "IBM_VMX")
 119             elseif(OUTPUT_TMP MATCHES " qpx ")
 120                 set(OUTPUT_SIMD "IBM_QPX")
 121             elseif(OUTPUT_TMP MATCHES " neon_asimd ")
 122                 set(OUTPUT_SIMD "ARM_NEON_ASIMD")
 123             elseif(OUTPUT_TMP MATCHES " neon ")
 124                 set(OUTPUT_SIMD "ARM_NEON")
 125             endif()
 126         endif()
 127
 128         set(${_suggested_simd} "${OUTPUT_SIMD}" PARENT_SCOPE)
 129         message(STATUS "Detected best SIMD instructions for this CPU - ${OUTPUT_SIMD}")
 130     else()
 131         set(${_suggested_simd} "None" PARENT_SCOPE)
 132         message(WARNING "Cannot detect SIMD architecture for this cross-compile; you should check it manually.")
 133     endif()
 134 endfunction()
 135
 136 function(gmx_detect_simd _suggested_simd)
 137     if(NOT DEFINED GMX_SIMD)
 138         if(GMX_TARGET_BGQ)
 139             set(${_suggested_simd} "IBM_QPX")
 140         elseif(GMX_TARGET_FUJITSU_SPARC64)
 141             # HPC-ACE is always present. In the future we
 142             # should add detection for HPC-ACE2 here.
 143             set(${_suggested_simd} "Sparc64_HPC_ACE")
 144         elseif(GMX_TARGET_MIC)
 145             set(${_suggested_simd} "MIC")
 146         else()
 147             gmx_suggest_simd(${_suggested_simd})
 148         endif()
 149
 150         set(${_suggested_simd} ${${_suggested_simd}} PARENT_SCOPE)
 151     endif()
 152 endfunction()