docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 find_package(PythonInterp 2.7)
  62 find_package(Sphinx 1.3 QUIET COMPONENTS pygments)
  63
  64 # Even if we aren't going to make the full webpage, set up to put all
  65 # the documentation output in the same place, for convenience
  66 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  67 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  68
  69 # The directory from which man pages will be installed; if it remains
  70 # empty, they will be silently skipped.
  71 set(MAN_PAGE_DIR)
  72 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  73     # When building from the tarball, install the bundled man pages
  74     # (unless overridden).
  75     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  76 endif()
  77
  78 add_subdirectory(doxygen)
  79 add_subdirectory(manual)
  80
  81 if (SPHINX_FOUND)
  82     # We need to have all the Sphinx input files in a single directory, and
  83     # since some of them are generated, we copy everything into the build tree,
  84     # to this directory.
  85     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  86     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  87     if (SOURCE_MD5SUM STREQUAL "unknown")
  88         # But for testing the webpage build (e.g. from the repo) we
  89         # need a default value.
  90         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  91     else()
  92         # The real build of the webpage happens from the tarball, and
  93         # this should be set to the matching MD5 sum.
  94         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
  95     endif()
  96     set(SPHINX_SOURCE_FILES
  97         index.rst
  98         download.rst
  99         dev-manual/index.rst
 100         dev-manual/build-system.rst
 101         dev-manual/doxygen.rst
 102         dev-manual/formatting.rst
 103         dev-manual/gmxtree.rst
 104         dev-manual/includestyle.rst
 105         dev-manual/jenkins.rst
 106         dev-manual/language-features.rst
 107         dev-manual/naming.rst
 108         dev-manual/overview.rst
 109         dev-manual/relocatable-binaries.rst
 110         dev-manual/style.rst
 111         dev-manual/testutils.rst
 112         dev-manual/tools.rst
 113         dev-manual/uncrustify.rst
 114         fragments/doxygen-links.rst
 115         install-guide/index.rst
 116         user-guide/index.rst
 117         user-guide/getting-started.rst
 118         user-guide/flow.rst
 119         user-guide/cutoff-schemes.rst
 120         user-guide/mdrun-features.rst
 121         user-guide/mdrun-performance.rst
 122         user-guide/mdp-options.rst
 123         user-guide/file-formats.rst
 124         user-guide/cmdline.rst
 125         user-guide/environment-variables.rst
 126         user-guide/plotje.gif
 127         user-guide/xvgr.gif
 128         conf.py
 129         links.dat
 130         )
 131
 132     include(SphinxMacros.cmake)
 133     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 134
 135     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 136     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 137         EXTRA_VARS
 138             SPHINX_EXTENSION_PATH RELENG_PATH
 139             EXPECTED_DOXYGEN_VERSION
 140             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 141             REQUIRED_OPENCL_MIN_VERSION
 142             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 143             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 144             GMX_TNG_MINIMUM_REQUIRED_VERSION
 145         COMMENT "Configuring Sphinx configuration file")
 146     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 147     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 148     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 149         include(${RELENG_PATH}/docs/FileList.cmake)
 150         gmx_add_sphinx_source_files(
 151             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 152             FILES ${RELENG_SPHINX_FILES})
 153     else()
 154         gmx_add_dummy_sphinx_input_file(dev-manual/releng/index.rst
 155             "releng repository (missing)")
 156     endif()
 157     gmx_add_sphinx_input_target(sphinx-input)
 158     # Remove other rst files from the build tree, since they confuse Sphinx.
 159     # Skip generated files in onlinehelp/, and fragments.
 160     # The latter do not cause issues with obsolete files, as they
 161     # are not considered as Sphinx input files, but will only be
 162     # included using an explicit .. include::.
 163     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 164
 165     # TODO: Make this remove obsolete .rst files.
 166     # TODO: This does not work in cross-compilation scenarios; disable up to
 167     # the necessary level.
 168     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 169         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 170         COMMAND gmx -quiet help -export rst
 171         DEPENDS gmx
 172         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 173         COMMENT "Generating reStructuredText help")
 174     # This dependency ensures that the directories exist before the
 175     # executable tries to write things there.
 176     add_dependencies(sphinx-programs sphinx-input)
 177
 178     # Make the INSTALL file for CPack for the tarball. This gets put
 179     # into the tarball via the CPack rules below, which requires that
 180     # the INSTALL file is in a separate directory by itself.
 181     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 182     add_custom_target(install-guide
 183         COMMAND
 184             ${SPHINX_EXECUTABLE}
 185             -q -b text
 186             -w sphinx-install.log
 187             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 188             -c ${SPHINX_INPUT_DIR}
 189             "${SPHINX_INPUT_DIR}/install-guide"
 190             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 191         COMMAND
 192             ${CMAKE_COMMAND} -E rename
 193             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 194             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 195         WORKING_DIRECTORY
 196             ${CMAKE_CURRENT_BINARY_DIR}
 197         COMMENT "Building INSTALL with Sphinx"
 198         VERBATIM
 199         )
 200     add_dependencies(install-guide sphinx-input)
 201     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 202
 203     # Sphinx cache with pickled ReST documents
 204     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 205
 206     add_custom_target(webpage-sphinx
 207         COMMAND
 208             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 209         COMMAND
 210             ${SPHINX_EXECUTABLE}
 211             -q -b html
 212             -w sphinx-html.log
 213             -d "${SPHINX_CACHE_DIR}"
 214             "${SPHINX_INPUT_DIR}"
 215             "${HTML_OUTPUT_DIR}"
 216         WORKING_DIRECTORY
 217             ${CMAKE_CURRENT_BINARY_DIR}
 218         COMMENT "Building HTML documentation with Sphinx"
 219         VERBATIM
 220         )
 221     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 222
 223     add_custom_target(man
 224         COMMAND
 225             ${SPHINX_EXECUTABLE}
 226             -q -b man
 227             -w sphinx-man.log
 228             -d ${SPHINX_CACHE_DIR}
 229             -t do_man
 230             ${SPHINX_INPUT_DIR}
 231             ${CMAKE_CURRENT_BINARY_DIR}/man
 232         COMMENT "Building man pages with Sphinx"
 233         VERBATIM)
 234     add_dependencies(man sphinx-input sphinx-programs)
 235     if (GMX_BUILD_HELP)
 236         # If requested, install the man pages built by the 'man' target
 237         # created above.  Nothing will be installed if the user did not
 238         # manually build the target.
 239         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 240     endif()
 241 else()
 242     add_custom_target(webpage-sphinx
 243         COMMAND ${CMAKE_COMMAND} -E echo
 244             "HTML pages cannot be built because Sphinx is not available"
 245         VERBATIM)
 246     add_custom_target(install-guide
 247         COMMAND ${CMAKE_COMMAND} -E echo
 248             "INSTALL cannot be built because Sphinx is not available"
 249         VERBATIM)
 250     add_custom_target(man
 251         COMMAND ${CMAKE_COMMAND} -E echo
 252             "man pages cannot be built because Sphinx is not available"
 253         VERBATIM)
 254 endif()
 255
 256 if (MAN_PAGE_DIR)
 257     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 258     # Trailing slash on directory is significant for
 259     # install(DIRECTORY). See CMake docs.
 260     install(DIRECTORY ${MAN_PAGE_DIR}/
 261         DESTINATION ${MAN_INSTALL_DIR}/man1
 262         COMPONENT man OPTIONAL
 263         FILES_MATCHING PATTERN "*.1")
 264 endif()
 265 gmx_cpack_add_generated_source_directory(man)
 266
 267 # Determine whether we can build all the HTML pages and content linked from
 268 # there.  If not, construct an informative message if the user tries to
 269 # build the target; most people never need to know, unless they've asked for
 270 # the webpage build.
 271 set(HTML_BUILD_IS_POSSIBLE ON)
 272 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 273 set(HTML_BUILD_WARNINGS)
 274
 275 # Next, turn it off if any of the preconditions are unsatisified
 276 if (NOT PYTHON_EXECUTABLE)
 277     set(HTML_BUILD_IS_POSSIBLE OFF)
 278     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 279 elseif (NOT SPHINX_FOUND)
 280     # Hardly anything gets built if Sphinx is not available, so don't bother.
 281     set(HTML_BUILD_IS_POSSIBLE OFF)
 282     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx is required")
 283 endif()
 284 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 285     list(APPEND HTML_BUILD_WARNINGS
 286          "Reference PDF manual was not built, so links to it do not work")
 287 endif()
 288 if (NOT DOXYGEN_EXECUTABLE)
 289     list(APPEND HTML_BUILD_WARNINGS
 290         "Doxygen was not available, so links to Doxygen do not work")
 291 endif()
 292 if (NOT DOXYGEN_DOT_EXECUTABLE)
 293     list(APPEND HTML_BUILD_WARNINGS
 294         "dot/graphviz was not found, so some graphs are missing")
 295 endif()
 296
 297 if (HTML_BUILD_IS_POSSIBLE)
 298     set(_webpage_target_properties)
 299     if (HTML_BUILD_WARNINGS)
 300         list(APPEND _webpage_target_properties
 301              COMMAND ${CMAKE_COMMAND} -E echo
 302                  "webpage was built, but with the following limitations:")
 303         foreach(_warning ${HTML_BUILD_WARNINGS})
 304         list(APPEND _webpage_target_properties
 305              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 306         endforeach()
 307     endif()
 308
 309     if (MANUAL_BUILD_IS_POSSIBLE)
 310         # Make the PDF reference guide
 311         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 312         # TODO Make this depend on the output of the manual build, so that the
 313         # file actually gets copied multiple times.
 314         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 315         add_custom_command(
 316             OUTPUT ${_manual_target_location}
 317             COMMAND ${CMAKE_COMMAND}
 318                 -E remove -f ${_manual_target_location}
 319             COMMAND ${CMAKE_COMMAND}
 320                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 321             DEPENDS manual
 322             VERBATIM)
 323         list(APPEND _webpage_target_properties
 324              DEPENDS ${_manual_target_location})
 325     endif()
 326
 327     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 328     # makes all the Doxygen output directly in
 329     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 330     # to).
 331
 332     # Add a top-level target that builds everything related to the webpage,
 333     # for Jenkins (and possibly others) to use
 334     add_custom_target(webpage ${_webpage_target_properties}
 335         COMMENT "Building webpage"
 336         VERBATIM)
 337     add_dependencies(webpage webpage-sphinx doxygen-all)
 338 else()
 339     add_custom_target(webpage
 340         COMMAND ${CMAKE_COMMAND} -E echo
 341             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 342         COMMENT "Webpage build not possible"
 343         VERBATIM)
 344 endif()