docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # Prepare directories for pdf/tex output
  76 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  77 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  78 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  79
  80 # The directory from which man pages will be installed; if it remains
  81 # empty, they will be silently skipped.
  82 set(MAN_PAGE_DIR)
  83 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  84     # When building from the tarball, install the bundled man pages
  85     # (unless overridden).
  86     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  87 endif()
  88
  89 add_subdirectory(doxygen)
  90 if (SPHINX_FOUND)
  91     # We need to have all the Sphinx input files in a single directory, and
  92     # since some of them are generated, we copy everything into the build tree,
  93     # to this directory.
  94     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  95     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  96     # As the manual build now depends also on Sphinx, the inclusion path needs
  97     # to be set after we know the basic information for Sphinx.
  98     add_subdirectory(manual)
  99     if (SOURCE_MD5SUM STREQUAL "unknown")
 100         # But for testing the webpage build (e.g. from the repo) we
 101         # need a default value.
 102         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 103     else()
 104         # The real build of the webpage happens from the tarball, and
 105         # this should be set to the matching MD5 sum.
 106         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 107     endif()
 108     # The reference manual still contains the individual sections from the
 109     # LaTeX document, with the files below grouped and annotated by chapter.
 110     set(REFERENCEMANUAL_SPHINX_FILES_GENERAL
 111         # Main index file, preface and introduction.
 112         reference-manual/index.rst
 113         reference-manual/preface.rst
 114         reference-manual/introduction.rst
 115         # Definitions and Units chapter
 116         reference-manual/definitions.rst
 117         # Topologies chapter
 118         reference-manual/topologies.rst
 119         reference-manual/topologies/particle-type.rst
 120         reference-manual/topologies/parameter-files.rst
 121         reference-manual/topologies/molecule-definition.rst
 122         reference-manual/topologies/constraint-algorithm-section.rst
 123         reference-manual/topologies/pdb2gmx-input-files.rst
 124         reference-manual/topologies/topology-file-formats.rst
 125         reference-manual/topologies/force-field-organization.rst
 126         # File formats chapter
 127         reference-manual/file-formats.rst
 128         # Run parameters and programs chapter
 129         reference-manual/run-parameters.rst
 130         # Implementation details chapter
 131         reference-manual/details.rst
 132         # Averages and fluctations chapter
 133         reference-manual/averages.rst
 134         # References
 135         reference-manual/references.rst
 136         # PNG formated plot files that don't need to be converted into PNG
 137         # for the web page.
 138         reference-manual/plots/peregrine.png
 139         reference-manual/plots/adress.png
 140         reference-manual/plots/plotje.png
 141         reference-manual/plots/xvgr.png
 142         )
 143     set(REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES
 144         # Algorithms chapter
 145         reference-manual/algorithms.rst
 146         reference-manual/algorithms/periodic-boundary-conditions.rst
 147         reference-manual/algorithms/group-concept.rst
 148         reference-manual/algorithms/molecular-dynamics.rst
 149         reference-manual/algorithms/shell-molecular-dynamics.rst
 150         reference-manual/algorithms/constraint-algorithms.rst
 151         reference-manual/algorithms/simulated-annealing.rst
 152         reference-manual/algorithms/stochastic-dynamics.rst
 153         reference-manual/algorithms/brownian-dynamics.rst
 154         reference-manual/algorithms/energy-minimization.rst
 155         reference-manual/algorithms/normal-mode-analysis.rst
 156         reference-manual/algorithms/free-energy-calculations.rst
 157         reference-manual/algorithms/replica-exchange.rst
 158         reference-manual/algorithms/essential-dynamics.rst
 159         reference-manual/algorithms/expanded-ensemble.rst
 160         reference-manual/algorithms/parallelization-domain-decomp.rst
 161         # Interaction functions and force fields chapter
 162         reference-manual/functions.rst
 163         reference-manual/functions/bonded-interactions.rst
 164         reference-manual/functions/force-field.rst
 165         reference-manual/functions/free-energy-interactions.rst
 166         reference-manual/functions/interaction-methods.rst
 167         reference-manual/functions/long-range-electrostatics.rst
 168         reference-manual/functions/long-range-vdw.rst
 169         reference-manual/functions/nonbonded-interactions.rst
 170         reference-manual/functions/polarization.rst
 171         reference-manual/functions/restraints.rst
 172         # Special topics chapter
 173         reference-manual/special.rst
 174         reference-manual/special/free-energy-implementation.rst
 175         reference-manual/special/pulling.rst
 176         reference-manual/special/awh.rst
 177         reference-manual/special/enforced-rotation.rst
 178         reference-manual/special/electric-fields.rst
 179         reference-manual/special/comp-electrophys.rst
 180         reference-manual/special/free-energy-pmf.rst
 181         reference-manual/special/remove-fast-dgf.rst
 182         reference-manual/special/viscosity-calculation.rst
 183         reference-manual/special/tabulated-interaction-functions.rst
 184         reference-manual/special/qmmm.rst
 185         reference-manual/special/vmd-imd.rst
 186         reference-manual/special/membrane-embedding.rst
 187         # Analysis chapter
 188         reference-manual/analysis.rst
 189         reference-manual/analysis/using-groups.rst
 190         reference-manual/analysis/looking-at-trajectory.rst
 191         reference-manual/analysis/general-properties.rst
 192         reference-manual/analysis/radial-distribution-function.rst
 193         reference-manual/analysis/correlation-function.rst
 194         reference-manual/analysis/curve-fitting.rst
 195         reference-manual/analysis/mean-square-displacement.rst
 196         reference-manual/analysis/bond-angle-dihedral.rst
 197         reference-manual/analysis/radius-of-gyration.rst
 198         reference-manual/analysis/rmsd.rst
 199         reference-manual/analysis/covariance-analysis.rst
 200         reference-manual/analysis/dihedral-pca.rst
 201         reference-manual/analysis/protein-related.rst
 202         reference-manual/analysis/interface-related.rst)
 203     # The image files have also been ordered by the respective
 204     # chapter they are included in in the reference manual
 205     set(REFERENCEMANUAL_IMAGE_FILES
 206         # General folder
 207         reference-manual/plots/decomp.pdf
 208         reference-manual/plots/dih.pdf
 209         reference-manual/plots/drift-all.pdf
 210         reference-manual/plots/f-angle.pdf
 211         reference-manual/plots/f-bond.pdf
 212         reference-manual/plots/fp-highres.pdf
 213         reference-manual/plots/int-mat.pdf
 214         reference-manual/plots/mdpar.pdf
 215         reference-manual/plots/parsort.pdf
 216         reference-manual/plots/ring.pdf
 217         reference-manual/plots/shiftf.pdf
 218         # Algorithms chapter
 219         reference-manual/algorithms/plots/dd-cells.pdf
 220         reference-manual/algorithms/plots/dd-tric.pdf
 221         reference-manual/algorithms/plots/flowchart.pdf
 222         reference-manual/algorithms/plots/free1.pdf
 223         reference-manual/algorithms/plots/free2.pdf
 224         reference-manual/algorithms/plots/leapfrog.pdf
 225         reference-manual/algorithms/plots/lincs.pdf
 226         reference-manual/algorithms/plots/maxwell.pdf
 227         reference-manual/algorithms/plots/mpmd-pme.pdf
 228         reference-manual/algorithms/plots/nstric.pdf
 229         reference-manual/algorithms/plots/par-lincs2.pdf
 230         reference-manual/algorithms/plots/pbctric.pdf
 231         reference-manual/algorithms/plots/rhododec.pdf
 232         reference-manual/algorithms/plots/truncoct.pdf
 233         reference-manual/algorithms/plots/verlet-drift.pdf
 234         # Interaction functions chapter
 235         reference-manual/functions/plots/angle.pdf
 236         reference-manual/functions/plots/bstretch.pdf
 237         reference-manual/functions/plots/chain.pdf
 238         reference-manual/functions/plots/dummies.pdf
 239         reference-manual/functions/plots/f-bham.pdf
 240         reference-manual/functions/plots/fbposres.pdf
 241         reference-manual/functions/plots/f-dih.pdf
 242         reference-manual/functions/plots/f-dr.pdf
 243         reference-manual/functions/plots/fig-02.pdf
 244         reference-manual/functions/plots/fig-04.pdf
 245         reference-manual/functions/plots/f-imps.pdf
 246         reference-manual/functions/plots/f-lj.pdf
 247         reference-manual/functions/plots/f-morse.pdf
 248         reference-manual/functions/plots/f-pr.pdf
 249         reference-manual/functions/plots/f-rbs.pdf
 250         reference-manual/functions/plots/ring-imp.pdf
 251         reference-manual/functions/plots/softcore.pdf
 252         reference-manual/functions/plots/subst-im.pdf
 253         reference-manual/functions/plots/tetra-im.pdf
 254         reference-manual/functions/plots/vcrf.pdf
 255         reference-manual/functions/plots/vsite-4fdn.pdf
 256         # Special topics chapter
 257         reference-manual/special/plots/awh-invN.pdf
 258         reference-manual/special/plots/awh-pmfs.pdf
 259         reference-manual/special/plots/awh-sampleweights.pdf
 260         reference-manual/special/plots/awh-traj.pdf
 261         reference-manual/special/plots/compelsetup.pdf
 262         reference-manual/special/plots/dumaro.pdf
 263         reference-manual/special/plots/dumtypes.pdf
 264         reference-manual/special/plots/equipotential.pdf
 265         reference-manual/special/plots/field.pdf
 266         reference-manual/special/plots/gaussians.pdf
 267         reference-manual/special/plots/pulldirrel.pdf
 268         reference-manual/special/plots/pull.pdf
 269         reference-manual/special/plots/pullref.pdf
 270         reference-manual/special/plots/rotation.pdf
 271         # Analysis chapter
 272         reference-manual/analysis/plots/dih-def.pdf
 273         reference-manual/analysis/plots/distm.pdf
 274         reference-manual/analysis/plots/dssp.pdf
 275         reference-manual/analysis/plots/hbond-insert.pdf
 276         reference-manual/analysis/plots/hbond.pdf
 277         reference-manual/analysis/plots/hpr-wheel.pdf
 278         reference-manual/analysis/plots/msdwater.pdf
 279         reference-manual/analysis/plots/ngmxdump.pdf
 280         reference-manual/analysis/plots/phipsi.pdf
 281         reference-manual/analysis/plots/rama.pdf
 282         reference-manual/analysis/plots/rdfO-O.pdf
 283         reference-manual/analysis/plots/rdf.pdf
 284         reference-manual/analysis/plots/sgangle.pdf
 285         )
 286     set(SPHINX_SOURCE_FILES
 287         index.rst
 288         download.rst
 289         conf.py
 290         links.dat
 291         dev-manual/build-system.rst
 292         dev-manual/change-management.rst
 293         dev-manual/commitstyle.rst
 294         dev-manual/documentation-generation.rst
 295         dev-manual/contribute.rst
 296         dev-manual/doxygen.rst
 297         dev-manual/error-handling.rst
 298         dev-manual/formatting.rst
 299         dev-manual/gmxtree.rst
 300         dev-manual/includestyle.rst
 301         dev-manual/index.rst
 302         dev-manual/jenkins.rst
 303         dev-manual/language-features.rst
 304         dev-manual/naming.rst
 305         dev-manual/overview.rst
 306         dev-manual/physical_validation.rst
 307         dev-manual/redmine-states.png
 308         dev-manual/relocatable-binaries.rst
 309         dev-manual/reportstyle.rst
 310         dev-manual/style.rst
 311         dev-manual/testutils.rst
 312         dev-manual/tools.rst
 313         dev-manual/uncrustify.rst
 314         fragments/doxygen-links.rst
 315         how-to/index.rst
 316         how-to/beginners.rst
 317         how-to/topology.rst
 318         how-to/special.rst
 319         how-to/visualize.rst
 320         install-guide/index.rst
 321         release-notes/index.rst
 322         release-notes/2019/major/highlights.rst
 323         release-notes/2019/major/features.rst
 324         release-notes/2019/major/performance.rst
 325         release-notes/2019/major/tools.rst
 326         release-notes/2019/major/bugs-fixed.rst
 327         release-notes/2019/major/removed-functionality.rst
 328         release-notes/2019/major/deprecated-functionality.rst
 329         release-notes/2019/major/portability.rst
 330         release-notes/2019/major/miscellaneous.rst
 331         release-notes/2018/2018.4.rst
 332         release-notes/2018/2018.3.rst
 333         release-notes/2018/2018.2.rst
 334         release-notes/2018/2018.1.rst
 335         release-notes/2018/major/highlights.rst
 336         release-notes/2018/major/features.rst
 337         release-notes/2018/major/performance.rst
 338         release-notes/2018/major/tools.rst
 339         release-notes/2018/major/bugs-fixed.rst
 340         release-notes/2018/major/removed-features.rst
 341         release-notes/2018/major/portability.rst
 342         release-notes/2018/major/miscellaneous.rst
 343         release-notes/2016/2016.5.rst
 344         release-notes/2016/2016.4.rst
 345         release-notes/2016/2016.3.rst
 346         release-notes/2016/2016.2.rst
 347         release-notes/2016/2016.1.rst
 348         release-notes/2016/major/highlights.rst
 349         release-notes/2016/major/new-features.rst
 350         release-notes/2016/major/performance.rst
 351         release-notes/2016/major/tools.rst
 352         release-notes/2016/major/bugs-fixed.rst
 353         release-notes/2016/major/removed-features.rst
 354         release-notes/2016/major/miscellaneous.rst
 355         release-notes/older/index.rst
 356         # the entry for user-guide/index.rst should not appear here,
 357         # as it will be included conditionally further down depending on
 358         # if the documentation will be build with the full reference
 359         # manual or without.
 360         user-guide/cmdline.rst
 361         user-guide/cutoff-schemes.rst
 362         user-guide/deprecation-policy.rst
 363         user-guide/environment-variables.rst
 364         user-guide/faq.rst
 365         user-guide/floating-point.rst
 366         user-guide/flow.rst
 367         user-guide/force-fields.rst
 368         user-guide/getting-started.rst
 369         user-guide/index.rst
 370         user-guide/managing-simulations.rst
 371         user-guide/mdp-options.rst
 372         user-guide/mdrun-features.rst
 373         user-guide/mdrun-performance.rst
 374         user-guide/run-time-errors.rst
 375         user-guide/system-preparation.rst
 376         user-guide/terminology.rst
 377         )
 378
 379     include(SphinxMacros.cmake)
 380     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 381
 382     # set temporary variables for doi inclusion
 383     # into the manual, plain string + some wrapping
 384     # for release builds, and dummy string for non-release
 385     # builds
 386     if("${GMX_MANUAL_DOI}" STREQUAL "")
 387       # empty string means no doi, set dummy text
 388       set(GMX_MANUAL_DOI_STRING "This is not a release build of GROMACS, so please reference")
 389       set(GMX_MANUAL_DOI_STRING "${GMX_MANUAL_DOI_STRING} one of the GROMACS papers and the base release of the manual.")
 390     else()
 391       # release version, set plain old boring string
 392       set(GMX_MANUAL_DOI_STRING "Please reference this documentation as https://doi.org/${GMX_MANUAL_DOI}.")
 393     endif()
 394     # same for source doi, but modify the text
 395     if("${GMX_SOURCE_DOI}" STREQUAL "")
 396       # empty string means no release build
 397       set(GMX_SOURCE_DOI_STRING "This is not a release build of GROMACS. Please reference one of the")
 398       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} GROMACS papers, as well as the base release that this version is built from.")
 399       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} Also, please state what modifcations have been performed or where the version")
 400       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} was sourced from.")
 401     else()
 402       # release version, give them a doi url string
 403       set(GMX_SOURCE_DOI_STRING "To cite the source code for this release, please cite")
 404       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} https://doi.org/${GMX_SOURCE_DOI}.")
 405     endif()
 406
 407     if(IMAGE_CONVERT_POSSIBLE)
 408         set(IMAGE_CONVERT_STRING "possible")
 409     else()
 410         set(IMAGE_CONVERT_STRING "impossible")
 411     endif()
 412
 413     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 414     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 415         EXTRA_VARS
 416             SPHINX_EXTENSION_PATH RELENG_PATH
 417             IMAGE_CONVERT_STRING
 418             EXPECTED_DOXYGEN_VERSION
 419             EXPECTED_SPHINX_VERSION
 420             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 421             REQUIRED_OPENCL_MIN_VERSION
 422             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 423             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 424             GMX_TNG_MINIMUM_REQUIRED_VERSION
 425             GMX_LMFIT_REQUIRED_VERSION
 426             GMX_MANUAL_DOI_STRING
 427             GMX_SOURCE_DOI_STRING
 428         COMMENT "Configuring Sphinx configuration file")
 429     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 430     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 431     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 432         include(${RELENG_PATH}/docs/FileList.cmake)
 433         gmx_add_sphinx_source_files(
 434             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 435             FILES ${RELENG_SPHINX_FILES})
 436     else()
 437         gmx_add_sphinx_source_files(FILES
 438             dev-manual/releng/index.rst
 439             dev-manual/releng/jenkins-howto.rst
 440             dev-manual/releng/jenkins-ui.rst
 441             )
 442     endif()
 443     gmx_add_sphinx_source_files(
 444         FILES
 445         ${REFERENCEMANUAL_SPHINX_FILES_GENERAL})
 446     if (IMAGE_CONVERT_POSSIBLE)
 447         gmx_add_sphinx_source_files(
 448             FILES
 449             ${REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES}
 450             ${REFERENCEMANUAL_IMAGE_FILES})
 451         gmx_add_sphinx_image_conversion_files(
 452             FILES
 453             ${REFERENCEMANUAL_IMAGE_FILES})
 454     endif()
 455     gmx_add_sphinx_input_target(sphinx-input-rst)
 456     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 457     add_custom_target(sphinx-input)
 458     add_dependencies(sphinx-input sphinx-input-rst sphinx-image-conversion)
 459     # Remove other rst files from the build tree, since they confuse Sphinx.
 460     # Skip generated files in onlinehelp/, and fragments.
 461     # The latter do not cause issues with obsolete files, as they
 462     # are not considered as Sphinx input files, but will only be
 463     # included using an explicit .. include::.
 464     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 465
 466     # TODO: Make this remove obsolete .rst files.
 467     # TODO: This does not work in cross-compilation scenarios; disable up to
 468     # the necessary level.
 469     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 470         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 471         COMMAND gmx -quiet help -export rst
 472         DEPENDS gmx
 473         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 474         COMMENT "Generating reStructuredText help")
 475     # This dependency ensures that the directories exist before the
 476     # executable tries to write things there.
 477     add_dependencies(sphinx-programs sphinx-input)
 478
 479     # Make the INSTALL file for CPack for the tarball. This gets put
 480     # into the tarball via the CPack rules below, which requires that
 481     # the INSTALL file is in a separate directory by itself.
 482     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 483     add_custom_target(install-guide
 484         COMMAND
 485             ${SPHINX_EXECUTABLE}
 486             -q -E -b text
 487             -w sphinx-install.log
 488             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 489             -c ${SPHINX_INPUT_DIR}
 490             "${SPHINX_INPUT_DIR}/install-guide"
 491             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 492         COMMAND
 493             ${CMAKE_COMMAND} -E rename
 494             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 495             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 496         WORKING_DIRECTORY
 497             ${CMAKE_CURRENT_BINARY_DIR}
 498         COMMENT "Building INSTALL with Sphinx"
 499         VERBATIM
 500         )
 501     add_dependencies(install-guide sphinx-input)
 502     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 503
 504     # Sphinx cache with pickled ReST documents
 505     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 506     add_custom_target(webpage-sphinx
 507         DEPENDS sphinx-programs
 508         DEPENDS sphinx-input
 509         DEPENDS sphinx-image-conversion
 510         COMMAND
 511             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 512         COMMAND
 513             ${SPHINX_EXECUTABLE}
 514             -q -E -b html
 515             -w sphinx-html.log
 516             -d "${SPHINX_CACHE_DIR}"
 517             "${SPHINX_INPUT_DIR}"
 518             "${HTML_OUTPUT_DIR}"
 519         WORKING_DIRECTORY
 520             ${CMAKE_CURRENT_BINARY_DIR}
 521         COMMENT "Building HTML documentation with Sphinx"
 522         VERBATIM
 523         )
 524
 525     add_custom_target(man
 526         COMMAND
 527             ${SPHINX_EXECUTABLE}
 528             -q -E -b man
 529             -w sphinx-man.log
 530             -d ${SPHINX_CACHE_DIR}
 531             -t do_man
 532             ${SPHINX_INPUT_DIR}
 533             ${CMAKE_CURRENT_BINARY_DIR}/man
 534         COMMENT "Building man pages with Sphinx"
 535         VERBATIM)
 536     add_dependencies(man sphinx-input sphinx-programs)
 537     if (GMX_BUILD_HELP)
 538         # If requested, install the man pages built by the 'man' target
 539         # created above.  Nothing will be installed if the user did not
 540         # manually build the target.
 541         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 542     endif()
 543
 544 else()
 545     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 546     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is not available")
 547
 548     add_custom_target(webpage-sphinx
 549         COMMAND ${CMAKE_COMMAND} -E echo
 550             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 551         VERBATIM)
 552     add_custom_target(install-guide
 553         COMMAND ${CMAKE_COMMAND} -E echo
 554             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 555         VERBATIM)
 556     add_custom_target(man
 557         COMMAND ${CMAKE_COMMAND} -E echo
 558             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 559         VERBATIM)
 560     add_custom_target(sphinx-create-texman
 561         COMMAND ${CMAKE_COMMAND} -E echo
 562             "Cannot prepare LaTeX input files because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 563         VERBATIM)
 564 endif()
 565
 566 if (MAN_PAGE_DIR)
 567     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 568     # Trailing slash on directory is significant for
 569     # install(DIRECTORY). See CMake docs.
 570     install(DIRECTORY ${MAN_PAGE_DIR}/
 571         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 572         COMPONENT man OPTIONAL
 573         FILES_MATCHING PATTERN "*.1")
 574 endif()
 575 gmx_cpack_add_generated_source_directory(man)
 576
 577 # Determine whether we can build all the HTML pages and content linked from
 578 # there.  If not, construct an informative message if the user tries to
 579 # build the target; most people never need to know, unless they've asked for
 580 # the webpage build.
 581 set(HTML_BUILD_IS_POSSIBLE ON)
 582 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 583 set(HTML_BUILD_WARNINGS)
 584
 585 # Next, turn it off if any of the preconditions are unsatisified
 586 if (NOT PYTHON_EXECUTABLE)
 587     set(HTML_BUILD_IS_POSSIBLE OFF)
 588     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 589 elseif (NOT SPHINX_FOUND)
 590     # Hardly anything gets built if Sphinx is not available, so don't bother.
 591     set(HTML_BUILD_IS_POSSIBLE OFF)
 592     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 593 endif()
 594 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 595     list(APPEND HTML_BUILD_WARNINGS
 596          "Reference PDF manual was not built, so links to it do not work")
 597 endif()
 598 if (NOT DOXYGEN_EXECUTABLE)
 599     list(APPEND HTML_BUILD_WARNINGS
 600         "Doxygen was not available, so links to Doxygen do not work")
 601 endif()
 602 if (NOT DOXYGEN_DOT_EXECUTABLE)
 603     list(APPEND HTML_BUILD_WARNINGS
 604         "dot/graphviz was not found, so some graphs are missing")
 605 endif()
 606
 607 if (HTML_BUILD_IS_POSSIBLE)
 608     set(_webpage_target_properties)
 609     if (HTML_BUILD_WARNINGS)
 610         list(APPEND _webpage_target_properties
 611              COMMAND ${CMAKE_COMMAND} -E echo
 612                  "webpage was built, but with the following limitations:")
 613         foreach(_warning ${HTML_BUILD_WARNINGS})
 614         list(APPEND _webpage_target_properties
 615              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 616         endforeach()
 617     endif()
 618
 619     if (MANUAL_BUILD_IS_POSSIBLE)
 620         # Make the PDF reference guide
 621         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 622         # TODO Make this depend on the output of the manual build, so that the
 623         # file actually gets copied multiple times.
 624         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 625         add_custom_command(
 626             OUTPUT ${_manual_target_location}
 627             COMMAND ${CMAKE_COMMAND}
 628                 -E remove -f ${_manual_target_location}
 629             COMMAND ${CMAKE_COMMAND}
 630                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 631             DEPENDS manual
 632             VERBATIM)
 633         list(APPEND _webpage_target_properties
 634              DEPENDS ${_manual_target_location})
 635     endif()
 636
 637     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 638     # makes all the Doxygen output directly in
 639     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 640     # to).
 641
 642     # Add a top-level target that builds everything related to the webpage,
 643     # for Jenkins (and possibly others) to use
 644     add_custom_target(webpage ${_webpage_target_properties}
 645         COMMENT "Building webpage"
 646         VERBATIM)
 647     add_dependencies(webpage webpage-sphinx doxygen-all)
 648 else()
 649     add_custom_target(webpage
 650         COMMAND ${CMAKE_COMMAND} -E echo
 651             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 652         COMMENT "Webpage build not possible"
 653         VERBATIM)
 654 endif()