2 # This file is part of the GROMACS molecular simulation package.
4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
6 # Copyright (c) 2019,2020, by the GROMACS development team, led by
7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
8 # and including many others, as listed in the AUTHORS file in the
9 # top-level source directory and at http://www.gromacs.org.
11 # GROMACS is free software; you can redistribute it and/or
12 # modify it under the terms of the GNU Lesser General Public License
13 # as published by the Free Software Foundation; either version 2.1
14 # of the License, or (at your option) any later version.
16 # GROMACS is distributed in the hope that it will be useful,
17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
19 # Lesser General Public License for more details.
21 # You should have received a copy of the GNU Lesser General Public
22 # License along with GROMACS; if not, see
23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
26 # If you want to redistribute modifications to GROMACS, please
27 # consider that scientific software is very special. Version
28 # control is crucial - bugs must be traceable. We will be happy to
29 # consider code for inclusion in the official distribution, but
30 # derived work must not be called official GROMACS. Details are found
31 # in the README & COPYING files - if they are missing, get the
32 # official version at http://www.gromacs.org.
34 # To help us fund GROMACS development, we humbly ask that you cite
35 # the research papers on the package. Check out http://www.gromacs.org.
37 cmake_minimum_required(VERSION 3.13)
38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
41 # CMake modules/macros are in a subdirectory to keep this file cleaner
42 # This needs to be set before project() in order to pick up toolchain files
43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
46 # Providing a default value >=10.14 helps to find modern C++ compatibility,
47 # such as by defaulting to the Clang libc++ instead of libstdc++.
48 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
49 "OS X deployment target affects default SDK version and compiler flags."
51 # By default, limit the binary architecture to a single 64-bit build.
52 set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
53 "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
59 set(CMAKE_CXX_STANDARD 17)
60 set(CMAKE_CXX_STANDARD_REQUIRED ON)
61 set(CMAKE_CXX_EXTENSIONS OFF)
63 include(gmxManageCcache)
65 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
66 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
67 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
69 find_package(LibStdCpp)
71 # Python is first referenced in gmxVersionInfo, so we perform the search early
72 # to find a suitable installation for all components.
73 include(gmxPythonDiscovery)
74 # Set up common version variables, as well as general information about
75 # the build tree (whether the build is from a source package or from a git
76 # repository). Also declares a few functions that will be used for generating
77 # version info files later.
78 include(gmxBuildTreeInfo)
79 include(gmxVersionInfo)
81 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
82 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
84 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
85 message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
88 include(gmxBuildTypeReference)
89 include(gmxBuildTypeProfile)
90 include(gmxBuildTypeTSAN)
91 include(gmxBuildTypeASAN)
92 include(gmxBuildTypeMSAN)
93 include(gmxBuildTypeReleaseWithAssert)
95 if(NOT CMAKE_BUILD_TYPE)
96 set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
97 # Set the possible values of build type for cmake-gui
98 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
99 "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
101 if(CMAKE_CONFIGURATION_TYPES)
102 # Add appropriate GROMACS-specific build types for the Visual
103 # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
104 # are already present by default).
105 list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
106 list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
107 set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
108 "List of configuration types"
111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
115 include(gmxCTestUtilities)
118 include(gmxCPackUtilities)
121 # Variables that accumulate stuff influencing the installed headers
122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
123 set(INSTALLED_HEADER_DEFINITIONS "")
125 ########################################################################
126 # Global non-cache variables for implementing the build system
127 ########################################################################
129 # These variables collect libraries that GROMACS requires for
130 # linking. They should be appended to with list(APPEND ${name}
131 # new-library) calls. They are:
132 # - Libraries that are required for libgromacs (only)
133 set(GMX_EXTRA_LIBRARIES "")
134 # - Libraries that are required for all code in the repository
135 set(GMX_COMMON_LIBRARIES "")
136 # - Libraries that all code linked against libgromacs needs
137 # (i.e., something that is exposed in installed headers).
138 set(GMX_PUBLIC_LIBRARIES "")
140 ########################################################################
141 # Check and warn if cache generated on a different host is being reused
142 ########################################################################
144 execute_process(COMMAND hostname
145 OUTPUT_VARIABLE TMP_HOSTNAME
146 OUTPUT_STRIP_TRAILING_WHITESPACE)
147 # Only check for host name if not running in a CI environment, as the cache might
148 # be reused there between different machines in different stages
149 if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
150 AND NOT DEFINED ENV{CI_JOB_ID})
152 The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
153 is being reused! This could lead to inconsistencies; therefore, it is
154 recommended to regenerate the cache!")
156 set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
157 "Hostname of the machine where the cache was generated.")
160 ########################################################################
161 # Detect architecture before setting options so we can alter defaults
162 ########################################################################
163 # Detect the architecture the compiler is targetting, detect
164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
165 # to use if none is specified, and populate the cache option for CPU
167 include(gmxDetectTargetArchitecture)
168 gmx_detect_target_architecture()
170 ########################################################################
171 # User input options #
172 ########################################################################
173 include(gmxOptionUtilities)
175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
177 # Fujitsu only has SIMD in double precision, so this will be faster
178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
183 option(GMX_MPI "Build a parallel (message-passing) version of GROMACS" OFF)
184 option(GMX_THREAD_MPI "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
185 gmx_dependent_option(
187 "Enable MPI_IN_PLACE for MPIs that have it defined"
190 mark_as_advanced(GMX_MPI_IN_PLACE)
192 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
194 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
195 mark_as_advanced(GMX_FAHCORE)
197 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
198 mark_as_advanced(GMX_COOL_QUOTES)
199 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
201 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
203 gmx_option_multichoice(
205 "Framework for GPU acceleration"
209 gmx_option_multichoice(
211 "SIMD instruction set for CPU kernels and compiler optimization"
213 AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
216 set(GMX_FFT_LIBRARY_DEFAULT "mkl")
218 set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
221 gmx_option_multichoice(
224 "${GMX_FFT_LIBRARY_DEFAULT}"
225 fftw3 mkl "fftpack[built-in]")
226 gmx_dependent_option(
228 "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
230 "GMX_FFT_LIBRARY STREQUAL FFTW3")
231 gmx_dependent_option(
232 GMX_DISABLE_FFTW_MEASURE
233 "Do not optimize FFTW setups (not needed with SSE)"
235 "GMX_FFT_LIBRARY STREQUAL FFTW3")
236 mark_as_advanced(GMX_BUILD_OWN_FFTW)
237 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
239 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
240 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
242 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
244 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
245 mark_as_advanced(GMX_BROKEN_CALLOC)
247 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
249 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
251 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
253 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
254 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
256 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
257 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
259 option(GMX_BUILD_FOR_COVERAGE
260 "Tune build for better code coverage metrics (e.g., disable asserts)"
262 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
264 option(GMX_DEVELOPER_BUILD
265 "Enable Developer convenience features: always build unit-tests"
267 mark_as_advanced(GMX_DEVELOPER_BUILD)
269 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
270 option(GMX_COMPILER_WARNINGS
271 "Enable a default set of compiler warnings"
272 ${GMX_COMPILER_WARNINGS_DEFAULT})
273 mark_as_advanced(GMX_COMPILER_WARNINGS)
274 # Always turn on compiler warnings with a developer build.
275 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
277 option(GMX_BUILD_SHARED_EXE
278 "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
280 mark_as_advanced(GMX_BUILD_SHARED_EXE)
282 option(GMX_PHYSICAL_VALIDATION
283 "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
284 'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
286 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
288 ######################################################################
289 # Detect OpenMP support
290 ######################################################################
291 # The OpenMP detection _must_ come before tests for other CFLAGS.
292 include(gmxManageOpenMP)
296 ######################################################################
298 # These need to be done early (before further tests).
299 #####################################################################
304 # These variables should be used for CMake-style lists (ie. separated
305 # by semicolons) of additional compiler flags which are not generated
306 # in gmxCFlags nor are SIMD or MPI related.
308 # TODO These variables should be consolidated into
309 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
310 # things that work in C compilation (e.g. merging from old branches)
311 # might not also work for C++ compilation.
312 set(EXTRA_C_FLAGS "")
313 set(EXTRA_CXX_FLAGS "")
315 # Run through a number of tests for buggy compilers and other issues
316 include(gmxTestCompilerProblems)
317 gmx_test_compiler_problems()
319 # Implement double-precision option. This is complicated because we
320 # need installed headers to use the precision mode of the build that
321 # produced the library, but cannot use config.h in that case. We also
322 # want such variables to always have a definition, because #if is more
323 # robust than #ifdef. So, we put this value on the compiler command
326 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
327 # because no installed header needs it
329 set(GMX_DOUBLE_VALUE 1)
331 set(GMX_DOUBLE_VALUE 0)
333 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
334 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
336 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
337 if(GMX_IMD AND WIN32)
338 list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
343 ########################################################################
344 # Basic system tests (standard libraries, headers, functions, types) #
345 ########################################################################
346 include(CheckIncludeFiles)
347 include(CheckIncludeFileCXX)
348 check_include_files(unistd.h HAVE_UNISTD_H)
349 check_include_files(pwd.h HAVE_PWD_H)
350 check_include_files(dirent.h HAVE_DIRENT_H)
351 check_include_files(time.h HAVE_TIME_H)
352 check_include_files(sys/time.h HAVE_SYS_TIME_H)
353 check_include_files(io.h HAVE_IO_H)
354 check_include_files(sched.h HAVE_SCHED_H)
355 check_include_files(xmmintrin.h HAVE_XMMINTRIN_H)
357 include(CheckCXXSymbolExists)
358 check_cxx_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
359 check_cxx_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
360 check_cxx_symbol_exists(nice unistd.h HAVE_NICE)
361 check_cxx_symbol_exists(fsync unistd.h HAVE_FSYNC)
362 check_cxx_symbol_exists(_fileno stdio.h HAVE__FILENO)
363 check_cxx_symbol_exists(fileno stdio.h HAVE_FILENO)
364 check_cxx_symbol_exists(_commit io.h HAVE__COMMIT)
365 check_cxx_symbol_exists(sigaction signal.h HAVE_SIGACTION)
367 # We cannot check for the __builtins as symbols, but check if code compiles
368 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}" HAVE_BUILTIN_CLZ)
369 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
371 check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
372 check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
373 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
374 check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
375 check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
378 include(CheckLibraryExists)
379 find_library(HAVE_LIBM m)
380 mark_as_advanced(HAVE_LIBM)
381 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
382 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
383 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
385 include(TestSchedAffinity)
386 test_sched_affinity(HAVE_SCHED_AFFINITY)
388 # Aligned memory allocation. We need to check for both mm_malloc(),
389 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
390 include(gmxTestMMMalloc)
391 gmx_test_mm_malloc(HAVE__MM_MALLOC)
392 check_cxx_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
393 check_cxx_symbol_exists(memalign stdlib.h HAVE_MEMALIGN)
395 # No need to waste time on this test on platforms where it will never be true
396 check_cxx_symbol_exists(_aligned_malloc stdlib.h HAVE__ALIGNED_MALLOC)
399 include(TestBigEndian)
400 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
402 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
404 # Management of GROMACS options for specific toolchains should go
405 # here. Because the initial settings for some of the main options have
406 # already happened, but things like library detection and MPI compiler
407 # feature detection have not, the docstrings for any over-rides of
408 # GROMACS defaults or user settings will make sense. Also, any
409 # toolchain-related reasons for choosing whether to detect various
410 # things can be sorted out now, before the detection takes place.
411 if(GMX_TARGET_FUJITSU_SPARC64)
412 include(gmxManageFujitsuSparc64)
415 ########################################################################
416 #Process MPI settings
417 ########################################################################
418 include(gmxManageMPI)
420 ########################################################################
421 #Process MiMiC settings
422 ########################################################################
423 include(gmxManageMimic)
425 ########################################################################
426 #Process shared/static library settings
427 ########################################################################
428 include(gmxManageSharedLibraries)
431 ########################################################################
432 # Specify install locations
433 ########################################################################
434 # Use GNUInstallDirs to set paths on multiarch systems.
435 include(GNUInstallDirs)
437 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
438 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
440 # Internal convenience so we do not have to join two path segments in the code
441 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
443 # If the nesting level wrt. the installation root is changed,
444 # gromacs-config.cmake.cmakein needs to be adapted.
445 set(GMX_INSTALL_CMAKEDIR ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
447 # TODO: Make GMXRC adapt if this is changed
448 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
450 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
452 # Binary and library suffix options
453 include(gmxManageSuffixes)
456 ########################################################################
457 # Find external packages #
458 ########################################################################
460 # Unconditionally find the package, as it is also required for unit
461 # tests. This exports LIBXML2_FOUND, which we should not use because
462 # it does not tell us that linking will succeed. Instead, we test that
464 #if(DEFINED LIBXML2_LIBRARIES)
465 # set(LibXml2_FIND_QUIETLY TRUE)
467 #find_package(LibXml2)
468 #include(gmxTestLibXml2)
469 #gmx_test_libxml2(HAVE_LIBXML2)
470 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
472 #mark_as_advanced(GMX_XML)
473 # Don't actually do anything, since libxml2 is currently not used by libgromacs
474 #if(GMX_XML AND NOT HAVE_LIBXML2)
475 # message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
478 # include_directories(${LIBXML2_INCLUDE_DIR})
479 # set(PKG_XML libxml-2.0)
480 # set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
483 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
486 # Find quietly the second time.
487 if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
488 set(HWLOC_FIND_QUIETLY TRUE)
490 find_package(HWLOC 1.5)
493 if (HWLOC_LIBRARIES MATCHES ".a$")
494 set(_STATIC_HWLOC TRUE)
497 gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
498 if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
499 message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
500 set(GMX_USE_HWLOC OFF)
502 set(GMX_USE_HWLOC ON)
506 include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
507 list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
509 elseif(GMX_HWLOC_FORCE)
510 message(FATAL_ERROR "HWLOC package support required, but not found.")
513 set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
516 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
517 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
518 if(GMX_EXTERNAL_TINYXML2)
519 # Find an external TinyXML-2 library.
520 find_package(TinyXML-2 3.0.0)
521 set(HAVE_TINYXML2 ${TinyXML2_FOUND})
522 if(NOT HAVE_TINYXML2)
523 message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
527 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
528 mark_as_advanced(GMX_EXTRAE)
533 include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
536 message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
540 option(GMX_X11 "Use X window system" OFF)
543 # X11 includes/libraries are only set in the ngmx subdirectory!
546 "X11 include files and/or libraries were not found. "
547 "Set GMX_X11=OFF to compile without X11 support. "
548 "gmx view will not be available.")
550 include_directories(SYSTEM ${X11_INCLUDE_DIR})
554 # Enable core threading facilities
555 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
557 # enable MPI functions
559 set(MPI_IN_PLACE_EXISTS 1)
561 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
562 if (TMPI_ATOMICS_DISABLED)
563 add_definitions(-DTMPI_ATOMICS_DISABLED)
566 include(gmxManageTNG)
568 include(gmxManageLmfit)
570 string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
571 if(NOT ${_gmx_gpu_uppercase} STREQUAL "NONE")
573 if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
574 include(gmxManageCuda)
575 elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
576 include(gmxManageOpenCL)
579 message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
584 # Not ideal to set this without the GPU acceleration, but the source presently requires GMX_GPU
585 # to be set to GMX_GPU_None for a non-GPU build to work.
586 set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_${_gmx_gpu_uppercase}")
593 set(GMX_NATIVE_WINDOWS 1)
594 # This makes windows.h not declare min/max as macros that would break
595 # C++ code using std::min/std::max.
596 add_definitions(-DNOMINMAX)
599 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
600 mark_as_advanced(GMX_BUILD_UNITTESTS)
601 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
603 ########################################################################
604 # Our own GROMACS tests
605 ########################################################################
607 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
608 # Required for config.h, maybe should only be set in src/CMakeLists.txt
609 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
611 include(gmxTestInlineASM)
612 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
614 include(gmxSetBuildInformation)
615 gmx_set_build_information()
617 # Anything but truly ancient hardware should support rdtscp, so we enable it by default
618 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)" ON)
619 mark_as_advanced(GMX_USE_RDTSCP)
621 include(gmxTestLargeFiles)
622 gmx_test_large_files(GMX_LARGEFILES)
624 include(gmxTestSignal)
625 gmx_test_sigusr1(HAVE_SIGUSR1)
627 include(gmxTestPipes)
628 gmx_test_pipes(HAVE_PIPES)
631 gmx_test_xdr(GMX_SYSTEM_XDR)
632 # Darwin has system XDR, but it uses a three-argument flavour of
633 # xdrproc_t that it guarantees will still work if you pass the normal
634 # two-argument xdr filters, but gcc 8 warns about the cast necessary
635 # to do that, so it's simpler to just use our own XDR library.
637 # TODO It would be better to craft a cmake test which fails if such
638 # XDR operations cause warnings, and succeeds otherwise, because it is
639 # generally preferable to use system libraries where possible.
640 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
641 set(GMX_INTERNAL_XDR 1)
645 ##################################################
646 # Process SIMD instruction settings
647 ##################################################
648 # This checks what flags to add in order to
649 # support the SIMD instructions we need, it sets
650 # correct defines for the SIMD instructions supported,
651 # and adds advanced options to control accuracy
652 # for SIMD math operations.
653 include(gmxManageSimd)
656 ##################################################
657 # Process FFT library settings
658 ##################################################
659 include(gmxManageFFTLibraries)
662 include(gmxManageLinearAlgebraLibraries)
664 include(gmxManagePluginSupport)
665 gmx_manage_plugin_support()
668 if(NOT GMX_VMD_PLUGIN_PATH)
673 # Link real-time library for POSIX timers. The check for clock_gettime
674 # confirms the linkability of rt.
675 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
676 list(APPEND GMX_EXTRA_LIBRARIES rt)
679 # Math and thread libraries must often come after all others when linking...
681 list(APPEND GMX_PUBLIC_LIBRARIES m)
684 option(GMX_NACL "Configure for Native Client builds" OFF)
686 list(APPEND GMX_EXTRA_LIBRARIES nosys)
687 set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
688 # TODO: Is this still necessary with the check for its presence?
692 mark_as_advanced(GMX_NACL)
695 set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
696 "Path to swindirect.h")
697 include_directories(${COREWRAP_INCLUDE_DIR})
700 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
701 mark_as_advanced(GMX_BUILD_HELP)
702 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
704 "Rebuilding shell completions or man pages is not supported for "
705 "in-source builds from a source distribution. "
706 "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
709 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
710 # these are set after everything else
711 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
712 set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
713 set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
715 message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
716 message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
717 foreach(build_type ${build_types_with_explicit_flags})
718 message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
720 message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
721 foreach(build_type ${build_types_with_explicit_flags})
722 message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
724 message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
725 message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
727 # Allow `admin` directory to be easily conveyed to nested CMake commands.
728 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
730 ################################################################
731 # Shared library load path settings
732 ################################################################
733 if(NOT GMX_BUILD_SHARED_EXE)
735 set(CMAKE_SKIP_RPATH TRUE)
736 set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
737 set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
739 # The build folder always has bin/ and lib/; if we are also going to
740 # install to lib/, then the installation RPATH works also in the build
741 # tree. This makes installation slightly faster (no need to rewrite the
742 # RPATHs), and makes the binaries in the build tree relocatable.
743 if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
744 set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
745 set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
747 # Set the RPATH as relative to the executable location to make the
748 # binaries relocatable.
749 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
750 set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
751 set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
753 set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
755 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
756 set(CMAKE_MACOSX_RPATH 1)
759 #COPYING file: Only necessary for binary distributions.
760 #Simpler to always install.
761 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
763 if (GMX_BUILD_FOR_COVERAGE)
764 # Code heavy with asserts makes conditional coverage close to useless metric,
765 # as by design most of the false branches are impossible to trigger in
766 # correctly functioning code. And the benefit of testing those that could
767 # be triggered by using an API against its specification isn't usually
769 add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
773 include(tests/CheckTarget.cmake)
776 # TODO: Determine control flow and defaults for package installation and testing use cases.
777 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
778 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
779 mark_as_advanced(GMX_PYTHON_PACKAGE)
781 if (NOT GMX_BUILD_MDRUN_ONLY)
782 find_package(ImageMagick QUIET COMPONENTS convert)
783 include(gmxTestImageMagick)
784 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
785 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
786 add_subdirectory(docs)
787 add_subdirectory(share)
788 add_subdirectory(scripts)
790 add_subdirectory(src)
793 add_subdirectory(tests)
796 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
797 add_subdirectory(python_packaging)
800 gmx_cpack_write_config()
802 #######################
804 #######################
805 CONFIGURE_FILE( "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
806 "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
808 ###########################
809 ADD_CUSTOM_TARGET(uninstall
810 "${CMAKE_COMMAND}" -P
811 "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
812 ###########################
813 set_directory_properties(PROPERTIES
814 ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")